qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2
   3 #include "cl_client.qh"
   4 #include "race.qh"
   5 #include "scores.qh"
   6 #include "scores_rules.qh"
   7
   8 #include "bot/bot.qh"
   9
  10 #include "command/vote.qh"
  11
  12 #include "mutators/mutators_include.qh"
  13
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/gamemodes/all.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit()
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  50
  51         qualifying_override = -1;
  52
  53         VoteReset();
  54
  55         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  56         get_mi_min_max(1);
  57         world.mins = mi_min;
  58         world.maxs = mi_max;
  59
  60         MapInfo_LoadMapSettings(mapname);
  61         serverflags &= ~SERVERFLAG_TEAMPLAY;
  62         teamplay = 0;
  63         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  64
  65         if (!cvar_value_issafe(world.fog))
  66         {
  67                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
  68                 world.fog = string_null;
  69         }
  70         if(MapInfo_Map_fog != "")
  71                 if(MapInfo_Map_fog == "none")
  72                         world.fog = string_null;
  73                 else
  74                         world.fog = strzone(MapInfo_Map_fog);
  75         clientstuff = strzone(MapInfo_Map_clientstuff);
  76
  77         MapInfo_ClearTemps();
  78
  79         // set both here, gamemode can override it later
  80         timelimit_override = autocvar_timelimit_override;
  81         fraglimit_override = autocvar_fraglimit_override;
  82         leadlimit_override = autocvar_leadlimit_override;
  83         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  84
  85         if(g_dm)
  86         {
  87                 MUTATOR_ADD(gamemode_deathmatch);
  88         }
  89
  90         if(g_tdm)
  91         {
  92                 ActivateTeamplay();
  93                 fraglimit_override = autocvar_g_tdm_point_limit;
  94                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
  95                 if(autocvar_g_tdm_team_spawns)
  96                         have_team_spawns = -1; // request team spawns
  97                 MUTATOR_ADD(gamemode_tdm);
  98         }
  99
 100         if(g_domination)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_g_domination_point_limit;
 104                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 105                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
 106                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
 107                 have_team_spawns = -1; // request team spawns
 108                 MUTATOR_ADD(gamemode_domination);
 109         }
 110
 111         if(g_ctf)
 112         {
 113                 ActivateTeamplay();
 114                 fraglimit_override = autocvar_capturelimit_override;
 115                 leadlimit_override = autocvar_captureleadlimit_override;
 116                 have_team_spawns = -1; // request team spawns
 117                 MUTATOR_ADD(gamemode_ctf);
 118         }
 119
 120         if(g_lms)
 121         {
 122                 fraglimit_override = autocvar_g_lms_lives_override;
 123                 leadlimit_override = 0; // not supported by LMS
 124                 if(fraglimit_override == 0)
 125                         fraglimit_override = -1;
 126                 MUTATOR_ADD(gamemode_lms);
 127         }
 128
 129         if(g_ca)
 130         {
 131                 ActivateTeamplay();
 132                 fraglimit_override = autocvar_g_ca_point_limit;
 133                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 134                 if(autocvar_g_ca_team_spawns)
 135                         have_team_spawns = -1; // request team spawns
 136                 MUTATOR_ADD(gamemode_ca);
 137         }
 138
 139         if(g_keyhunt)
 140         {
 141                 ActivateTeamplay();
 142                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 143                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 144                 if(autocvar_g_keyhunt_team_spawns)
 145                         have_team_spawns = -1; // request team spawns
 146                 MUTATOR_ADD(gamemode_keyhunt);
 147         }
 148
 149         if(g_freezetag)
 150         {
 151                 ActivateTeamplay();
 152                 fraglimit_override = autocvar_g_freezetag_point_limit;
 153                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 154                 if(autocvar_g_freezetag_team_spawns)
 155                         have_team_spawns = -1; // request team spawns
 156                 MUTATOR_ADD(gamemode_freezetag);
 157         }
 158
 159         if(g_assault)
 160         {
 161                 ActivateTeamplay();
 162                 have_team_spawns = -1; // request team spawns
 163                 MUTATOR_ADD(gamemode_assault);
 164         }
 165
 166         if(g_onslaught)
 167         {
 168                 ActivateTeamplay();
 169                 fraglimit_override = autocvar_g_onslaught_point_limit;
 170                 have_team_spawns = -1; // request team spawns
 171                 MUTATOR_ADD(gamemode_onslaught);
 172         }
 173
 174         if(g_race)
 175         {
 176                 if(autocvar_g_race_teams)
 177                 {
 178                         ActivateTeamplay();
 179                         race_teams = bound(2, autocvar_g_race_teams, 4);
 180                         have_team_spawns = -1; // request team spawns
 181                 }
 182                 else
 183                         race_teams = 0;
 184                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 185                 fraglimit_override = autocvar_g_race_laps_limit;
 186                 leadlimit_override = 0; // currently not supported by race
 187
 188                 // we need to find out the correct value for g_race_qualifying
 189                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 190
 191                 if(autocvar_g_campaign)
 192                 {
 193                         g_race_qualifying = 1;
 194                         independent_players = 1;
 195                 }
 196                 else if(!autocvar_g_campaign && want_qualifying)
 197                 {
 198                         g_race_qualifying = 2;
 199                         independent_players = 1;
 200                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
 201                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
 202                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
 203                         fraglimit_override = 0;
 204                         leadlimit_override = 0;
 205                         timelimit_override = autocvar_g_race_qualifying_timelimit;
 206                 }
 207                 else
 208                 {
 209                         g_race_qualifying = 0;
 210                 }
 211
 212                 MUTATOR_ADD(gamemode_race);
 213         }
 214
 215         if(g_cts)
 216         {
 217                 g_race_qualifying = 1;
 218                 fraglimit_override = 0;
 219                 leadlimit_override = 0;
 220                 independent_players = 1;
 221                 MUTATOR_ADD(gamemode_cts);
 222         }
 223
 224         if(g_nexball)
 225         {
 226                 fraglimit_override = autocvar_g_nexball_goallimit;
 227                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 228                 ActivateTeamplay();
 229                 have_team_spawns = -1; // request team spawns
 230                 MUTATOR_ADD(gamemode_nexball);
 231         }
 232
 233         if(g_keepaway)
 234         {
 235                 MUTATOR_ADD(gamemode_keepaway);
 236         }
 237
 238         if(g_invasion)
 239         {
 240                 fraglimit_override = autocvar_g_invasion_point_limit;
 241                 if(autocvar_g_invasion_teams >= 2)
 242                 {
 243                         ActivateTeamplay();
 244                         if(autocvar_g_invasion_team_spawns)
 245                                 have_team_spawns = -1; // request team spawns
 246                 }
 247                 MUTATOR_ADD(gamemode_invasion);
 248         }
 249
 250         cache_mutatormsg = strzone("");
 251         cache_lastmutatormsg = strzone("");
 252
 253         // enforce the server's universal frag/time limits
 254         if(!autocvar_g_campaign)
 255         {
 256                 if(fraglimit_override >= 0)
 257                         cvar_set("fraglimit", ftos(fraglimit_override));
 258                 if(timelimit_override >= 0)
 259                         cvar_set("timelimit", ftos(timelimit_override));
 260                 if(leadlimit_override >= 0)
 261                         cvar_set("leadlimit", ftos(leadlimit_override));
 262                 if(qualifying_override >= 0)
 263                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 264         }
 265
 266         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 267 }
 268
 269 string GetClientVersionMessage()
 270 {SELFPARAM();
 271         string versionmsg;
 272         if (self.version_mismatch) {
 273                 if(self.version < autocvar_gameversion) {
 274                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 275                 } else {
 276                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 277                 }
 278         } else {
 279                 versionmsg = "^2client version and server version are compatible.^8";
 280         }
 281         return versionmsg;
 282 }
 283
 284 string getwelcomemessage(void)
 285 {
 286         string s, modifications, motd;
 287
 288         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 289         modifications = ret_string;
 290
 291         if(g_weaponarena)
 292         {
 293                 if(g_weaponarena_random)
 294                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 295                 else
 296                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 297         }
 298         else if(cvar("g_balance_blaster_weaponstart") == 0)
 299                 modifications = strcat(modifications, ", No start weapons");
 300         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 301                 modifications = strcat(modifications, ", Low gravity");
 302         if(g_cloaked && !g_cts)
 303                 modifications = strcat(modifications, ", Cloaked");
 304         if(g_weapon_stay && !g_cts)
 305                 modifications = strcat(modifications, ", Weapons stay");
 306         if(g_jetpack)
 307                 modifications = strcat(modifications, ", Jet pack");
 308         if(autocvar_g_powerups == 0)
 309                 modifications = strcat(modifications, ", No powerups");
 310         if(autocvar_g_powerups > 0)
 311                 modifications = strcat(modifications, ", Powerups");
 312         modifications = substring(modifications, 2, strlen(modifications) - 2);
 313
 314         string versionmessage;
 315         versionmessage = GetClientVersionMessage();
 316
 317         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 318         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 319
 320         if(modifications != "")
 321                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 322
 323         if (cvar("g_nades"))
 324                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 325
 326         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 327         {
 328                 if(cache_lastmutatormsg)
 329                         strunzone(cache_lastmutatormsg);
 330                 if(cache_mutatormsg)
 331                         strunzone(cache_mutatormsg);
 332                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 333                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 334         }
 335
 336         if (cache_mutatormsg != "") {
 337                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 338         }
 339
 340         string mutator_msg = "";
 341         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
 342         mutator_msg = ret_string;
 343
 344         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
 345
 346         motd = autocvar_sv_motd;
 347         if (motd != "") {
 348                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 349         }
 350         return s;
 351 }
 352
 353 void SetPlayerColors(entity pl, float _color)
 354 {
 355         /*string s;
 356         s = ftos(cl);
 357         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 358         pl.team = cl + 1;
 359         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 360         pl.clientcolors = 16*cl + cl;*/
 361
 362         float pants, shirt;
 363         pants = _color & 0x0F;
 364         shirt = _color & 0xF0;
 365
 366
 367         if(teamplay) {
 368                 setcolor(pl, 16*pants + pants);
 369         } else {
 370                 setcolor(pl, shirt + pants);
 371         }
 372 }
 373
 374 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 375 {
 376         float _color;
 377
 378         if(t == 4)
 379                 _color = NUM_TEAM_4 - 1;
 380         else if(t == 3)
 381                 _color = NUM_TEAM_3 - 1;
 382         else if(t == 2)
 383                 _color = NUM_TEAM_2 - 1;
 384         else
 385                 _color = NUM_TEAM_1 - 1;
 386
 387         SetPlayerColors(pl,_color);
 388
 389         if(t != s) {
 390                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 391
 392                 if(!noprint)
 393                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 394         }
 395
 396 }
 397
 398 // set c1...c4 to show what teams are allowed
 399 void CheckAllowedTeams (entity for_whom)
 400 {SELFPARAM();
 401         float dm;
 402         entity head;
 403         string teament_name;
 404
 405         c1 = c2 = c3 = c4 = -1;
 406         cb1 = cb2 = cb3 = cb4 = 0;
 407
 408         teament_name = string_null;
 409         if(g_onslaught)
 410         {
 411                 // onslaught is special
 412                 head = findchain(classname, "onslaught_generator");
 413                 while (head)
 414                 {
 415                         if (head.team == NUM_TEAM_1) c1 = 0;
 416                         if (head.team == NUM_TEAM_2) c2 = 0;
 417                         if (head.team == NUM_TEAM_3) c3 = 0;
 418                         if (head.team == NUM_TEAM_4) c4 = 0;
 419                         head = head.chain;
 420                 }
 421         }
 422         else if(g_domination)
 423                 teament_name = "dom_team";
 424         else if(g_ctf)
 425                 teament_name = "ctf_team";
 426         else if(g_tdm)
 427                 teament_name = "tdm_team";
 428         else if(g_nexball)
 429                 teament_name = "nexball_team";
 430         else if(g_assault)
 431                 c1 = c2 = 0; // Assault always has 2 teams
 432         else
 433         {
 434                 // cover anything else by treating it like tdm with no teams spawned
 435                 dm = 2;
 436
 437                 MUTATOR_CALLHOOK(GetTeamCount, dm);
 438                 dm = ret_float;
 439
 440                 if(dm >= 4)
 441                         c1 = c2 = c3 = c4 = 0;
 442                 else if(dm >= 3)
 443                         c1 = c2 = c3 = 0;
 444                 else
 445                         c1 = c2 = 0;
 446         }
 447
 448         // find out what teams are allowed if necessary
 449         if(teament_name)
 450         {
 451                 head = find(world, classname, teament_name);
 452                 while(head)
 453                 {
 454                         if(!(g_domination && head.netname == ""))
 455                         {
 456                                 if(head.team == NUM_TEAM_1)
 457                                         c1 = 0;
 458                                 else if(head.team == NUM_TEAM_2)
 459                                         c2 = 0;
 460                                 else if(head.team == NUM_TEAM_3)
 461                                         c3 = 0;
 462                                 else if(head.team == NUM_TEAM_4)
 463                                         c4 = 0;
 464                         }
 465                         head = find(head, classname, teament_name);
 466                 }
 467         }
 468
 469         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 470         if(c3==-1 && c4==-1)
 471         if(autocvar_bot_vs_human && for_whom)
 472         {
 473                 if(autocvar_bot_vs_human > 0)
 474                 {
 475                         // bots are all blue
 476                         if(IS_BOT_CLIENT(for_whom))
 477                                 c1 = c3 = c4 = -1;
 478                         else
 479                                 c2 = -1;
 480                 }
 481                 else
 482                 {
 483                         // bots are all red
 484                         if(IS_BOT_CLIENT(for_whom))
 485                                 c2 = c3 = c4 = -1;
 486                         else
 487                                 c1 = -1;
 488                 }
 489         }
 490
 491         // if player has a forced team, ONLY allow that one
 492         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 493                 c2 = c3 = c4 = -1;
 494         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 495                 c1 = c3 = c4 = -1;
 496         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 497                 c1 = c2 = c4 = -1;
 498         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 499                 c1 = c2 = c3 = -1;
 500 }
 501
 502 float PlayerValue(entity p)
 503 {
 504         return 1;
 505         // FIXME: it always returns 1...
 506 }
 507
 508 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 509 // teams that are allowed will now have their player counts stored in c1...c4
 510 void GetTeamCounts(entity ignore)
 511 {
 512         entity head;
 513         float value, bvalue;
 514         // now count how many players are on each team already
 515
 516         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 517         // also remember the lowest-scoring player
 518
 519         FOR_EACH_CLIENT(head)
 520         {
 521                 float t;
 522                 if(IS_PLAYER(head) || head.caplayer)
 523                         t = head.team;
 524                 else if(head.team_forced > 0)
 525                         t = head.team_forced; // reserve the spot
 526                 else
 527                         continue;
 528                 if(head != ignore)// && head.netname != "")
 529                 {
 530                         value = PlayerValue(head);
 531                         if(IS_BOT_CLIENT(head))
 532                                 bvalue = value;
 533                         else
 534                                 bvalue = 0;
 535                         if(t == NUM_TEAM_1)
 536                         {
 537                                 if(c1 >= 0)
 538                                 {
 539                                         c1 = c1 + value;
 540                                         cb1 = cb1 + bvalue;
 541                                 }
 542                         }
 543                         if(t == NUM_TEAM_2)
 544                         {
 545                                 if(c2 >= 0)
 546                                 {
 547                                         c2 = c2 + value;
 548                                         cb2 = cb2 + bvalue;
 549                                 }
 550                         }
 551                         if(t == NUM_TEAM_3)
 552                         {
 553                                 if(c3 >= 0)
 554                                 {
 555                                         c3 = c3 + value;
 556                                         cb3 = cb3 + bvalue;
 557                                 }
 558                         }
 559                         if(t == NUM_TEAM_4)
 560                         {
 561                                 if(c4 >= 0)
 562                                 {
 563                                         c4 = c4 + value;
 564                                         cb4 = cb4 + bvalue;
 565                                 }
 566                         }
 567                 }
 568         }
 569
 570         // if the player who has a forced team has not joined yet, reserve the spot
 571         if(autocvar_g_campaign)
 572         {
 573                 switch(autocvar_g_campaign_forceteam)
 574                 {
 575                         case 1: if(c1 == cb1) ++c1; break;
 576                         case 2: if(c2 == cb2) ++c2; break;
 577                         case 3: if(c3 == cb3) ++c3; break;
 578                         case 4: if(c4 == cb4) ++c4; break;
 579                 }
 580         }
 581 }
 582
 583 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 584 {
 585         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 586         float f;
 587         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 588
 589         switch(ta)
 590         {
 591                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 592                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 593                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 594                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 595         }
 596         switch(tb)
 597         {
 598                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 599                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 600                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 601                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 602         }
 603
 604         // invalid
 605         if(ca < 0 || cb < 0)
 606                 return false;
 607
 608         // equal
 609         if(ta == tb)
 610                 return true;
 611
 612         if(IS_REAL_CLIENT(e))
 613         {
 614                 if(bots_would_leave)
 615                 {
 616                         ca -= cba * 0.999;
 617                         cb -= cbb * 0.999;
 618                 }
 619         }
 620
 621         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 622         if(ca < 1)
 623                 if(cb >= 1)
 624                         return true;
 625         if(ca >= 1)
 626                 if(cb < 1)
 627                         return false;
 628
 629         // first, normalize
 630         f = max(ca, cb, 1);
 631         ca /= f;
 632         cb /= f;
 633         f = max(sa, sb, 1);
 634         sa /= f;
 635         sb /= f;
 636
 637         // the more we're at the end of the match, the more take scores into account
 638         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 639         ca += (sa - ca) * f;
 640         cb += (sb - cb) * f;
 641
 642         return ca <= cb;
 643 }
 644
 645 // returns # of smallest team (1, 2, 3, 4)
 646 // NOTE: Assumes CheckAllowedTeams has already been called!
 647 float FindSmallestTeam(entity pl, float ignore_pl)
 648 {
 649         float totalteams, t;
 650         totalteams = 0;
 651
 652         // find out what teams are available
 653         //CheckAllowedTeams();
 654
 655         // make sure there are at least 2 teams to join
 656         if(c1 >= 0)
 657                 totalteams = totalteams + 1;
 658         if(c2 >= 0)
 659                 totalteams = totalteams + 1;
 660         if(c3 >= 0)
 661                 totalteams = totalteams + 1;
 662         if(c4 >= 0)
 663                 totalteams = totalteams + 1;
 664
 665         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 666                 totalteams += 1;
 667
 668         if(totalteams <= 1)
 669         {
 670                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 671                         return 1; // special case for campaign and player joining
 672                 else
 673                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 674         }
 675
 676         // count how many players are in each team
 677         if(ignore_pl)
 678                 GetTeamCounts(pl);
 679         else
 680                 GetTeamCounts(world);
 681
 682         RandomSelection_Init();
 683
 684         t = 1;
 685         if(TeamSmallerEqThanTeam(2, t, pl))
 686                 t = 2;
 687         if(TeamSmallerEqThanTeam(3, t, pl))
 688                 t = 3;
 689         if(TeamSmallerEqThanTeam(4, t, pl))
 690                 t = 4;
 691
 692         // now t is the minimum, or A minimum!
 693         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 694                 RandomSelection_Add(world, 1, string_null, 1, 1);
 695         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 696                 RandomSelection_Add(world, 2, string_null, 1, 1);
 697         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 698                 RandomSelection_Add(world, 3, string_null, 1, 1);
 699         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 700                 RandomSelection_Add(world, 4, string_null, 1, 1);
 701
 702         return RandomSelection_chosen_float;
 703 }
 704
 705 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 706 {SELFPARAM();
 707         float smallest, selectedteam;
 708
 709         // don't join a team if we're not playing a team game
 710         if(!teamplay)
 711                 return 0;
 712
 713         // find out what teams are available
 714         CheckAllowedTeams(pl);
 715
 716         // if we don't care what team he ends up on, put him on whatever team he entered as.
 717         // if he's not on a valid team, then let other code put him on the smallest team
 718         if(!forcebestteam)
 719         {
 720                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 721                         selectedteam = pl.team;
 722                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 723                         selectedteam = pl.team;
 724                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 725                         selectedteam = pl.team;
 726                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 727                         selectedteam = pl.team;
 728                 else
 729                         selectedteam = -1;
 730
 731                 if(selectedteam > 0)
 732                 {
 733                         if(!only_return_best)
 734                         {
 735                                 SetPlayerColors(pl, selectedteam - 1);
 736
 737                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 738                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 739                                 LogTeamchange(pl.playerid, pl.team, 99);
 740                         }
 741                         return selectedteam;
 742                 }
 743                 // otherwise end up on the smallest team (handled below)
 744         }
 745
 746         smallest = FindSmallestTeam(pl, true);
 747
 748         if(!only_return_best && !pl.bot_forced_team)
 749         {
 750                 TeamchangeFrags(self);
 751                 if(smallest == 1)
 752                 {
 753                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 754                 }
 755                 else if(smallest == 2)
 756                 {
 757                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 758                 }
 759                 else if(smallest == 3)
 760                 {
 761                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 762                 }
 763                 else if(smallest == 4)
 764                 {
 765                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 766                 }
 767                 else
 768                 {
 769                         error("smallest team: invalid team\n");
 770                 }
 771
 772                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 773
 774                 if(pl.deadflag == DEAD_NO)
 775                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE.m_id, pl.origin, '0 0 0');
 776         }
 777
 778         return smallest;
 779 }
 780
 781 //void() ctf_playerchanged;
 782 void SV_ChangeTeam(float _color)
 783 {SELFPARAM();
 784         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 785
 786         // in normal deathmatch we can just apply the color and we're done
 787         if(!teamplay) {
 788                 SetPlayerColors(self, _color);
 789                 return;
 790         }
 791
 792         scolor = self.clientcolors & 0x0F;
 793         dcolor = _color & 0x0F;
 794
 795         if(scolor == NUM_TEAM_1 - 1)
 796                 steam = 1;
 797         else if(scolor == NUM_TEAM_2 - 1)
 798                 steam = 2;
 799         else if(scolor == NUM_TEAM_3 - 1)
 800                 steam = 3;
 801         else // if(scolor == NUM_TEAM_4 - 1)
 802                 steam = 4;
 803         if(dcolor == NUM_TEAM_1 - 1)
 804                 dteam = 1;
 805         else if(dcolor == NUM_TEAM_2 - 1)
 806                 dteam = 2;
 807         else if(dcolor == NUM_TEAM_3 - 1)
 808                 dteam = 3;
 809         else // if(dcolor == NUM_TEAM_4 - 1)
 810                 dteam = 4;
 811
 812         CheckAllowedTeams(self);
 813
 814         if(dteam == 1 && c1 < 0) dteam = 4;
 815         if(dteam == 4 && c4 < 0) dteam = 3;
 816         if(dteam == 3 && c3 < 0) dteam = 2;
 817         if(dteam == 2 && c2 < 0) dteam = 1;
 818
 819         // not changing teams
 820         if(scolor == dcolor)
 821         {
 822                 //bprint("same team change\n");
 823                 SetPlayerTeam(self, dteam, steam, true);
 824                 return;
 825         }
 826
 827         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 828                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 829                 return; // changing teams is not allowed
 830         }
 831
 832         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 833         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 834         {
 835                 GetTeamCounts(self);
 836                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 837                 {
 838                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 839                         return;
 840                 }
 841         }
 842
 843 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 844
 845         if(IS_PLAYER(self) && steam != dteam)
 846         {
 847                 // reduce frags during a team change
 848                 TeamchangeFrags(self);
 849         }
 850
 851         // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 852         if(!IS_CLIENT(self))
 853                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_CONNECTING, self.netname);
 854
 855         SetPlayerTeam(self, dteam, steam, !IS_CLIENT(self));
 856
 857         if(IS_PLAYER(self) && steam != dteam)
 858         {
 859                 // kill player when changing teams
 860                 if(self.deadflag == DEAD_NO)
 861                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE.m_id, self.origin, '0 0 0');
 862         }
 863 }
 864
 865 void ShufflePlayerOutOfTeam (float source_team)
 866 {
 867         float smallestteam, smallestteam_count, steam;
 868         float lowest_bot_score, lowest_player_score;
 869         entity head, lowest_bot, lowest_player, selected;
 870
 871         smallestteam = 0;
 872         smallestteam_count = 999999999;
 873
 874         if(c1 >= 0 && c1 < smallestteam_count)
 875         {
 876                 smallestteam = 1;
 877                 smallestteam_count = c1;
 878         }
 879         if(c2 >= 0 && c2 < smallestteam_count)
 880         {
 881                 smallestteam = 2;
 882                 smallestteam_count = c2;
 883         }
 884         if(c3 >= 0 && c3 < smallestteam_count)
 885         {
 886                 smallestteam = 3;
 887                 smallestteam_count = c3;
 888         }
 889         if(c4 >= 0 && c4 < smallestteam_count)
 890         {
 891                 smallestteam = 4;
 892                 smallestteam_count = c4;
 893         }
 894
 895         if(!smallestteam)
 896         {
 897                 bprint("warning: no smallest team\n");
 898                 return;
 899         }
 900
 901         if(source_team == 1)
 902                 steam = NUM_TEAM_1;
 903         else if(source_team == 2)
 904                 steam = NUM_TEAM_2;
 905         else if(source_team == 3)
 906                 steam = NUM_TEAM_3;
 907         else // if(source_team == 4)
 908                 steam = NUM_TEAM_4;
 909
 910         lowest_bot = world;
 911         lowest_bot_score = 999999999;
 912         lowest_player = world;
 913         lowest_player_score = 999999999;
 914
 915         // find the lowest-scoring player & bot of that team
 916         FOR_EACH_PLAYER(head)
 917         {
 918                 if(head.team == steam)
 919                 {
 920                         if(head.isbot)
 921                         {
 922                                 if(head.totalfrags < lowest_bot_score)
 923                                 {
 924                                         lowest_bot = head;
 925                                         lowest_bot_score = head.totalfrags;
 926                                 }
 927                         }
 928                         else
 929                         {
 930                                 if(head.totalfrags < lowest_player_score)
 931                                 {
 932                                         lowest_player = head;
 933                                         lowest_player_score = head.totalfrags;
 934                                 }
 935                         }
 936                 }
 937         }
 938
 939         // prefers to move a bot...
 940         if(lowest_bot != world)
 941                 selected = lowest_bot;
 942         // but it will move a player if it has to
 943         else
 944                 selected = lowest_player;
 945         // don't do anything if it couldn't find anyone
 946         if(!selected)
 947         {
 948                 bprint("warning: couldn't find a player to move from team\n");
 949                 return;
 950         }
 951
 952         // smallest team gains a member
 953         if(smallestteam == 1)
 954         {
 955                 c1 = c1 + 1;
 956         }
 957         else if(smallestteam == 2)
 958         {
 959                 c2 = c2 + 1;
 960         }
 961         else if(smallestteam == 3)
 962         {
 963                 c3 = c3 + 1;
 964         }
 965         else if(smallestteam == 4)
 966         {
 967                 c4 = c4 + 1;
 968         }
 969         else
 970         {
 971                 bprint("warning: destination team invalid\n");
 972                 return;
 973         }
 974         // source team loses a member
 975         if(source_team == 1)
 976         {
 977                 c1 = c1 + 1;
 978         }
 979         else if(source_team == 2)
 980         {
 981                 c2 = c2 + 2;
 982         }
 983         else if(source_team == 3)
 984         {
 985                 c3 = c3 + 3;
 986         }
 987         else if(source_team == 4)
 988         {
 989                 c4 = c4 + 4;
 990         }
 991         else
 992         {
 993                 bprint("warning: source team invalid\n");
 994                 return;
 995         }
 996
 997         // move the player to the new team
 998         TeamchangeFrags(selected);
 999         SetPlayerTeam(selected, smallestteam, source_team, false);
1000
1001         if(selected.deadflag == DEAD_NO)
1002                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE.m_id, selected.origin, '0 0 0');
1003         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
1004 }