This seems to fix team modes in campaign. Yay.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / teamplay.qc
1 string cache_mutatormsg;
2 string cache_lastmutatormsg;
3
4 // client counts for each team
5 float c1, c2, c3, c4;
6 // # of bots on those teams
7 float cb1, cb2, cb3, cb4;
8
9 float audit_teams_time;
10
11 float IsTeamBalanceForced()
12 {
13         if(intermission_running)
14                 return 0; // no rebalancing whatsoever please
15         if(!teams_matter)
16                 return 0;
17         if(autocvar_g_campaign)
18                 return 0;
19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
20                 return 0;
21         if(!autocvar_g_balance_teams_force)
22                 return -1;
23         return 1;
24 }
25
26 void TeamchangeFrags(entity e)
27 {
28         PlayerScore_Clear(e);
29 }
30
31 vector TeamColor(float teem)
32 {
33         switch(teem)
34         {
35                 case COLOR_TEAM1:
36                         return '1 0.0625 0.0625';
37                 case COLOR_TEAM2:
38                         return '0.0625 0.0625 1';
39                 case COLOR_TEAM3:
40                         return '1 1 0.0625';
41                 case COLOR_TEAM4:
42                         return '1 0.0625 1';
43                 default:
44                         return '1 1 1';
45         }
46 }
47
48 string TeamName(float t)
49 {
50         return strcat(Team_ColorName(t), " Team");
51 }
52 string ColoredTeamName(float t)
53 {
54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
55 }
56 string TeamNoName(float t)
57 {
58         // fixme: Search for team entities and get their .netname's!
59         if(t == 1)
60                 return "Red Team";
61         if(t == 2)
62                 return "Blue Team";
63         if(t == 3)
64                 return "Yellow Team";
65         if(t == 4)
66                 return "Pink Team";
67         return "Neutral Team";
68 }
69
70 void dom_init();
71 void ctf_init();
72 void runematch_init();
73 void tdm_init();
74 void nb_init();
75 void entcs_init();
76
77 void LogTeamchange(float player_id, float team_number, float type)
78 {
79         if(!autocvar_sv_eventlog)
80                 return;
81
82         if(player_id < 1)
83                 return;
84
85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
86 }
87
88 void WriteGameCvars()
89 {
90         cvar_set("g_dm", ftos(g_dm));
91         cvar_set("g_tdm", ftos(g_tdm));
92         cvar_set("g_domination", ftos(g_domination));
93         cvar_set("g_ctf", ftos(g_ctf));
94         cvar_set("g_runematch", ftos(g_runematch));
95         cvar_set("g_lms", ftos(g_lms));
96         cvar_set("g_arena", ftos(g_arena));
97         cvar_set("g_ca", ftos(g_ca));
98         cvar_set("g_keyhunt", ftos(g_keyhunt));
99         cvar_set("g_assault", ftos(g_assault));
100         cvar_set("g_onslaught", ftos(g_onslaught));
101         cvar_set("g_race", ftos(g_race));
102         cvar_set("g_nexball", ftos(g_nexball));
103         cvar_set("g_cts", ftos(g_cts));
104         cvar_set("g_freezetag", ftos(g_freezetag));
105         cvar_set("g_keepaway", ftos(g_keepaway));
106 }
107
108 void ReadGameCvars()
109 {
110         float found;
111         float prev;
112         float i;
113
114         found = 0;
115         prev = autocvar_gamecfg;
116         for(i = 0; i < 2; ++i)
117         {
118 //#NO AUTOCVARS START
119                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
120                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
121                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
122                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
123                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
124                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
125                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
126                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
127                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
128                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
129                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
130                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
131                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
132                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
133                 found += (g_freezetag = (!found && (prev != GAME_FREEZETAG) && cvar("g_freezetag")));
134                 found += (g_keepaway = (!found && (prev != GAME_KEEPAWAY) && cvar("g_keepaway")));
135 //#NO AUTOCVARS END
136
137                 if(found)
138                         break;
139
140                 prev = -1; // second attempt takes place WITHOUT prev set
141         }
142
143         if(!found)
144                 g_dm = 1;
145
146         if(g_dm && autocvar_deathmatch_force_teamplay)
147         {
148                 g_dm = 0;
149                 g_tdm = 1;
150         }
151
152         teams_matter = 0;
153 }
154
155 void default_delayedinit()
156 {
157         if(!scores_initialized)
158                 ScoreRules_generic();
159 }
160
161 void ActivateTeamplay()
162 {
163         serverflags |= SERVERFLAG_TEAMPLAY;
164         teams_matter = 1;
165 }
166
167 void InitGameplayMode()
168 {
169         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
170
171         qualifying_override = -1;
172
173         VoteReset();
174
175         teams_matter = 0;
176
177         // make sure only ONE type is selected
178         ReadGameCvars();
179         WriteGameCvars();
180
181         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
182         get_mi_min_max(1);
183         world.mins = mi_min;
184         world.maxs = mi_max;
185
186         MapInfo_LoadMapSettings(mapname);
187
188         if not(cvar_value_issafe(world.fog))
189         {
190                 print("The current map contains a potentially harmful fog setting, ignored\n");
191                 world.fog = string_null;
192         }
193         if(MapInfo_Map_fog != "")
194                 if(MapInfo_Map_fog == "none")
195                         world.fog = string_null;
196                 else
197                         world.fog = strzone(MapInfo_Map_fog);
198         clientstuff = strzone(MapInfo_Map_clientstuff);
199
200         MapInfo_ClearTemps();
201
202         // in case mapinfo switched the type
203         ReadGameCvars();
204
205         // set both here, gamemode can override it later
206         timelimit_override = autocvar_timelimit_override;
207         fraglimit_override = autocvar_fraglimit_override;
208         leadlimit_override = autocvar_leadlimit_override;
209
210         if(g_dm)
211         {
212                 game = GAME_DEATHMATCH;
213                 gamemode_name = "Deathmatch";
214         }
215
216         if(g_tdm)
217         {
218                 game = GAME_TEAM_DEATHMATCH;
219                 gamemode_name = "Team Deathmatch";
220                 ActivateTeamplay();
221                 tdm_init();
222                 if(autocvar_g_tdm_team_spawns)
223                         have_team_spawns = -1; // request team spawns
224         }
225
226         if(g_domination)
227         {
228                 game = GAME_DOMINATION;
229                 gamemode_name = "Domination";
230                 ActivateTeamplay();
231                 fraglimit_override = autocvar_g_domination_point_limit;
232                 leadlimit_override = autocvar_g_domination_point_leadlimit;
233                 dom_init();
234                 have_team_spawns = -1; // request team spawns
235         }
236
237         if(g_ctf)
238         {
239                 game = GAME_CTF;
240                 gamemode_name = "Capture the Flag";
241                 ActivateTeamplay();
242                 g_ctf_win_mode = autocvar_g_ctf_win_mode;
243                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
244                 if(g_ctf_win_mode == 2)
245                 {
246                         fraglimit_override = autocvar_g_ctf_capture_limit;
247                         leadlimit_override = autocvar_g_ctf_capture_leadlimit;
248                 }
249                 else
250                 {
251                         fraglimit_override = autocvar_capturelimit_override;
252                         leadlimit_override = autocvar_captureleadlimit_override;
253                 }
254                 ctf_init();
255                 have_team_spawns = -1; // request team spawns
256         }
257
258         if(g_runematch)
259         {
260                 game = GAME_RUNEMATCH;
261                 gamemode_name = "Rune Match";
262                 if(autocvar_deathmatch_force_teamplay)
263                         ActivateTeamplay();
264                 fraglimit_override = autocvar_g_runematch_point_limit;
265                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
266                 runematch_init();
267         }
268
269         if(g_lms)
270         {
271                 game = GAME_LMS;
272                 gamemode_name = "Last Man Standing";
273                 fraglimit_override = autocvar_g_lms_lives_override;
274                 leadlimit_override = 0; // not supported by LMS
275                 if(fraglimit_override == 0)
276                         fraglimit_override = -1;
277                 lms_lowest_lives = 9999;
278                 lms_next_place = 0;
279                 ScoreRules_lms();
280         }
281
282         if(g_arena)
283         {
284                 game = GAME_ARENA;
285                 gamemode_name = "Arena";
286                 fraglimit_override = autocvar_g_arena_point_limit;
287                 leadlimit_override = autocvar_g_arena_point_leadlimit;
288                 maxspawned = autocvar_g_arena_maxspawned;
289                 if(maxspawned < 2)
290                         maxspawned = 2;
291                 arena_roundbased = autocvar_g_arena_roundbased;
292         }
293
294         if(g_ca)
295         {
296                 game = GAME_CA;
297                 gamemode_name = "Clan Arena";
298                 ActivateTeamplay();
299                 fraglimit_override = autocvar_g_ca_point_limit;
300                 leadlimit_override = autocvar_g_ca_point_leadlimit;
301                 precache_sound("ctf/red_capture.wav");
302                 precache_sound("ctf/blue_capture.wav");
303         }
304         if(g_keyhunt)
305         {
306                 game = GAME_KEYHUNT;
307                 gamemode_name = "Key Hunt";
308                 ActivateTeamplay();
309                 fraglimit_override = autocvar_g_keyhunt_point_limit;
310                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
311                 MUTATOR_ADD(gamemode_keyhunt);
312         }
313
314         if(g_freezetag)
315         {
316                 game = GAME_FREEZETAG;
317                 gamemode_name = "Freeze Tag";
318                 ActivateTeamplay();
319                 fraglimit_override = autocvar_g_freezetag_point_limit;
320                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
321                 MUTATOR_ADD(gamemode_freezetag);
322         }
323
324         if(g_assault)
325         {
326                 game = GAME_ASSAULT;
327                 gamemode_name = "Assault";
328                 ActivateTeamplay();
329                 ScoreRules_assault();
330                 have_team_spawns = -1; // request team spawns
331         }
332
333         if(g_onslaught)
334         {
335                 game = GAME_ONSLAUGHT;
336                 gamemode_name = "Onslaught";
337                 ActivateTeamplay();
338                 have_team_spawns = -1; // request team spawns
339         }
340
341         if(g_race)
342         {
343                 game = GAME_RACE;
344                 gamemode_name = "Race";
345
346                 if(autocvar_g_race_teams)
347                 {
348                         ActivateTeamplay();
349                         race_teams = bound(2, autocvar_g_race_teams, 4);
350                         have_team_spawns = -1; // request team spawns
351                 }
352                 else
353                         race_teams = 0;
354
355                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
356                 fraglimit_override = autocvar_g_race_laps_limit;
357                 leadlimit_override = 0; // currently not supported by race
358         }
359
360         if(g_cts)
361         {
362                 game = GAME_CTS;
363                 gamemode_name = "CTS";
364                 g_race_qualifying = 1;
365                 fraglimit_override = 0;
366                 leadlimit_override = 0;
367         }
368
369         if(g_nexball)
370         {
371                 game = GAME_NEXBALL;
372                 gamemode_name = "Nexball";
373                 fraglimit_override = autocvar_g_nexball_goallimit;
374                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
375                 ActivateTeamplay();
376                 nb_init();
377                 have_team_spawns = -1; // request team spawns
378         }
379
380         if(g_keepaway)
381         {
382                 game = GAME_KEEPAWAY;
383                 gamemode_name = "Keepaway";
384                 MUTATOR_ADD(gamemode_keepaway);
385         }
386
387         if(teams_matter)
388                 entcs_init();
389
390         // save it (for the next startup)
391         cvar_set("gamecfg", ftos(game));
392
393         cache_mutatormsg = strzone("");
394         cache_lastmutatormsg = strzone("");
395
396         // enforce the server's universal frag/time limits
397         if(!autocvar_g_campaign)
398         {
399                 if(fraglimit_override >= 0)
400                         cvar_set("fraglimit", ftos(fraglimit_override));
401                 if(timelimit_override >= 0)
402                         cvar_set("timelimit", ftos(timelimit_override));
403                 if(leadlimit_override >= 0)
404                         cvar_set("leadlimit", ftos(leadlimit_override));
405                 if(qualifying_override >= 0)
406                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
407         }
408
409         if(g_race)
410         {
411                 // we need to find out the correct value for g_race_qualifying
412                 if(autocvar_g_campaign)
413                 {
414                         g_race_qualifying = 1;
415                 }
416                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
417                 {
418                         g_race_qualifying = 2;
419                         race_fraglimit = autocvar_fraglimit;
420                         race_leadlimit = autocvar_leadlimit;
421                         race_timelimit = autocvar_timelimit;
422                         cvar_set("fraglimit", "0");
423                         cvar_set("leadlimit", "0");
424                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
425                 }
426                 else
427                         g_race_qualifying = 0;
428         }
429
430         if(g_race || g_cts)
431         {
432                 if(g_race_qualifying)
433                         independent_players = 1;
434
435                 ScoreRules_race();
436         }
437
438         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
439 }
440
441 string GetClientVersionMessage() {
442         local string versionmsg;
443         if (self.version_mismatch) {
444                 if(self.version < autocvar_gameversion) {
445                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
446                 } else {
447                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
448                 }
449         } else {
450                 versionmsg = "^2client version and server version are compatible.^8";
451         }
452         return versionmsg;
453 }
454
455
456 void PrintWelcomeMessage(entity pl)
457 {
458         string s, modifications, motd;
459
460         if(self.cvar_scr_centertime == 0) return;
461
462         if(autocvar_g_campaign)
463         {
464                 if(self.classname == "player" && !self.BUTTON_INFO)
465                         return;
466         }
467         else
468         {
469                 if((time - self.jointime) > autocvar_welcome_message_time && !self.BUTTON_INFO)
470                         return;
471         }
472
473         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
474                 if(self.welcomemessage_time > time) return;
475                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
476         }
477
478         if(autocvar_g_campaign)
479         {
480                 centerprint(pl, campaign_message);
481                 return;
482         }
483
484 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
485         if(!self.BUTTON_INFO)
486         {
487                 // TODO get rid of this too
488                 local string specString;
489                 specString = NEWLINES;
490                 //if(time < game_starttime) //also show the countdown when being a spectator
491                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
492                 //else
493                 if (timeoutStatus != 0)
494                         specString = strcat(specString, "\n\n", getTimeoutText(1));
495                 else
496                 {
497                         if(self.classname == "player")
498                                 return;
499                         goto normal;
500                 }
501                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
502         }
503
504 :normal
505         ret_string = "";
506         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
507         modifications = ret_string;
508         
509         if(g_minstagib)
510                 modifications = strcat(modifications, ", MinstaGib");
511         if(g_weaponarena)
512         {
513                 if(g_weaponarena_random)
514                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
515                 else
516                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
517         }
518         if(autocvar_g_start_weapon_laser == 0)
519                 modifications = strcat(modifications, ", No start weapons");
520         if(autocvar_sv_gravity < 800)
521                 modifications = strcat(modifications, ", Low gravity");
522         if(g_cloaked)
523                 modifications = strcat(modifications, ", Cloaked");
524         if(g_grappling_hook)
525                 modifications = strcat(modifications, ", Hook");
526         if(g_midair)
527                 modifications = strcat(modifications, ", Midair");
528         if(g_pinata)
529                 modifications = strcat(modifications, ", Pinata");
530         if(g_weapon_stay)
531                 modifications = strcat(modifications, ", Weapons stay");
532         if(g_bloodloss > 0)
533                 modifications = strcat(modifications, ", Bloodloss");
534         if(g_jetpack)
535                 modifications = strcat(modifications, ", Jet pack");
536         modifications = substring(modifications, 2, strlen(modifications) - 2);
537
538         local string versionmessage;
539         versionmessage = GetClientVersionMessage();
540
541         s = strcat(s, NEWLINES, "This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
542         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
543
544         if(modifications != "")
545                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
546
547         if(timeoutStatus != 0)
548                 s = strcat(s, "\n\n", getTimeoutText(1));
549
550         if (g_grappling_hook)
551                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
552
553         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
554         {
555                 if(cache_lastmutatormsg)
556                         strunzone(cache_lastmutatormsg);
557                 if(cache_mutatormsg)
558                         strunzone(cache_mutatormsg);
559                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
560                 cache_mutatormsg = strzone(cache_lastmutatormsg);
561         }
562
563         if (cache_mutatormsg != "") {
564                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
565         }
566
567         motd = autocvar_sv_motd;
568         if (motd != "") {
569                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
570         }
571         s = strcat(s, "\n");
572
573         centerprint(pl, s);
574 }
575
576
577 void SetPlayerColors(entity pl, float _color)
578 {
579         /*string s;
580         s = ftos(cl);
581         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
582         pl.team = cl + 1;
583         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
584         pl.clientcolors = 16*cl + cl;*/
585
586         float pants, shirt;
587         pants = _color & 0x0F;
588         shirt = _color & 0xF0;
589
590
591         if(teams_matter) {
592                 setcolor(pl, 16*pants + pants);
593         } else {
594                 setcolor(pl, shirt + pants);
595         }
596 }
597
598 void SetPlayerTeam(entity pl, float t, float s, float noprint)
599 {
600         float _color;
601
602         if(t == 4)
603                 _color = COLOR_TEAM4 - 1;
604         else if(t == 3)
605                 _color = COLOR_TEAM3 - 1;
606         else if(t == 2)
607                 _color = COLOR_TEAM2 - 1;
608         else
609                 _color = COLOR_TEAM1 - 1;
610
611         SetPlayerColors(pl,_color);
612
613         if(t != s) {
614                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
615
616                 if(!noprint)
617                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
618         }
619
620 }
621
622 // set c1...c4 to show what teams are allowed
623 void CheckAllowedTeams (entity for_whom)
624 {
625         float dm;
626         entity head;
627         string teament_name;
628
629         c1 = c2 = c3 = c4 = -1;
630         cb1 = cb2 = cb3 = cb4 = 0;
631
632         if(autocvar_g_campaign && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
633         {
634                 c1 = 0; // only allow RED team for player joining
635         }
636         else if(g_onslaught)
637         {
638                 // onslaught is special
639                 head = findchain(classname, "onslaught_generator");
640                 while (head)
641                 {
642                         if (head.team == COLOR_TEAM1) c1 = 0;
643                         if (head.team == COLOR_TEAM2) c2 = 0;
644                         if (head.team == COLOR_TEAM3) c3 = 0;
645                         if (head.team == COLOR_TEAM4) c4 = 0;
646                         head = head.chain;
647                 }
648         }
649         else if(g_domination)
650                 teament_name = "dom_team";
651         else if(g_ctf)
652                 teament_name = "ctf_team";
653         else if(g_tdm)
654                 teament_name = "tdm_team";
655         else if(g_nexball)
656                 teament_name = "nexball_team";
657         else if(g_assault)
658                 c1 = c2 = 0; // Assault always has 2 teams
659         else
660         {
661                 // cover anything else by treating it like tdm with no teams spawned
662                 if(g_race)
663                         dm = race_teams;
664                 else
665                         dm = 2;
666
667                 ret_float = dm;
668                 MUTATOR_CALLHOOK(GetTeamCount);
669                 dm = ret_float;
670
671                 if(dm >= 4)
672                         c1 = c2 = c3 = c4 = 0;
673                 else if(dm >= 3)
674                         c1 = c2 = c3 = 0;
675                 else
676                         c1 = c2 = 0;
677         }
678
679         // find out what teams are allowed if necessary
680         if(teament_name)
681         {
682                 head = find(world, classname, teament_name);
683                 while(head)
684                 {
685                         if(!(g_domination && head.netname == ""))
686                         {
687                                 if(head.team == COLOR_TEAM1)
688                                         c1 = 0;
689                                 else if(head.team == COLOR_TEAM2)
690                                         c2 = 0;
691                                 else if(head.team == COLOR_TEAM3)
692                                         c3 = 0;
693                                 else if(head.team == COLOR_TEAM4)
694                                         c4 = 0;
695                         }
696                         head = find(head, classname, teament_name);
697                 }
698         }
699
700         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
701         if(c3==-1 && c4==-1)
702         if(autocvar_bot_vs_human && for_whom)
703         {
704                 if(autocvar_bot_vs_human > 0)
705                 {
706                         // bots are all blue
707                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
708                                 c1 = c3 = c4 = -1;
709                         else
710                                 c2 = -1;
711                 }
712                 else
713                 {
714                         // bots are all red
715                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
716                                 c2 = c3 = c4 = -1;
717                         else
718                                 c1 = -1;
719                 }
720         }
721
722         // if player has a forced team, ONLY allow that one
723         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
724                 c2 = c3 = c4 = -1;
725         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
726                 c1 = c3 = c4 = -1;
727         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
728                 c1 = c2 = c4 = -1;
729         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
730                 c1 = c2 = c3 = -1;
731 }
732
733 float PlayerValue(entity p)
734 {
735         if(IsTeamBalanceForced() == 1)
736                 return 1;
737         return 1;
738         // FIXME: it always returns 1...
739 }
740
741 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
742 // teams that are allowed will now have their player counts stored in c1...c4
743 void GetTeamCounts(entity ignore)
744 {
745         entity head;
746         float value, bvalue;
747         // now count how many players are on each team already
748
749         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
750         // also remember the lowest-scoring player
751
752         FOR_EACH_PLAYER(head)
753         {
754                 if(head != ignore)// && head.netname != "")
755                 {
756                         value = PlayerValue(head);
757                         if(clienttype(head) == CLIENTTYPE_BOT)
758                                 bvalue = value;
759                         else
760                                 bvalue = 0;
761                         if(head.team == COLOR_TEAM1)
762                         {
763                                 if(c1 >= 0)
764                                 {
765                                         c1 = c1 + value;
766                                         cb1 = cb1 + bvalue;
767                                 }
768                         }
769                         if(head.team == COLOR_TEAM2)
770                         {
771                                 if(c2 >= 0)
772                                 {
773                                         c2 = c2 + value;
774                                         cb2 = cb2 + bvalue;
775                                 }
776                         }
777                         if(head.team == COLOR_TEAM3)
778                         {
779                                 if(c3 >= 0)
780                                 {
781                                         c3 = c3 + value;
782                                         cb3 = cb3 + bvalue;
783                                 }
784                         }
785                         if(head.team == COLOR_TEAM4)
786                         {
787                                 if(c4 >= 0)
788                                 {
789                                         c4 = c4 + value;
790                                         cb4 = cb4 + bvalue;
791                                 }
792                         }
793                 }
794         }
795 }
796
797 // returns # of smallest team (1, 2, 3, 4)
798 // NOTE: Assumes CheckAllowedTeams has already been called!
799 float FindSmallestTeam(entity pl, float ignore_pl)
800 {
801         float totalteams, balance_type, maxc;
802         totalteams = 0;
803
804         // find out what teams are available
805         //CheckAllowedTeams();
806
807         // make sure there are at least 2 teams to join
808         if(c1 >= 0)
809                 totalteams = totalteams + 1;
810         if(c2 >= 0)
811                 totalteams = totalteams + 1;
812         if(c3 >= 0)
813                 totalteams = totalteams + 1;
814         if(c4 >= 0)
815                 totalteams = totalteams + 1;
816
817         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
818                 totalteams += 1;
819
820         if(totalteams <= 1)
821         {
822                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
823                         return 1; // special case for campaign and player joining
824                 else if(g_domination)
825                         error("Too few teams available for domination\n");
826                 else if(g_ctf)
827                         error("Too few teams available for ctf\n");
828                 else if(g_keyhunt)
829                         error("Too few teams available for key hunt\n");
830                 else if(g_freezetag)
831                         error("Too few teams available for freeze tag\n");
832                 else
833                         error("Too few teams available for team deathmatch\n");
834         }
835
836         // count how many players are in each team
837         if(ignore_pl)
838                 GetTeamCounts(pl);
839         else
840                 GetTeamCounts(world);
841
842         // c1...c4 now have counts of each team
843         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
844
845     if(autocvar_g_campaign)
846     {
847         entity e;
848         FOR_EACH_REALCLIENT(e)
849             if(e.team != COLOR_TEAM1) // player is forced to the red team in campaign
850                 ++c1; // player will join the red team, join bots accordingly
851     }
852         // 2 gives priority to what team you're already on, 1 goes in order
853         // 2 doesn't seem to work though...
854         balance_type = 1;
855
856         if(bots_would_leave)
857         //if(pl.classname != "player")
858         if(clienttype(pl) != CLIENTTYPE_BOT)
859         {
860                 c1 -= cb1 * 255.0/256.0;
861                 c2 -= cb2 * 255.0/256.0;
862                 c3 -= cb3 * 255.0/256.0;
863                 c4 -= cb4 * 255.0/256.0;
864         }
865         maxc = max4(c1, c2, c3, c4);
866
867         RandomSelection_Init();
868         if(balance_type == 1)
869         {
870                 // 1: use team count, then score (note: can only use 8 significant bits of score)
871                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
872                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
873                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
874                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
875         }
876         else if(balance_type == 2)
877         {
878                 // 1: use team count, if equal prefer own team
879                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
880                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
881                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
882                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
883         }
884         else if(balance_type == 3)
885         {
886                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
887                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
888                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
889                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
890                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
891         }
892         return RandomSelection_chosen_float;
893 }
894
895 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
896 {
897         float smallest, selectedteam;
898
899         // don't join a team if we're not playing a team game
900         if(!teams_matter)
901                 return 0;
902
903         // find out what teams are available
904         CheckAllowedTeams(pl);
905
906         // if we want the player in a certain team for campaign, force him there
907         if(autocvar_g_campaign)
908         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
909         {
910                 switch(autocvar_g_campaign_forceteam)
911                 {
912                         case 1:
913                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
914                                 LogTeamchange(pl.playerid, pl.team, 2);
915                                 return COLOR_TEAM1;
916                         case 2:
917                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
918                                 LogTeamchange(pl.playerid, pl.team, 2);
919                                 return COLOR_TEAM2;
920                         case 3:
921                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
922                                 LogTeamchange(pl.playerid, pl.team, 2);
923                                 return COLOR_TEAM3;
924                         case 4:
925                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
926                                 LogTeamchange(pl.playerid, pl.team, 2);
927                                 return COLOR_TEAM4;
928                         default:
929                                 break;
930                 }
931         }
932
933         // if we don't care what team he ends up on, put him on whatever team he entered as.
934         // if he's not on a valid team, then let other code put him on the smallest team
935         if(!forcebestteam)
936         {
937                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
938                         selectedteam = pl.team;
939                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
940                         selectedteam = pl.team;
941                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
942                         selectedteam = pl.team;
943                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
944                         selectedteam = pl.team;
945                 else
946                         selectedteam = -1;
947
948                 if(selectedteam > 0)
949                 {
950                         if(!only_return_best)
951                         {
952                                 SetPlayerColors(pl, selectedteam - 1);
953
954                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
955                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
956                                 LogTeamchange(pl.playerid, pl.team, 99);
957                         }
958                         return selectedteam;
959                 }
960                 // otherwise end up on the smallest team (handled below)
961         }
962
963         smallest = FindSmallestTeam(pl, TRUE);
964
965         if(!only_return_best && !pl.bot_forced_team)
966         {
967                 TeamchangeFrags(self);
968                 if(smallest == 1)
969                 {
970                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
971                 }
972                 else if(smallest == 2)
973                 {
974                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
975                 }
976                 else if(smallest == 3)
977                 {
978                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
979                 }
980                 else if(smallest == 4)
981                 {
982                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
983                 }
984                 else
985                 {
986                         error("smallest team: invalid team\n");
987                 }
988
989                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
990
991                 if(pl.deadflag == DEAD_NO)
992                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
993         }
994
995         return smallest;
996 }
997
998 //void() ctf_playerchanged;
999 void SV_ChangeTeam(float _color)
1000 {
1001         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
1002
1003         // in normal deathmatch we can just apply the color and we're done
1004         if(!teams_matter) {
1005                 SetPlayerColors(self, _color);
1006                 return;
1007         }
1008
1009         scolor = self.clientcolors & 0x0F;
1010         dcolor = _color & 0x0F;
1011
1012         if(scolor == COLOR_TEAM1 - 1)
1013                 steam = 1;
1014         else if(scolor == COLOR_TEAM2 - 1)
1015                 steam = 2;
1016         else if(scolor == COLOR_TEAM3 - 1)
1017                 steam = 3;
1018         else // if(scolor == COLOR_TEAM4 - 1)
1019                 steam = 4;
1020         if(dcolor == COLOR_TEAM1 - 1)
1021                 dteam = 1;
1022         else if(dcolor == COLOR_TEAM2 - 1)
1023                 dteam = 2;
1024         else if(dcolor == COLOR_TEAM3 - 1)
1025                 dteam = 3;
1026         else // if(dcolor == COLOR_TEAM4 - 1)
1027                 dteam = 4;
1028
1029         CheckAllowedTeams(self);
1030
1031         if(dteam == 1 && c1 < 0) dteam = 4;
1032         if(dteam == 4 && c4 < 0) dteam = 3;
1033         if(dteam == 3 && c3 < 0) dteam = 2;
1034         if(dteam == 2 && c2 < 0) dteam = 1;
1035
1036         // not changing teams
1037         if(scolor == dcolor)
1038         {
1039                 //bprint("same team change\n");
1040                 SetPlayerTeam(self, dteam, steam, TRUE);
1041                 return;
1042         }
1043
1044         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
1045                 sprint(self, "Team changes not allowed\n");
1046                 return; // changing teams is not allowed
1047         }
1048
1049         if(autocvar_g_balance_teams_prevent_imbalance)
1050         {
1051                 // only allow changing to a smaller or equal size team
1052
1053                 // find out what teams are available
1054                 //CheckAllowedTeams();
1055                 // count how many players on each team
1056                 GetTeamCounts(world);
1057
1058                 // get desired team
1059                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1060                 {
1061                         dcount = c1;
1062                         dbotcount = cb1;
1063                 }
1064                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1065                 {
1066                         dcount = c2;
1067                         dbotcount = cb2;
1068                 }
1069                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1070                 {
1071                         dcount = c3;
1072                         dbotcount = cb3;
1073                 }
1074                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1075                 {
1076                         dcount = c4;
1077                         dbotcount = cb4;
1078                 }
1079                 else
1080                 {
1081                         sprint(self, "Cannot change to an invalid team\n");
1082
1083                         return;
1084                 }
1085
1086                 // get starting team
1087                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1088                         scount = c1;
1089                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1090                         scount = c2;
1091                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1092                         scount = c3;
1093                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1094                         scount = c4;
1095
1096                 if(scount) // started at a valid, nonempty team
1097                 {
1098                         // check if we're trying to change to a larger team that doens't have bots to swap with
1099                         if(dcount >= scount && dbotcount <= 0)
1100                         {
1101                                 sprint(self, "Cannot change to a larger team\n");
1102                                 return; // can't change to a larger team
1103                         }
1104                 }
1105         }
1106
1107 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1108
1109         if(self.classname == "player" && steam != dteam)
1110         {
1111                 // reduce frags during a team change
1112                 TeamchangeFrags(self);
1113         }
1114
1115         SetPlayerTeam(self, dteam, steam, FALSE);
1116
1117         if(self.classname == "player" && steam != dteam)
1118         {
1119                 // kill player when changing teams
1120                 if(self.deadflag == DEAD_NO)
1121                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1122         }
1123         //ctf_playerchanged();
1124 }
1125
1126 void ShufflePlayerOutOfTeam (float source_team)
1127 {
1128         float smallestteam, smallestteam_count, steam;
1129         float lowest_bot_score, lowest_player_score;
1130         entity head, lowest_bot, lowest_player, selected;
1131
1132         smallestteam = 0;
1133         smallestteam_count = 999999999;
1134
1135         if(c1 >= 0 && c1 < smallestteam_count)
1136         {
1137                 smallestteam = 1;
1138                 smallestteam_count = c1;
1139         }
1140         if(c2 >= 0 && c2 < smallestteam_count)
1141         {
1142                 smallestteam = 2;
1143                 smallestteam_count = c2;
1144         }
1145         if(c3 >= 0 && c3 < smallestteam_count)
1146         {
1147                 smallestteam = 3;
1148                 smallestteam_count = c3;
1149         }
1150         if(c4 >= 0 && c4 < smallestteam_count)
1151         {
1152                 smallestteam = 4;
1153                 smallestteam_count = c4;
1154         }
1155
1156         if(!smallestteam)
1157         {
1158                 bprint("warning: no smallest team\n");
1159                 return;
1160         }
1161
1162         if(source_team == 1)
1163                 steam = COLOR_TEAM1;
1164         else if(source_team == 2)
1165                 steam = COLOR_TEAM2;
1166         else if(source_team == 3)
1167                 steam = COLOR_TEAM3;
1168         else if(source_team == 4)
1169                 steam = COLOR_TEAM4;
1170
1171         lowest_bot = world;
1172         lowest_bot_score = 999999999;
1173         lowest_player = world;
1174         lowest_player_score = 999999999;
1175
1176         // find the lowest-scoring player & bot of that team
1177         FOR_EACH_PLAYER(head)
1178         {
1179                 if(head.team == steam)
1180                 {
1181                         if(head.isbot)
1182                         {
1183                                 if(head.totalfrags < lowest_bot_score)
1184                                 {
1185                                         lowest_bot = head;
1186                                         lowest_bot_score = head.totalfrags;
1187                                 }
1188                         }
1189                         else
1190                         {
1191                                 if(head.totalfrags < lowest_player_score)
1192                                 {
1193                                         lowest_player = head;
1194                                         lowest_player_score = head.totalfrags;
1195                                 }
1196                         }
1197                 }
1198         }
1199
1200         // prefers to move a bot...
1201         if(lowest_bot != world)
1202                 selected = lowest_bot;
1203         // but it will move a player if it has to
1204         else
1205                 selected = lowest_player;
1206         // don't do anything if it couldn't find anyone
1207         if(!selected)
1208         {
1209                 bprint("warning: couldn't find a player to move from team\n");
1210                 return;
1211         }
1212
1213         // smallest team gains a member
1214         if(smallestteam == 1)
1215         {
1216                 c1 = c1 + 1;
1217         }
1218         else if(smallestteam == 2)
1219         {
1220                 c2 = c2 + 1;
1221         }
1222         else if(smallestteam == 3)
1223         {
1224                 c3 = c3 + 1;
1225         }
1226         else if(smallestteam == 4)
1227         {
1228                 c4 = c4 + 1;
1229         }
1230         else
1231         {
1232                 bprint("warning: destination team invalid\n");
1233                 return;
1234         }
1235         // source team loses a member
1236         if(source_team == 1)
1237         {
1238                 c1 = c1 + 1;
1239         }
1240         else if(source_team == 2)
1241         {
1242                 c2 = c2 + 2;
1243         }
1244         else if(source_team == 3)
1245         {
1246                 c3 = c3 + 3;
1247         }
1248         else if(source_team == 4)
1249         {
1250                 c4 = c4 + 4;
1251         }
1252         else
1253         {
1254                 bprint("warning: source team invalid\n");
1255                 return;
1256         }
1257
1258         // move the player to the new team
1259         TeamchangeFrags(selected);
1260         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1261
1262         if(selected.deadflag == DEAD_NO)
1263                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1264         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1265 }
1266
1267 void CauseRebalance(float source_team, float howmany_toomany)
1268 {
1269         if(IsTeamBalanceForced() == 1)
1270         {
1271                 bprint("Rebalancing Teams\n");
1272                 ShufflePlayerOutOfTeam(source_team);
1273         }
1274 }
1275
1276 // part of g_balance_teams_force
1277 // occasionally perform an audit of the teams to make
1278 // sure they're more or less balanced in player count.
1279 void AuditTeams()
1280 {
1281         float numplayers, numteams, smallest, toomany;
1282         float balance;
1283         balance = IsTeamBalanceForced();
1284         if(balance == 0)
1285                 return;
1286
1287         if(audit_teams_time > time)
1288                 return;
1289
1290         audit_teams_time = time + 4 + random();
1291
1292 //      bprint("Auditing teams\n");
1293
1294         CheckAllowedTeams(world);
1295         GetTeamCounts(world);
1296
1297
1298         numteams = numplayers = smallest = 0;
1299         if(c1 >= 0)
1300         {
1301                 numteams = numteams + 1;
1302                 numplayers = numplayers + c1;
1303                 smallest = c1;
1304         }
1305         if(c2 >= 0)
1306         {
1307                 numteams = numteams + 1;
1308                 numplayers = numplayers + c2;
1309                 if(c2 < smallest)
1310                         smallest = c2;
1311         }
1312         if(c3 >= 0)
1313         {
1314                 numteams = numteams + 1;
1315                 numplayers = numplayers + c3;
1316                 if(c3 < smallest)
1317                         smallest = c3;
1318         }
1319         if(c4 >= 0)
1320         {
1321                 numteams = numteams + 1;
1322                 numplayers = numplayers + c4;
1323                 if(c4 < smallest)
1324                         smallest = c4;
1325         }
1326
1327         if(numplayers <= 0)
1328                 return; // no players to move around
1329         if(numteams < 2)
1330                 return; // don't bother shuffling if for some reason there aren't any teams
1331
1332         toomany = smallest + 1;
1333
1334         if(c1 && c1 > toomany)
1335                 CauseRebalance(1, c1 - toomany);
1336         if(c2 && c2 > toomany)
1337                 CauseRebalance(2, c2 - toomany);
1338         if(c3 && c3 > toomany)
1339                 CauseRebalance(3, c3 - toomany);
1340         if(c4 && c4 > toomany)
1341                 CauseRebalance(4, c4 - toomany);
1342
1343         // if teams are still unbalanced, balance them further in the next audit,
1344         // which will happen sooner (keep doing rapid audits until things are in order)
1345         audit_teams_time = time + 0.7 + random()*0.3;
1346 }
1347
1348 // code from here on is just to support maps that don't have team entities
1349 void tdm_spawnteam (string teamname, float teamcolor)
1350 {
1351         local entity e;
1352         e = spawn();
1353         e.classname = "tdm_team";
1354         e.netname = teamname;
1355         e.cnt = teamcolor;
1356         e.team = e.cnt + 1;
1357 };
1358
1359 // spawn some default teams if the map is not set up for tdm
1360 void tdm_spawnteams()
1361 {
1362         float numteams;
1363
1364         numteams = autocvar_g_tdm_teams_override;
1365         if(numteams < 2)
1366                 numteams = autocvar_g_tdm_teams;
1367         numteams = bound(2, numteams, 4);
1368
1369         tdm_spawnteam("Red", COLOR_TEAM1-1);
1370         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1371         if(numteams >= 3)
1372                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1373         if(numteams >= 4)
1374                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1375 };
1376
1377 void tdm_delayedinit()
1378 {
1379         // if no teams are found, spawn defaults
1380         if (find(world, classname, "tdm_team") == world)
1381                 tdm_spawnteams();
1382 };
1383
1384 void tdm_init()
1385 {
1386         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1387 };