qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void nb_init();
  75 void entcs_init();
  76
  77 void LogTeamchange(float player_id, float team_number, float type)
  78 {
  79         if(!autocvar_sv_eventlog)
  80                 return;
  81
  82         if(player_id < 1)
  83                 return;
  84
  85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  86 }
  87
  88 void WriteGameCvars()
  89 {
  90         cvar_set("g_dm", ftos(g_dm));
  91         cvar_set("g_tdm", ftos(g_tdm));
  92         cvar_set("g_domination", ftos(g_domination));
  93         cvar_set("g_ctf", ftos(g_ctf));
  94         cvar_set("g_runematch", ftos(g_runematch));
  95         cvar_set("g_lms", ftos(g_lms));
  96         cvar_set("g_arena", ftos(g_arena));
  97         cvar_set("g_ca", ftos(g_ca));
  98         cvar_set("g_keyhunt", ftos(g_keyhunt));
  99         cvar_set("g_assault", ftos(g_assault));
 100         cvar_set("g_onslaught", ftos(g_onslaught));
 101         cvar_set("g_race", ftos(g_race));
 102         cvar_set("g_nexball", ftos(g_nexball));
 103         cvar_set("g_cts", ftos(g_cts));
 104         cvar_set("g_freezetag", ftos(g_freezetag));
 105         cvar_set("g_keepaway", ftos(g_keepaway));
 106 }
 107
 108 void ReadGameCvars()
 109 {
 110         float found;
 111         float prev;
 112         float i;
 113
 114         found = 0;
 115         prev = autocvar_gamecfg;
 116         for(i = 0; i < 2; ++i)
 117         {
 118 //#NO AUTOCVARS START
 119                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 120                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 121                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 122                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 123                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 124                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 125                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 126                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 127                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 128                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 129                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 130                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 131                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 132                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 133                 found += (g_freezetag = (!found && (prev != GAME_FREEZETAG) && cvar("g_freezetag")));
 134                 found += (g_keepaway = (!found && (prev != GAME_KEEPAWAY) && cvar("g_keepaway")));
 135 //#NO AUTOCVARS END
 136
 137                 if(found)
 138                         break;
 139
 140                 prev = -1; // second attempt takes place WITHOUT prev set
 141         }
 142
 143         if(!found)
 144                 g_dm = 1;
 145
 146         if(g_dm && autocvar_deathmatch_force_teamplay)
 147         {
 148                 g_dm = 0;
 149                 g_tdm = 1;
 150         }
 151
 152         teams_matter = 0;
 153         serverflags &~= SERVERFLAG_TEAMPLAY;
 154 }
 155
 156 void default_delayedinit()
 157 {
 158         if(!scores_initialized)
 159                 ScoreRules_generic();
 160 }
 161
 162 void ActivateTeamplay()
 163 {
 164         serverflags |= SERVERFLAG_TEAMPLAY;
 165         teams_matter = 1;
 166 }
 167
 168 void InitGameplayMode()
 169 {
 170         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 171
 172         qualifying_override = -1;
 173
 174         VoteReset();
 175
 176         // make sure only ONE type is selected
 177         ReadGameCvars();
 178         WriteGameCvars();
 179
 180         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 181         get_mi_min_max(1);
 182         world.mins = mi_min;
 183         world.maxs = mi_max;
 184
 185         MapInfo_LoadMapSettings(mapname);
 186
 187         if not(cvar_value_issafe(world.fog))
 188         {
 189                 print("The current map contains a potentially harmful fog setting, ignored\n");
 190                 world.fog = string_null;
 191         }
 192         if(MapInfo_Map_fog != "")
 193                 if(MapInfo_Map_fog == "none")
 194                         world.fog = string_null;
 195                 else
 196                         world.fog = strzone(MapInfo_Map_fog);
 197         clientstuff = strzone(MapInfo_Map_clientstuff);
 198
 199         MapInfo_ClearTemps();
 200
 201         // in case mapinfo switched the type
 202         ReadGameCvars();
 203
 204         // set both here, gamemode can override it later
 205         timelimit_override = autocvar_timelimit_override;
 206         fraglimit_override = autocvar_fraglimit_override;
 207         leadlimit_override = autocvar_leadlimit_override;
 208
 209         if(g_dm)
 210         {
 211                 game = GAME_DEATHMATCH;
 212                 gamemode_name = "Deathmatch";
 213         }
 214
 215         if(g_tdm)
 216         {
 217                 game = GAME_TEAM_DEATHMATCH;
 218                 gamemode_name = "Team Deathmatch";
 219                 ActivateTeamplay();
 220                 tdm_init();
 221                 if(autocvar_g_tdm_team_spawns)
 222                         have_team_spawns = -1; // request team spawns
 223         }
 224
 225         if(g_domination)
 226         {
 227                 game = GAME_DOMINATION;
 228                 gamemode_name = "Domination";
 229                 ActivateTeamplay();
 230                 fraglimit_override = autocvar_g_domination_point_limit;
 231                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 232                 dom_init();
 233                 have_team_spawns = -1; // request team spawns
 234         }
 235
 236         if(g_ctf)
 237         {
 238                 game = GAME_CTF;
 239                 gamemode_name = "Capture the Flag";
 240                 ActivateTeamplay();
 241                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
 242                 if(g_ctf_win_mode == 2)
 243                 {
 244                         fraglimit_override = autocvar_g_ctf_capture_limit;
 245                         leadlimit_override = autocvar_g_ctf_capture_leadlimit;
 246                 }
 247                 else
 248                 {
 249                         fraglimit_override = autocvar_capturelimit_override;
 250                         leadlimit_override = autocvar_captureleadlimit_override;
 251                 }
 252                 ctf_init();
 253                 have_team_spawns = -1; // request team spawns
 254         }
 255
 256         if(g_runematch)
 257         {
 258                 game = GAME_RUNEMATCH;
 259                 gamemode_name = "Rune Match";
 260                 if(autocvar_deathmatch_force_teamplay)
 261                         ActivateTeamplay();
 262                 fraglimit_override = autocvar_g_runematch_point_limit;
 263                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 264                 runematch_init();
 265         }
 266
 267         if(g_lms)
 268         {
 269                 game = GAME_LMS;
 270                 gamemode_name = "Last Man Standing";
 271                 fraglimit_override = autocvar_g_lms_lives_override;
 272                 leadlimit_override = 0; // not supported by LMS
 273                 if(fraglimit_override == 0)
 274                         fraglimit_override = -1;
 275                 lms_lowest_lives = 9999;
 276                 lms_next_place = 0;
 277                 ScoreRules_lms();
 278         }
 279
 280         if(g_arena)
 281         {
 282                 game = GAME_ARENA;
 283                 gamemode_name = "Arena";
 284                 fraglimit_override = autocvar_g_arena_point_limit;
 285                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 286                 maxspawned = autocvar_g_arena_maxspawned;
 287                 if(maxspawned < 2)
 288                         maxspawned = 2;
 289                 arena_roundbased = autocvar_g_arena_roundbased;
 290         }
 291
 292         if(g_ca)
 293         {
 294                 game = GAME_CA;
 295                 gamemode_name = "Clan Arena";
 296                 ActivateTeamplay();
 297                 fraglimit_override = autocvar_g_ca_point_limit;
 298                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 299                 precache_sound("ctf/red_capture.wav");
 300                 precache_sound("ctf/blue_capture.wav");
 301         }
 302         if(g_keyhunt)
 303         {
 304                 game = GAME_KEYHUNT;
 305                 gamemode_name = "Key Hunt";
 306                 ActivateTeamplay();
 307                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 308                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 309                 MUTATOR_ADD(gamemode_keyhunt);
 310         }
 311
 312         if(g_freezetag)
 313         {
 314                 game = GAME_FREEZETAG;
 315                 gamemode_name = "Freeze Tag";
 316                 ActivateTeamplay();
 317                 fraglimit_override = autocvar_g_freezetag_point_limit;
 318                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 319                 MUTATOR_ADD(gamemode_freezetag);
 320         }
 321
 322         if(g_assault)
 323         {
 324                 game = GAME_ASSAULT;
 325                 gamemode_name = "Assault";
 326                 ActivateTeamplay();
 327                 ScoreRules_assault();
 328                 have_team_spawns = -1; // request team spawns
 329         }
 330
 331         if(g_onslaught)
 332         {
 333                 game = GAME_ONSLAUGHT;
 334                 gamemode_name = "Onslaught";
 335                 ActivateTeamplay();
 336                 have_team_spawns = -1; // request team spawns
 337         }
 338
 339         if(g_race)
 340         {
 341                 game = GAME_RACE;
 342                 gamemode_name = "Race";
 343
 344                 if(autocvar_g_race_teams)
 345                 {
 346                         ActivateTeamplay();
 347                         race_teams = bound(2, autocvar_g_race_teams, 4);
 348                         have_team_spawns = -1; // request team spawns
 349                 }
 350                 else
 351                         race_teams = 0;
 352
 353                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 354                 fraglimit_override = autocvar_g_race_laps_limit;
 355                 leadlimit_override = 0; // currently not supported by race
 356         }
 357
 358         if(g_cts)
 359         {
 360                 game = GAME_CTS;
 361                 gamemode_name = "CTS";
 362                 g_race_qualifying = 1;
 363                 fraglimit_override = 0;
 364                 leadlimit_override = 0;
 365         }
 366
 367         if(g_nexball)
 368         {
 369                 game = GAME_NEXBALL;
 370                 gamemode_name = "Nexball";
 371                 fraglimit_override = autocvar_g_nexball_goallimit;
 372                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 373                 ActivateTeamplay();
 374                 nb_init();
 375                 have_team_spawns = -1; // request team spawns
 376         }
 377
 378         if(g_keepaway)
 379         {
 380                 game = GAME_KEEPAWAY;
 381                 gamemode_name = "Keepaway";
 382                 MUTATOR_ADD(gamemode_keepaway);
 383         }
 384
 385         if(teams_matter)
 386                 entcs_init();
 387
 388         // save it (for the next startup)
 389         cvar_set("gamecfg", ftos(game));
 390
 391         cache_mutatormsg = strzone("");
 392         cache_lastmutatormsg = strzone("");
 393
 394         // enforce the server's universal frag/time limits
 395         if(!autocvar_g_campaign)
 396         {
 397                 if(fraglimit_override >= 0)
 398                         cvar_set("fraglimit", ftos(fraglimit_override));
 399                 if(timelimit_override >= 0)
 400                         cvar_set("timelimit", ftos(timelimit_override));
 401                 if(leadlimit_override >= 0)
 402                         cvar_set("leadlimit", ftos(leadlimit_override));
 403                 if(qualifying_override >= 0)
 404                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 405         }
 406
 407         if(g_race)
 408         {
 409                 // we need to find out the correct value for g_race_qualifying
 410                 if(autocvar_g_campaign)
 411                 {
 412                         g_race_qualifying = 1;
 413                 }
 414                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 415                 {
 416                         g_race_qualifying = 2;
 417                         race_fraglimit = autocvar_fraglimit;
 418                         race_leadlimit = autocvar_leadlimit;
 419                         race_timelimit = autocvar_timelimit;
 420                         cvar_set("fraglimit", "0");
 421                         cvar_set("leadlimit", "0");
 422                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 423                 }
 424                 else
 425                         g_race_qualifying = 0;
 426         }
 427
 428         if(g_race || g_cts)
 429         {
 430                 if(g_race_qualifying)
 431                         independent_players = 1;
 432
 433                 ScoreRules_race();
 434         }
 435
 436         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 437 }
 438
 439 string GetClientVersionMessage() {
 440         local string versionmsg;
 441         if (self.version_mismatch) {
 442                 if(self.version < autocvar_gameversion) {
 443                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 444                 } else {
 445                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 446                 }
 447         } else {
 448                 versionmsg = "^2client version and server version are compatible.^8";
 449         }
 450         return versionmsg;
 451 }
 452
 453
 454 void PrintWelcomeMessage(entity pl)
 455 {
 456         string s, modifications, motd;
 457
 458         if(self.cvar_hud_panel_centerprint_time == 0) return;
 459
 460         if(autocvar_g_campaign)
 461         {
 462                 if(self.classname == "player" && !self.BUTTON_INFO)
 463                         return;
 464         }
 465         else
 466         {
 467                 if((time - self.jointime) > autocvar_welcome_message_time && !self.BUTTON_INFO)
 468                         return;
 469         }
 470
 471         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 472                 if(self.welcomemessage_time > time) return;
 473                 self.welcomemessage_time = time + max(0.5, self.cvar_hud_panel_centerprint_time * 0.6);
 474         }
 475
 476         if(autocvar_g_campaign)
 477         {
 478                 centerprint(pl, campaign_message);
 479                 return;
 480         }
 481
 482 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 483         if(!self.BUTTON_INFO)
 484         {
 485                 // TODO get rid of this too
 486                 local string specString;
 487                 //if(time < game_starttime) //also show the countdown when being a spectator
 488                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 489                 //else
 490                 if (timeoutStatus != 0)
 491                         specString = getTimeoutText(1);
 492                 else
 493                 {
 494                         if(self.classname == "player")
 495                                 return;
 496                         goto normal;
 497                 }
 498                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 499         }
 500
 501 :normal
 502         ret_string = "";
 503         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 504         modifications = ret_string;
 505
 506         if(g_minstagib)
 507                 modifications = strcat(modifications, ", MinstaGib");
 508         if(g_weaponarena)
 509         {
 510                 if(g_weaponarena_random)
 511                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 512                 else
 513                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 514         }
 515         if(autocvar_g_start_weapon_laser == 0)
 516                 modifications = strcat(modifications, ", No start weapons");
 517         if(autocvar_sv_gravity < 800)
 518                 modifications = strcat(modifications, ", Low gravity");
 519         if(g_cloaked && !g_cts)
 520                 modifications = strcat(modifications, ", Cloaked");
 521         if(g_grappling_hook)
 522                 modifications = strcat(modifications, ", Hook");
 523         if(g_midair)
 524                 modifications = strcat(modifications, ", Midair");
 525         if(g_pinata)
 526                 modifications = strcat(modifications, ", Piñata");
 527         if(g_weapon_stay && !g_cts)
 528                 modifications = strcat(modifications, ", Weapons stay");
 529         if(g_bloodloss > 0)
 530                 modifications = strcat(modifications, ", Blood loss");
 531         if(g_jetpack)
 532                 modifications = strcat(modifications, ", Jet pack");
 533         modifications = substring(modifications, 2, strlen(modifications) - 2);
 534
 535         local string versionmessage;
 536         versionmessage = GetClientVersionMessage();
 537
 538         s = strcat(CPID_MOTD, "This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 539         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 540
 541         if(modifications != "")
 542                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 543
 544         if(timeoutStatus != 0)
 545                 s = strcat(s, "\n\n", getTimeoutText(1));
 546
 547         if (g_grappling_hook)
 548                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 549
 550         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 551         {
 552                 if(cache_lastmutatormsg)
 553                         strunzone(cache_lastmutatormsg);
 554                 if(cache_mutatormsg)
 555                         strunzone(cache_mutatormsg);
 556                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 557                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 558         }
 559
 560         if (cache_mutatormsg != "") {
 561                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 562         }
 563
 564         motd = autocvar_sv_motd;
 565         if (motd != "") {
 566                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 567         }
 568         s = strcat(s, "\n");
 569
 570         centerprint(pl, s);
 571 }
 572
 573
 574 void SetPlayerColors(entity pl, float _color)
 575 {
 576         /*string s;
 577         s = ftos(cl);
 578         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 579         pl.team = cl + 1;
 580         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 581         pl.clientcolors = 16*cl + cl;*/
 582
 583         float pants, shirt;
 584         pants = _color & 0x0F;
 585         shirt = _color & 0xF0;
 586
 587
 588         if(teams_matter) {
 589                 setcolor(pl, 16*pants + pants);
 590         } else {
 591                 setcolor(pl, shirt + pants);
 592         }
 593 }
 594
 595 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 596 {
 597         float _color;
 598
 599         if(t == 4)
 600                 _color = COLOR_TEAM4 - 1;
 601         else if(t == 3)
 602                 _color = COLOR_TEAM3 - 1;
 603         else if(t == 2)
 604                 _color = COLOR_TEAM2 - 1;
 605         else
 606                 _color = COLOR_TEAM1 - 1;
 607
 608         SetPlayerColors(pl,_color);
 609
 610         if(t != s) {
 611                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 612
 613                 if(!noprint)
 614                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 615         }
 616
 617 }
 618
 619 // set c1...c4 to show what teams are allowed
 620 void CheckAllowedTeams (entity for_whom)
 621 {
 622         float dm;
 623         entity head;
 624         string teament_name;
 625
 626         c1 = c2 = c3 = c4 = -1;
 627         cb1 = cb2 = cb3 = cb4 = 0;
 628
 629         if(g_onslaught)
 630         {
 631                 // onslaught is special
 632                 head = findchain(classname, "onslaught_generator");
 633                 while (head)
 634                 {
 635                         if (head.team == COLOR_TEAM1) c1 = 0;
 636                         if (head.team == COLOR_TEAM2) c2 = 0;
 637                         if (head.team == COLOR_TEAM3) c3 = 0;
 638                         if (head.team == COLOR_TEAM4) c4 = 0;
 639                         head = head.chain;
 640                 }
 641         }
 642         else if(g_domination)
 643                 teament_name = "dom_team";
 644         else if(g_ctf)
 645                 teament_name = "ctf_team";
 646         else if(g_tdm)
 647                 teament_name = "tdm_team";
 648         else if(g_nexball)
 649                 teament_name = "nexball_team";
 650         else if(g_assault)
 651                 c1 = c2 = 0; // Assault always has 2 teams
 652         else
 653         {
 654                 // cover anything else by treating it like tdm with no teams spawned
 655                 if(g_race)
 656                         dm = race_teams;
 657                 else
 658                         dm = 2;
 659
 660                 ret_float = dm;
 661                 MUTATOR_CALLHOOK(GetTeamCount);
 662                 dm = ret_float;
 663
 664                 if(dm >= 4)
 665                         c1 = c2 = c3 = c4 = 0;
 666                 else if(dm >= 3)
 667                         c1 = c2 = c3 = 0;
 668                 else
 669                         c1 = c2 = 0;
 670         }
 671
 672         // find out what teams are allowed if necessary
 673         if(teament_name)
 674         {
 675                 head = find(world, classname, teament_name);
 676                 while(head)
 677                 {
 678                         if(!(g_domination && head.netname == ""))
 679                         {
 680                                 if(head.team == COLOR_TEAM1)
 681                                         c1 = 0;
 682                                 else if(head.team == COLOR_TEAM2)
 683                                         c2 = 0;
 684                                 else if(head.team == COLOR_TEAM3)
 685                                         c3 = 0;
 686                                 else if(head.team == COLOR_TEAM4)
 687                                         c4 = 0;
 688                         }
 689                         head = find(head, classname, teament_name);
 690                 }
 691         }
 692
 693         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 694         if(c3==-1 && c4==-1)
 695         if(autocvar_bot_vs_human && for_whom)
 696         {
 697                 if(autocvar_bot_vs_human > 0)
 698                 {
 699                         // bots are all blue
 700                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 701                                 c1 = c3 = c4 = -1;
 702                         else
 703                                 c2 = -1;
 704                 }
 705                 else
 706                 {
 707                         // bots are all red
 708                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 709                                 c2 = c3 = c4 = -1;
 710                         else
 711                                 c1 = -1;
 712                 }
 713         }
 714
 715         // if player has a forced team, ONLY allow that one
 716         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 717                 c2 = c3 = c4 = -1;
 718         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 719                 c1 = c3 = c4 = -1;
 720         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 721                 c1 = c2 = c4 = -1;
 722         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 723                 c1 = c2 = c3 = -1;
 724 }
 725
 726 float PlayerValue(entity p)
 727 {
 728         if(IsTeamBalanceForced() == 1)
 729                 return 1;
 730         return 1;
 731         // FIXME: it always returns 1...
 732 }
 733
 734 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 735 // teams that are allowed will now have their player counts stored in c1...c4
 736 void GetTeamCounts(entity ignore)
 737 {
 738         entity head;
 739         float value, bvalue;
 740         // now count how many players are on each team already
 741
 742         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 743         // also remember the lowest-scoring player
 744
 745         FOR_EACH_CLIENT(head)
 746         {
 747                 float t;
 748                 if(head.classname == "player")
 749                         t = head.team;
 750                 else if(head.team_forced > 0)
 751                         t = head.team_forced; // reserve the spot
 752                 else
 753                         continue;
 754                 if(head != ignore)// && head.netname != "")
 755                 {
 756                         value = PlayerValue(head);
 757                         if(clienttype(head) == CLIENTTYPE_BOT)
 758                                 bvalue = value;
 759                         else
 760                                 bvalue = 0;
 761                         if(t == COLOR_TEAM1)
 762                         {
 763                                 if(c1 >= 0)
 764                                 {
 765                                         c1 = c1 + value;
 766                                         cb1 = cb1 + bvalue;
 767                                 }
 768                         }
 769                         if(t == COLOR_TEAM2)
 770                         {
 771                                 if(c2 >= 0)
 772                                 {
 773                                         c2 = c2 + value;
 774                                         cb2 = cb2 + bvalue;
 775                                 }
 776                         }
 777                         if(t == COLOR_TEAM3)
 778                         {
 779                                 if(c3 >= 0)
 780                                 {
 781                                         c3 = c3 + value;
 782                                         cb3 = cb3 + bvalue;
 783                                 }
 784                         }
 785                         if(t == COLOR_TEAM4)
 786                         {
 787                                 if(c4 >= 0)
 788                                 {
 789                                         c4 = c4 + value;
 790                                         cb4 = cb4 + bvalue;
 791                                 }
 792                         }
 793                 }
 794         }
 795
 796         // if the player who has a forced team has not joined yet, reserve the spot
 797         if(autocvar_g_campaign)
 798         {
 799                 switch(autocvar_g_campaign_forceteam)
 800                 {
 801                         case 1: if(c1 == cb1) ++c1; break;
 802                         case 2: if(c2 == cb2) ++c2; break;
 803                         case 3: if(c3 == cb3) ++c3; break;
 804                         case 4: if(c4 == cb4) ++c4; break;
 805                 }
 806         }
 807 }
 808
 809 // returns # of smallest team (1, 2, 3, 4)
 810 // NOTE: Assumes CheckAllowedTeams has already been called!
 811 float FindSmallestTeam(entity pl, float ignore_pl)
 812 {
 813         float totalteams, balance_type, maxc;
 814         totalteams = 0;
 815
 816         // find out what teams are available
 817         //CheckAllowedTeams();
 818
 819         // make sure there are at least 2 teams to join
 820         if(c1 >= 0)
 821                 totalteams = totalteams + 1;
 822         if(c2 >= 0)
 823                 totalteams = totalteams + 1;
 824         if(c3 >= 0)
 825                 totalteams = totalteams + 1;
 826         if(c4 >= 0)
 827                 totalteams = totalteams + 1;
 828
 829         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 830                 totalteams += 1;
 831
 832         if(totalteams <= 1)
 833         {
 834                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 835                         return 1; // special case for campaign and player joining
 836                 else if(g_domination)
 837                         error("Too few teams available for domination\n");
 838                 else if(g_ctf)
 839                         error("Too few teams available for ctf\n");
 840                 else if(g_keyhunt)
 841                         error("Too few teams available for key hunt\n");
 842                 else if(g_freezetag)
 843                         error("Too few teams available for freeze tag\n");
 844                 else
 845                         error("Too few teams available for team deathmatch\n");
 846         }
 847
 848         // count how many players are in each team
 849         if(ignore_pl)
 850                 GetTeamCounts(pl);
 851         else
 852                 GetTeamCounts(world);
 853
 854         // c1...c4 now have counts of each team
 855         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 856
 857         // 2 gives priority to what team you're already on, 1 goes in order
 858         // 2 doesn't seem to work though...
 859         balance_type = 1;
 860
 861         if(bots_would_leave)
 862         //if(pl.classname != "player")
 863         if(clienttype(pl) != CLIENTTYPE_BOT)
 864         {
 865                 c1 -= cb1 * 255.0/256.0;
 866                 c2 -= cb2 * 255.0/256.0;
 867                 c3 -= cb3 * 255.0/256.0;
 868                 c4 -= cb4 * 255.0/256.0;
 869         }
 870         maxc = max4(c1, c2, c3, c4);
 871
 872         RandomSelection_Init();
 873         if(balance_type == 1)
 874         {
 875                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 876                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 877                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 878                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 879                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 880         }
 881         else if(balance_type == 2)
 882         {
 883                 // 1: use team count, if equal prefer own team
 884                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 885                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 886                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 887                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 888         }
 889         else if(balance_type == 3)
 890         {
 891                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 892                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 893                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 894                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 895                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 896         }
 897         return RandomSelection_chosen_float;
 898 }
 899
 900 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 901 {
 902         float smallest, selectedteam;
 903
 904         // don't join a team if we're not playing a team game
 905         if(!teams_matter)
 906                 return 0;
 907
 908         // find out what teams are available
 909         CheckAllowedTeams(pl);
 910
 911         // if we don't care what team he ends up on, put him on whatever team he entered as.
 912         // if he's not on a valid team, then let other code put him on the smallest team
 913         if(!forcebestteam)
 914         {
 915                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 916                         selectedteam = pl.team;
 917                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 918                         selectedteam = pl.team;
 919                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 920                         selectedteam = pl.team;
 921                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 922                         selectedteam = pl.team;
 923                 else
 924                         selectedteam = -1;
 925
 926                 if(selectedteam > 0)
 927                 {
 928                         if(!only_return_best)
 929                         {
 930                                 SetPlayerColors(pl, selectedteam - 1);
 931
 932                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 933                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 934                                 LogTeamchange(pl.playerid, pl.team, 99);
 935                         }
 936                         return selectedteam;
 937                 }
 938                 // otherwise end up on the smallest team (handled below)
 939         }
 940
 941         smallest = FindSmallestTeam(pl, TRUE);
 942
 943         if(!only_return_best && !pl.bot_forced_team)
 944         {
 945                 TeamchangeFrags(self);
 946                 if(smallest == 1)
 947                 {
 948                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 949                 }
 950                 else if(smallest == 2)
 951                 {
 952                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 953                 }
 954                 else if(smallest == 3)
 955                 {
 956                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 957                 }
 958                 else if(smallest == 4)
 959                 {
 960                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 961                 }
 962                 else
 963                 {
 964                         error("smallest team: invalid team\n");
 965                 }
 966
 967                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 968
 969                 if(pl.deadflag == DEAD_NO)
 970                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 971         }
 972
 973         return smallest;
 974 }
 975
 976 //void() ctf_playerchanged;
 977 void SV_ChangeTeam(float _color)
 978 {
 979         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 980
 981         // in normal deathmatch we can just apply the color and we're done
 982         if(!teams_matter) {
 983                 SetPlayerColors(self, _color);
 984                 return;
 985         }
 986
 987         scolor = self.clientcolors & 0x0F;
 988         dcolor = _color & 0x0F;
 989
 990         if(scolor == COLOR_TEAM1 - 1)
 991                 steam = 1;
 992         else if(scolor == COLOR_TEAM2 - 1)
 993                 steam = 2;
 994         else if(scolor == COLOR_TEAM3 - 1)
 995                 steam = 3;
 996         else // if(scolor == COLOR_TEAM4 - 1)
 997                 steam = 4;
 998         if(dcolor == COLOR_TEAM1 - 1)
 999                 dteam = 1;
1000         else if(dcolor == COLOR_TEAM2 - 1)
1001                 dteam = 2;
1002         else if(dcolor == COLOR_TEAM3 - 1)
1003                 dteam = 3;
1004         else // if(dcolor == COLOR_TEAM4 - 1)
1005                 dteam = 4;
1006
1007         CheckAllowedTeams(self);
1008
1009         if(dteam == 1 && c1 < 0) dteam = 4;
1010         if(dteam == 4 && c4 < 0) dteam = 3;
1011         if(dteam == 3 && c3 < 0) dteam = 2;
1012         if(dteam == 2 && c2 < 0) dteam = 1;
1013
1014         // not changing teams
1015         if(scolor == dcolor)
1016         {
1017                 //bprint("same team change\n");
1018                 SetPlayerTeam(self, dteam, steam, TRUE);
1019                 return;
1020         }
1021
1022         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
1023                 sprint(self, "Team changes not allowed\n");
1024                 return; // changing teams is not allowed
1025         }
1026
1027         if(autocvar_g_balance_teams_prevent_imbalance)
1028         {
1029                 // only allow changing to a smaller or equal size team
1030
1031                 // find out what teams are available
1032                 //CheckAllowedTeams();
1033                 // count how many players on each team
1034                 GetTeamCounts(world);
1035
1036                 // get desired team
1037                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1038                 {
1039                         dcount = c1;
1040                         dbotcount = cb1;
1041                 }
1042                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1043                 {
1044                         dcount = c2;
1045                         dbotcount = cb2;
1046                 }
1047                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1048                 {
1049                         dcount = c3;
1050                         dbotcount = cb3;
1051                 }
1052                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1053                 {
1054                         dcount = c4;
1055                         dbotcount = cb4;
1056                 }
1057                 else
1058                 {
1059                         sprint(self, "Cannot change to an invalid team\n");
1060
1061                         return;
1062                 }
1063
1064                 // get starting team
1065                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1066                         scount = c1;
1067                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1068                         scount = c2;
1069                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1070                         scount = c3;
1071                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1072                         scount = c4;
1073
1074                 if(scount) // started at a valid, nonempty team
1075                 {
1076                         // check if we're trying to change to a larger team that doens't have bots to swap with
1077                         if(dcount >= scount && dbotcount <= 0)
1078                         {
1079                                 sprint(self, "Cannot change to a larger team\n");
1080                                 return; // can't change to a larger team
1081                         }
1082                 }
1083         }
1084
1085 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1086
1087         if(self.classname == "player" && steam != dteam)
1088         {
1089                 // reduce frags during a team change
1090                 TeamchangeFrags(self);
1091         }
1092
1093         SetPlayerTeam(self, dteam, steam, FALSE);
1094
1095         if(self.classname == "player" && steam != dteam)
1096         {
1097                 // kill player when changing teams
1098                 if(self.deadflag == DEAD_NO)
1099                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1100         }
1101         //ctf_playerchanged();
1102 }
1103
1104 void ShufflePlayerOutOfTeam (float source_team)
1105 {
1106         float smallestteam, smallestteam_count, steam;
1107         float lowest_bot_score, lowest_player_score;
1108         entity head, lowest_bot, lowest_player, selected;
1109
1110         smallestteam = 0;
1111         smallestteam_count = 999999999;
1112
1113         if(c1 >= 0 && c1 < smallestteam_count)
1114         {
1115                 smallestteam = 1;
1116                 smallestteam_count = c1;
1117         }
1118         if(c2 >= 0 && c2 < smallestteam_count)
1119         {
1120                 smallestteam = 2;
1121                 smallestteam_count = c2;
1122         }
1123         if(c3 >= 0 && c3 < smallestteam_count)
1124         {
1125                 smallestteam = 3;
1126                 smallestteam_count = c3;
1127         }
1128         if(c4 >= 0 && c4 < smallestteam_count)
1129         {
1130                 smallestteam = 4;
1131                 smallestteam_count = c4;
1132         }
1133
1134         if(!smallestteam)
1135         {
1136                 bprint("warning: no smallest team\n");
1137                 return;
1138         }
1139
1140         if(source_team == 1)
1141                 steam = COLOR_TEAM1;
1142         else if(source_team == 2)
1143                 steam = COLOR_TEAM2;
1144         else if(source_team == 3)
1145                 steam = COLOR_TEAM3;
1146         else if(source_team == 4)
1147                 steam = COLOR_TEAM4;
1148
1149         lowest_bot = world;
1150         lowest_bot_score = 999999999;
1151         lowest_player = world;
1152         lowest_player_score = 999999999;
1153
1154         // find the lowest-scoring player & bot of that team
1155         FOR_EACH_PLAYER(head)
1156         {
1157                 if(head.team == steam)
1158                 {
1159                         if(head.isbot)
1160                         {
1161                                 if(head.totalfrags < lowest_bot_score)
1162                                 {
1163                                         lowest_bot = head;
1164                                         lowest_bot_score = head.totalfrags;
1165                                 }
1166                         }
1167                         else
1168                         {
1169                                 if(head.totalfrags < lowest_player_score)
1170                                 {
1171                                         lowest_player = head;
1172                                         lowest_player_score = head.totalfrags;
1173                                 }
1174                         }
1175                 }
1176         }
1177
1178         // prefers to move a bot...
1179         if(lowest_bot != world)
1180                 selected = lowest_bot;
1181         // but it will move a player if it has to
1182         else
1183                 selected = lowest_player;
1184         // don't do anything if it couldn't find anyone
1185         if(!selected)
1186         {
1187                 bprint("warning: couldn't find a player to move from team\n");
1188                 return;
1189         }
1190
1191         // smallest team gains a member
1192         if(smallestteam == 1)
1193         {
1194                 c1 = c1 + 1;
1195         }
1196         else if(smallestteam == 2)
1197         {
1198                 c2 = c2 + 1;
1199         }
1200         else if(smallestteam == 3)
1201         {
1202                 c3 = c3 + 1;
1203         }
1204         else if(smallestteam == 4)
1205         {
1206                 c4 = c4 + 1;
1207         }
1208         else
1209         {
1210                 bprint("warning: destination team invalid\n");
1211                 return;
1212         }
1213         // source team loses a member
1214         if(source_team == 1)
1215         {
1216                 c1 = c1 + 1;
1217         }
1218         else if(source_team == 2)
1219         {
1220                 c2 = c2 + 2;
1221         }
1222         else if(source_team == 3)
1223         {
1224                 c3 = c3 + 3;
1225         }
1226         else if(source_team == 4)
1227         {
1228                 c4 = c4 + 4;
1229         }
1230         else
1231         {
1232                 bprint("warning: source team invalid\n");
1233                 return;
1234         }
1235
1236         // move the player to the new team
1237         TeamchangeFrags(selected);
1238         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1239
1240         if(selected.deadflag == DEAD_NO)
1241                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1242         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1243 }
1244
1245 void CauseRebalance(float source_team, float howmany_toomany)
1246 {
1247         if(IsTeamBalanceForced() == 1)
1248         {
1249                 bprint("Rebalancing Teams\n");
1250                 ShufflePlayerOutOfTeam(source_team);
1251         }
1252 }
1253
1254 // part of g_balance_teams_force
1255 // occasionally perform an audit of the teams to make
1256 // sure they're more or less balanced in player count.
1257 void AuditTeams()
1258 {
1259         float numplayers, numteams, smallest, toomany;
1260         float balance;
1261         balance = IsTeamBalanceForced();
1262         if(balance == 0)
1263                 return;
1264
1265         if(audit_teams_time > time)
1266                 return;
1267
1268         audit_teams_time = time + 4 + random();
1269
1270 //      bprint("Auditing teams\n");
1271
1272         CheckAllowedTeams(world);
1273         GetTeamCounts(world);
1274
1275
1276         numteams = numplayers = smallest = 0;
1277         if(c1 >= 0)
1278         {
1279                 numteams = numteams + 1;
1280                 numplayers = numplayers + c1;
1281                 smallest = c1;
1282         }
1283         if(c2 >= 0)
1284         {
1285                 numteams = numteams + 1;
1286                 numplayers = numplayers + c2;
1287                 if(c2 < smallest)
1288                         smallest = c2;
1289         }
1290         if(c3 >= 0)
1291         {
1292                 numteams = numteams + 1;
1293                 numplayers = numplayers + c3;
1294                 if(c3 < smallest)
1295                         smallest = c3;
1296         }
1297         if(c4 >= 0)
1298         {
1299                 numteams = numteams + 1;
1300                 numplayers = numplayers + c4;
1301                 if(c4 < smallest)
1302                         smallest = c4;
1303         }
1304
1305         if(numplayers <= 0)
1306                 return; // no players to move around
1307         if(numteams < 2)
1308                 return; // don't bother shuffling if for some reason there aren't any teams
1309
1310         toomany = smallest + 1;
1311
1312         if(c1 && c1 > toomany)
1313                 CauseRebalance(1, c1 - toomany);
1314         if(c2 && c2 > toomany)
1315                 CauseRebalance(2, c2 - toomany);
1316         if(c3 && c3 > toomany)
1317                 CauseRebalance(3, c3 - toomany);
1318         if(c4 && c4 > toomany)
1319                 CauseRebalance(4, c4 - toomany);
1320
1321         // if teams are still unbalanced, balance them further in the next audit,
1322         // which will happen sooner (keep doing rapid audits until things are in order)
1323         audit_teams_time = time + 0.7 + random()*0.3;
1324 }
1325
1326 // code from here on is just to support maps that don't have team entities
1327 void tdm_spawnteam (string teamname, float teamcolor)
1328 {
1329         local entity e;
1330         e = spawn();
1331         e.classname = "tdm_team";
1332         e.netname = teamname;
1333         e.cnt = teamcolor;
1334         e.team = e.cnt + 1;
1335 };
1336
1337 // spawn some default teams if the map is not set up for tdm
1338 void tdm_spawnteams()
1339 {
1340         float numteams;
1341
1342         numteams = autocvar_g_tdm_teams_override;
1343         if(numteams < 2)
1344                 numteams = autocvar_g_tdm_teams;
1345         numteams = bound(2, numteams, 4);
1346
1347         tdm_spawnteam("Red", COLOR_TEAM1-1);
1348         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1349         if(numteams >= 3)
1350                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1351         if(numteams >= 4)
1352                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1353 };
1354
1355 void tdm_delayedinit()
1356 {
1357         // if no teams are found, spawn defaults
1358         if (find(world, classname, "tdm_team") == world)
1359                 tdm_spawnteams();
1360 };
1361
1362 void tdm_init()
1363 {
1364         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1365 };