more clever conveyor implementation by plugging into cl_physics
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / teamplay.qc
1 string cache_mutatormsg;
2 string cache_lastmutatormsg;
3
4 // client counts for each team
5 float c1, c2, c3, c4;
6 // # of bots on those teams
7 float cb1, cb2, cb3, cb4;
8
9 float audit_teams_time;
10
11 float IsTeamBalanceForced()
12 {
13         if(intermission_running)
14                 return 0; // no rebalancing whatsoever please
15         if(!teamplay)
16                 return 0;
17         if(autocvar_g_campaign)
18                 return 0;
19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
20                 return 0;
21         if(!autocvar_g_balance_teams_force)
22                 return -1;
23         return 1;
24 }
25
26 void TeamchangeFrags(entity e)
27 {
28         PlayerScore_Clear(e);
29 }
30
31 vector TeamColor(float teem)
32 {
33         switch(teem)
34         {
35                 case COLOR_TEAM1:
36                         return '1 0.0625 0.0625';
37                 case COLOR_TEAM2:
38                         return '0.0625 0.0625 1';
39                 case COLOR_TEAM3:
40                         return '1 1 0.0625';
41                 case COLOR_TEAM4:
42                         return '1 0.0625 1';
43                 default:
44                         return '1 1 1';
45         }
46 }
47
48 string TeamName(float t)
49 {
50         return strcat(Team_ColorName(t), " Team");
51 }
52 string ColoredTeamName(float t)
53 {
54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
55 }
56 string TeamNoName(float t)
57 {
58         // fixme: Search for team entities and get their .netname's!
59         if(t == 1)
60                 return "Red Team";
61         if(t == 2)
62                 return "Blue Team";
63         if(t == 3)
64                 return "Yellow Team";
65         if(t == 4)
66                 return "Pink Team";
67         return "Neutral Team";
68 }
69
70 void dom_init();
71 void ctf_init();
72 void runematch_init();
73 void tdm_init();
74 void nb_init();
75 void entcs_init();
76
77 void LogTeamchange(float player_id, float team_number, float type)
78 {
79         if(!autocvar_sv_eventlog)
80                 return;
81
82         if(player_id < 1)
83                 return;
84
85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
86 }
87
88 void default_delayedinit()
89 {
90         if(!scores_initialized)
91                 ScoreRules_generic();
92 }
93
94 void ActivateTeamplay()
95 {
96         serverflags |= SERVERFLAG_TEAMPLAY;
97         teamplay = 1;
98 }
99
100 void InitGameplayMode()
101 {
102         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
103
104         qualifying_override = -1;
105
106         VoteReset();
107
108         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
109         get_mi_min_max(1);
110         world.mins = mi_min;
111         world.maxs = mi_max;
112
113         MapInfo_LoadMapSettings(mapname);
114         teamplay = 0;
115         serverflags &~= SERVERFLAG_TEAMPLAY;
116
117         if not(cvar_value_issafe(world.fog))
118         {
119                 print("The current map contains a potentially harmful fog setting, ignored\n");
120                 world.fog = string_null;
121         }
122         if(MapInfo_Map_fog != "")
123                 if(MapInfo_Map_fog == "none")
124                         world.fog = string_null;
125                 else
126                         world.fog = strzone(MapInfo_Map_fog);
127         clientstuff = strzone(MapInfo_Map_clientstuff);
128
129         MapInfo_ClearTemps();
130
131         // set both here, gamemode can override it later
132         timelimit_override = autocvar_timelimit_override;
133         fraglimit_override = autocvar_fraglimit_override;
134         leadlimit_override = autocvar_leadlimit_override;
135         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
136
137         if(g_dm)
138         {
139         }
140
141         if(g_tdm)
142         {
143                 ActivateTeamplay();
144                 tdm_init();
145                 if(autocvar_g_tdm_team_spawns)
146                         have_team_spawns = -1; // request team spawns
147         }
148
149         if(g_domination)
150         {
151                 ActivateTeamplay();
152                 fraglimit_override = autocvar_g_domination_point_limit;
153                 leadlimit_override = autocvar_g_domination_point_leadlimit;
154                 dom_init();
155                 have_team_spawns = -1; // request team spawns
156         }
157
158         if(g_ctf)
159         {
160                 ActivateTeamplay();
161                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
162                 fraglimit_override = autocvar_capturelimit_override;
163                 leadlimit_override = autocvar_captureleadlimit_override;
164                 ctf_init();
165                 have_team_spawns = -1; // request team spawns
166         }
167
168         if(g_runematch)
169         {
170                 // ActivateTeamplay();
171                 fraglimit_override = autocvar_g_runematch_point_limit;
172                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
173                 runematch_init();
174         }
175
176         if(g_lms)
177         {
178                 fraglimit_override = autocvar_g_lms_lives_override;
179                 leadlimit_override = 0; // not supported by LMS
180                 if(fraglimit_override == 0)
181                         fraglimit_override = -1;
182                 lms_lowest_lives = 9999;
183                 lms_next_place = 0;
184                 ScoreRules_lms();
185         }
186
187         if(g_arena)
188         {
189                 fraglimit_override = autocvar_g_arena_point_limit;
190                 leadlimit_override = autocvar_g_arena_point_leadlimit;
191                 maxspawned = autocvar_g_arena_maxspawned;
192                 if(maxspawned < 2)
193                         maxspawned = 2;
194                 arena_roundbased = autocvar_g_arena_roundbased;
195         }
196
197         if(g_ca)
198         {
199                 ActivateTeamplay();
200                 fraglimit_override = autocvar_g_ca_point_limit;
201                 leadlimit_override = autocvar_g_ca_point_leadlimit;
202                 precache_sound("ctf/red_capture.wav");
203                 precache_sound("ctf/blue_capture.wav");
204         }
205         if(g_keyhunt)
206         {
207                 ActivateTeamplay();
208                 fraglimit_override = autocvar_g_keyhunt_point_limit;
209                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
210                 MUTATOR_ADD(gamemode_keyhunt);
211         }
212
213         if(g_freezetag)
214         {
215                 ActivateTeamplay();
216                 fraglimit_override = autocvar_g_freezetag_point_limit;
217                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
218                 MUTATOR_ADD(gamemode_freezetag);
219         }
220
221         if(g_assault)
222         {
223                 ActivateTeamplay();
224                 ScoreRules_assault();
225                 have_team_spawns = -1; // request team spawns
226         }
227
228         if(g_onslaught)
229         {
230                 ActivateTeamplay();
231                 have_team_spawns = -1; // request team spawns
232         }
233
234         if(g_race)
235         {
236
237                 if(autocvar_g_race_teams)
238                 {
239                         ActivateTeamplay();
240                         race_teams = bound(2, autocvar_g_race_teams, 4);
241                         have_team_spawns = -1; // request team spawns
242                 }
243                 else
244                         race_teams = 0;
245
246                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
247                 fraglimit_override = autocvar_g_race_laps_limit;
248                 leadlimit_override = 0; // currently not supported by race
249         }
250
251         if(g_cts)
252         {
253                 g_race_qualifying = 1;
254                 fraglimit_override = 0;
255                 leadlimit_override = 0;
256         }
257
258         if(g_nexball)
259         {
260                 fraglimit_override = autocvar_g_nexball_goallimit;
261                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
262                 ActivateTeamplay();
263                 nb_init();
264                 have_team_spawns = -1; // request team spawns
265         }
266
267         if(g_keepaway)
268         {
269                 MUTATOR_ADD(gamemode_keepaway);
270         }
271
272         if(teamplay)
273                 entcs_init();
274
275         cache_mutatormsg = strzone("");
276         cache_lastmutatormsg = strzone("");
277
278         // enforce the server's universal frag/time limits
279         if(!autocvar_g_campaign)
280         {
281                 if(fraglimit_override >= 0)
282                         cvar_set("fraglimit", ftos(fraglimit_override));
283                 if(timelimit_override >= 0)
284                         cvar_set("timelimit", ftos(timelimit_override));
285                 if(leadlimit_override >= 0)
286                         cvar_set("leadlimit", ftos(leadlimit_override));
287                 if(qualifying_override >= 0)
288                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
289         }
290
291         if(g_race)
292         {
293                 // we need to find out the correct value for g_race_qualifying
294                 if(autocvar_g_campaign)
295                 {
296                         g_race_qualifying = 1;
297                 }
298                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
299                 {
300                         g_race_qualifying = 2;
301                         race_fraglimit = autocvar_fraglimit;
302                         race_leadlimit = autocvar_leadlimit;
303                         race_timelimit = autocvar_timelimit;
304                         cvar_set("fraglimit", "0");
305                         cvar_set("leadlimit", "0");
306                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
307                 }
308                 else
309                         g_race_qualifying = 0;
310         }
311
312         if(g_race || g_cts)
313         {
314                 if(g_race_qualifying)
315                         independent_players = 1;
316
317                 ScoreRules_race();
318         }
319
320         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
321 }
322
323 string GetClientVersionMessage() {
324         string versionmsg;
325         if (self.version_mismatch) {
326                 if(self.version < autocvar_gameversion) {
327                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
328                 } else {
329                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
330                 }
331         } else {
332                 versionmsg = "^2client version and server version are compatible.^8";
333         }
334         return versionmsg;
335 }
336
337 string getwelcomemessage(void)
338 {
339         string s, modifications, motd;
340
341         ret_string = "";
342         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
343         modifications = ret_string;
344         
345         if(g_minstagib)
346                 modifications = strcat(modifications, ", MinstaGib");
347         if(g_weaponarena)
348         {
349                 if(g_weaponarena_random)
350                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
351                 else
352                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
353         }
354         if(autocvar_g_start_weapon_laser == 0)
355                 modifications = strcat(modifications, ", No start weapons");
356         if(autocvar_sv_gravity < 800)
357                 modifications = strcat(modifications, ", Low gravity");
358         if(g_cloaked && !g_cts)
359                 modifications = strcat(modifications, ", Cloaked");
360         if(g_grappling_hook)
361                 modifications = strcat(modifications, ", Hook");
362         if(g_midair)
363                 modifications = strcat(modifications, ", Midair");
364         if(g_pinata)
365                 modifications = strcat(modifications, ", PiƱata");
366         if(g_weapon_stay && !g_cts)
367                 modifications = strcat(modifications, ", Weapons stay");
368         if(g_bloodloss > 0)
369                 modifications = strcat(modifications, ", Blood loss");
370         if(g_jetpack)
371                 modifications = strcat(modifications, ", Jet pack");
372         if(autocvar_g_powerups == 0)
373                 modifications = strcat(modifications, ", No powerups");
374         if(autocvar_g_powerups > 0)
375                 modifications = strcat(modifications, ", Powerups");
376         modifications = substring(modifications, 2, strlen(modifications) - 2);
377
378         string versionmessage;
379         versionmessage = GetClientVersionMessage();
380
381         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
382         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
383
384         if(modifications != "")
385                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
386
387         if (g_grappling_hook)
388                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
389
390         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
391         {
392                 if(cache_lastmutatormsg)
393                         strunzone(cache_lastmutatormsg);
394                 if(cache_mutatormsg)
395                         strunzone(cache_mutatormsg);
396                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
397                 cache_mutatormsg = strzone(cache_lastmutatormsg);
398         }
399
400         if (cache_mutatormsg != "") {
401                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
402         }
403
404         motd = autocvar_sv_motd;
405         if (motd != "") {
406                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
407         }
408         return s;
409 }
410
411 void SetPlayerColors(entity pl, float _color)
412 {
413         /*string s;
414         s = ftos(cl);
415         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
416         pl.team = cl + 1;
417         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
418         pl.clientcolors = 16*cl + cl;*/
419
420         float pants, shirt;
421         pants = _color & 0x0F;
422         shirt = _color & 0xF0;
423
424
425         if(teamplay) {
426                 setcolor(pl, 16*pants + pants);
427         } else {
428                 setcolor(pl, shirt + pants);
429         }
430 }
431
432 void SetPlayerTeam(entity pl, float t, float s, float noprint)
433 {
434         float _color;
435
436         if(t == 4)
437                 _color = COLOR_TEAM4 - 1;
438         else if(t == 3)
439                 _color = COLOR_TEAM3 - 1;
440         else if(t == 2)
441                 _color = COLOR_TEAM2 - 1;
442         else
443                 _color = COLOR_TEAM1 - 1;
444
445         SetPlayerColors(pl,_color);
446
447         if(t != s) {
448                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
449
450                 if(!noprint)
451                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
452         }
453
454 }
455
456 // set c1...c4 to show what teams are allowed
457 void CheckAllowedTeams (entity for_whom)
458 {
459         float dm;
460         entity head;
461         string teament_name;
462
463         c1 = c2 = c3 = c4 = -1;
464         cb1 = cb2 = cb3 = cb4 = 0;
465
466         if(g_onslaught)
467         {
468                 // onslaught is special
469                 head = findchain(classname, "onslaught_generator");
470                 while (head)
471                 {
472                         if (head.team == COLOR_TEAM1) c1 = 0;
473                         if (head.team == COLOR_TEAM2) c2 = 0;
474                         if (head.team == COLOR_TEAM3) c3 = 0;
475                         if (head.team == COLOR_TEAM4) c4 = 0;
476                         head = head.chain;
477                 }
478         }
479         else if(g_domination)
480                 teament_name = "dom_team";
481         else if(g_ctf)
482                 teament_name = "ctf_team";
483         else if(g_tdm)
484                 teament_name = "tdm_team";
485         else if(g_nexball)
486                 teament_name = "nexball_team";
487         else if(g_assault)
488                 c1 = c2 = 0; // Assault always has 2 teams
489         else
490         {
491                 // cover anything else by treating it like tdm with no teams spawned
492                 if(g_race)
493                         dm = race_teams;
494                 else
495                         dm = 2;
496
497                 ret_float = dm;
498                 MUTATOR_CALLHOOK(GetTeamCount);
499                 dm = ret_float;
500
501                 if(dm >= 4)
502                         c1 = c2 = c3 = c4 = 0;
503                 else if(dm >= 3)
504                         c1 = c2 = c3 = 0;
505                 else
506                         c1 = c2 = 0;
507         }
508
509         // find out what teams are allowed if necessary
510         if(teament_name)
511         {
512                 head = find(world, classname, teament_name);
513                 while(head)
514                 {
515                         if(!(g_domination && head.netname == ""))
516                         {
517                                 if(head.team == COLOR_TEAM1)
518                                         c1 = 0;
519                                 else if(head.team == COLOR_TEAM2)
520                                         c2 = 0;
521                                 else if(head.team == COLOR_TEAM3)
522                                         c3 = 0;
523                                 else if(head.team == COLOR_TEAM4)
524                                         c4 = 0;
525                         }
526                         head = find(head, classname, teament_name);
527                 }
528         }
529
530         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
531         if(c3==-1 && c4==-1)
532         if(autocvar_bot_vs_human && for_whom)
533         {
534                 if(autocvar_bot_vs_human > 0)
535                 {
536                         // bots are all blue
537                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
538                                 c1 = c3 = c4 = -1;
539                         else
540                                 c2 = -1;
541                 }
542                 else
543                 {
544                         // bots are all red
545                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
546                                 c2 = c3 = c4 = -1;
547                         else
548                                 c1 = -1;
549                 }
550         }
551
552         // if player has a forced team, ONLY allow that one
553         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
554                 c2 = c3 = c4 = -1;
555         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
556                 c1 = c3 = c4 = -1;
557         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
558                 c1 = c2 = c4 = -1;
559         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
560                 c1 = c2 = c3 = -1;
561 }
562
563 float PlayerValue(entity p)
564 {
565         if(IsTeamBalanceForced() == 1)
566                 return 1;
567         return 1;
568         // FIXME: it always returns 1...
569 }
570
571 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
572 // teams that are allowed will now have their player counts stored in c1...c4
573 void GetTeamCounts(entity ignore)
574 {
575         entity head;
576         float value, bvalue;
577         // now count how many players are on each team already
578
579         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
580         // also remember the lowest-scoring player
581
582         FOR_EACH_CLIENT(head)
583         {
584                 float t;
585                 if(head.classname == "player")
586                         t = head.team;
587                 else if(head.team_forced > 0)
588                         t = head.team_forced; // reserve the spot
589                 else
590                         continue;
591                 if(head != ignore)// && head.netname != "")
592                 {
593                         value = PlayerValue(head);
594                         if(clienttype(head) == CLIENTTYPE_BOT)
595                                 bvalue = value;
596                         else
597                                 bvalue = 0;
598                         if(t == COLOR_TEAM1)
599                         {
600                                 if(c1 >= 0)
601                                 {
602                                         c1 = c1 + value;
603                                         cb1 = cb1 + bvalue;
604                                 }
605                         }
606                         if(t == COLOR_TEAM2)
607                         {
608                                 if(c2 >= 0)
609                                 {
610                                         c2 = c2 + value;
611                                         cb2 = cb2 + bvalue;
612                                 }
613                         }
614                         if(t == COLOR_TEAM3)
615                         {
616                                 if(c3 >= 0)
617                                 {
618                                         c3 = c3 + value;
619                                         cb3 = cb3 + bvalue;
620                                 }
621                         }
622                         if(t == COLOR_TEAM4)
623                         {
624                                 if(c4 >= 0)
625                                 {
626                                         c4 = c4 + value;
627                                         cb4 = cb4 + bvalue;
628                                 }
629                         }
630                 }
631         }
632
633         // if the player who has a forced team has not joined yet, reserve the spot
634         if(autocvar_g_campaign)
635         {
636                 switch(autocvar_g_campaign_forceteam)
637                 {
638                         case 1: if(c1 == cb1) ++c1; break;
639                         case 2: if(c2 == cb2) ++c2; break;
640                         case 3: if(c3 == cb3) ++c3; break;
641                         case 4: if(c4 == cb4) ++c4; break;
642                 }
643         }
644 }
645
646 // returns # of smallest team (1, 2, 3, 4)
647 // NOTE: Assumes CheckAllowedTeams has already been called!
648 float FindSmallestTeam(entity pl, float ignore_pl)
649 {
650         float totalteams, balance_type, maxc;
651         totalteams = 0;
652
653         // find out what teams are available
654         //CheckAllowedTeams();
655
656         // make sure there are at least 2 teams to join
657         if(c1 >= 0)
658                 totalteams = totalteams + 1;
659         if(c2 >= 0)
660                 totalteams = totalteams + 1;
661         if(c3 >= 0)
662                 totalteams = totalteams + 1;
663         if(c4 >= 0)
664                 totalteams = totalteams + 1;
665
666         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
667                 totalteams += 1;
668
669         if(totalteams <= 1)
670         {
671                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
672                         return 1; // special case for campaign and player joining
673                 else if(g_domination)
674                         error("Too few teams available for domination\n");
675                 else if(g_ctf)
676                         error("Too few teams available for ctf\n");
677                 else if(g_keyhunt)
678                         error("Too few teams available for key hunt\n");
679                 else if(g_freezetag)
680                         error("Too few teams available for freeze tag\n");
681                 else
682                         error("Too few teams available for team deathmatch\n");
683         }
684
685         // count how many players are in each team
686         if(ignore_pl)
687                 GetTeamCounts(pl);
688         else
689                 GetTeamCounts(world);
690
691         // c1...c4 now have counts of each team
692         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
693
694         // 2 gives priority to what team you're already on, 1 goes in order
695         // 2 doesn't seem to work though...
696         balance_type = 1;
697
698         if(bots_would_leave)
699         //if(pl.classname != "player")
700         if(clienttype(pl) != CLIENTTYPE_BOT)
701         {
702                 c1 -= cb1 * 255.0/256.0;
703                 c2 -= cb2 * 255.0/256.0;
704                 c3 -= cb3 * 255.0/256.0;
705                 c4 -= cb4 * 255.0/256.0;
706         }
707         maxc = max4(c1, c2, c3, c4);
708
709         RandomSelection_Init();
710         if(balance_type == 1)
711         {
712                 // 1: use team count, then score (note: can only use 8 significant bits of score)
713                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
714                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
715                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
716                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
717         }
718         else if(balance_type == 2)
719         {
720                 // 1: use team count, if equal prefer own team
721                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
722                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
723                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
724                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
725         }
726         else if(balance_type == 3)
727         {
728                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
729                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
730                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
731                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
732                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
733         }
734         return RandomSelection_chosen_float;
735 }
736
737 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
738 {
739         float smallest, selectedteam;
740
741         // don't join a team if we're not playing a team game
742         if(!teamplay)
743                 return 0;
744
745         // find out what teams are available
746         CheckAllowedTeams(pl);
747
748         // if we don't care what team he ends up on, put him on whatever team he entered as.
749         // if he's not on a valid team, then let other code put him on the smallest team
750         if(!forcebestteam)
751         {
752                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
753                         selectedteam = pl.team;
754                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
755                         selectedteam = pl.team;
756                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
757                         selectedteam = pl.team;
758                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
759                         selectedteam = pl.team;
760                 else
761                         selectedteam = -1;
762
763                 if(selectedteam > 0)
764                 {
765                         if(!only_return_best)
766                         {
767                                 SetPlayerColors(pl, selectedteam - 1);
768
769                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
770                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
771                                 LogTeamchange(pl.playerid, pl.team, 99);
772                         }
773                         return selectedteam;
774                 }
775                 // otherwise end up on the smallest team (handled below)
776         }
777
778         smallest = FindSmallestTeam(pl, TRUE);
779
780         if(!only_return_best && !pl.bot_forced_team)
781         {
782                 TeamchangeFrags(self);
783                 if(smallest == 1)
784                 {
785                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
786                 }
787                 else if(smallest == 2)
788                 {
789                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
790                 }
791                 else if(smallest == 3)
792                 {
793                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
794                 }
795                 else if(smallest == 4)
796                 {
797                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
798                 }
799                 else
800                 {
801                         error("smallest team: invalid team\n");
802                 }
803
804                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
805
806                 if(pl.deadflag == DEAD_NO)
807                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
808         }
809
810         return smallest;
811 }
812
813 //void() ctf_playerchanged;
814 void SV_ChangeTeam(float _color)
815 {
816         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
817
818         // in normal deathmatch we can just apply the color and we're done
819         if(!teamplay) {
820                 SetPlayerColors(self, _color);
821                 return;
822         }
823
824         scolor = self.clientcolors & 0x0F;
825         dcolor = _color & 0x0F;
826
827         if(scolor == COLOR_TEAM1 - 1)
828                 steam = 1;
829         else if(scolor == COLOR_TEAM2 - 1)
830                 steam = 2;
831         else if(scolor == COLOR_TEAM3 - 1)
832                 steam = 3;
833         else // if(scolor == COLOR_TEAM4 - 1)
834                 steam = 4;
835         if(dcolor == COLOR_TEAM1 - 1)
836                 dteam = 1;
837         else if(dcolor == COLOR_TEAM2 - 1)
838                 dteam = 2;
839         else if(dcolor == COLOR_TEAM3 - 1)
840                 dteam = 3;
841         else // if(dcolor == COLOR_TEAM4 - 1)
842                 dteam = 4;
843
844         CheckAllowedTeams(self);
845
846         if(dteam == 1 && c1 < 0) dteam = 4;
847         if(dteam == 4 && c4 < 0) dteam = 3;
848         if(dteam == 3 && c3 < 0) dteam = 2;
849         if(dteam == 2 && c2 < 0) dteam = 1;
850
851         // not changing teams
852         if(scolor == dcolor)
853         {
854                 //bprint("same team change\n");
855                 SetPlayerTeam(self, dteam, steam, TRUE);
856                 return;
857         }
858
859         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
860                 sprint(self, "Team changes not allowed\n");
861                 return; // changing teams is not allowed
862         }
863
864         if(autocvar_g_balance_teams_prevent_imbalance)
865         {
866                 // only allow changing to a smaller or equal size team
867
868                 // find out what teams are available
869                 //CheckAllowedTeams();
870                 // count how many players on each team
871                 GetTeamCounts(world);
872
873                 // get desired team
874                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
875                 {
876                         dcount = c1;
877                         dbotcount = cb1;
878                 }
879                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
880                 {
881                         dcount = c2;
882                         dbotcount = cb2;
883                 }
884                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
885                 {
886                         dcount = c3;
887                         dbotcount = cb3;
888                 }
889                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
890                 {
891                         dcount = c4;
892                         dbotcount = cb4;
893                 }
894                 else
895                 {
896                         sprint(self, "Cannot change to an invalid team\n");
897
898                         return;
899                 }
900
901                 // get starting team
902                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
903                         scount = c1;
904                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
905                         scount = c2;
906                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
907                         scount = c3;
908                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
909                         scount = c4;
910
911                 if(scount) // started at a valid, nonempty team
912                 {
913                         // check if we're trying to change to a larger team that doens't have bots to swap with
914                         if(dcount >= scount && dbotcount <= 0)
915                         {
916                                 sprint(self, "Cannot change to a larger team\n");
917                                 return; // can't change to a larger team
918                         }
919                 }
920         }
921
922 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
923
924         if(self.classname == "player" && steam != dteam)
925         {
926                 // reduce frags during a team change
927                 TeamchangeFrags(self);
928         }
929
930         SetPlayerTeam(self, dteam, steam, FALSE);
931
932         if(self.classname == "player" && steam != dteam)
933         {
934                 // kill player when changing teams
935                 if(self.deadflag == DEAD_NO)
936                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
937         }
938         //ctf_playerchanged();
939 }
940
941 void ShufflePlayerOutOfTeam (float source_team)
942 {
943         float smallestteam, smallestteam_count, steam;
944         float lowest_bot_score, lowest_player_score;
945         entity head, lowest_bot, lowest_player, selected;
946
947         smallestteam = 0;
948         smallestteam_count = 999999999;
949
950         if(c1 >= 0 && c1 < smallestteam_count)
951         {
952                 smallestteam = 1;
953                 smallestteam_count = c1;
954         }
955         if(c2 >= 0 && c2 < smallestteam_count)
956         {
957                 smallestteam = 2;
958                 smallestteam_count = c2;
959         }
960         if(c3 >= 0 && c3 < smallestteam_count)
961         {
962                 smallestteam = 3;
963                 smallestteam_count = c3;
964         }
965         if(c4 >= 0 && c4 < smallestteam_count)
966         {
967                 smallestteam = 4;
968                 smallestteam_count = c4;
969         }
970
971         if(!smallestteam)
972         {
973                 bprint("warning: no smallest team\n");
974                 return;
975         }
976
977         if(source_team == 1)
978                 steam = COLOR_TEAM1;
979         else if(source_team == 2)
980                 steam = COLOR_TEAM2;
981         else if(source_team == 3)
982                 steam = COLOR_TEAM3;
983         else if(source_team == 4)
984                 steam = COLOR_TEAM4;
985
986         lowest_bot = world;
987         lowest_bot_score = 999999999;
988         lowest_player = world;
989         lowest_player_score = 999999999;
990
991         // find the lowest-scoring player & bot of that team
992         FOR_EACH_PLAYER(head)
993         {
994                 if(head.team == steam)
995                 {
996                         if(head.isbot)
997                         {
998                                 if(head.totalfrags < lowest_bot_score)
999                                 {
1000                                         lowest_bot = head;
1001                                         lowest_bot_score = head.totalfrags;
1002                                 }
1003                         }
1004                         else
1005                         {
1006                                 if(head.totalfrags < lowest_player_score)
1007                                 {
1008                                         lowest_player = head;
1009                                         lowest_player_score = head.totalfrags;
1010                                 }
1011                         }
1012                 }
1013         }
1014
1015         // prefers to move a bot...
1016         if(lowest_bot != world)
1017                 selected = lowest_bot;
1018         // but it will move a player if it has to
1019         else
1020                 selected = lowest_player;
1021         // don't do anything if it couldn't find anyone
1022         if(!selected)
1023         {
1024                 bprint("warning: couldn't find a player to move from team\n");
1025                 return;
1026         }
1027
1028         // smallest team gains a member
1029         if(smallestteam == 1)
1030         {
1031                 c1 = c1 + 1;
1032         }
1033         else if(smallestteam == 2)
1034         {
1035                 c2 = c2 + 1;
1036         }
1037         else if(smallestteam == 3)
1038         {
1039                 c3 = c3 + 1;
1040         }
1041         else if(smallestteam == 4)
1042         {
1043                 c4 = c4 + 1;
1044         }
1045         else
1046         {
1047                 bprint("warning: destination team invalid\n");
1048                 return;
1049         }
1050         // source team loses a member
1051         if(source_team == 1)
1052         {
1053                 c1 = c1 + 1;
1054         }
1055         else if(source_team == 2)
1056         {
1057                 c2 = c2 + 2;
1058         }
1059         else if(source_team == 3)
1060         {
1061                 c3 = c3 + 3;
1062         }
1063         else if(source_team == 4)
1064         {
1065                 c4 = c4 + 4;
1066         }
1067         else
1068         {
1069                 bprint("warning: source team invalid\n");
1070                 return;
1071         }
1072
1073         // move the player to the new team
1074         TeamchangeFrags(selected);
1075         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1076
1077         if(selected.deadflag == DEAD_NO)
1078                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1079         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1080 }
1081
1082 void CauseRebalance(float source_team, float howmany_toomany)
1083 {
1084         if(IsTeamBalanceForced() == 1)
1085         {
1086                 bprint("Rebalancing Teams\n");
1087                 ShufflePlayerOutOfTeam(source_team);
1088         }
1089 }
1090
1091 // part of g_balance_teams_force
1092 // occasionally perform an audit of the teams to make
1093 // sure they're more or less balanced in player count.
1094 void AuditTeams()
1095 {
1096         float numplayers, numteams, smallest, toomany;
1097         float balance;
1098         balance = IsTeamBalanceForced();
1099         if(balance == 0)
1100                 return;
1101
1102         if(audit_teams_time > time)
1103                 return;
1104
1105         audit_teams_time = time + 4 + random();
1106
1107 //      bprint("Auditing teams\n");
1108
1109         CheckAllowedTeams(world);
1110         GetTeamCounts(world);
1111
1112
1113         numteams = numplayers = smallest = 0;
1114         if(c1 >= 0)
1115         {
1116                 numteams = numteams + 1;
1117                 numplayers = numplayers + c1;
1118                 smallest = c1;
1119         }
1120         if(c2 >= 0)
1121         {
1122                 numteams = numteams + 1;
1123                 numplayers = numplayers + c2;
1124                 if(c2 < smallest)
1125                         smallest = c2;
1126         }
1127         if(c3 >= 0)
1128         {
1129                 numteams = numteams + 1;
1130                 numplayers = numplayers + c3;
1131                 if(c3 < smallest)
1132                         smallest = c3;
1133         }
1134         if(c4 >= 0)
1135         {
1136                 numteams = numteams + 1;
1137                 numplayers = numplayers + c4;
1138                 if(c4 < smallest)
1139                         smallest = c4;
1140         }
1141
1142         if(numplayers <= 0)
1143                 return; // no players to move around
1144         if(numteams < 2)
1145                 return; // don't bother shuffling if for some reason there aren't any teams
1146
1147         toomany = smallest + 1;
1148
1149         if(c1 && c1 > toomany)
1150                 CauseRebalance(1, c1 - toomany);
1151         if(c2 && c2 > toomany)
1152                 CauseRebalance(2, c2 - toomany);
1153         if(c3 && c3 > toomany)
1154                 CauseRebalance(3, c3 - toomany);
1155         if(c4 && c4 > toomany)
1156                 CauseRebalance(4, c4 - toomany);
1157
1158         // if teams are still unbalanced, balance them further in the next audit,
1159         // which will happen sooner (keep doing rapid audits until things are in order)
1160         audit_teams_time = time + 0.7 + random()*0.3;
1161 }
1162
1163 // code from here on is just to support maps that don't have team entities
1164 void tdm_spawnteam (string teamname, float teamcolor)
1165 {
1166         entity e;
1167         e = spawn();
1168         e.classname = "tdm_team";
1169         e.netname = teamname;
1170         e.cnt = teamcolor;
1171         e.team = e.cnt + 1;
1172 }
1173
1174 // spawn some default teams if the map is not set up for tdm
1175 void tdm_spawnteams()
1176 {
1177         float numteams;
1178
1179         numteams = autocvar_g_tdm_teams_override;
1180         if(numteams < 2)
1181                 numteams = autocvar_g_tdm_teams;
1182         numteams = bound(2, numteams, 4);
1183
1184         tdm_spawnteam("Red", COLOR_TEAM1-1);
1185         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1186         if(numteams >= 3)
1187                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1188         if(numteams >= 4)
1189                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1190 }
1191
1192 void tdm_delayedinit()
1193 {
1194         // if no teams are found, spawn defaults
1195         if (find(world, classname, "tdm_team") == world)
1196                 tdm_spawnteams();
1197 }
1198
1199 void tdm_init()
1200 {
1201         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1202 }