qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_arena)
 119         {
 120                 fraglimit_override = autocvar_g_arena_point_limit;
 121                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 122                 MUTATOR_ADD(gamemode_arena);
 123         }
 124
 125         if(g_ca)
 126         {
 127                 ActivateTeamplay();
 128                 fraglimit_override = autocvar_g_ca_point_limit;
 129                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 130                 MUTATOR_ADD(gamemode_ca);
 131         }
 132
 133         if(g_keyhunt)
 134         {
 135                 ActivateTeamplay();
 136                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 137                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 138                 MUTATOR_ADD(gamemode_keyhunt);
 139         }
 140
 141         if(g_freezetag)
 142         {
 143                 ActivateTeamplay();
 144                 fraglimit_override = autocvar_g_freezetag_point_limit;
 145                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 146                 MUTATOR_ADD(gamemode_freezetag);
 147         }
 148
 149         if(g_assault)
 150         {
 151                 ActivateTeamplay();
 152                 MUTATOR_ADD(gamemode_assault);
 153                 have_team_spawns = -1; // request team spawns
 154         }
 155
 156         if(g_onslaught)
 157         {
 158                 ActivateTeamplay();
 159                 have_team_spawns = -1; // request team spawns
 160                 MUTATOR_ADD(gamemode_onslaught);
 161         }
 162
 163         if(g_race)
 164         {
 165
 166                 if(autocvar_g_race_teams)
 167                 {
 168                         ActivateTeamplay();
 169                         race_teams = bound(2, autocvar_g_race_teams, 4);
 170                         have_team_spawns = -1; // request team spawns
 171                 }
 172                 else
 173                         race_teams = 0;
 174
 175                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 176                 fraglimit_override = autocvar_g_race_laps_limit;
 177                 leadlimit_override = 0; // currently not supported by race
 178         }
 179
 180         if(g_cts)
 181         {
 182                 g_race_qualifying = 1;
 183                 fraglimit_override = 0;
 184                 leadlimit_override = 0;
 185         }
 186
 187         if(g_nexball)
 188         {
 189         fraglimit_override = autocvar_g_nexball_goallimit;
 190         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 191         ActivateTeamplay();
 192         have_team_spawns = -1; // request team spawns
 193             MUTATOR_ADD(gamemode_nexball);
 194         }
 195
 196         if(g_keepaway)
 197         {
 198                 MUTATOR_ADD(gamemode_keepaway);
 199         }
 200
 201         if(teamplay)
 202                 entcs_init();
 203
 204         cache_mutatormsg = strzone("");
 205         cache_lastmutatormsg = strzone("");
 206
 207         // enforce the server's universal frag/time limits
 208         if(!autocvar_g_campaign)
 209         {
 210                 if(fraglimit_override >= 0)
 211                         cvar_set("fraglimit", ftos(fraglimit_override));
 212                 if(timelimit_override >= 0)
 213                         cvar_set("timelimit", ftos(timelimit_override));
 214                 if(leadlimit_override >= 0)
 215                         cvar_set("leadlimit", ftos(leadlimit_override));
 216                 if(qualifying_override >= 0)
 217                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 218         }
 219
 220         if(g_race)
 221         {
 222                 // we need to find out the correct value for g_race_qualifying
 223                 if(autocvar_g_campaign)
 224                 {
 225                         g_race_qualifying = 1;
 226                 }
 227                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 228                 {
 229                         g_race_qualifying = 2;
 230                         race_fraglimit = autocvar_fraglimit;
 231                         race_leadlimit = autocvar_leadlimit;
 232                         race_timelimit = autocvar_timelimit;
 233                         cvar_set("fraglimit", "0");
 234                         cvar_set("leadlimit", "0");
 235                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 236                 }
 237                 else
 238                         g_race_qualifying = 0;
 239         }
 240
 241         if(g_race || g_cts)
 242         {
 243                 if(g_race_qualifying)
 244                         independent_players = 1;
 245
 246                 ScoreRules_race();
 247         }
 248
 249         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 250 }
 251
 252 string GetClientVersionMessage() {
 253         string versionmsg;
 254         if (self.version_mismatch) {
 255                 if(self.version < autocvar_gameversion) {
 256                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 257                 } else {
 258                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 259                 }
 260         } else {
 261                 versionmsg = "^2client version and server version are compatible.^8";
 262         }
 263         return versionmsg;
 264 }
 265
 266 string getwelcomemessage(void)
 267 {
 268         string s, modifications, motd;
 269
 270         ret_string = "";
 271         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 272         modifications = ret_string;
 273
 274         if(g_weaponarena)
 275         {
 276                 if(g_weaponarena_random)
 277                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 278                 else
 279                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 280         }
 281         if(autocvar_g_start_weapon_laser == 0)
 282                 modifications = strcat(modifications, ", No start weapons");
 283         if(autocvar_sv_gravity < 800)
 284                 modifications = strcat(modifications, ", Low gravity");
 285         if(g_cloaked && !g_cts)
 286                 modifications = strcat(modifications, ", Cloaked");
 287         if(g_grappling_hook)
 288                 modifications = strcat(modifications, ", Hook");
 289         if(g_weapon_stay && !g_cts)
 290                 modifications = strcat(modifications, ", Weapons stay");
 291         if(g_jetpack)
 292                 modifications = strcat(modifications, ", Jet pack");
 293         if(autocvar_g_powerups == 0)
 294                 modifications = strcat(modifications, ", No powerups");
 295         if(autocvar_g_powerups > 0)
 296                 modifications = strcat(modifications, ", Powerups");
 297         modifications = substring(modifications, 2, strlen(modifications) - 2);
 298
 299         string versionmessage;
 300         versionmessage = GetClientVersionMessage();
 301
 302         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 303         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 304
 305         if(modifications != "")
 306                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 307
 308         if (g_grappling_hook)
 309                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 310
 311         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 312         {
 313                 if(cache_lastmutatormsg)
 314                         strunzone(cache_lastmutatormsg);
 315                 if(cache_mutatormsg)
 316                         strunzone(cache_mutatormsg);
 317                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 318                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 319         }
 320
 321         if (cache_mutatormsg != "") {
 322                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 323         }
 324
 325         motd = autocvar_sv_motd;
 326         if (motd != "") {
 327                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 328         }
 329         return s;
 330 }
 331
 332 void SetPlayerColors(entity pl, float _color)
 333 {
 334         /*string s;
 335         s = ftos(cl);
 336         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 337         pl.team = cl + 1;
 338         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 339         pl.clientcolors = 16*cl + cl;*/
 340
 341         float pants, shirt;
 342         pants = _color & 0x0F;
 343         shirt = _color & 0xF0;
 344
 345
 346         if(teamplay) {
 347                 setcolor(pl, 16*pants + pants);
 348         } else {
 349                 setcolor(pl, shirt + pants);
 350         }
 351 }
 352
 353 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 354 {
 355         float _color;
 356
 357         if(t == 4)
 358                 _color = NUM_TEAM_4 - 1;
 359         else if(t == 3)
 360                 _color = NUM_TEAM_3 - 1;
 361         else if(t == 2)
 362                 _color = NUM_TEAM_2 - 1;
 363         else
 364                 _color = NUM_TEAM_1 - 1;
 365
 366         SetPlayerColors(pl,_color);
 367
 368         if(t != s) {
 369                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 370
 371                 if(!noprint)
 372                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 373         }
 374
 375 }
 376
 377 // set c1...c4 to show what teams are allowed
 378 void CheckAllowedTeams (entity for_whom)
 379 {
 380         float dm;
 381         entity head;
 382         string teament_name;
 383
 384         c1 = c2 = c3 = c4 = -1;
 385         cb1 = cb2 = cb3 = cb4 = 0;
 386
 387         teament_name = string_null;
 388         if(g_onslaught)
 389         {
 390                 // onslaught is special
 391                 head = findchain(classname, "onslaught_generator");
 392                 while (head)
 393                 {
 394                         if (head.team == NUM_TEAM_1) c1 = 0;
 395                         if (head.team == NUM_TEAM_2) c2 = 0;
 396                         if (head.team == NUM_TEAM_3) c3 = 0;
 397                         if (head.team == NUM_TEAM_4) c4 = 0;
 398                         head = head.chain;
 399                 }
 400         }
 401         else if(g_domination)
 402                 teament_name = "dom_team";
 403         else if(g_ctf)
 404                 teament_name = "ctf_team";
 405         else if(g_tdm)
 406                 teament_name = "tdm_team";
 407         else if(g_nexball)
 408                 teament_name = "nexball_team";
 409         else if(g_assault)
 410                 c1 = c2 = 0; // Assault always has 2 teams
 411         else
 412         {
 413                 // cover anything else by treating it like tdm with no teams spawned
 414                 if(g_race)
 415                         dm = race_teams;
 416                 else
 417                         dm = 2;
 418
 419                 ret_float = dm;
 420                 MUTATOR_CALLHOOK(GetTeamCount);
 421                 dm = ret_float;
 422
 423                 if(dm >= 4)
 424                         c1 = c2 = c3 = c4 = 0;
 425                 else if(dm >= 3)
 426                         c1 = c2 = c3 = 0;
 427                 else
 428                         c1 = c2 = 0;
 429         }
 430
 431         // find out what teams are allowed if necessary
 432         if(teament_name)
 433         {
 434                 head = find(world, classname, teament_name);
 435                 while(head)
 436                 {
 437                         if(!(g_domination && head.netname == ""))
 438                         {
 439                                 if(head.team == NUM_TEAM_1)
 440                                         c1 = 0;
 441                                 else if(head.team == NUM_TEAM_2)
 442                                         c2 = 0;
 443                                 else if(head.team == NUM_TEAM_3)
 444                                         c3 = 0;
 445                                 else if(head.team == NUM_TEAM_4)
 446                                         c4 = 0;
 447                         }
 448                         head = find(head, classname, teament_name);
 449                 }
 450         }
 451
 452         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 453         if(c3==-1 && c4==-1)
 454         if(autocvar_bot_vs_human && for_whom)
 455         {
 456                 if(autocvar_bot_vs_human > 0)
 457                 {
 458                         // bots are all blue
 459                         if(IS_BOT_CLIENT(for_whom))
 460                                 c1 = c3 = c4 = -1;
 461                         else
 462                                 c2 = -1;
 463                 }
 464                 else
 465                 {
 466                         // bots are all red
 467                         if(IS_BOT_CLIENT(for_whom))
 468                                 c2 = c3 = c4 = -1;
 469                         else
 470                                 c1 = -1;
 471                 }
 472         }
 473
 474         // if player has a forced team, ONLY allow that one
 475         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 476                 c2 = c3 = c4 = -1;
 477         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 478                 c1 = c3 = c4 = -1;
 479         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 480                 c1 = c2 = c4 = -1;
 481         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 482                 c1 = c2 = c3 = -1;
 483 }
 484
 485 float PlayerValue(entity p)
 486 {
 487         return 1;
 488         // FIXME: it always returns 1...
 489 }
 490
 491 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 492 // teams that are allowed will now have their player counts stored in c1...c4
 493 void GetTeamCounts(entity ignore)
 494 {
 495         entity head;
 496         float value, bvalue;
 497         // now count how many players are on each team already
 498
 499         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 500         // also remember the lowest-scoring player
 501
 502         FOR_EACH_CLIENT(head)
 503         {
 504                 float t;
 505                 if(IS_PLAYER(head))
 506                         t = head.team;
 507                 else if(head.team_forced > 0)
 508                         t = head.team_forced; // reserve the spot
 509                 else
 510                         continue;
 511                 if(head != ignore)// && head.netname != "")
 512                 {
 513                         value = PlayerValue(head);
 514                         if(IS_BOT_CLIENT(head))
 515                                 bvalue = value;
 516                         else
 517                                 bvalue = 0;
 518                         if(t == NUM_TEAM_1)
 519                         {
 520                                 if(c1 >= 0)
 521                                 {
 522                                         c1 = c1 + value;
 523                                         cb1 = cb1 + bvalue;
 524                                 }
 525                         }
 526                         if(t == NUM_TEAM_2)
 527                         {
 528                                 if(c2 >= 0)
 529                                 {
 530                                         c2 = c2 + value;
 531                                         cb2 = cb2 + bvalue;
 532                                 }
 533                         }
 534                         if(t == NUM_TEAM_3)
 535                         {
 536                                 if(c3 >= 0)
 537                                 {
 538                                         c3 = c3 + value;
 539                                         cb3 = cb3 + bvalue;
 540                                 }
 541                         }
 542                         if(t == NUM_TEAM_4)
 543                         {
 544                                 if(c4 >= 0)
 545                                 {
 546                                         c4 = c4 + value;
 547                                         cb4 = cb4 + bvalue;
 548                                 }
 549                         }
 550                 }
 551         }
 552
 553         // if the player who has a forced team has not joined yet, reserve the spot
 554         if(autocvar_g_campaign)
 555         {
 556                 switch(autocvar_g_campaign_forceteam)
 557                 {
 558                         case 1: if(c1 == cb1) ++c1; break;
 559                         case 2: if(c2 == cb2) ++c2; break;
 560                         case 3: if(c3 == cb3) ++c3; break;
 561                         case 4: if(c4 == cb4) ++c4; break;
 562                 }
 563         }
 564 }
 565
 566 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 567 {
 568         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 569         float f;
 570         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 571
 572         switch(ta)
 573         {
 574                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 575                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 576                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 577                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 578         }
 579         switch(tb)
 580         {
 581                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 582                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 583                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 584                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 585         }
 586
 587         // invalid
 588         if(ca < 0 || cb < 0)
 589                 return FALSE;
 590
 591         // equal
 592         if(ta == tb)
 593                 return TRUE;
 594
 595         if(IS_REAL_CLIENT(e))
 596         {
 597                 if(bots_would_leave)
 598                 {
 599                         ca -= cba * 0.999;
 600                         cb -= cbb * 0.999;
 601                 }
 602         }
 603
 604         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 605         if(ca < 1)
 606                 if(cb >= 1)
 607                         return TRUE;
 608         if(ca >= 1)
 609                 if(cb < 1)
 610                         return FALSE;
 611
 612         // first, normalize
 613         f = max(ca, cb, 1);
 614         ca /= f;
 615         cb /= f;
 616         f = max(sa, sb, 1);
 617         sa /= f;
 618         sb /= f;
 619
 620         // the more we're at the end of the match, the more take scores into account
 621         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 622         ca += (sa - ca) * f;
 623         cb += (sb - cb) * f;
 624
 625         return ca <= cb;
 626 }
 627
 628 // returns # of smallest team (1, 2, 3, 4)
 629 // NOTE: Assumes CheckAllowedTeams has already been called!
 630 float FindSmallestTeam(entity pl, float ignore_pl)
 631 {
 632         float totalteams, t;
 633         totalteams = 0;
 634
 635         // find out what teams are available
 636         //CheckAllowedTeams();
 637
 638         // make sure there are at least 2 teams to join
 639         if(c1 >= 0)
 640                 totalteams = totalteams + 1;
 641         if(c2 >= 0)
 642                 totalteams = totalteams + 1;
 643         if(c3 >= 0)
 644                 totalteams = totalteams + 1;
 645         if(c4 >= 0)
 646                 totalteams = totalteams + 1;
 647
 648         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 649                 totalteams += 1;
 650
 651         if(totalteams <= 1)
 652         {
 653                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 654                         return 1; // special case for campaign and player joining
 655                 else if(g_domination)
 656                         error("Too few teams available for domination\n");
 657                 else if(g_ctf)
 658                         error("Too few teams available for ctf\n");
 659                 else if(g_keyhunt)
 660                         error("Too few teams available for key hunt\n");
 661                 else if(g_freezetag)
 662                         error("Too few teams available for freeze tag\n");
 663                 else
 664                         error("Too few teams available for team deathmatch\n");
 665         }
 666
 667         // count how many players are in each team
 668         if(ignore_pl)
 669                 GetTeamCounts(pl);
 670         else
 671                 GetTeamCounts(world);
 672
 673         RandomSelection_Init();
 674
 675         t = 1;
 676         if(TeamSmallerEqThanTeam(2, t, pl))
 677                 t = 2;
 678         if(TeamSmallerEqThanTeam(3, t, pl))
 679                 t = 3;
 680         if(TeamSmallerEqThanTeam(4, t, pl))
 681                 t = 4;
 682
 683         // now t is the minimum, or A minimum!
 684         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 685                 RandomSelection_Add(world, 1, string_null, 1, 1);
 686         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 687                 RandomSelection_Add(world, 2, string_null, 1, 1);
 688         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 689                 RandomSelection_Add(world, 3, string_null, 1, 1);
 690         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 691                 RandomSelection_Add(world, 4, string_null, 1, 1);
 692
 693         return RandomSelection_chosen_float;
 694 }
 695
 696 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 697 {
 698         float smallest, selectedteam;
 699
 700         // don't join a team if we're not playing a team game
 701         if(!teamplay)
 702                 return 0;
 703
 704         // find out what teams are available
 705         CheckAllowedTeams(pl);
 706
 707         // if we don't care what team he ends up on, put him on whatever team he entered as.
 708         // if he's not on a valid team, then let other code put him on the smallest team
 709         if(!forcebestteam)
 710         {
 711                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 712                         selectedteam = pl.team;
 713                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 714                         selectedteam = pl.team;
 715                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 716                         selectedteam = pl.team;
 717                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 718                         selectedteam = pl.team;
 719                 else
 720                         selectedteam = -1;
 721
 722                 if(selectedteam > 0)
 723                 {
 724                         if(!only_return_best)
 725                         {
 726                                 SetPlayerColors(pl, selectedteam - 1);
 727
 728                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 729                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 730                                 LogTeamchange(pl.playerid, pl.team, 99);
 731                         }
 732                         return selectedteam;
 733                 }
 734                 // otherwise end up on the smallest team (handled below)
 735         }
 736
 737         smallest = FindSmallestTeam(pl, TRUE);
 738
 739         if(!only_return_best && !pl.bot_forced_team)
 740         {
 741                 TeamchangeFrags(self);
 742                 if(smallest == 1)
 743                 {
 744                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 745                 }
 746                 else if(smallest == 2)
 747                 {
 748                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 749                 }
 750                 else if(smallest == 3)
 751                 {
 752                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 753                 }
 754                 else if(smallest == 4)
 755                 {
 756                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 757                 }
 758                 else
 759                 {
 760                         error("smallest team: invalid team\n");
 761                 }
 762
 763                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 764
 765                 if(pl.deadflag == DEAD_NO)
 766                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 767         }
 768
 769         return smallest;
 770 }
 771
 772 //void() ctf_playerchanged;
 773 void SV_ChangeTeam(float _color)
 774 {
 775         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 776
 777         // in normal deathmatch we can just apply the color and we're done
 778         if(!teamplay) {
 779                 SetPlayerColors(self, _color);
 780                 return;
 781         }
 782
 783         scolor = self.clientcolors & 0x0F;
 784         dcolor = _color & 0x0F;
 785
 786         if(scolor == NUM_TEAM_1 - 1)
 787                 steam = 1;
 788         else if(scolor == NUM_TEAM_2 - 1)
 789                 steam = 2;
 790         else if(scolor == NUM_TEAM_3 - 1)
 791                 steam = 3;
 792         else // if(scolor == NUM_TEAM_4 - 1)
 793                 steam = 4;
 794         if(dcolor == NUM_TEAM_1 - 1)
 795                 dteam = 1;
 796         else if(dcolor == NUM_TEAM_2 - 1)
 797                 dteam = 2;
 798         else if(dcolor == NUM_TEAM_3 - 1)
 799                 dteam = 3;
 800         else // if(dcolor == NUM_TEAM_4 - 1)
 801                 dteam = 4;
 802
 803         CheckAllowedTeams(self);
 804
 805         if(dteam == 1 && c1 < 0) dteam = 4;
 806         if(dteam == 4 && c4 < 0) dteam = 3;
 807         if(dteam == 3 && c3 < 0) dteam = 2;
 808         if(dteam == 2 && c2 < 0) dteam = 1;
 809
 810         // not changing teams
 811         if(scolor == dcolor)
 812         {
 813                 //bprint("same team change\n");
 814                 SetPlayerTeam(self, dteam, steam, TRUE);
 815                 return;
 816         }
 817
 818         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 819                 sprint(self, "Team changes not allowed\n");
 820                 return; // changing teams is not allowed
 821         }
 822
 823         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 824         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 825         {
 826                 GetTeamCounts(self);
 827                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 828                 {
 829                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 830                         return;
 831                 }
 832         }
 833
 834 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 835
 836         if(IS_PLAYER(self) && steam != dteam)
 837         {
 838                 // reduce frags during a team change
 839                 TeamchangeFrags(self);
 840         }
 841
 842         SetPlayerTeam(self, dteam, steam, FALSE);
 843
 844         if(IS_PLAYER(self) && steam != dteam)
 845         {
 846                 // kill player when changing teams
 847                 if(self.deadflag == DEAD_NO)
 848                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 849         }
 850 }
 851
 852 void ShufflePlayerOutOfTeam (float source_team)
 853 {
 854         float smallestteam, smallestteam_count, steam;
 855         float lowest_bot_score, lowest_player_score;
 856         entity head, lowest_bot, lowest_player, selected;
 857
 858         smallestteam = 0;
 859         smallestteam_count = 999999999;
 860
 861         if(c1 >= 0 && c1 < smallestteam_count)
 862         {
 863                 smallestteam = 1;
 864                 smallestteam_count = c1;
 865         }
 866         if(c2 >= 0 && c2 < smallestteam_count)
 867         {
 868                 smallestteam = 2;
 869                 smallestteam_count = c2;
 870         }
 871         if(c3 >= 0 && c3 < smallestteam_count)
 872         {
 873                 smallestteam = 3;
 874                 smallestteam_count = c3;
 875         }
 876         if(c4 >= 0 && c4 < smallestteam_count)
 877         {
 878                 smallestteam = 4;
 879                 smallestteam_count = c4;
 880         }
 881
 882         if(!smallestteam)
 883         {
 884                 bprint("warning: no smallest team\n");
 885                 return;
 886         }
 887
 888         if(source_team == 1)
 889                 steam = NUM_TEAM_1;
 890         else if(source_team == 2)
 891                 steam = NUM_TEAM_2;
 892         else if(source_team == 3)
 893                 steam = NUM_TEAM_3;
 894         else // if(source_team == 4)
 895                 steam = NUM_TEAM_4;
 896
 897         lowest_bot = world;
 898         lowest_bot_score = 999999999;
 899         lowest_player = world;
 900         lowest_player_score = 999999999;
 901
 902         // find the lowest-scoring player & bot of that team
 903         FOR_EACH_PLAYER(head)
 904         {
 905                 if(head.team == steam)
 906                 {
 907                         if(head.isbot)
 908                         {
 909                                 if(head.totalfrags < lowest_bot_score)
 910                                 {
 911                                         lowest_bot = head;
 912                                         lowest_bot_score = head.totalfrags;
 913                                 }
 914                         }
 915                         else
 916                         {
 917                                 if(head.totalfrags < lowest_player_score)
 918                                 {
 919                                         lowest_player = head;
 920                                         lowest_player_score = head.totalfrags;
 921                                 }
 922                         }
 923                 }
 924         }
 925
 926         // prefers to move a bot...
 927         if(lowest_bot != world)
 928                 selected = lowest_bot;
 929         // but it will move a player if it has to
 930         else
 931                 selected = lowest_player;
 932         // don't do anything if it couldn't find anyone
 933         if(!selected)
 934         {
 935                 bprint("warning: couldn't find a player to move from team\n");
 936                 return;
 937         }
 938
 939         // smallest team gains a member
 940         if(smallestteam == 1)
 941         {
 942                 c1 = c1 + 1;
 943         }
 944         else if(smallestteam == 2)
 945         {
 946                 c2 = c2 + 1;
 947         }
 948         else if(smallestteam == 3)
 949         {
 950                 c3 = c3 + 1;
 951         }
 952         else if(smallestteam == 4)
 953         {
 954                 c4 = c4 + 1;
 955         }
 956         else
 957         {
 958                 bprint("warning: destination team invalid\n");
 959                 return;
 960         }
 961         // source team loses a member
 962         if(source_team == 1)
 963         {
 964                 c1 = c1 + 1;
 965         }
 966         else if(source_team == 2)
 967         {
 968                 c2 = c2 + 2;
 969         }
 970         else if(source_team == 3)
 971         {
 972                 c3 = c3 + 3;
 973         }
 974         else if(source_team == 4)
 975         {
 976                 c4 = c4 + 4;
 977         }
 978         else
 979         {
 980                 bprint("warning: source team invalid\n");
 981                 return;
 982         }
 983
 984         // move the player to the new team
 985         TeamchangeFrags(selected);
 986         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 987
 988         if(selected.deadflag == DEAD_NO)
 989                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 990         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
 991 }
 992
 993 // code from here on is just to support maps that don't have team entities
 994 void tdm_spawnteam (string teamname, float teamcolor)
 995 {
 996         entity e;
 997         e = spawn();
 998         e.classname = "tdm_team";
 999         e.netname = teamname;
1000         e.cnt = teamcolor;
1001         e.team = e.cnt + 1;
1002 }
1003
1004 // spawn some default teams if the map is not set up for tdm
1005 void tdm_spawnteams()
1006 {
1007         float numteams;
1008
1009         numteams = autocvar_g_tdm_teams_override;
1010         if(numteams < 2)
1011                 numteams = autocvar_g_tdm_teams;
1012         numteams = bound(2, numteams, 4);
1013
1014         tdm_spawnteam("Red", NUM_TEAM_1-1);
1015         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1016         if(numteams >= 3)
1017                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1018         if(numteams >= 4)
1019                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1020 }
1021
1022 void tdm_delayedinit()
1023 {
1024         // if no teams are found, spawn defaults
1025         if (find(world, classname, "tdm_team") == world)
1026                 tdm_spawnteams();
1027 }
1028
1029 void tdm_init()
1030 {
1031         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1032 }