qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void nb_init();
  75 void entcs_init();
  76
  77 void LogTeamchange(float player_id, float team_number, float type)
  78 {
  79         if(!autocvar_sv_eventlog)
  80                 return;
  81
  82         if(player_id < 1)
  83                 return;
  84
  85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  86 }
  87
  88 void WriteGameCvars()
  89 {
  90         cvar_set("g_dm", ftos(g_dm));
  91         cvar_set("g_tdm", ftos(g_tdm));
  92         cvar_set("g_domination", ftos(g_domination));
  93         cvar_set("g_ctf", ftos(g_ctf));
  94         cvar_set("g_runematch", ftos(g_runematch));
  95         cvar_set("g_lms", ftos(g_lms));
  96         cvar_set("g_arena", ftos(g_arena));
  97         cvar_set("g_ca", ftos(g_ca));
  98         cvar_set("g_keyhunt", ftos(g_keyhunt));
  99         cvar_set("g_assault", ftos(g_assault));
 100         cvar_set("g_onslaught", ftos(g_onslaught));
 101         cvar_set("g_race", ftos(g_race));
 102         cvar_set("g_nexball", ftos(g_nexball));
 103         cvar_set("g_cts", ftos(g_cts));
 104         cvar_set("g_freezetag", ftos(g_freezetag));
 105         cvar_set("g_keepaway", ftos(g_keepaway));
 106 }
 107
 108 void ReadGameCvars()
 109 {
 110         float found;
 111         float prev;
 112         float i;
 113
 114         found = 0;
 115         prev = autocvar_gamecfg;
 116         for(i = 0; i < 2; ++i)
 117         {
 118 //#NO AUTOCVARS START
 119                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 120                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 121                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 122                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 123                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 124                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 125                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 126                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 127                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 128                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 129                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 130                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 131                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 132                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 133                 found += (g_freezetag = (!found && (prev != GAME_FREEZETAG) && cvar("g_freezetag")));
 134                 found += (g_keepaway = (!found && (prev != GAME_KEEPAWAY) && cvar("g_keepaway")));
 135 //#NO AUTOCVARS END
 136
 137                 if(found)
 138                         break;
 139
 140                 prev = -1; // second attempt takes place WITHOUT prev set
 141         }
 142
 143         if(!found)
 144                 g_dm = 1;
 145
 146         if(g_dm && autocvar_deathmatch_force_teamplay)
 147         {
 148                 g_dm = 0;
 149                 g_tdm = 1;
 150         }
 151
 152         teams_matter = 0;
 153 }
 154
 155 void default_delayedinit()
 156 {
 157         if(!scores_initialized)
 158                 ScoreRules_generic();
 159 }
 160
 161 void ActivateTeamplay()
 162 {
 163         serverflags |= SERVERFLAG_TEAMPLAY;
 164         teams_matter = 1;
 165 }
 166
 167 void InitGameplayMode()
 168 {
 169         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 170
 171         qualifying_override = -1;
 172
 173         VoteReset();
 174
 175         teams_matter = 0;
 176
 177         // make sure only ONE type is selected
 178         ReadGameCvars();
 179         WriteGameCvars();
 180
 181         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 182         get_mi_min_max(1);
 183         world.mins = mi_min;
 184         world.maxs = mi_max;
 185
 186         MapInfo_LoadMapSettings(mapname);
 187
 188         if not(cvar_value_issafe(world.fog))
 189         {
 190                 print("The current map contains a potentially harmful fog setting, ignored\n");
 191                 world.fog = string_null;
 192         }
 193         if(MapInfo_Map_fog != "")
 194                 if(MapInfo_Map_fog == "none")
 195                         world.fog = string_null;
 196                 else
 197                         world.fog = strzone(MapInfo_Map_fog);
 198         clientstuff = strzone(MapInfo_Map_clientstuff);
 199
 200         MapInfo_ClearTemps();
 201
 202         // in case mapinfo switched the type
 203         ReadGameCvars();
 204
 205         // set both here, gamemode can override it later
 206         timelimit_override = autocvar_timelimit_override;
 207         fraglimit_override = autocvar_fraglimit_override;
 208         leadlimit_override = autocvar_leadlimit_override;
 209
 210         if(g_dm)
 211         {
 212                 game = GAME_DEATHMATCH;
 213                 gamemode_name = "Deathmatch";
 214         }
 215
 216         if(g_tdm)
 217         {
 218                 game = GAME_TEAM_DEATHMATCH;
 219                 gamemode_name = "Team Deathmatch";
 220                 ActivateTeamplay();
 221                 tdm_init();
 222                 if(autocvar_g_tdm_team_spawns)
 223                         have_team_spawns = -1; // request team spawns
 224         }
 225
 226         if(g_domination)
 227         {
 228                 game = GAME_DOMINATION;
 229                 gamemode_name = "Domination";
 230                 ActivateTeamplay();
 231                 fraglimit_override = autocvar_g_domination_point_limit;
 232                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 233                 dom_init();
 234                 have_team_spawns = -1; // request team spawns
 235         }
 236
 237         if(g_ctf)
 238         {
 239                 game = GAME_CTF;
 240                 gamemode_name = "Capture the Flag";
 241                 ActivateTeamplay();
 242                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
 243                 if(autocvar_g_ctf_win_mode == 2)
 244                 {
 245                         fraglimit_override = autocvar_g_ctf_capture_limit;
 246                         leadlimit_override = autocvar_g_ctf_capture_leadlimit;
 247                 }
 248                 else
 249                 {
 250                         fraglimit_override = autocvar_capturelimit_override;
 251                         leadlimit_override = autocvar_captureleadlimit_override;
 252                 }
 253                 ctf_init();
 254                 have_team_spawns = -1; // request team spawns
 255         }
 256
 257         if(g_runematch)
 258         {
 259                 game = GAME_RUNEMATCH;
 260                 gamemode_name = "Rune Match";
 261                 if(autocvar_deathmatch_force_teamplay)
 262                         ActivateTeamplay();
 263                 fraglimit_override = autocvar_g_runematch_point_limit;
 264                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 265                 runematch_init();
 266         }
 267
 268         if(g_lms)
 269         {
 270                 game = GAME_LMS;
 271                 gamemode_name = "Last Man Standing";
 272                 fraglimit_override = autocvar_g_lms_lives_override;
 273                 leadlimit_override = 0; // not supported by LMS
 274                 if(fraglimit_override == 0)
 275                         fraglimit_override = -1;
 276                 lms_lowest_lives = 9999;
 277                 lms_next_place = 0;
 278                 ScoreRules_lms();
 279         }
 280
 281         if(g_arena)
 282         {
 283                 game = GAME_ARENA;
 284                 gamemode_name = "Arena";
 285                 fraglimit_override = autocvar_g_arena_point_limit;
 286                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 287                 maxspawned = autocvar_g_arena_maxspawned;
 288                 if(maxspawned < 2)
 289                         maxspawned = 2;
 290                 arena_roundbased = autocvar_g_arena_roundbased;
 291         }
 292
 293         if(g_ca)
 294         {
 295                 game = GAME_CA;
 296                 gamemode_name = "Clan Arena";
 297                 ActivateTeamplay();
 298                 fraglimit_override = autocvar_g_ca_point_limit;
 299                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 300                 precache_sound("ctf/red_capture.wav");
 301                 precache_sound("ctf/blue_capture.wav");
 302         }
 303         if(g_keyhunt)
 304         {
 305                 game = GAME_KEYHUNT;
 306                 gamemode_name = "Key Hunt";
 307                 ActivateTeamplay();
 308                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 309                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 310                 MUTATOR_ADD(gamemode_keyhunt);
 311         }
 312
 313         if(g_freezetag)
 314         {
 315                 game = GAME_FREEZETAG;
 316                 gamemode_name = "Freeze Tag";
 317                 ActivateTeamplay();
 318                 fraglimit_override = autocvar_g_freezetag_point_limit;
 319                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 320                 MUTATOR_ADD(gamemode_freezetag);
 321         }
 322
 323         if(g_assault)
 324         {
 325                 game = GAME_ASSAULT;
 326                 gamemode_name = "Assault";
 327                 ActivateTeamplay();
 328                 ScoreRules_assault();
 329                 have_team_spawns = -1; // request team spawns
 330         }
 331
 332         if(g_onslaught)
 333         {
 334                 game = GAME_ONSLAUGHT;
 335                 gamemode_name = "Onslaught";
 336                 ActivateTeamplay();
 337                 have_team_spawns = -1; // request team spawns
 338         }
 339
 340         if(g_race)
 341         {
 342                 game = GAME_RACE;
 343                 gamemode_name = "Race";
 344
 345                 if(autocvar_g_race_teams)
 346                 {
 347                         ActivateTeamplay();
 348                         race_teams = bound(2, autocvar_g_race_teams, 4);
 349                         have_team_spawns = -1; // request team spawns
 350                 }
 351                 else
 352                         race_teams = 0;
 353
 354                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 355                 fraglimit_override = autocvar_g_race_laps_limit;
 356                 leadlimit_override = 0; // currently not supported by race
 357         }
 358
 359         if(g_cts)
 360         {
 361                 game = GAME_CTS;
 362                 gamemode_name = "CTS";
 363                 g_race_qualifying = 1;
 364                 fraglimit_override = 0;
 365                 leadlimit_override = 0;
 366         }
 367
 368         if(g_nexball)
 369         {
 370                 game = GAME_NEXBALL;
 371                 gamemode_name = "Nexball";
 372                 fraglimit_override = autocvar_g_nexball_goallimit;
 373                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 374                 ActivateTeamplay();
 375                 nb_init();
 376                 have_team_spawns = -1; // request team spawns
 377         }
 378
 379         if(g_keepaway)
 380         {
 381                 game = GAME_KEEPAWAY;
 382                 gamemode_name = "Keepaway";
 383                 MUTATOR_ADD(gamemode_keepaway);
 384         }
 385
 386         if(teams_matter)
 387                 entcs_init();
 388
 389         // save it (for the next startup)
 390         cvar_set("gamecfg", ftos(game));
 391
 392         cache_mutatormsg = strzone("");
 393         cache_lastmutatormsg = strzone("");
 394
 395         // enforce the server's universal frag/time limits
 396         if(!autocvar_g_campaign)
 397         {
 398                 if(fraglimit_override >= 0)
 399                         cvar_set("fraglimit", ftos(fraglimit_override));
 400                 if(timelimit_override >= 0)
 401                         cvar_set("timelimit", ftos(timelimit_override));
 402                 if(leadlimit_override >= 0)
 403                         cvar_set("leadlimit", ftos(leadlimit_override));
 404                 if(qualifying_override >= 0)
 405                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 406         }
 407
 408         if(g_race)
 409         {
 410                 // we need to find out the correct value for g_race_qualifying
 411                 if(autocvar_g_campaign)
 412                 {
 413                         g_race_qualifying = 1;
 414                 }
 415                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 416                 {
 417                         g_race_qualifying = 2;
 418                         race_fraglimit = autocvar_fraglimit;
 419                         race_leadlimit = autocvar_leadlimit;
 420                         race_timelimit = autocvar_timelimit;
 421                         cvar_set("fraglimit", "0");
 422                         cvar_set("leadlimit", "0");
 423                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 424                 }
 425                 else
 426                         g_race_qualifying = 0;
 427         }
 428
 429         if(g_race || g_cts)
 430         {
 431                 if(g_race_qualifying)
 432                         independent_players = 1;
 433
 434                 ScoreRules_race();
 435         }
 436
 437         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 438 }
 439
 440 string GetClientVersionMessage() {
 441         local string versionmsg;
 442         if (self.version_mismatch) {
 443                 if(self.version < autocvar_gameversion) {
 444                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 445                 } else {
 446                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 447                 }
 448         } else {
 449                 versionmsg = "^2client version and server version are compatible.^8";
 450         }
 451         return versionmsg;
 452 }
 453
 454
 455 void PrintWelcomeMessage(entity pl)
 456 {
 457         string s, modifications, motd;
 458
 459         if(self.cvar_scr_centertime == 0) return;
 460
 461         if(autocvar_g_campaign)
 462         {
 463                 if(self.classname == "player" && !self.BUTTON_INFO)
 464                         return;
 465         }
 466         else
 467         {
 468                 if((time - self.jointime) > autocvar_welcome_message_time && !self.BUTTON_INFO)
 469                         return;
 470         }
 471
 472         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 473                 if(self.welcomemessage_time > time) return;
 474                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 475         }
 476
 477         if(autocvar_g_campaign)
 478         {
 479                 centerprint(pl, campaign_message);
 480                 return;
 481         }
 482
 483 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 484         if(!self.BUTTON_INFO)
 485         {
 486                 // TODO get rid of this too
 487                 local string specString;
 488                 specString = NEWLINES;
 489                 //if(time < game_starttime) //also show the countdown when being a spectator
 490                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 491                 //else
 492                 if (timeoutStatus != 0)
 493                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 494                 else
 495                 {
 496                         if(self.classname == "player")
 497                                 return;
 498                         goto normal;
 499                 }
 500                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 501         }
 502
 503 :normal
 504         ret_string = "";
 505         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 506         modifications = ret_string;
 507
 508         if(g_minstagib)
 509                 modifications = strcat(modifications, ", MinstaGib");
 510         if(g_weaponarena)
 511         {
 512                 if(g_weaponarena_random)
 513                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 514                 else
 515                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 516         }
 517         if(autocvar_g_start_weapon_laser == 0)
 518                 modifications = strcat(modifications, ", No start weapons");
 519         if(autocvar_sv_gravity < 800)
 520                 modifications = strcat(modifications, ", Low gravity");
 521         if(g_cloaked)
 522                 modifications = strcat(modifications, ", Cloaked");
 523         if(g_grappling_hook)
 524                 modifications = strcat(modifications, ", Hook");
 525         if(g_midair)
 526                 modifications = strcat(modifications, ", Midair");
 527         if(g_pinata)
 528                 modifications = strcat(modifications, ", Pinata");
 529         if(g_weapon_stay)
 530                 modifications = strcat(modifications, ", Weapons stay");
 531         if(g_bloodloss > 0)
 532                 modifications = strcat(modifications, ", Bloodloss");
 533         if(g_jetpack)
 534                 modifications = strcat(modifications, ", Jet pack");
 535         modifications = substring(modifications, 2, strlen(modifications) - 2);
 536
 537         local string versionmessage;
 538         versionmessage = GetClientVersionMessage();
 539
 540         s = strcat(s, NEWLINES, "This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 541         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 542
 543         if(modifications != "")
 544                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 545
 546         if(timeoutStatus != 0)
 547                 s = strcat(s, "\n\n", getTimeoutText(1));
 548
 549         if (g_grappling_hook)
 550                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 551
 552         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 553         {
 554                 if(cache_lastmutatormsg)
 555                         strunzone(cache_lastmutatormsg);
 556                 if(cache_mutatormsg)
 557                         strunzone(cache_mutatormsg);
 558                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 559                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 560         }
 561
 562         if (cache_mutatormsg != "") {
 563                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 564         }
 565
 566         motd = autocvar_sv_motd;
 567         if (motd != "") {
 568                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 569         }
 570         s = strcat(s, "\n");
 571
 572         centerprint(pl, s);
 573 }
 574
 575
 576 void SetPlayerColors(entity pl, float _color)
 577 {
 578         /*string s;
 579         s = ftos(cl);
 580         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 581         pl.team = cl + 1;
 582         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 583         pl.clientcolors = 16*cl + cl;*/
 584
 585         float pants, shirt;
 586         pants = _color & 0x0F;
 587         shirt = _color & 0xF0;
 588
 589
 590         if(teams_matter) {
 591                 setcolor(pl, 16*pants + pants);
 592         } else {
 593                 setcolor(pl, shirt + pants);
 594         }
 595 }
 596
 597 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 598 {
 599         float _color;
 600
 601         if(t == 4)
 602                 _color = COLOR_TEAM4 - 1;
 603         else if(t == 3)
 604                 _color = COLOR_TEAM3 - 1;
 605         else if(t == 2)
 606                 _color = COLOR_TEAM2 - 1;
 607         else
 608                 _color = COLOR_TEAM1 - 1;
 609
 610         SetPlayerColors(pl,_color);
 611
 612         if(t != s) {
 613                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 614
 615                 if(!noprint)
 616                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 617         }
 618
 619 }
 620
 621 // set c1...c4 to show what teams are allowed
 622 void CheckAllowedTeams (entity for_whom)
 623 {
 624         float dm;
 625         entity head;
 626         string teament_name;
 627
 628         c1 = c2 = c3 = c4 = -1;
 629         cb1 = cb2 = cb3 = cb4 = 0;
 630
 631         if(autocvar_g_campaign && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
 632         {
 633                 c1 = 0; // only allow RED team for player joining
 634         }
 635         else if(g_onslaught)
 636         {
 637                 // onslaught is special
 638                 head = findchain(classname, "onslaught_generator");
 639                 while (head)
 640                 {
 641                         if (head.team == COLOR_TEAM1) c1 = 0;
 642                         if (head.team == COLOR_TEAM2) c2 = 0;
 643                         if (head.team == COLOR_TEAM3) c3 = 0;
 644                         if (head.team == COLOR_TEAM4) c4 = 0;
 645                         head = head.chain;
 646                 }
 647         }
 648         else if(g_domination)
 649                 teament_name = "dom_team";
 650         else if(g_ctf)
 651                 teament_name = "ctf_team";
 652         else if(g_tdm)
 653                 teament_name = "tdm_team";
 654         else if(g_nexball)
 655                 teament_name = "nexball_team";
 656         else if(g_assault)
 657                 c1 = c2 = 0; // Assault always has 2 teams
 658         else
 659         {
 660                 // cover anything else by treating it like tdm with no teams spawned
 661                 if(g_race)
 662                         dm = race_teams;
 663                 else
 664                         dm = 2;
 665
 666                 ret_float = dm;
 667                 MUTATOR_CALLHOOK(GetTeamCount);
 668                 dm = ret_float;
 669
 670                 if(dm >= 4)
 671                         c1 = c2 = c3 = c4 = 0;
 672                 else if(dm >= 3)
 673                         c1 = c2 = c3 = 0;
 674                 else
 675                         c1 = c2 = 0;
 676         }
 677
 678         // find out what teams are allowed if necessary
 679         if(teament_name)
 680         {
 681                 head = find(world, classname, teament_name);
 682                 while(head)
 683                 {
 684                         if(!(g_domination && head.netname == ""))
 685                         {
 686                                 if(head.team == COLOR_TEAM1)
 687                                         c1 = 0;
 688                                 else if(head.team == COLOR_TEAM2)
 689                                         c2 = 0;
 690                                 else if(head.team == COLOR_TEAM3)
 691                                         c3 = 0;
 692                                 else if(head.team == COLOR_TEAM4)
 693                                         c4 = 0;
 694                         }
 695                         head = find(head, classname, teament_name);
 696                 }
 697         }
 698
 699         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 700         if(c3==-1 && c4==-1)
 701         if(autocvar_bot_vs_human && for_whom)
 702         {
 703                 if(autocvar_bot_vs_human > 0)
 704                 {
 705                         // bots are all blue
 706                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 707                                 c1 = c3 = c4 = -1;
 708                         else
 709                                 c2 = -1;
 710                 }
 711                 else
 712                 {
 713                         // bots are all red
 714                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 715                                 c2 = c3 = c4 = -1;
 716                         else
 717                                 c1 = -1;
 718                 }
 719         }
 720
 721         // if player has a forced team, ONLY allow that one
 722         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 723                 c2 = c3 = c4 = -1;
 724         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 725                 c1 = c3 = c4 = -1;
 726         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 727                 c1 = c2 = c4 = -1;
 728         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 729                 c1 = c2 = c3 = -1;
 730 }
 731
 732 float PlayerValue(entity p)
 733 {
 734         if(IsTeamBalanceForced() == 1)
 735                 return 1;
 736         return 1;
 737         // FIXME: it always returns 1...
 738 }
 739
 740 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 741 // teams that are allowed will now have their player counts stored in c1...c4
 742 void GetTeamCounts(entity ignore)
 743 {
 744         entity head;
 745         float value, bvalue;
 746         // now count how many players are on each team already
 747
 748         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 749         // also remember the lowest-scoring player
 750
 751         FOR_EACH_PLAYER(head)
 752         {
 753                 if(head != ignore)// && head.netname != "")
 754                 {
 755                         value = PlayerValue(head);
 756                         if(clienttype(head) == CLIENTTYPE_BOT)
 757                                 bvalue = value;
 758                         else
 759                                 bvalue = 0;
 760                         if(head.team == COLOR_TEAM1)
 761                         {
 762                                 if(c1 >= 0)
 763                                 {
 764                                         c1 = c1 + value;
 765                                         cb1 = cb1 + bvalue;
 766                                 }
 767                         }
 768                         if(head.team == COLOR_TEAM2)
 769                         {
 770                                 if(c2 >= 0)
 771                                 {
 772                                         c2 = c2 + value;
 773                                         cb2 = cb2 + bvalue;
 774                                 }
 775                         }
 776                         if(head.team == COLOR_TEAM3)
 777                         {
 778                                 if(c3 >= 0)
 779                                 {
 780                                         c3 = c3 + value;
 781                                         cb3 = cb3 + bvalue;
 782                                 }
 783                         }
 784                         if(head.team == COLOR_TEAM4)
 785                         {
 786                                 if(c4 >= 0)
 787                                 {
 788                                         c4 = c4 + value;
 789                                         cb4 = cb4 + bvalue;
 790                                 }
 791                         }
 792                 }
 793         }
 794 }
 795
 796 // returns # of smallest team (1, 2, 3, 4)
 797 // NOTE: Assumes CheckAllowedTeams has already been called!
 798 float FindSmallestTeam(entity pl, float ignore_pl)
 799 {
 800         float totalteams, balance_type, maxc;
 801         totalteams = 0;
 802
 803         // find out what teams are available
 804         //CheckAllowedTeams();
 805
 806         // make sure there are at least 2 teams to join
 807         if(c1 >= 0)
 808                 totalteams = totalteams + 1;
 809         if(c2 >= 0)
 810                 totalteams = totalteams + 1;
 811         if(c3 >= 0)
 812                 totalteams = totalteams + 1;
 813         if(c4 >= 0)
 814                 totalteams = totalteams + 1;
 815
 816         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 817                 totalteams += 1;
 818
 819         if(totalteams <= 1)
 820         {
 821                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 822                         return 1; // special case for campaign and player joining
 823                 else if(g_domination)
 824                         error("Too few teams available for domination\n");
 825                 else if(g_ctf)
 826                         error("Too few teams available for ctf\n");
 827                 else if(g_keyhunt)
 828                         error("Too few teams available for key hunt\n");
 829                 else if(g_freezetag)
 830                         error("Too few teams available for freeze tag\n");
 831                 else
 832                         error("Too few teams available for team deathmatch\n");
 833         }
 834
 835         // count how many players are in each team
 836         if(ignore_pl)
 837                 GetTeamCounts(pl);
 838         else
 839                 GetTeamCounts(world);
 840
 841         // c1...c4 now have counts of each team
 842         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 843
 844         // 2 gives priority to what team you're already on, 1 goes in order
 845         // 2 doesn't seem to work though...
 846         balance_type = 1;
 847
 848         if(bots_would_leave)
 849         //if(pl.classname != "player")
 850         if(clienttype(pl) != CLIENTTYPE_BOT)
 851         {
 852                 c1 -= cb1 * 255.0/256.0;
 853                 c2 -= cb2 * 255.0/256.0;
 854                 c3 -= cb3 * 255.0/256.0;
 855                 c4 -= cb4 * 255.0/256.0;
 856         }
 857         maxc = max4(c1, c2, c3, c4);
 858
 859         RandomSelection_Init();
 860         if(balance_type == 1)
 861         {
 862                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 863                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 864                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 865                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 866                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 867         }
 868         else if(balance_type == 2)
 869         {
 870                 // 1: use team count, if equal prefer own team
 871                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 872                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 873                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 874                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 875         }
 876         else if(balance_type == 3)
 877         {
 878                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 879                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 880                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 881                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 882                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 883         }
 884         return RandomSelection_chosen_float;
 885 }
 886
 887 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 888 {
 889         float smallest, selectedteam;
 890
 891         // don't join a team if we're not playing a team game
 892         if(!teams_matter)
 893                 return 0;
 894
 895         // find out what teams are available
 896         CheckAllowedTeams(pl);
 897
 898         // if we want the player in a certain team for campaign, force him there
 899         if(autocvar_g_campaign)
 900         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
 901         {
 902                 switch(autocvar_g_campaign_forceteam)
 903                 {
 904                         case 1:
 905                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
 906                                 LogTeamchange(pl.playerid, pl.team, 2);
 907                                 return COLOR_TEAM1;
 908                         case 2:
 909                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
 910                                 LogTeamchange(pl.playerid, pl.team, 2);
 911                                 return COLOR_TEAM2;
 912                         case 3:
 913                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
 914                                 LogTeamchange(pl.playerid, pl.team, 2);
 915                                 return COLOR_TEAM3;
 916                         case 4:
 917                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
 918                                 LogTeamchange(pl.playerid, pl.team, 2);
 919                                 return COLOR_TEAM4;
 920                         default:
 921                                 break;
 922                 }
 923         }
 924
 925         // if we don't care what team he ends up on, put him on whatever team he entered as.
 926         // if he's not on a valid team, then let other code put him on the smallest team
 927         if(!forcebestteam)
 928         {
 929                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 930                         selectedteam = pl.team;
 931                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 932                         selectedteam = pl.team;
 933                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 934                         selectedteam = pl.team;
 935                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 936                         selectedteam = pl.team;
 937                 else
 938                         selectedteam = -1;
 939
 940                 if(selectedteam > 0)
 941                 {
 942                         if(!only_return_best)
 943                         {
 944                                 SetPlayerColors(pl, selectedteam - 1);
 945
 946                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 947                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 948                                 LogTeamchange(pl.playerid, pl.team, 99);
 949                         }
 950                         return selectedteam;
 951                 }
 952                 // otherwise end up on the smallest team (handled below)
 953         }
 954
 955         smallest = FindSmallestTeam(pl, TRUE);
 956
 957         if(!only_return_best && !pl.bot_forced_team)
 958         {
 959                 TeamchangeFrags(self);
 960                 if(smallest == 1)
 961                 {
 962                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 963                 }
 964                 else if(smallest == 2)
 965                 {
 966                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 967                 }
 968                 else if(smallest == 3)
 969                 {
 970                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 971                 }
 972                 else if(smallest == 4)
 973                 {
 974                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 975                 }
 976                 else
 977                 {
 978                         error("smallest team: invalid team\n");
 979                 }
 980
 981                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 982
 983                 if(pl.deadflag == DEAD_NO)
 984                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 985         }
 986
 987         return smallest;
 988 }
 989
 990 //void() ctf_playerchanged;
 991 void SV_ChangeTeam(float _color)
 992 {
 993         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 994
 995         // in normal deathmatch we can just apply the color and we're done
 996         if(!teams_matter) {
 997                 SetPlayerColors(self, _color);
 998                 return;
 999         }
1000
1001         scolor = self.clientcolors & 0x0F;
1002         dcolor = _color & 0x0F;
1003
1004         if(scolor == COLOR_TEAM1 - 1)
1005                 steam = 1;
1006         else if(scolor == COLOR_TEAM2 - 1)
1007                 steam = 2;
1008         else if(scolor == COLOR_TEAM3 - 1)
1009                 steam = 3;
1010         else // if(scolor == COLOR_TEAM4 - 1)
1011                 steam = 4;
1012         if(dcolor == COLOR_TEAM1 - 1)
1013                 dteam = 1;
1014         else if(dcolor == COLOR_TEAM2 - 1)
1015                 dteam = 2;
1016         else if(dcolor == COLOR_TEAM3 - 1)
1017                 dteam = 3;
1018         else // if(dcolor == COLOR_TEAM4 - 1)
1019                 dteam = 4;
1020
1021         CheckAllowedTeams(self);
1022
1023         if(dteam == 1 && c1 < 0) dteam = 4;
1024         if(dteam == 4 && c4 < 0) dteam = 3;
1025         if(dteam == 3 && c3 < 0) dteam = 2;
1026         if(dteam == 2 && c2 < 0) dteam = 1;
1027
1028         // not changing teams
1029         if(scolor == dcolor)
1030         {
1031                 //bprint("same team change\n");
1032                 SetPlayerTeam(self, dteam, steam, TRUE);
1033                 return;
1034         }
1035
1036         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
1037                 sprint(self, "Team changes not allowed\n");
1038                 return; // changing teams is not allowed
1039         }
1040
1041         if(autocvar_g_balance_teams_prevent_imbalance)
1042         {
1043                 // only allow changing to a smaller or equal size team
1044
1045                 // find out what teams are available
1046                 //CheckAllowedTeams();
1047                 // count how many players on each team
1048                 GetTeamCounts(world);
1049
1050                 // get desired team
1051                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1052                 {
1053                         dcount = c1;
1054                         dbotcount = cb1;
1055                 }
1056                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1057                 {
1058                         dcount = c2;
1059                         dbotcount = cb2;
1060                 }
1061                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1062                 {
1063                         dcount = c3;
1064                         dbotcount = cb3;
1065                 }
1066                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1067                 {
1068                         dcount = c4;
1069                         dbotcount = cb4;
1070                 }
1071                 else
1072                 {
1073                         sprint(self, "Cannot change to an invalid team\n");
1074
1075                         return;
1076                 }
1077
1078                 // get starting team
1079                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1080                         scount = c1;
1081                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1082                         scount = c2;
1083                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1084                         scount = c3;
1085                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1086                         scount = c4;
1087
1088                 if(scount) // started at a valid, nonempty team
1089                 {
1090                         // check if we're trying to change to a larger team that doens't have bots to swap with
1091                         if(dcount >= scount && dbotcount <= 0)
1092                         {
1093                                 sprint(self, "Cannot change to a larger team\n");
1094                                 return; // can't change to a larger team
1095                         }
1096                 }
1097         }
1098
1099 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1100
1101         if(self.classname == "player" && steam != dteam)
1102         {
1103                 // reduce frags during a team change
1104                 TeamchangeFrags(self);
1105         }
1106
1107         SetPlayerTeam(self, dteam, steam, FALSE);
1108
1109         if(self.classname == "player" && steam != dteam)
1110         {
1111                 // kill player when changing teams
1112                 if(self.deadflag == DEAD_NO)
1113                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1114         }
1115         //ctf_playerchanged();
1116 }
1117
1118 void ShufflePlayerOutOfTeam (float source_team)
1119 {
1120         float smallestteam, smallestteam_count, steam;
1121         float lowest_bot_score, lowest_player_score;
1122         entity head, lowest_bot, lowest_player, selected;
1123
1124         smallestteam = 0;
1125         smallestteam_count = 999999999;
1126
1127         if(c1 >= 0 && c1 < smallestteam_count)
1128         {
1129                 smallestteam = 1;
1130                 smallestteam_count = c1;
1131         }
1132         if(c2 >= 0 && c2 < smallestteam_count)
1133         {
1134                 smallestteam = 2;
1135                 smallestteam_count = c2;
1136         }
1137         if(c3 >= 0 && c3 < smallestteam_count)
1138         {
1139                 smallestteam = 3;
1140                 smallestteam_count = c3;
1141         }
1142         if(c4 >= 0 && c4 < smallestteam_count)
1143         {
1144                 smallestteam = 4;
1145                 smallestteam_count = c4;
1146         }
1147
1148         if(!smallestteam)
1149         {
1150                 bprint("warning: no smallest team\n");
1151                 return;
1152         }
1153
1154         if(source_team == 1)
1155                 steam = COLOR_TEAM1;
1156         else if(source_team == 2)
1157                 steam = COLOR_TEAM2;
1158         else if(source_team == 3)
1159                 steam = COLOR_TEAM3;
1160         else if(source_team == 4)
1161                 steam = COLOR_TEAM4;
1162
1163         lowest_bot = world;
1164         lowest_bot_score = 999999999;
1165         lowest_player = world;
1166         lowest_player_score = 999999999;
1167
1168         // find the lowest-scoring player & bot of that team
1169         FOR_EACH_PLAYER(head)
1170         {
1171                 if(head.team == steam)
1172                 {
1173                         if(head.isbot)
1174                         {
1175                                 if(head.totalfrags < lowest_bot_score)
1176                                 {
1177                                         lowest_bot = head;
1178                                         lowest_bot_score = head.totalfrags;
1179                                 }
1180                         }
1181                         else
1182                         {
1183                                 if(head.totalfrags < lowest_player_score)
1184                                 {
1185                                         lowest_player = head;
1186                                         lowest_player_score = head.totalfrags;
1187                                 }
1188                         }
1189                 }
1190         }
1191
1192         // prefers to move a bot...
1193         if(lowest_bot != world)
1194                 selected = lowest_bot;
1195         // but it will move a player if it has to
1196         else
1197                 selected = lowest_player;
1198         // don't do anything if it couldn't find anyone
1199         if(!selected)
1200         {
1201                 bprint("warning: couldn't find a player to move from team\n");
1202                 return;
1203         }
1204
1205         // smallest team gains a member
1206         if(smallestteam == 1)
1207         {
1208                 c1 = c1 + 1;
1209         }
1210         else if(smallestteam == 2)
1211         {
1212                 c2 = c2 + 1;
1213         }
1214         else if(smallestteam == 3)
1215         {
1216                 c3 = c3 + 1;
1217         }
1218         else if(smallestteam == 4)
1219         {
1220                 c4 = c4 + 1;
1221         }
1222         else
1223         {
1224                 bprint("warning: destination team invalid\n");
1225                 return;
1226         }
1227         // source team loses a member
1228         if(source_team == 1)
1229         {
1230                 c1 = c1 + 1;
1231         }
1232         else if(source_team == 2)
1233         {
1234                 c2 = c2 + 2;
1235         }
1236         else if(source_team == 3)
1237         {
1238                 c3 = c3 + 3;
1239         }
1240         else if(source_team == 4)
1241         {
1242                 c4 = c4 + 4;
1243         }
1244         else
1245         {
1246                 bprint("warning: source team invalid\n");
1247                 return;
1248         }
1249
1250         // move the player to the new team
1251         TeamchangeFrags(selected);
1252         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1253
1254         if(selected.deadflag == DEAD_NO)
1255                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1256         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1257 }
1258
1259 void CauseRebalance(float source_team, float howmany_toomany)
1260 {
1261         if(IsTeamBalanceForced() == 1)
1262         {
1263                 bprint("Rebalancing Teams\n");
1264                 ShufflePlayerOutOfTeam(source_team);
1265         }
1266 }
1267
1268 // part of g_balance_teams_force
1269 // occasionally perform an audit of the teams to make
1270 // sure they're more or less balanced in player count.
1271 void AuditTeams()
1272 {
1273         float numplayers, numteams, smallest, toomany;
1274         float balance;
1275         balance = IsTeamBalanceForced();
1276         if(balance == 0)
1277                 return;
1278
1279         if(audit_teams_time > time)
1280                 return;
1281
1282         audit_teams_time = time + 4 + random();
1283
1284 //      bprint("Auditing teams\n");
1285
1286         CheckAllowedTeams(world);
1287         GetTeamCounts(world);
1288
1289
1290         numteams = numplayers = smallest = 0;
1291         if(c1 >= 0)
1292         {
1293                 numteams = numteams + 1;
1294                 numplayers = numplayers + c1;
1295                 smallest = c1;
1296         }
1297         if(c2 >= 0)
1298         {
1299                 numteams = numteams + 1;
1300                 numplayers = numplayers + c2;
1301                 if(c2 < smallest)
1302                         smallest = c2;
1303         }
1304         if(c3 >= 0)
1305         {
1306                 numteams = numteams + 1;
1307                 numplayers = numplayers + c3;
1308                 if(c3 < smallest)
1309                         smallest = c3;
1310         }
1311         if(c4 >= 0)
1312         {
1313                 numteams = numteams + 1;
1314                 numplayers = numplayers + c4;
1315                 if(c4 < smallest)
1316                         smallest = c4;
1317         }
1318
1319         if(numplayers <= 0)
1320                 return; // no players to move around
1321         if(numteams < 2)
1322                 return; // don't bother shuffling if for some reason there aren't any teams
1323
1324         toomany = smallest + 1;
1325
1326         if(c1 && c1 > toomany)
1327                 CauseRebalance(1, c1 - toomany);
1328         if(c2 && c2 > toomany)
1329                 CauseRebalance(2, c2 - toomany);
1330         if(c3 && c3 > toomany)
1331                 CauseRebalance(3, c3 - toomany);
1332         if(c4 && c4 > toomany)
1333                 CauseRebalance(4, c4 - toomany);
1334
1335         // if teams are still unbalanced, balance them further in the next audit,
1336         // which will happen sooner (keep doing rapid audits until things are in order)
1337         audit_teams_time = time + 0.7 + random()*0.3;
1338 }
1339
1340 // code from here on is just to support maps that don't have team entities
1341 void tdm_spawnteam (string teamname, float teamcolor)
1342 {
1343         local entity e;
1344         e = spawn();
1345         e.classname = "tdm_team";
1346         e.netname = teamname;
1347         e.cnt = teamcolor;
1348         e.team = e.cnt + 1;
1349 };
1350
1351 // spawn some default teams if the map is not set up for tdm
1352 void tdm_spawnteams()
1353 {
1354         float numteams;
1355
1356         numteams = autocvar_g_tdm_teams_override;
1357         if(numteams < 2)
1358                 numteams = autocvar_g_tdm_teams;
1359         numteams = bound(2, numteams, 4);
1360
1361         tdm_spawnteam("Red", COLOR_TEAM1-1);
1362         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1363         if(numteams >= 3)
1364                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1365         if(numteams >= 4)
1366                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1367 };
1368
1369 void tdm_delayedinit()
1370 {
1371         // if no teams are found, spawn defaults
1372         if (find(world, classname, "tdm_team") == world)
1373                 tdm_spawnteams();
1374 };
1375
1376 void tdm_init()
1377 {
1378         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1379 };