qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void entcs_init();
  17
  18 void LogTeamchange(float player_id, float team_number, float type)
  19 {
  20         if(!autocvar_sv_eventlog)
  21                 return;
  22
  23         if(player_id < 1)
  24                 return;
  25
  26         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  27 }
  28
  29 void default_delayedinit()
  30 {
  31         if(!scores_initialized)
  32                 ScoreRules_generic();
  33 }
  34
  35 void ActivateTeamplay()
  36 {
  37         serverflags |= SERVERFLAG_TEAMPLAY;
  38         teamplay = 1;
  39 }
  40
  41 void InitGameplayMode()
  42 {
  43         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  44
  45         qualifying_override = -1;
  46
  47         VoteReset();
  48
  49         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  50         get_mi_min_max(1);
  51         world.mins = mi_min;
  52         world.maxs = mi_max;
  53
  54         MapInfo_LoadMapSettings(mapname);
  55         teamplay = 0;
  56         serverflags &= ~SERVERFLAG_TEAMPLAY;
  57
  58         if (!cvar_value_issafe(world.fog))
  59         {
  60                 print("The current map contains a potentially harmful fog setting, ignored\n");
  61                 world.fog = string_null;
  62         }
  63         if(MapInfo_Map_fog != "")
  64                 if(MapInfo_Map_fog == "none")
  65                         world.fog = string_null;
  66                 else
  67                         world.fog = strzone(MapInfo_Map_fog);
  68         clientstuff = strzone(MapInfo_Map_clientstuff);
  69
  70         MapInfo_ClearTemps();
  71
  72         // set both here, gamemode can override it later
  73         timelimit_override = autocvar_timelimit_override;
  74         fraglimit_override = autocvar_fraglimit_override;
  75         leadlimit_override = autocvar_leadlimit_override;
  76         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  77
  78         if(g_dm)
  79         {
  80         }
  81
  82         if(g_tdm)
  83         {
  84                 ActivateTeamplay();
  85                 fraglimit_override = autocvar_g_tdm_point_limit;
  86                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
  87                 MUTATOR_ADD(gamemode_tdm);
  88
  89                 if(autocvar_g_tdm_team_spawns)
  90                         have_team_spawns = -1; // request team spawns
  91         }
  92
  93         if(g_domination)
  94         {
  95                 ActivateTeamplay();
  96                 fraglimit_override = autocvar_g_domination_point_limit;
  97                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  98                 MUTATOR_ADD(gamemode_domination);
  99
 100                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
 101                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
 102
 103                 have_team_spawns = -1; // request team spawns
 104         }
 105
 106         if(g_ctf)
 107         {
 108                 ActivateTeamplay();
 109                 fraglimit_override = autocvar_capturelimit_override;
 110                 leadlimit_override = autocvar_captureleadlimit_override;
 111                 MUTATOR_ADD(gamemode_ctf);
 112                 have_team_spawns = -1; // request team spawns
 113         }
 114
 115         if(g_lms)
 116         {
 117                 fraglimit_override = autocvar_g_lms_lives_override;
 118                 leadlimit_override = 0; // not supported by LMS
 119                 if(fraglimit_override == 0)
 120                         fraglimit_override = -1;
 121                 MUTATOR_ADD(gamemode_lms);
 122         }
 123
 124         if(g_ca)
 125         {
 126                 ActivateTeamplay();
 127                 fraglimit_override = autocvar_g_ca_point_limit;
 128                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 129                 MUTATOR_ADD(gamemode_ca);
 130                 if(autocvar_g_ca_team_spawns)
 131                         have_team_spawns = -1; // request team spawns
 132         }
 133
 134         if(g_keyhunt)
 135         {
 136                 ActivateTeamplay();
 137                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 138                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 139                 MUTATOR_ADD(gamemode_keyhunt);
 140         }
 141
 142         if(g_freezetag)
 143         {
 144                 ActivateTeamplay();
 145                 fraglimit_override = autocvar_g_freezetag_point_limit;
 146                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 147                 MUTATOR_ADD(gamemode_freezetag);
 148                 if(autocvar_g_freezetag_team_spawns)
 149                         have_team_spawns = -1; // request team spawns
 150         }
 151
 152         if(g_assault)
 153         {
 154                 ActivateTeamplay();
 155                 MUTATOR_ADD(gamemode_assault);
 156                 have_team_spawns = -1; // request team spawns
 157         }
 158
 159         if(g_onslaught)
 160         {
 161                 ActivateTeamplay();
 162                 have_team_spawns = -1; // request team spawns
 163                 MUTATOR_ADD(gamemode_onslaught);
 164         }
 165
 166         if(g_race)
 167         {
 168                 if(autocvar_g_race_teams)
 169                 {
 170                         ActivateTeamplay();
 171                         race_teams = bound(2, autocvar_g_race_teams, 4);
 172                         have_team_spawns = -1; // request team spawns
 173                 }
 174                 else
 175                         race_teams = 0;
 176
 177                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 178                 fraglimit_override = autocvar_g_race_laps_limit;
 179                 leadlimit_override = 0; // currently not supported by race
 180
 181                 MUTATOR_ADD(gamemode_race);
 182         }
 183
 184         if(g_cts)
 185         {
 186                 g_race_qualifying = 1;
 187                 fraglimit_override = 0;
 188                 leadlimit_override = 0;
 189                 MUTATOR_ADD(gamemode_cts);
 190         }
 191
 192         if(g_nexball)
 193         {
 194         fraglimit_override = autocvar_g_nexball_goallimit;
 195         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 196         ActivateTeamplay();
 197         have_team_spawns = -1; // request team spawns
 198             MUTATOR_ADD(gamemode_nexball);
 199         }
 200
 201         if(g_keepaway)
 202         {
 203                 MUTATOR_ADD(gamemode_keepaway);
 204         }
 205
 206         if(g_invasion)
 207         {
 208                 fraglimit_override = autocvar_g_invasion_point_limit;
 209                 if(autocvar_g_invasion_teams >= 2)
 210                 {
 211                         ActivateTeamplay();
 212                         if(autocvar_g_invasion_team_spawns)
 213                                 have_team_spawns = -1; // request team spawns
 214                 }
 215                 MUTATOR_ADD(gamemode_invasion);
 216         }
 217
 218         if(teamplay)
 219                 entcs_init();
 220
 221         cache_mutatormsg = strzone("");
 222         cache_lastmutatormsg = strzone("");
 223
 224         // enforce the server's universal frag/time limits
 225         if(!autocvar_g_campaign)
 226         {
 227                 if(fraglimit_override >= 0)
 228                         cvar_set("fraglimit", ftos(fraglimit_override));
 229                 if(timelimit_override >= 0)
 230                         cvar_set("timelimit", ftos(timelimit_override));
 231                 if(leadlimit_override >= 0)
 232                         cvar_set("leadlimit", ftos(leadlimit_override));
 233                 if(qualifying_override >= 0)
 234                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 235         }
 236
 237         if(g_race)
 238         {
 239                 // we need to find out the correct value for g_race_qualifying
 240                 if(autocvar_g_campaign)
 241                 {
 242                         g_race_qualifying = 1;
 243                 }
 244                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 245                 {
 246                         g_race_qualifying = 2;
 247                         race_fraglimit = autocvar_fraglimit;
 248                         race_leadlimit = autocvar_leadlimit;
 249                         race_timelimit = autocvar_timelimit;
 250                         cvar_set("fraglimit", "0");
 251                         cvar_set("leadlimit", "0");
 252                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 253                 }
 254                 else
 255                         g_race_qualifying = 0;
 256         }
 257
 258         if(g_race || g_cts)
 259         if(g_race_qualifying)
 260                 independent_players = 1;
 261
 262         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 263 }
 264
 265 string GetClientVersionMessage() {
 266         string versionmsg;
 267         if (self.version_mismatch) {
 268                 if(self.version < autocvar_gameversion) {
 269                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 270                 } else {
 271                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 272                 }
 273         } else {
 274                 versionmsg = "^2client version and server version are compatible.^8";
 275         }
 276         return versionmsg;
 277 }
 278
 279 string getwelcomemessage(void)
 280 {
 281         string s, modifications, motd;
 282
 283         ret_string = "";
 284         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 285         modifications = ret_string;
 286
 287         if(g_weaponarena)
 288         {
 289                 if(g_weaponarena_random)
 290                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 291                 else
 292                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 293         }
 294         if(cvar("g_balance_blaster_weaponstart") == 0)
 295                 modifications = strcat(modifications, ", No start weapons");
 296         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 297                 modifications = strcat(modifications, ", Low gravity");
 298         if(g_cloaked && !g_cts)
 299                 modifications = strcat(modifications, ", Cloaked");
 300         if(g_grappling_hook)
 301                 modifications = strcat(modifications, ", Hook");
 302         if(g_weapon_stay && !g_cts)
 303                 modifications = strcat(modifications, ", Weapons stay");
 304         if(g_jetpack)
 305                 modifications = strcat(modifications, ", Jet pack");
 306         if(autocvar_g_powerups == 0)
 307                 modifications = strcat(modifications, ", No powerups");
 308         if(autocvar_g_powerups > 0)
 309                 modifications = strcat(modifications, ", Powerups");
 310         modifications = substring(modifications, 2, strlen(modifications) - 2);
 311
 312         string versionmessage;
 313         versionmessage = GetClientVersionMessage();
 314
 315         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 316         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 317
 318         if(modifications != "")
 319                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 320
 321         if (g_grappling_hook)
 322                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 323
 324         if (cvar("g_nades"))
 325                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 326
 327         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 328         {
 329                 if(cache_lastmutatormsg)
 330                         strunzone(cache_lastmutatormsg);
 331                 if(cache_mutatormsg)
 332                         strunzone(cache_mutatormsg);
 333                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 334                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 335         }
 336
 337         if (cache_mutatormsg != "") {
 338                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 339         }
 340
 341         motd = autocvar_sv_motd;
 342         if (motd != "") {
 343                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 344         }
 345         return s;
 346 }
 347
 348 void SetPlayerColors(entity pl, float _color)
 349 {
 350         /*string s;
 351         s = ftos(cl);
 352         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 353         pl.team = cl + 1;
 354         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 355         pl.clientcolors = 16*cl + cl;*/
 356
 357         float pants, shirt;
 358         pants = _color & 0x0F;
 359         shirt = _color & 0xF0;
 360
 361
 362         if(teamplay) {
 363                 setcolor(pl, 16*pants + pants);
 364         } else {
 365                 setcolor(pl, shirt + pants);
 366         }
 367 }
 368
 369 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 370 {
 371         float _color;
 372
 373         if(t == 4)
 374                 _color = NUM_TEAM_4 - 1;
 375         else if(t == 3)
 376                 _color = NUM_TEAM_3 - 1;
 377         else if(t == 2)
 378                 _color = NUM_TEAM_2 - 1;
 379         else
 380                 _color = NUM_TEAM_1 - 1;
 381
 382         SetPlayerColors(pl,_color);
 383
 384         if(t != s) {
 385                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 386
 387                 if(!noprint)
 388                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 389         }
 390
 391 }
 392
 393 // set c1...c4 to show what teams are allowed
 394 void CheckAllowedTeams (entity for_whom)
 395 {
 396         float dm;
 397         entity head;
 398         string teament_name;
 399
 400         c1 = c2 = c3 = c4 = -1;
 401         cb1 = cb2 = cb3 = cb4 = 0;
 402
 403         teament_name = string_null;
 404         if(g_onslaught)
 405         {
 406                 // onslaught is special
 407                 head = findchain(classname, "onslaught_generator");
 408                 while (head)
 409                 {
 410                         if (head.team == NUM_TEAM_1) c1 = 0;
 411                         if (head.team == NUM_TEAM_2) c2 = 0;
 412                         if (head.team == NUM_TEAM_3) c3 = 0;
 413                         if (head.team == NUM_TEAM_4) c4 = 0;
 414                         head = head.chain;
 415                 }
 416         }
 417         else if(g_domination)
 418                 teament_name = "dom_team";
 419         else if(g_ctf)
 420                 teament_name = "ctf_team";
 421         else if(g_tdm)
 422                 teament_name = "tdm_team";
 423         else if(g_nexball)
 424                 teament_name = "nexball_team";
 425         else if(g_assault)
 426                 c1 = c2 = 0; // Assault always has 2 teams
 427         else
 428         {
 429                 // cover anything else by treating it like tdm with no teams spawned
 430                 dm = 2;
 431
 432                 ret_float = dm;
 433                 MUTATOR_CALLHOOK(GetTeamCount);
 434                 dm = ret_float;
 435
 436                 if(dm >= 4)
 437                         c1 = c2 = c3 = c4 = 0;
 438                 else if(dm >= 3)
 439                         c1 = c2 = c3 = 0;
 440                 else
 441                         c1 = c2 = 0;
 442         }
 443
 444         // find out what teams are allowed if necessary
 445         if(teament_name)
 446         {
 447                 head = find(world, classname, teament_name);
 448                 while(head)
 449                 {
 450                         if(!(g_domination && head.netname == ""))
 451                         {
 452                                 if(head.team == NUM_TEAM_1)
 453                                         c1 = 0;
 454                                 else if(head.team == NUM_TEAM_2)
 455                                         c2 = 0;
 456                                 else if(head.team == NUM_TEAM_3)
 457                                         c3 = 0;
 458                                 else if(head.team == NUM_TEAM_4)
 459                                         c4 = 0;
 460                         }
 461                         head = find(head, classname, teament_name);
 462                 }
 463         }
 464
 465         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 466         if(c3==-1 && c4==-1)
 467         if(autocvar_bot_vs_human && for_whom)
 468         {
 469                 if(autocvar_bot_vs_human > 0)
 470                 {
 471                         // bots are all blue
 472                         if(IS_BOT_CLIENT(for_whom))
 473                                 c1 = c3 = c4 = -1;
 474                         else
 475                                 c2 = -1;
 476                 }
 477                 else
 478                 {
 479                         // bots are all red
 480                         if(IS_BOT_CLIENT(for_whom))
 481                                 c2 = c3 = c4 = -1;
 482                         else
 483                                 c1 = -1;
 484                 }
 485         }
 486
 487         // if player has a forced team, ONLY allow that one
 488         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 489                 c2 = c3 = c4 = -1;
 490         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 491                 c1 = c3 = c4 = -1;
 492         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 493                 c1 = c2 = c4 = -1;
 494         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 495                 c1 = c2 = c3 = -1;
 496 }
 497
 498 float PlayerValue(entity p)
 499 {
 500         return 1;
 501         // FIXME: it always returns 1...
 502 }
 503
 504 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 505 // teams that are allowed will now have their player counts stored in c1...c4
 506 void GetTeamCounts(entity ignore)
 507 {
 508         entity head;
 509         float value, bvalue;
 510         // now count how many players are on each team already
 511
 512         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 513         // also remember the lowest-scoring player
 514
 515         FOR_EACH_CLIENT(head)
 516         {
 517                 float t;
 518                 if(IS_PLAYER(head))
 519                         t = head.team;
 520                 else if(head.team_forced > 0)
 521                         t = head.team_forced; // reserve the spot
 522                 else
 523                         continue;
 524                 if(head != ignore)// && head.netname != "")
 525                 {
 526                         value = PlayerValue(head);
 527                         if(IS_BOT_CLIENT(head))
 528                                 bvalue = value;
 529                         else
 530                                 bvalue = 0;
 531                         if(t == NUM_TEAM_1)
 532                         {
 533                                 if(c1 >= 0)
 534                                 {
 535                                         c1 = c1 + value;
 536                                         cb1 = cb1 + bvalue;
 537                                 }
 538                         }
 539                         if(t == NUM_TEAM_2)
 540                         {
 541                                 if(c2 >= 0)
 542                                 {
 543                                         c2 = c2 + value;
 544                                         cb2 = cb2 + bvalue;
 545                                 }
 546                         }
 547                         if(t == NUM_TEAM_3)
 548                         {
 549                                 if(c3 >= 0)
 550                                 {
 551                                         c3 = c3 + value;
 552                                         cb3 = cb3 + bvalue;
 553                                 }
 554                         }
 555                         if(t == NUM_TEAM_4)
 556                         {
 557                                 if(c4 >= 0)
 558                                 {
 559                                         c4 = c4 + value;
 560                                         cb4 = cb4 + bvalue;
 561                                 }
 562                         }
 563                 }
 564         }
 565
 566         // if the player who has a forced team has not joined yet, reserve the spot
 567         if(autocvar_g_campaign)
 568         {
 569                 switch(autocvar_g_campaign_forceteam)
 570                 {
 571                         case 1: if(c1 == cb1) ++c1; break;
 572                         case 2: if(c2 == cb2) ++c2; break;
 573                         case 3: if(c3 == cb3) ++c3; break;
 574                         case 4: if(c4 == cb4) ++c4; break;
 575                 }
 576         }
 577 }
 578
 579 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 580 {
 581         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 582         float f;
 583         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 584
 585         switch(ta)
 586         {
 587                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 588                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 589                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 590                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 591         }
 592         switch(tb)
 593         {
 594                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 595                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 596                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 597                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 598         }
 599
 600         // invalid
 601         if(ca < 0 || cb < 0)
 602                 return FALSE;
 603
 604         // equal
 605         if(ta == tb)
 606                 return TRUE;
 607
 608         if(IS_REAL_CLIENT(e))
 609         {
 610                 if(bots_would_leave)
 611                 {
 612                         ca -= cba * 0.999;
 613                         cb -= cbb * 0.999;
 614                 }
 615         }
 616
 617         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 618         if(ca < 1)
 619                 if(cb >= 1)
 620                         return TRUE;
 621         if(ca >= 1)
 622                 if(cb < 1)
 623                         return FALSE;
 624
 625         // first, normalize
 626         f = max(ca, cb, 1);
 627         ca /= f;
 628         cb /= f;
 629         f = max(sa, sb, 1);
 630         sa /= f;
 631         sb /= f;
 632
 633         // the more we're at the end of the match, the more take scores into account
 634         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 635         ca += (sa - ca) * f;
 636         cb += (sb - cb) * f;
 637
 638         return ca <= cb;
 639 }
 640
 641 // returns # of smallest team (1, 2, 3, 4)
 642 // NOTE: Assumes CheckAllowedTeams has already been called!
 643 float FindSmallestTeam(entity pl, float ignore_pl)
 644 {
 645         float totalteams, t;
 646         totalteams = 0;
 647
 648         // find out what teams are available
 649         //CheckAllowedTeams();
 650
 651         // make sure there are at least 2 teams to join
 652         if(c1 >= 0)
 653                 totalteams = totalteams + 1;
 654         if(c2 >= 0)
 655                 totalteams = totalteams + 1;
 656         if(c3 >= 0)
 657                 totalteams = totalteams + 1;
 658         if(c4 >= 0)
 659                 totalteams = totalteams + 1;
 660
 661         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 662                 totalteams += 1;
 663
 664         if(totalteams <= 1)
 665         {
 666                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 667                         return 1; // special case for campaign and player joining
 668                 else if(g_domination)
 669                         error("Too few teams available for domination\n");
 670                 else if(g_ctf)
 671                         error("Too few teams available for ctf\n");
 672                 else if(g_keyhunt)
 673                         error("Too few teams available for key hunt\n");
 674                 else if(g_freezetag)
 675                         error("Too few teams available for freeze tag\n");
 676                 else
 677                         error("Too few teams available for team deathmatch\n");
 678         }
 679
 680         // count how many players are in each team
 681         if(ignore_pl)
 682                 GetTeamCounts(pl);
 683         else
 684                 GetTeamCounts(world);
 685
 686         RandomSelection_Init();
 687
 688         t = 1;
 689         if(TeamSmallerEqThanTeam(2, t, pl))
 690                 t = 2;
 691         if(TeamSmallerEqThanTeam(3, t, pl))
 692                 t = 3;
 693         if(TeamSmallerEqThanTeam(4, t, pl))
 694                 t = 4;
 695
 696         // now t is the minimum, or A minimum!
 697         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 698                 RandomSelection_Add(world, 1, string_null, 1, 1);
 699         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 700                 RandomSelection_Add(world, 2, string_null, 1, 1);
 701         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 702                 RandomSelection_Add(world, 3, string_null, 1, 1);
 703         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 704                 RandomSelection_Add(world, 4, string_null, 1, 1);
 705
 706         return RandomSelection_chosen_float;
 707 }
 708
 709 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 710 {
 711         float smallest, selectedteam;
 712
 713         // don't join a team if we're not playing a team game
 714         if(!teamplay)
 715                 return 0;
 716
 717         // find out what teams are available
 718         CheckAllowedTeams(pl);
 719
 720         // if we don't care what team he ends up on, put him on whatever team he entered as.
 721         // if he's not on a valid team, then let other code put him on the smallest team
 722         if(!forcebestteam)
 723         {
 724                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 725                         selectedteam = pl.team;
 726                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 727                         selectedteam = pl.team;
 728                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 729                         selectedteam = pl.team;
 730                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 731                         selectedteam = pl.team;
 732                 else
 733                         selectedteam = -1;
 734
 735                 if(selectedteam > 0)
 736                 {
 737                         if(!only_return_best)
 738                         {
 739                                 SetPlayerColors(pl, selectedteam - 1);
 740
 741                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 742                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 743                                 LogTeamchange(pl.playerid, pl.team, 99);
 744                         }
 745                         return selectedteam;
 746                 }
 747                 // otherwise end up on the smallest team (handled below)
 748         }
 749
 750         smallest = FindSmallestTeam(pl, TRUE);
 751
 752         if(!only_return_best && !pl.bot_forced_team)
 753         {
 754                 TeamchangeFrags(self);
 755                 if(smallest == 1)
 756                 {
 757                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 758                 }
 759                 else if(smallest == 2)
 760                 {
 761                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 762                 }
 763                 else if(smallest == 3)
 764                 {
 765                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 766                 }
 767                 else if(smallest == 4)
 768                 {
 769                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 770                 }
 771                 else
 772                 {
 773                         error("smallest team: invalid team\n");
 774                 }
 775
 776                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 777
 778                 if(pl.deadflag == DEAD_NO)
 779                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 780         }
 781
 782         return smallest;
 783 }
 784
 785 //void() ctf_playerchanged;
 786 void SV_ChangeTeam(float _color)
 787 {
 788         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 789
 790         // in normal deathmatch we can just apply the color and we're done
 791         if(!teamplay) {
 792                 SetPlayerColors(self, _color);
 793                 return;
 794         }
 795
 796         scolor = self.clientcolors & 0x0F;
 797         dcolor = _color & 0x0F;
 798
 799         if(scolor == NUM_TEAM_1 - 1)
 800                 steam = 1;
 801         else if(scolor == NUM_TEAM_2 - 1)
 802                 steam = 2;
 803         else if(scolor == NUM_TEAM_3 - 1)
 804                 steam = 3;
 805         else // if(scolor == NUM_TEAM_4 - 1)
 806                 steam = 4;
 807         if(dcolor == NUM_TEAM_1 - 1)
 808                 dteam = 1;
 809         else if(dcolor == NUM_TEAM_2 - 1)
 810                 dteam = 2;
 811         else if(dcolor == NUM_TEAM_3 - 1)
 812                 dteam = 3;
 813         else // if(dcolor == NUM_TEAM_4 - 1)
 814                 dteam = 4;
 815
 816         CheckAllowedTeams(self);
 817
 818         if(dteam == 1 && c1 < 0) dteam = 4;
 819         if(dteam == 4 && c4 < 0) dteam = 3;
 820         if(dteam == 3 && c3 < 0) dteam = 2;
 821         if(dteam == 2 && c2 < 0) dteam = 1;
 822
 823         // not changing teams
 824         if(scolor == dcolor)
 825         {
 826                 //bprint("same team change\n");
 827                 SetPlayerTeam(self, dteam, steam, TRUE);
 828                 return;
 829         }
 830
 831         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 832                 sprint(self, "Team changes not allowed\n");
 833                 return; // changing teams is not allowed
 834         }
 835
 836         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 837         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 838         {
 839                 GetTeamCounts(self);
 840                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 841                 {
 842                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 843                         return;
 844                 }
 845         }
 846
 847 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 848
 849         if(IS_PLAYER(self) && steam != dteam)
 850         {
 851                 // reduce frags during a team change
 852                 TeamchangeFrags(self);
 853         }
 854
 855         SetPlayerTeam(self, dteam, steam, FALSE);
 856
 857         if(IS_PLAYER(self) && steam != dteam)
 858         {
 859                 // kill player when changing teams
 860                 if(self.deadflag == DEAD_NO)
 861                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 862         }
 863 }
 864
 865 void ShufflePlayerOutOfTeam (float source_team)
 866 {
 867         float smallestteam, smallestteam_count, steam;
 868         float lowest_bot_score, lowest_player_score;
 869         entity head, lowest_bot, lowest_player, selected;
 870
 871         smallestteam = 0;
 872         smallestteam_count = 999999999;
 873
 874         if(c1 >= 0 && c1 < smallestteam_count)
 875         {
 876                 smallestteam = 1;
 877                 smallestteam_count = c1;
 878         }
 879         if(c2 >= 0 && c2 < smallestteam_count)
 880         {
 881                 smallestteam = 2;
 882                 smallestteam_count = c2;
 883         }
 884         if(c3 >= 0 && c3 < smallestteam_count)
 885         {
 886                 smallestteam = 3;
 887                 smallestteam_count = c3;
 888         }
 889         if(c4 >= 0 && c4 < smallestteam_count)
 890         {
 891                 smallestteam = 4;
 892                 smallestteam_count = c4;
 893         }
 894
 895         if(!smallestteam)
 896         {
 897                 bprint("warning: no smallest team\n");
 898                 return;
 899         }
 900
 901         if(source_team == 1)
 902                 steam = NUM_TEAM_1;
 903         else if(source_team == 2)
 904                 steam = NUM_TEAM_2;
 905         else if(source_team == 3)
 906                 steam = NUM_TEAM_3;
 907         else // if(source_team == 4)
 908                 steam = NUM_TEAM_4;
 909
 910         lowest_bot = world;
 911         lowest_bot_score = 999999999;
 912         lowest_player = world;
 913         lowest_player_score = 999999999;
 914
 915         // find the lowest-scoring player & bot of that team
 916         FOR_EACH_PLAYER(head)
 917         {
 918                 if(head.team == steam)
 919                 {
 920                         if(head.isbot)
 921                         {
 922                                 if(head.totalfrags < lowest_bot_score)
 923                                 {
 924                                         lowest_bot = head;
 925                                         lowest_bot_score = head.totalfrags;
 926                                 }
 927                         }
 928                         else
 929                         {
 930                                 if(head.totalfrags < lowest_player_score)
 931                                 {
 932                                         lowest_player = head;
 933                                         lowest_player_score = head.totalfrags;
 934                                 }
 935                         }
 936                 }
 937         }
 938
 939         // prefers to move a bot...
 940         if(lowest_bot != world)
 941                 selected = lowest_bot;
 942         // but it will move a player if it has to
 943         else
 944                 selected = lowest_player;
 945         // don't do anything if it couldn't find anyone
 946         if(!selected)
 947         {
 948                 bprint("warning: couldn't find a player to move from team\n");
 949                 return;
 950         }
 951
 952         // smallest team gains a member
 953         if(smallestteam == 1)
 954         {
 955                 c1 = c1 + 1;
 956         }
 957         else if(smallestteam == 2)
 958         {
 959                 c2 = c2 + 1;
 960         }
 961         else if(smallestteam == 3)
 962         {
 963                 c3 = c3 + 1;
 964         }
 965         else if(smallestteam == 4)
 966         {
 967                 c4 = c4 + 1;
 968         }
 969         else
 970         {
 971                 bprint("warning: destination team invalid\n");
 972                 return;
 973         }
 974         // source team loses a member
 975         if(source_team == 1)
 976         {
 977                 c1 = c1 + 1;
 978         }
 979         else if(source_team == 2)
 980         {
 981                 c2 = c2 + 2;
 982         }
 983         else if(source_team == 3)
 984         {
 985                 c3 = c3 + 3;
 986         }
 987         else if(source_team == 4)
 988         {
 989                 c4 = c4 + 4;
 990         }
 991         else
 992         {
 993                 bprint("warning: source team invalid\n");
 994                 return;
 995         }
 996
 997         // move the player to the new team
 998         TeamchangeFrags(selected);
 999         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1000
1001         if(selected.deadflag == DEAD_NO)
1002                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1003         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1004 }