qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162
 163                 if(autocvar_g_race_teams)
 164                 {
 165                         ActivateTeamplay();
 166                         race_teams = bound(2, autocvar_g_race_teams, 4);
 167                         have_team_spawns = -1; // request team spawns
 168                 }
 169                 else
 170                         race_teams = 0;
 171
 172                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 173                 fraglimit_override = autocvar_g_race_laps_limit;
 174                 leadlimit_override = 0; // currently not supported by race
 175         }
 176
 177         if(g_cts)
 178         {
 179                 g_race_qualifying = 1;
 180                 fraglimit_override = 0;
 181                 leadlimit_override = 0;
 182         }
 183
 184         if(g_nexball)
 185         {
 186         fraglimit_override = autocvar_g_nexball_goallimit;
 187         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 188         ActivateTeamplay();
 189         have_team_spawns = -1; // request team spawns
 190             MUTATOR_ADD(gamemode_nexball);
 191         }
 192
 193         if(g_keepaway)
 194         {
 195                 MUTATOR_ADD(gamemode_keepaway);
 196         }
 197
 198         if(g_invasion)
 199         {
 200                 timelimit_override = 0; // no timelimit in invasion, round based
 201                 fraglimit_override = autocvar_g_invasion_round_limit;
 202                 MUTATOR_ADD(gamemode_invasion);
 203         }
 204
 205         if(teamplay)
 206                 entcs_init();
 207
 208         cache_mutatormsg = strzone("");
 209         cache_lastmutatormsg = strzone("");
 210
 211         // enforce the server's universal frag/time limits
 212         if(!autocvar_g_campaign)
 213         {
 214                 if(fraglimit_override >= 0)
 215                         cvar_set("fraglimit", ftos(fraglimit_override));
 216                 if(timelimit_override >= 0)
 217                         cvar_set("timelimit", ftos(timelimit_override));
 218                 if(leadlimit_override >= 0)
 219                         cvar_set("leadlimit", ftos(leadlimit_override));
 220                 if(qualifying_override >= 0)
 221                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 222         }
 223
 224         if(g_race)
 225         {
 226                 // we need to find out the correct value for g_race_qualifying
 227                 if(autocvar_g_campaign)
 228                 {
 229                         g_race_qualifying = 1;
 230                 }
 231                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 232                 {
 233                         g_race_qualifying = 2;
 234                         race_fraglimit = autocvar_fraglimit;
 235                         race_leadlimit = autocvar_leadlimit;
 236                         race_timelimit = autocvar_timelimit;
 237                         cvar_set("fraglimit", "0");
 238                         cvar_set("leadlimit", "0");
 239                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 240                 }
 241                 else
 242                         g_race_qualifying = 0;
 243         }
 244
 245         if(g_invasion)
 246         {
 247                 inv_maxrounds = cvar("fraglimit");
 248                 cvar_set("fraglimit", "0");
 249         }
 250
 251         if(g_race || g_cts)
 252         {
 253                 if(g_race_qualifying)
 254                         independent_players = 1;
 255
 256                 ScoreRules_race();
 257         }
 258
 259         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 260 }
 261
 262 string GetClientVersionMessage() {
 263         string versionmsg;
 264         if (self.version_mismatch) {
 265                 if(self.version < autocvar_gameversion) {
 266                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 267                 } else {
 268                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 269                 }
 270         } else {
 271                 versionmsg = "^2client version and server version are compatible.^8";
 272         }
 273         return versionmsg;
 274 }
 275
 276 string getwelcomemessage(void)
 277 {
 278         string s, modifications, motd;
 279
 280         ret_string = "";
 281         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 282         modifications = ret_string;
 283
 284         if(g_weaponarena)
 285         {
 286                 if(g_weaponarena_random)
 287                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 288                 else
 289                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 290         }
 291         if(autocvar_g_start_weapon_laser == 0)
 292                 modifications = strcat(modifications, ", No start weapons");
 293         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 294                 modifications = strcat(modifications, ", Low gravity");
 295         if(g_cloaked && !g_cts)
 296                 modifications = strcat(modifications, ", Cloaked");
 297         if(g_grappling_hook)
 298                 modifications = strcat(modifications, ", Hook");
 299         if(g_weapon_stay && !g_cts)
 300                 modifications = strcat(modifications, ", Weapons stay");
 301         if(g_jetpack)
 302                 modifications = strcat(modifications, ", Jet pack");
 303         if(autocvar_g_powerups == 0)
 304                 modifications = strcat(modifications, ", No powerups");
 305         if(autocvar_g_powerups > 0)
 306                 modifications = strcat(modifications, ", Powerups");
 307         modifications = substring(modifications, 2, strlen(modifications) - 2);
 308
 309         string versionmessage;
 310         versionmessage = GetClientVersionMessage();
 311
 312         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 313         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 314
 315         if(modifications != "")
 316                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 317
 318         if (g_grappling_hook)
 319                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 320
 321         if (cvar("g_nades"))
 322                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 323
 324         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 325         {
 326                 if(cache_lastmutatormsg)
 327                         strunzone(cache_lastmutatormsg);
 328                 if(cache_mutatormsg)
 329                         strunzone(cache_mutatormsg);
 330                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 331                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 332         }
 333
 334         if (cache_mutatormsg != "") {
 335                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 336         }
 337
 338         motd = autocvar_sv_motd;
 339         if (motd != "") {
 340                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 341         }
 342         return s;
 343 }
 344
 345 void SetPlayerColors(entity pl, float _color)
 346 {
 347         /*string s;
 348         s = ftos(cl);
 349         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 350         pl.team = cl + 1;
 351         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 352         pl.clientcolors = 16*cl + cl;*/
 353
 354         float pants, shirt;
 355         pants = _color & 0x0F;
 356         shirt = _color & 0xF0;
 357
 358
 359         if(teamplay) {
 360                 setcolor(pl, 16*pants + pants);
 361         } else {
 362                 setcolor(pl, shirt + pants);
 363         }
 364 }
 365
 366 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 367 {
 368         float _color;
 369
 370         if(t == 4)
 371                 _color = NUM_TEAM_4 - 1;
 372         else if(t == 3)
 373                 _color = NUM_TEAM_3 - 1;
 374         else if(t == 2)
 375                 _color = NUM_TEAM_2 - 1;
 376         else
 377                 _color = NUM_TEAM_1 - 1;
 378
 379         SetPlayerColors(pl,_color);
 380
 381         if(t != s) {
 382                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 383
 384                 if(!noprint)
 385                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 386         }
 387
 388 }
 389
 390 // set c1...c4 to show what teams are allowed
 391 void CheckAllowedTeams (entity for_whom)
 392 {
 393         float dm;
 394         entity head;
 395         string teament_name;
 396
 397         c1 = c2 = c3 = c4 = -1;
 398         cb1 = cb2 = cb3 = cb4 = 0;
 399
 400         teament_name = string_null;
 401         if(g_onslaught)
 402         {
 403                 // onslaught is special
 404                 head = findchain(classname, "onslaught_generator");
 405                 while (head)
 406                 {
 407                         if (head.team == NUM_TEAM_1) c1 = 0;
 408                         if (head.team == NUM_TEAM_2) c2 = 0;
 409                         if (head.team == NUM_TEAM_3) c3 = 0;
 410                         if (head.team == NUM_TEAM_4) c4 = 0;
 411                         head = head.chain;
 412                 }
 413         }
 414         else if(g_domination)
 415                 teament_name = "dom_team";
 416         else if(g_ctf)
 417                 teament_name = "ctf_team";
 418         else if(g_tdm)
 419                 teament_name = "tdm_team";
 420         else if(g_nexball)
 421                 teament_name = "nexball_team";
 422         else if(g_assault)
 423                 c1 = c2 = 0; // Assault always has 2 teams
 424         else
 425         {
 426                 // cover anything else by treating it like tdm with no teams spawned
 427                 if(g_race)
 428                         dm = race_teams;
 429                 else
 430                         dm = 2;
 431
 432                 ret_float = dm;
 433                 MUTATOR_CALLHOOK(GetTeamCount);
 434                 dm = ret_float;
 435
 436                 if(dm >= 4)
 437                         c1 = c2 = c3 = c4 = 0;
 438                 else if(dm >= 3)
 439                         c1 = c2 = c3 = 0;
 440                 else
 441                         c1 = c2 = 0;
 442         }
 443
 444         // find out what teams are allowed if necessary
 445         if(teament_name)
 446         {
 447                 head = find(world, classname, teament_name);
 448                 while(head)
 449                 {
 450                         if(!(g_domination && head.netname == ""))
 451                         {
 452                                 if(head.team == NUM_TEAM_1)
 453                                         c1 = 0;
 454                                 else if(head.team == NUM_TEAM_2)
 455                                         c2 = 0;
 456                                 else if(head.team == NUM_TEAM_3)
 457                                         c3 = 0;
 458                                 else if(head.team == NUM_TEAM_4)
 459                                         c4 = 0;
 460                         }
 461                         head = find(head, classname, teament_name);
 462                 }
 463         }
 464
 465         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 466         if(c3==-1 && c4==-1)
 467         if(autocvar_bot_vs_human && for_whom)
 468         {
 469                 if(autocvar_bot_vs_human > 0)
 470                 {
 471                         // bots are all blue
 472                         if(IS_BOT_CLIENT(for_whom))
 473                                 c1 = c3 = c4 = -1;
 474                         else
 475                                 c2 = -1;
 476                 }
 477                 else
 478                 {
 479                         // bots are all red
 480                         if(IS_BOT_CLIENT(for_whom))
 481                                 c2 = c3 = c4 = -1;
 482                         else
 483                                 c1 = -1;
 484                 }
 485         }
 486
 487         // if player has a forced team, ONLY allow that one
 488         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 489                 c2 = c3 = c4 = -1;
 490         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 491                 c1 = c3 = c4 = -1;
 492         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 493                 c1 = c2 = c4 = -1;
 494         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 495                 c1 = c2 = c3 = -1;
 496 }
 497
 498 float PlayerValue(entity p)
 499 {
 500         return 1;
 501         // FIXME: it always returns 1...
 502 }
 503
 504 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 505 // teams that are allowed will now have their player counts stored in c1...c4
 506 void GetTeamCounts(entity ignore)
 507 {
 508         entity head;
 509         float value, bvalue;
 510         // now count how many players are on each team already
 511
 512         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 513         // also remember the lowest-scoring player
 514
 515         FOR_EACH_CLIENT(head)
 516         {
 517                 float t;
 518                 if(IS_PLAYER(head))
 519                         t = head.team;
 520                 else if(head.team_forced > 0)
 521                         t = head.team_forced; // reserve the spot
 522                 else
 523                         continue;
 524                 if(head != ignore)// && head.netname != "")
 525                 {
 526                         value = PlayerValue(head);
 527                         if(IS_BOT_CLIENT(head))
 528                                 bvalue = value;
 529                         else
 530                                 bvalue = 0;
 531                         if(t == NUM_TEAM_1)
 532                         {
 533                                 if(c1 >= 0)
 534                                 {
 535                                         c1 = c1 + value;
 536                                         cb1 = cb1 + bvalue;
 537                                 }
 538                         }
 539                         if(t == NUM_TEAM_2)
 540                         {
 541                                 if(c2 >= 0)
 542                                 {
 543                                         c2 = c2 + value;
 544                                         cb2 = cb2 + bvalue;
 545                                 }
 546                         }
 547                         if(t == NUM_TEAM_3)
 548                         {
 549                                 if(c3 >= 0)
 550                                 {
 551                                         c3 = c3 + value;
 552                                         cb3 = cb3 + bvalue;
 553                                 }
 554                         }
 555                         if(t == NUM_TEAM_4)
 556                         {
 557                                 if(c4 >= 0)
 558                                 {
 559                                         c4 = c4 + value;
 560                                         cb4 = cb4 + bvalue;
 561                                 }
 562                         }
 563                 }
 564         }
 565
 566         // if the player who has a forced team has not joined yet, reserve the spot
 567         if(autocvar_g_campaign)
 568         {
 569                 switch(autocvar_g_campaign_forceteam)
 570                 {
 571                         case 1: if(c1 == cb1) ++c1; break;
 572                         case 2: if(c2 == cb2) ++c2; break;
 573                         case 3: if(c3 == cb3) ++c3; break;
 574                         case 4: if(c4 == cb4) ++c4; break;
 575                 }
 576         }
 577 }
 578
 579 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 580 {
 581         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 582         float f;
 583         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 584
 585         switch(ta)
 586         {
 587                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 588                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 589                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 590                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 591         }
 592         switch(tb)
 593         {
 594                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 595                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 596                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 597                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 598         }
 599
 600         // invalid
 601         if(ca < 0 || cb < 0)
 602                 return FALSE;
 603
 604         // equal
 605         if(ta == tb)
 606                 return TRUE;
 607
 608         if(IS_REAL_CLIENT(e))
 609         {
 610                 if(bots_would_leave)
 611                 {
 612                         ca -= cba * 0.999;
 613                         cb -= cbb * 0.999;
 614                 }
 615         }
 616
 617         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 618         if(ca < 1)
 619                 if(cb >= 1)
 620                         return TRUE;
 621         if(ca >= 1)
 622                 if(cb < 1)
 623                         return FALSE;
 624
 625         // first, normalize
 626         f = max(ca, cb, 1);
 627         ca /= f;
 628         cb /= f;
 629         f = max(sa, sb, 1);
 630         sa /= f;
 631         sb /= f;
 632
 633         // the more we're at the end of the match, the more take scores into account
 634         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 635         ca += (sa - ca) * f;
 636         cb += (sb - cb) * f;
 637
 638         return ca <= cb;
 639 }
 640
 641 // returns # of smallest team (1, 2, 3, 4)
 642 // NOTE: Assumes CheckAllowedTeams has already been called!
 643 float FindSmallestTeam(entity pl, float ignore_pl)
 644 {
 645         float totalteams, t;
 646         totalteams = 0;
 647
 648         // find out what teams are available
 649         //CheckAllowedTeams();
 650
 651         // make sure there are at least 2 teams to join
 652         if(c1 >= 0)
 653                 totalteams = totalteams + 1;
 654         if(c2 >= 0)
 655                 totalteams = totalteams + 1;
 656         if(c3 >= 0)
 657                 totalteams = totalteams + 1;
 658         if(c4 >= 0)
 659                 totalteams = totalteams + 1;
 660
 661         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 662                 totalteams += 1;
 663
 664         if(totalteams <= 1)
 665         {
 666                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 667                         return 1; // special case for campaign and player joining
 668                 else if(g_domination)
 669                         error("Too few teams available for domination\n");
 670                 else if(g_ctf)
 671                         error("Too few teams available for ctf\n");
 672                 else if(g_keyhunt)
 673                         error("Too few teams available for key hunt\n");
 674                 else if(g_freezetag)
 675                         error("Too few teams available for freeze tag\n");
 676                 else
 677                         error("Too few teams available for team deathmatch\n");
 678         }
 679
 680         // count how many players are in each team
 681         if(ignore_pl)
 682                 GetTeamCounts(pl);
 683         else
 684                 GetTeamCounts(world);
 685
 686         RandomSelection_Init();
 687
 688         t = 1;
 689         if(TeamSmallerEqThanTeam(2, t, pl))
 690                 t = 2;
 691         if(TeamSmallerEqThanTeam(3, t, pl))
 692                 t = 3;
 693         if(TeamSmallerEqThanTeam(4, t, pl))
 694                 t = 4;
 695
 696         // now t is the minimum, or A minimum!
 697         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 698                 RandomSelection_Add(world, 1, string_null, 1, 1);
 699         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 700                 RandomSelection_Add(world, 2, string_null, 1, 1);
 701         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 702                 RandomSelection_Add(world, 3, string_null, 1, 1);
 703         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 704                 RandomSelection_Add(world, 4, string_null, 1, 1);
 705
 706         return RandomSelection_chosen_float;
 707 }
 708
 709 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 710 {
 711         float smallest, selectedteam;
 712
 713         // don't join a team if we're not playing a team game
 714         if(!teamplay)
 715                 return 0;
 716
 717         // find out what teams are available
 718         CheckAllowedTeams(pl);
 719
 720         // if we don't care what team he ends up on, put him on whatever team he entered as.
 721         // if he's not on a valid team, then let other code put him on the smallest team
 722         if(!forcebestteam)
 723         {
 724                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 725                         selectedteam = pl.team;
 726                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 727                         selectedteam = pl.team;
 728                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 729                         selectedteam = pl.team;
 730                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 731                         selectedteam = pl.team;
 732                 else
 733                         selectedteam = -1;
 734
 735                 if(selectedteam > 0)
 736                 {
 737                         if(!only_return_best)
 738                         {
 739                                 SetPlayerColors(pl, selectedteam - 1);
 740
 741                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 742                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 743                                 LogTeamchange(pl.playerid, pl.team, 99);
 744                         }
 745                         return selectedteam;
 746                 }
 747                 // otherwise end up on the smallest team (handled below)
 748         }
 749
 750         smallest = FindSmallestTeam(pl, TRUE);
 751
 752         if(!only_return_best && !pl.bot_forced_team)
 753         {
 754                 TeamchangeFrags(self);
 755                 if(smallest == 1)
 756                 {
 757                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 758                 }
 759                 else if(smallest == 2)
 760                 {
 761                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 762                 }
 763                 else if(smallest == 3)
 764                 {
 765                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 766                 }
 767                 else if(smallest == 4)
 768                 {
 769                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 770                 }
 771                 else
 772                 {
 773                         error("smallest team: invalid team\n");
 774                 }
 775
 776                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 777
 778                 if(pl.deadflag == DEAD_NO)
 779                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 780         }
 781
 782         return smallest;
 783 }
 784
 785 //void() ctf_playerchanged;
 786 void SV_ChangeTeam(float _color)
 787 {
 788         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 789
 790         // in normal deathmatch we can just apply the color and we're done
 791         if(!teamplay) {
 792                 SetPlayerColors(self, _color);
 793                 return;
 794         }
 795
 796         scolor = self.clientcolors & 0x0F;
 797         dcolor = _color & 0x0F;
 798
 799         if(scolor == NUM_TEAM_1 - 1)
 800                 steam = 1;
 801         else if(scolor == NUM_TEAM_2 - 1)
 802                 steam = 2;
 803         else if(scolor == NUM_TEAM_3 - 1)
 804                 steam = 3;
 805         else // if(scolor == NUM_TEAM_4 - 1)
 806                 steam = 4;
 807         if(dcolor == NUM_TEAM_1 - 1)
 808                 dteam = 1;
 809         else if(dcolor == NUM_TEAM_2 - 1)
 810                 dteam = 2;
 811         else if(dcolor == NUM_TEAM_3 - 1)
 812                 dteam = 3;
 813         else // if(dcolor == NUM_TEAM_4 - 1)
 814                 dteam = 4;
 815
 816         CheckAllowedTeams(self);
 817
 818         if(dteam == 1 && c1 < 0) dteam = 4;
 819         if(dteam == 4 && c4 < 0) dteam = 3;
 820         if(dteam == 3 && c3 < 0) dteam = 2;
 821         if(dteam == 2 && c2 < 0) dteam = 1;
 822
 823         // not changing teams
 824         if(scolor == dcolor)
 825         {
 826                 //bprint("same team change\n");
 827                 SetPlayerTeam(self, dteam, steam, TRUE);
 828                 return;
 829         }
 830
 831         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 832                 sprint(self, "Team changes not allowed\n");
 833                 return; // changing teams is not allowed
 834         }
 835
 836         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 837         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 838         {
 839                 GetTeamCounts(self);
 840                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 841                 {
 842                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 843                         return;
 844                 }
 845         }
 846
 847 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 848
 849         if(IS_PLAYER(self) && steam != dteam)
 850         {
 851                 // reduce frags during a team change
 852                 TeamchangeFrags(self);
 853         }
 854
 855         SetPlayerTeam(self, dteam, steam, FALSE);
 856
 857         if(IS_PLAYER(self) && steam != dteam)
 858         {
 859                 // kill player when changing teams
 860                 if(self.deadflag == DEAD_NO)
 861                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 862         }
 863 }
 864
 865 void ShufflePlayerOutOfTeam (float source_team)
 866 {
 867         float smallestteam, smallestteam_count, steam;
 868         float lowest_bot_score, lowest_player_score;
 869         entity head, lowest_bot, lowest_player, selected;
 870
 871         smallestteam = 0;
 872         smallestteam_count = 999999999;
 873
 874         if(c1 >= 0 && c1 < smallestteam_count)
 875         {
 876                 smallestteam = 1;
 877                 smallestteam_count = c1;
 878         }
 879         if(c2 >= 0 && c2 < smallestteam_count)
 880         {
 881                 smallestteam = 2;
 882                 smallestteam_count = c2;
 883         }
 884         if(c3 >= 0 && c3 < smallestteam_count)
 885         {
 886                 smallestteam = 3;
 887                 smallestteam_count = c3;
 888         }
 889         if(c4 >= 0 && c4 < smallestteam_count)
 890         {
 891                 smallestteam = 4;
 892                 smallestteam_count = c4;
 893         }
 894
 895         if(!smallestteam)
 896         {
 897                 bprint("warning: no smallest team\n");
 898                 return;
 899         }
 900
 901         if(source_team == 1)
 902                 steam = NUM_TEAM_1;
 903         else if(source_team == 2)
 904                 steam = NUM_TEAM_2;
 905         else if(source_team == 3)
 906                 steam = NUM_TEAM_3;
 907         else // if(source_team == 4)
 908                 steam = NUM_TEAM_4;
 909
 910         lowest_bot = world;
 911         lowest_bot_score = 999999999;
 912         lowest_player = world;
 913         lowest_player_score = 999999999;
 914
 915         // find the lowest-scoring player & bot of that team
 916         FOR_EACH_PLAYER(head)
 917         {
 918                 if(head.team == steam)
 919                 {
 920                         if(head.isbot)
 921                         {
 922                                 if(head.totalfrags < lowest_bot_score)
 923                                 {
 924                                         lowest_bot = head;
 925                                         lowest_bot_score = head.totalfrags;
 926                                 }
 927                         }
 928                         else
 929                         {
 930                                 if(head.totalfrags < lowest_player_score)
 931                                 {
 932                                         lowest_player = head;
 933                                         lowest_player_score = head.totalfrags;
 934                                 }
 935                         }
 936                 }
 937         }
 938
 939         // prefers to move a bot...
 940         if(lowest_bot != world)
 941                 selected = lowest_bot;
 942         // but it will move a player if it has to
 943         else
 944                 selected = lowest_player;
 945         // don't do anything if it couldn't find anyone
 946         if(!selected)
 947         {
 948                 bprint("warning: couldn't find a player to move from team\n");
 949                 return;
 950         }
 951
 952         // smallest team gains a member
 953         if(smallestteam == 1)
 954         {
 955                 c1 = c1 + 1;
 956         }
 957         else if(smallestteam == 2)
 958         {
 959                 c2 = c2 + 1;
 960         }
 961         else if(smallestteam == 3)
 962         {
 963                 c3 = c3 + 1;
 964         }
 965         else if(smallestteam == 4)
 966         {
 967                 c4 = c4 + 1;
 968         }
 969         else
 970         {
 971                 bprint("warning: destination team invalid\n");
 972                 return;
 973         }
 974         // source team loses a member
 975         if(source_team == 1)
 976         {
 977                 c1 = c1 + 1;
 978         }
 979         else if(source_team == 2)
 980         {
 981                 c2 = c2 + 2;
 982         }
 983         else if(source_team == 3)
 984         {
 985                 c3 = c3 + 3;
 986         }
 987         else if(source_team == 4)
 988         {
 989                 c4 = c4 + 4;
 990         }
 991         else
 992         {
 993                 bprint("warning: source team invalid\n");
 994                 return;
 995         }
 996
 997         // move the player to the new team
 998         TeamchangeFrags(selected);
 999         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1000
1001         if(selected.deadflag == DEAD_NO)
1002                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1003         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1004 }
1005
1006 // code from here on is just to support maps that don't have team entities
1007 void tdm_spawnteam (string teamname, float teamcolor)
1008 {
1009         entity e;
1010         e = spawn();
1011         e.classname = "tdm_team";
1012         e.netname = teamname;
1013         e.cnt = teamcolor;
1014         e.team = e.cnt + 1;
1015 }
1016
1017 // spawn some default teams if the map is not set up for tdm
1018 void tdm_spawnteams()
1019 {
1020         float numteams;
1021
1022         numteams = autocvar_g_tdm_teams_override;
1023         if(numteams < 2)
1024                 numteams = autocvar_g_tdm_teams;
1025         numteams = bound(2, numteams, 4);
1026
1027         tdm_spawnteam("Red", NUM_TEAM_1-1);
1028         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1029         if(numteams >= 3)
1030                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1031         if(numteams >= 4)
1032                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1033 }
1034
1035 void tdm_delayedinit()
1036 {
1037         // if no teams are found, spawn defaults
1038         if (find(world, classname, "tdm_team") == world)
1039                 tdm_spawnteams();
1040 }
1041
1042 void tdm_init()
1043 {
1044         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1045 }