qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2 #include "_all.qh"
   3
   4 #include "cl_client.qh"
   5 #include "race.qh"
   6 #include "scores.qh"
   7 #include "scores_rules.qh"
   8
   9 #include "bot/bot.qh"
  10
  11 #include "command/vote.qh"
  12
  13 #include "mutators/mutators_include.qh"
  14
  15 #include "../common/deathtypes.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit()
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  50
  51         qualifying_override = -1;
  52
  53         VoteReset();
  54
  55         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  56         get_mi_min_max(1);
  57         world.mins = mi_min;
  58         world.maxs = mi_max;
  59
  60         MapInfo_LoadMapSettings(mapname);
  61         serverflags &= ~SERVERFLAG_TEAMPLAY;
  62         teamplay = 0;
  63         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  64
  65         if (!cvar_value_issafe(world.fog))
  66         {
  67                 print("The current map contains a potentially harmful fog setting, ignored\n");
  68                 world.fog = string_null;
  69         }
  70         if(MapInfo_Map_fog != "")
  71                 if(MapInfo_Map_fog == "none")
  72                         world.fog = string_null;
  73                 else
  74                         world.fog = strzone(MapInfo_Map_fog);
  75         clientstuff = strzone(MapInfo_Map_clientstuff);
  76
  77         MapInfo_ClearTemps();
  78
  79         // set both here, gamemode can override it later
  80         timelimit_override = autocvar_timelimit_override;
  81         fraglimit_override = autocvar_fraglimit_override;
  82         leadlimit_override = autocvar_leadlimit_override;
  83         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  84
  85         if(g_dm)
  86         {
  87         }
  88
  89         if(g_tdm)
  90         {
  91                 ActivateTeamplay();
  92                 fraglimit_override = autocvar_g_tdm_point_limit;
  93                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
  94                 if(autocvar_g_tdm_team_spawns)
  95                         have_team_spawns = -1; // request team spawns
  96                 MUTATOR_ADD(gamemode_tdm);
  97         }
  98
  99         if(g_domination)
 100         {
 101                 ActivateTeamplay();
 102                 fraglimit_override = autocvar_g_domination_point_limit;
 103                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 104                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
 105                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
 106                 have_team_spawns = -1; // request team spawns
 107                 MUTATOR_ADD(gamemode_domination);
 108         }
 109
 110         if(g_ctf)
 111         {
 112                 ActivateTeamplay();
 113                 fraglimit_override = autocvar_capturelimit_override;
 114                 leadlimit_override = autocvar_captureleadlimit_override;
 115                 have_team_spawns = -1; // request team spawns
 116                 MUTATOR_ADD(gamemode_ctf);
 117         }
 118
 119         if(g_lms)
 120         {
 121                 fraglimit_override = autocvar_g_lms_lives_override;
 122                 leadlimit_override = 0; // not supported by LMS
 123                 if(fraglimit_override == 0)
 124                         fraglimit_override = -1;
 125                 MUTATOR_ADD(gamemode_lms);
 126         }
 127
 128         if(g_ca)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_ca_point_limit;
 132                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 133                 if(autocvar_g_ca_team_spawns)
 134                         have_team_spawns = -1; // request team spawns
 135                 MUTATOR_ADD(gamemode_ca);
 136         }
 137
 138         if(g_keyhunt)
 139         {
 140                 ActivateTeamplay();
 141                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 142                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 143                 MUTATOR_ADD(gamemode_keyhunt);
 144         }
 145
 146         if(g_freezetag)
 147         {
 148                 ActivateTeamplay();
 149                 fraglimit_override = autocvar_g_freezetag_point_limit;
 150                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 151                 if(autocvar_g_freezetag_team_spawns)
 152                         have_team_spawns = -1; // request team spawns
 153                 MUTATOR_ADD(gamemode_freezetag);
 154         }
 155
 156         if(g_assault)
 157         {
 158                 ActivateTeamplay();
 159                 have_team_spawns = -1; // request team spawns
 160                 MUTATOR_ADD(gamemode_assault);
 161         }
 162
 163         if(g_onslaught)
 164         {
 165                 ActivateTeamplay();
 166                 have_team_spawns = -1; // request team spawns
 167                 MUTATOR_ADD(gamemode_onslaught);
 168         }
 169
 170         if(g_race)
 171         {
 172                 if(autocvar_g_race_teams)
 173                 {
 174                         ActivateTeamplay();
 175                         race_teams = bound(2, autocvar_g_race_teams, 4);
 176                         have_team_spawns = -1; // request team spawns
 177                 }
 178                 else
 179                         race_teams = 0;
 180                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 181                 fraglimit_override = autocvar_g_race_laps_limit;
 182                 leadlimit_override = 0; // currently not supported by race
 183
 184                 // we need to find out the correct value for g_race_qualifying
 185                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 186
 187                 if(autocvar_g_campaign)
 188                 {
 189                         g_race_qualifying = 1;
 190                         independent_players = 1;
 191                 }
 192                 else if(!autocvar_g_campaign && want_qualifying)
 193                 {
 194                         g_race_qualifying = 2;
 195                         independent_players = 1;
 196                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
 197                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
 198                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
 199                         fraglimit_override = 0;
 200                         leadlimit_override = 0;
 201                         timelimit_override = autocvar_g_race_qualifying_timelimit;
 202                 }
 203                 else
 204                 {
 205                         g_race_qualifying = 0;
 206                 }
 207
 208                 MUTATOR_ADD(gamemode_race);
 209         }
 210
 211         if(g_cts)
 212         {
 213                 g_race_qualifying = 1;
 214                 fraglimit_override = 0;
 215                 leadlimit_override = 0;
 216                 independent_players = 1;
 217                 MUTATOR_ADD(gamemode_cts);
 218         }
 219
 220         if(g_nexball)
 221         {
 222                 fraglimit_override = autocvar_g_nexball_goallimit;
 223                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 224                 ActivateTeamplay();
 225                 have_team_spawns = -1; // request team spawns
 226                 MUTATOR_ADD(gamemode_nexball);
 227         }
 228
 229         if(g_keepaway)
 230         {
 231                 MUTATOR_ADD(gamemode_keepaway);
 232         }
 233
 234         if(g_invasion)
 235         {
 236                 fraglimit_override = autocvar_g_invasion_point_limit;
 237                 if(autocvar_g_invasion_teams >= 2)
 238                 {
 239                         ActivateTeamplay();
 240                         if(autocvar_g_invasion_team_spawns)
 241                                 have_team_spawns = -1; // request team spawns
 242                 }
 243                 MUTATOR_ADD(gamemode_invasion);
 244         }
 245
 246         if(teamplay)
 247                 entcs_init();
 248
 249         cache_mutatormsg = strzone("");
 250         cache_lastmutatormsg = strzone("");
 251
 252         // enforce the server's universal frag/time limits
 253         if(!autocvar_g_campaign)
 254         {
 255                 if(fraglimit_override >= 0)
 256                         cvar_set("fraglimit", ftos(fraglimit_override));
 257                 if(timelimit_override >= 0)
 258                         cvar_set("timelimit", ftos(timelimit_override));
 259                 if(leadlimit_override >= 0)
 260                         cvar_set("leadlimit", ftos(leadlimit_override));
 261                 if(qualifying_override >= 0)
 262                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 263         }
 264
 265         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 266 }
 267
 268 string GetClientVersionMessage() {
 269         string versionmsg;
 270         if (self.version_mismatch) {
 271                 if(self.version < autocvar_gameversion) {
 272                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 273                 } else {
 274                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 275                 }
 276         } else {
 277                 versionmsg = "^2client version and server version are compatible.^8";
 278         }
 279         return versionmsg;
 280 }
 281
 282 string getwelcomemessage(void)
 283 {
 284         string s, modifications, motd;
 285
 286         ret_string = "";
 287         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 288         modifications = ret_string;
 289
 290         if(g_weaponarena)
 291         {
 292                 if(g_weaponarena_random)
 293                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 294                 else
 295                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 296         }
 297         if(cvar("g_balance_blaster_weaponstart") == 0)
 298                 modifications = strcat(modifications, ", No start weapons");
 299         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 300                 modifications = strcat(modifications, ", Low gravity");
 301         if(g_cloaked && !g_cts)
 302                 modifications = strcat(modifications, ", Cloaked");
 303         if(g_grappling_hook)
 304                 modifications = strcat(modifications, ", Hook");
 305         if(g_weapon_stay && !g_cts)
 306                 modifications = strcat(modifications, ", Weapons stay");
 307         if(g_jetpack)
 308                 modifications = strcat(modifications, ", Jet pack");
 309         if(autocvar_g_powerups == 0)
 310                 modifications = strcat(modifications, ", No powerups");
 311         if(autocvar_g_powerups > 0)
 312                 modifications = strcat(modifications, ", Powerups");
 313         modifications = substring(modifications, 2, strlen(modifications) - 2);
 314
 315         string versionmessage;
 316         versionmessage = GetClientVersionMessage();
 317
 318         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 319         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 320
 321         if(modifications != "")
 322                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 323
 324         if (g_grappling_hook)
 325                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 326
 327         if (cvar("g_nades"))
 328                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 329
 330         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 331         {
 332                 if(cache_lastmutatormsg)
 333                         strunzone(cache_lastmutatormsg);
 334                 if(cache_mutatormsg)
 335                         strunzone(cache_mutatormsg);
 336                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 337                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 338         }
 339
 340         if (cache_mutatormsg != "") {
 341                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 342         }
 343
 344         motd = autocvar_sv_motd;
 345         if (motd != "") {
 346                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 347         }
 348         return s;
 349 }
 350
 351 void SetPlayerColors(entity pl, float _color)
 352 {
 353         /*string s;
 354         s = ftos(cl);
 355         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 356         pl.team = cl + 1;
 357         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 358         pl.clientcolors = 16*cl + cl;*/
 359
 360         float pants, shirt;
 361         pants = _color & 0x0F;
 362         shirt = _color & 0xF0;
 363
 364
 365         if(teamplay) {
 366                 setcolor(pl, 16*pants + pants);
 367         } else {
 368                 setcolor(pl, shirt + pants);
 369         }
 370 }
 371
 372 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 373 {
 374         float _color;
 375
 376         if(t == 4)
 377                 _color = NUM_TEAM_4 - 1;
 378         else if(t == 3)
 379                 _color = NUM_TEAM_3 - 1;
 380         else if(t == 2)
 381                 _color = NUM_TEAM_2 - 1;
 382         else
 383                 _color = NUM_TEAM_1 - 1;
 384
 385         SetPlayerColors(pl,_color);
 386
 387         if(t != s) {
 388                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 389
 390                 if(!noprint)
 391                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 392         }
 393
 394 }
 395
 396 // set c1...c4 to show what teams are allowed
 397 void CheckAllowedTeams (entity for_whom)
 398 {
 399         float dm;
 400         entity head;
 401         string teament_name;
 402
 403         c1 = c2 = c3 = c4 = -1;
 404         cb1 = cb2 = cb3 = cb4 = 0;
 405
 406         teament_name = string_null;
 407         if(g_onslaught)
 408         {
 409                 // onslaught is special
 410                 head = findchain(classname, "onslaught_generator");
 411                 while (head)
 412                 {
 413                         if (head.team == NUM_TEAM_1) c1 = 0;
 414                         if (head.team == NUM_TEAM_2) c2 = 0;
 415                         if (head.team == NUM_TEAM_3) c3 = 0;
 416                         if (head.team == NUM_TEAM_4) c4 = 0;
 417                         head = head.chain;
 418                 }
 419         }
 420         else if(g_domination)
 421                 teament_name = "dom_team";
 422         else if(g_ctf)
 423                 teament_name = "ctf_team";
 424         else if(g_tdm)
 425                 teament_name = "tdm_team";
 426         else if(g_nexball)
 427                 teament_name = "nexball_team";
 428         else if(g_assault)
 429                 c1 = c2 = 0; // Assault always has 2 teams
 430         else
 431         {
 432                 // cover anything else by treating it like tdm with no teams spawned
 433                 dm = 2;
 434
 435                 ret_float = dm;
 436                 MUTATOR_CALLHOOK(GetTeamCount);
 437                 dm = ret_float;
 438
 439                 if(dm >= 4)
 440                         c1 = c2 = c3 = c4 = 0;
 441                 else if(dm >= 3)
 442                         c1 = c2 = c3 = 0;
 443                 else
 444                         c1 = c2 = 0;
 445         }
 446
 447         // find out what teams are allowed if necessary
 448         if(teament_name)
 449         {
 450                 head = find(world, classname, teament_name);
 451                 while(head)
 452                 {
 453                         if(!(g_domination && head.netname == ""))
 454                         {
 455                                 if(head.team == NUM_TEAM_1)
 456                                         c1 = 0;
 457                                 else if(head.team == NUM_TEAM_2)
 458                                         c2 = 0;
 459                                 else if(head.team == NUM_TEAM_3)
 460                                         c3 = 0;
 461                                 else if(head.team == NUM_TEAM_4)
 462                                         c4 = 0;
 463                         }
 464                         head = find(head, classname, teament_name);
 465                 }
 466         }
 467
 468         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 469         if(c3==-1 && c4==-1)
 470         if(autocvar_bot_vs_human && for_whom)
 471         {
 472                 if(autocvar_bot_vs_human > 0)
 473                 {
 474                         // bots are all blue
 475                         if(IS_BOT_CLIENT(for_whom))
 476                                 c1 = c3 = c4 = -1;
 477                         else
 478                                 c2 = -1;
 479                 }
 480                 else
 481                 {
 482                         // bots are all red
 483                         if(IS_BOT_CLIENT(for_whom))
 484                                 c2 = c3 = c4 = -1;
 485                         else
 486                                 c1 = -1;
 487                 }
 488         }
 489
 490         // if player has a forced team, ONLY allow that one
 491         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 492                 c2 = c3 = c4 = -1;
 493         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 494                 c1 = c3 = c4 = -1;
 495         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 496                 c1 = c2 = c4 = -1;
 497         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 498                 c1 = c2 = c3 = -1;
 499 }
 500
 501 float PlayerValue(entity p)
 502 {
 503         return 1;
 504         // FIXME: it always returns 1...
 505 }
 506
 507 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 508 // teams that are allowed will now have their player counts stored in c1...c4
 509 void GetTeamCounts(entity ignore)
 510 {
 511         entity head;
 512         float value, bvalue;
 513         // now count how many players are on each team already
 514
 515         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 516         // also remember the lowest-scoring player
 517
 518         FOR_EACH_CLIENT(head)
 519         {
 520                 float t;
 521                 if(IS_PLAYER(head) || head.caplayer)
 522                         t = head.team;
 523                 else if(head.team_forced > 0)
 524                         t = head.team_forced; // reserve the spot
 525                 else
 526                         continue;
 527                 if(head != ignore)// && head.netname != "")
 528                 {
 529                         value = PlayerValue(head);
 530                         if(IS_BOT_CLIENT(head))
 531                                 bvalue = value;
 532                         else
 533                                 bvalue = 0;
 534                         if(t == NUM_TEAM_1)
 535                         {
 536                                 if(c1 >= 0)
 537                                 {
 538                                         c1 = c1 + value;
 539                                         cb1 = cb1 + bvalue;
 540                                 }
 541                         }
 542                         if(t == NUM_TEAM_2)
 543                         {
 544                                 if(c2 >= 0)
 545                                 {
 546                                         c2 = c2 + value;
 547                                         cb2 = cb2 + bvalue;
 548                                 }
 549                         }
 550                         if(t == NUM_TEAM_3)
 551                         {
 552                                 if(c3 >= 0)
 553                                 {
 554                                         c3 = c3 + value;
 555                                         cb3 = cb3 + bvalue;
 556                                 }
 557                         }
 558                         if(t == NUM_TEAM_4)
 559                         {
 560                                 if(c4 >= 0)
 561                                 {
 562                                         c4 = c4 + value;
 563                                         cb4 = cb4 + bvalue;
 564                                 }
 565                         }
 566                 }
 567         }
 568
 569         // if the player who has a forced team has not joined yet, reserve the spot
 570         if(autocvar_g_campaign)
 571         {
 572                 switch(autocvar_g_campaign_forceteam)
 573                 {
 574                         case 1: if(c1 == cb1) ++c1; break;
 575                         case 2: if(c2 == cb2) ++c2; break;
 576                         case 3: if(c3 == cb3) ++c3; break;
 577                         case 4: if(c4 == cb4) ++c4; break;
 578                 }
 579         }
 580 }
 581
 582 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 583 {
 584         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 585         float f;
 586         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 587
 588         switch(ta)
 589         {
 590                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 591                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 592                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 593                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 594         }
 595         switch(tb)
 596         {
 597                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 598                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 599                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 600                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 601         }
 602
 603         // invalid
 604         if(ca < 0 || cb < 0)
 605                 return false;
 606
 607         // equal
 608         if(ta == tb)
 609                 return true;
 610
 611         if(IS_REAL_CLIENT(e))
 612         {
 613                 if(bots_would_leave)
 614                 {
 615                         ca -= cba * 0.999;
 616                         cb -= cbb * 0.999;
 617                 }
 618         }
 619
 620         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 621         if(ca < 1)
 622                 if(cb >= 1)
 623                         return true;
 624         if(ca >= 1)
 625                 if(cb < 1)
 626                         return false;
 627
 628         // first, normalize
 629         f = max(ca, cb, 1);
 630         ca /= f;
 631         cb /= f;
 632         f = max(sa, sb, 1);
 633         sa /= f;
 634         sb /= f;
 635
 636         // the more we're at the end of the match, the more take scores into account
 637         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 638         ca += (sa - ca) * f;
 639         cb += (sb - cb) * f;
 640
 641         return ca <= cb;
 642 }
 643
 644 // returns # of smallest team (1, 2, 3, 4)
 645 // NOTE: Assumes CheckAllowedTeams has already been called!
 646 float FindSmallestTeam(entity pl, float ignore_pl)
 647 {
 648         float totalteams, t;
 649         totalteams = 0;
 650
 651         // find out what teams are available
 652         //CheckAllowedTeams();
 653
 654         // make sure there are at least 2 teams to join
 655         if(c1 >= 0)
 656                 totalteams = totalteams + 1;
 657         if(c2 >= 0)
 658                 totalteams = totalteams + 1;
 659         if(c3 >= 0)
 660                 totalteams = totalteams + 1;
 661         if(c4 >= 0)
 662                 totalteams = totalteams + 1;
 663
 664         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 665                 totalteams += 1;
 666
 667         if(totalteams <= 1)
 668         {
 669                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 670                         return 1; // special case for campaign and player joining
 671                 else
 672                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 673         }
 674
 675         // count how many players are in each team
 676         if(ignore_pl)
 677                 GetTeamCounts(pl);
 678         else
 679                 GetTeamCounts(world);
 680
 681         RandomSelection_Init();
 682
 683         t = 1;
 684         if(TeamSmallerEqThanTeam(2, t, pl))
 685                 t = 2;
 686         if(TeamSmallerEqThanTeam(3, t, pl))
 687                 t = 3;
 688         if(TeamSmallerEqThanTeam(4, t, pl))
 689                 t = 4;
 690
 691         // now t is the minimum, or A minimum!
 692         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 693                 RandomSelection_Add(world, 1, string_null, 1, 1);
 694         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 695                 RandomSelection_Add(world, 2, string_null, 1, 1);
 696         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 697                 RandomSelection_Add(world, 3, string_null, 1, 1);
 698         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 699                 RandomSelection_Add(world, 4, string_null, 1, 1);
 700
 701         return RandomSelection_chosen_float;
 702 }
 703
 704 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 705 {
 706         float smallest, selectedteam;
 707
 708         // don't join a team if we're not playing a team game
 709         if(!teamplay)
 710                 return 0;
 711
 712         // find out what teams are available
 713         CheckAllowedTeams(pl);
 714
 715         // if we don't care what team he ends up on, put him on whatever team he entered as.
 716         // if he's not on a valid team, then let other code put him on the smallest team
 717         if(!forcebestteam)
 718         {
 719                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 720                         selectedteam = pl.team;
 721                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 722                         selectedteam = pl.team;
 723                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 724                         selectedteam = pl.team;
 725                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 726                         selectedteam = pl.team;
 727                 else
 728                         selectedteam = -1;
 729
 730                 if(selectedteam > 0)
 731                 {
 732                         if(!only_return_best)
 733                         {
 734                                 SetPlayerColors(pl, selectedteam - 1);
 735
 736                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 737                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 738                                 LogTeamchange(pl.playerid, pl.team, 99);
 739                         }
 740                         return selectedteam;
 741                 }
 742                 // otherwise end up on the smallest team (handled below)
 743         }
 744
 745         smallest = FindSmallestTeam(pl, true);
 746
 747         if(!only_return_best && !pl.bot_forced_team)
 748         {
 749                 TeamchangeFrags(self);
 750                 if(smallest == 1)
 751                 {
 752                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 753                 }
 754                 else if(smallest == 2)
 755                 {
 756                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 757                 }
 758                 else if(smallest == 3)
 759                 {
 760                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 761                 }
 762                 else if(smallest == 4)
 763                 {
 764                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 765                 }
 766                 else
 767                 {
 768                         error("smallest team: invalid team\n");
 769                 }
 770
 771                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 772
 773                 if(pl.deadflag == DEAD_NO)
 774                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 775         }
 776
 777         return smallest;
 778 }
 779
 780 //void() ctf_playerchanged;
 781 void SV_ChangeTeam(float _color)
 782 {
 783         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 784
 785         // in normal deathmatch we can just apply the color and we're done
 786         if(!teamplay) {
 787                 SetPlayerColors(self, _color);
 788                 return;
 789         }
 790
 791         scolor = self.clientcolors & 0x0F;
 792         dcolor = _color & 0x0F;
 793
 794         if(scolor == NUM_TEAM_1 - 1)
 795                 steam = 1;
 796         else if(scolor == NUM_TEAM_2 - 1)
 797                 steam = 2;
 798         else if(scolor == NUM_TEAM_3 - 1)
 799                 steam = 3;
 800         else // if(scolor == NUM_TEAM_4 - 1)
 801                 steam = 4;
 802         if(dcolor == NUM_TEAM_1 - 1)
 803                 dteam = 1;
 804         else if(dcolor == NUM_TEAM_2 - 1)
 805                 dteam = 2;
 806         else if(dcolor == NUM_TEAM_3 - 1)
 807                 dteam = 3;
 808         else // if(dcolor == NUM_TEAM_4 - 1)
 809                 dteam = 4;
 810
 811         CheckAllowedTeams(self);
 812
 813         if(dteam == 1 && c1 < 0) dteam = 4;
 814         if(dteam == 4 && c4 < 0) dteam = 3;
 815         if(dteam == 3 && c3 < 0) dteam = 2;
 816         if(dteam == 2 && c2 < 0) dteam = 1;
 817
 818         // not changing teams
 819         if(scolor == dcolor)
 820         {
 821                 //bprint("same team change\n");
 822                 SetPlayerTeam(self, dteam, steam, true);
 823                 return;
 824         }
 825
 826         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 827                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 828                 return; // changing teams is not allowed
 829         }
 830
 831         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 832         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 833         {
 834                 GetTeamCounts(self);
 835                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 836                 {
 837                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 838                         return;
 839                 }
 840         }
 841
 842 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 843
 844         if(IS_PLAYER(self) && steam != dteam)
 845         {
 846                 // reduce frags during a team change
 847                 TeamchangeFrags(self);
 848         }
 849
 850         SetPlayerTeam(self, dteam, steam, false);
 851
 852         if(IS_PLAYER(self) && steam != dteam)
 853         {
 854                 // kill player when changing teams
 855                 if(self.deadflag == DEAD_NO)
 856                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 857         }
 858 }
 859
 860 void ShufflePlayerOutOfTeam (float source_team)
 861 {
 862         float smallestteam, smallestteam_count, steam;
 863         float lowest_bot_score, lowest_player_score;
 864         entity head, lowest_bot, lowest_player, selected;
 865
 866         smallestteam = 0;
 867         smallestteam_count = 999999999;
 868
 869         if(c1 >= 0 && c1 < smallestteam_count)
 870         {
 871                 smallestteam = 1;
 872                 smallestteam_count = c1;
 873         }
 874         if(c2 >= 0 && c2 < smallestteam_count)
 875         {
 876                 smallestteam = 2;
 877                 smallestteam_count = c2;
 878         }
 879         if(c3 >= 0 && c3 < smallestteam_count)
 880         {
 881                 smallestteam = 3;
 882                 smallestteam_count = c3;
 883         }
 884         if(c4 >= 0 && c4 < smallestteam_count)
 885         {
 886                 smallestteam = 4;
 887                 smallestteam_count = c4;
 888         }
 889
 890         if(!smallestteam)
 891         {
 892                 bprint("warning: no smallest team\n");
 893                 return;
 894         }
 895
 896         if(source_team == 1)
 897                 steam = NUM_TEAM_1;
 898         else if(source_team == 2)
 899                 steam = NUM_TEAM_2;
 900         else if(source_team == 3)
 901                 steam = NUM_TEAM_3;
 902         else // if(source_team == 4)
 903                 steam = NUM_TEAM_4;
 904
 905         lowest_bot = world;
 906         lowest_bot_score = 999999999;
 907         lowest_player = world;
 908         lowest_player_score = 999999999;
 909
 910         // find the lowest-scoring player & bot of that team
 911         FOR_EACH_PLAYER(head)
 912         {
 913                 if(head.team == steam)
 914                 {
 915                         if(head.isbot)
 916                         {
 917                                 if(head.totalfrags < lowest_bot_score)
 918                                 {
 919                                         lowest_bot = head;
 920                                         lowest_bot_score = head.totalfrags;
 921                                 }
 922                         }
 923                         else
 924                         {
 925                                 if(head.totalfrags < lowest_player_score)
 926                                 {
 927                                         lowest_player = head;
 928                                         lowest_player_score = head.totalfrags;
 929                                 }
 930                         }
 931                 }
 932         }
 933
 934         // prefers to move a bot...
 935         if(lowest_bot != world)
 936                 selected = lowest_bot;
 937         // but it will move a player if it has to
 938         else
 939                 selected = lowest_player;
 940         // don't do anything if it couldn't find anyone
 941         if(!selected)
 942         {
 943                 bprint("warning: couldn't find a player to move from team\n");
 944                 return;
 945         }
 946
 947         // smallest team gains a member
 948         if(smallestteam == 1)
 949         {
 950                 c1 = c1 + 1;
 951         }
 952         else if(smallestteam == 2)
 953         {
 954                 c2 = c2 + 1;
 955         }
 956         else if(smallestteam == 3)
 957         {
 958                 c3 = c3 + 1;
 959         }
 960         else if(smallestteam == 4)
 961         {
 962                 c4 = c4 + 1;
 963         }
 964         else
 965         {
 966                 bprint("warning: destination team invalid\n");
 967                 return;
 968         }
 969         // source team loses a member
 970         if(source_team == 1)
 971         {
 972                 c1 = c1 + 1;
 973         }
 974         else if(source_team == 2)
 975         {
 976                 c2 = c2 + 2;
 977         }
 978         else if(source_team == 3)
 979         {
 980                 c3 = c3 + 3;
 981         }
 982         else if(source_team == 4)
 983         {
 984                 c4 = c4 + 4;
 985         }
 986         else
 987         {
 988                 bprint("warning: source team invalid\n");
 989                 return;
 990         }
 991
 992         // move the player to the new team
 993         TeamchangeFrags(selected);
 994         SetPlayerTeam(selected, smallestteam, source_team, false);
 995
 996         if(selected.deadflag == DEAD_NO)
 997                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 998         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
 999 }