qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2 #include "_all.qh"
   3
   4 #include "cl_client.qh"
   5 #include "race.qh"
   6 #include "scores.qh"
   7 #include "scores_rules.qh"
   8
   9 #include "bot/bot.qh"
  10
  11 #include "command/vote.qh"
  12
  13 #include "mutators/mutators_include.qh"
  14
  15 #include "../common/deathtypes.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit()
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44 }
  45
  46 void InitGameplayMode()
  47 {
  48         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  49
  50         qualifying_override = -1;
  51
  52         VoteReset();
  53
  54         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  55         get_mi_min_max(1);
  56         world.mins = mi_min;
  57         world.maxs = mi_max;
  58
  59         MapInfo_LoadMapSettings(mapname);
  60         teamplay = 0;
  61         serverflags &= ~SERVERFLAG_TEAMPLAY;
  62
  63         if (!cvar_value_issafe(world.fog))
  64         {
  65                 print("The current map contains a potentially harmful fog setting, ignored\n");
  66                 world.fog = string_null;
  67         }
  68         if(MapInfo_Map_fog != "")
  69                 if(MapInfo_Map_fog == "none")
  70                         world.fog = string_null;
  71                 else
  72                         world.fog = strzone(MapInfo_Map_fog);
  73         clientstuff = strzone(MapInfo_Map_clientstuff);
  74
  75         MapInfo_ClearTemps();
  76
  77         // set both here, gamemode can override it later
  78         timelimit_override = autocvar_timelimit_override;
  79         fraglimit_override = autocvar_fraglimit_override;
  80         leadlimit_override = autocvar_leadlimit_override;
  81         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  82
  83         if(g_dm)
  84         {
  85         }
  86
  87         if(g_tdm)
  88         {
  89                 ActivateTeamplay();
  90                 fraglimit_override = autocvar_g_tdm_point_limit;
  91                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
  92                 if(autocvar_g_tdm_team_spawns)
  93                         have_team_spawns = -1; // request team spawns
  94                 MUTATOR_ADD(gamemode_tdm);
  95         }
  96
  97         if(g_domination)
  98         {
  99                 ActivateTeamplay();
 100                 fraglimit_override = autocvar_g_domination_point_limit;
 101                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 102                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
 103                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
 104                 have_team_spawns = -1; // request team spawns
 105                 MUTATOR_ADD(gamemode_domination);
 106         }
 107
 108         if(g_ctf)
 109         {
 110                 ActivateTeamplay();
 111                 fraglimit_override = autocvar_capturelimit_override;
 112                 leadlimit_override = autocvar_captureleadlimit_override;
 113                 have_team_spawns = -1; // request team spawns
 114                 MUTATOR_ADD(gamemode_ctf);
 115         }
 116
 117         if(g_lms)
 118         {
 119                 fraglimit_override = autocvar_g_lms_lives_override;
 120                 leadlimit_override = 0; // not supported by LMS
 121                 if(fraglimit_override == 0)
 122                         fraglimit_override = -1;
 123                 MUTATOR_ADD(gamemode_lms);
 124         }
 125
 126         if(g_ca)
 127         {
 128                 ActivateTeamplay();
 129                 fraglimit_override = autocvar_g_ca_point_limit;
 130                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 131                 if(autocvar_g_ca_team_spawns)
 132                         have_team_spawns = -1; // request team spawns
 133                 MUTATOR_ADD(gamemode_ca);
 134         }
 135
 136         if(g_keyhunt)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 140                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_keyhunt);
 142         }
 143
 144         if(g_freezetag)
 145         {
 146                 ActivateTeamplay();
 147                 fraglimit_override = autocvar_g_freezetag_point_limit;
 148                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 149                 if(autocvar_g_freezetag_team_spawns)
 150                         have_team_spawns = -1; // request team spawns
 151                 MUTATOR_ADD(gamemode_freezetag);
 152         }
 153
 154         if(g_assault)
 155         {
 156                 ActivateTeamplay();
 157                 have_team_spawns = -1; // request team spawns
 158                 MUTATOR_ADD(gamemode_assault);
 159         }
 160
 161         if(g_onslaught)
 162         {
 163                 ActivateTeamplay();
 164                 have_team_spawns = -1; // request team spawns
 165                 MUTATOR_ADD(gamemode_onslaught);
 166         }
 167
 168         if(g_race)
 169         {
 170                 if(autocvar_g_race_teams)
 171                 {
 172                         ActivateTeamplay();
 173                         race_teams = bound(2, autocvar_g_race_teams, 4);
 174                         have_team_spawns = -1; // request team spawns
 175                 }
 176                 else
 177                         race_teams = 0;
 178                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 179                 fraglimit_override = autocvar_g_race_laps_limit;
 180                 leadlimit_override = 0; // currently not supported by race
 181
 182                 // we need to find out the correct value for g_race_qualifying
 183                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 184
 185                 if(autocvar_g_campaign)
 186                 {
 187                         g_race_qualifying = 1;
 188                         independent_players = 1;
 189                 }
 190                 else if(!autocvar_g_campaign && want_qualifying)
 191                 {
 192                         g_race_qualifying = 2;
 193                         independent_players = 1;
 194                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
 195                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
 196                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
 197                         fraglimit_override = 0;
 198                         leadlimit_override = 0;
 199                         timelimit_override = autocvar_g_race_qualifying_timelimit;
 200                 }
 201                 else
 202                 {
 203                         g_race_qualifying = 0;
 204                 }
 205
 206                 MUTATOR_ADD(gamemode_race);
 207         }
 208
 209         if(g_cts)
 210         {
 211                 g_race_qualifying = 1;
 212                 fraglimit_override = 0;
 213                 leadlimit_override = 0;
 214                 independent_players = 1;
 215                 MUTATOR_ADD(gamemode_cts);
 216         }
 217
 218         if(g_nexball)
 219         {
 220                 fraglimit_override = autocvar_g_nexball_goallimit;
 221                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 222                 ActivateTeamplay();
 223                 have_team_spawns = -1; // request team spawns
 224                 MUTATOR_ADD(gamemode_nexball);
 225         }
 226
 227         if(g_keepaway)
 228         {
 229                 MUTATOR_ADD(gamemode_keepaway);
 230         }
 231
 232         if(g_invasion)
 233         {
 234                 fraglimit_override = autocvar_g_invasion_point_limit;
 235                 if(autocvar_g_invasion_teams >= 2)
 236                 {
 237                         ActivateTeamplay();
 238                         if(autocvar_g_invasion_team_spawns)
 239                                 have_team_spawns = -1; // request team spawns
 240                 }
 241                 MUTATOR_ADD(gamemode_invasion);
 242         }
 243
 244         if(teamplay)
 245                 entcs_init();
 246
 247         cache_mutatormsg = strzone("");
 248         cache_lastmutatormsg = strzone("");
 249
 250         // enforce the server's universal frag/time limits
 251         if(!autocvar_g_campaign)
 252         {
 253                 if(fraglimit_override >= 0)
 254                         cvar_set("fraglimit", ftos(fraglimit_override));
 255                 if(timelimit_override >= 0)
 256                         cvar_set("timelimit", ftos(timelimit_override));
 257                 if(leadlimit_override >= 0)
 258                         cvar_set("leadlimit", ftos(leadlimit_override));
 259                 if(qualifying_override >= 0)
 260                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 261         }
 262
 263         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 264 }
 265
 266 string GetClientVersionMessage() {
 267         string versionmsg;
 268         if (self.version_mismatch) {
 269                 if(self.version < autocvar_gameversion) {
 270                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 271                 } else {
 272                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 273                 }
 274         } else {
 275                 versionmsg = "^2client version and server version are compatible.^8";
 276         }
 277         return versionmsg;
 278 }
 279
 280 string getwelcomemessage(void)
 281 {
 282         string s, modifications, motd;
 283
 284         ret_string = "";
 285         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 286         modifications = ret_string;
 287
 288         if(g_weaponarena)
 289         {
 290                 if(g_weaponarena_random)
 291                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 292                 else
 293                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 294         }
 295         if(cvar("g_balance_blaster_weaponstart") == 0)
 296                 modifications = strcat(modifications, ", No start weapons");
 297         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 298                 modifications = strcat(modifications, ", Low gravity");
 299         if(g_cloaked && !g_cts)
 300                 modifications = strcat(modifications, ", Cloaked");
 301         if(g_grappling_hook)
 302                 modifications = strcat(modifications, ", Hook");
 303         if(g_weapon_stay && !g_cts)
 304                 modifications = strcat(modifications, ", Weapons stay");
 305         if(g_jetpack)
 306                 modifications = strcat(modifications, ", Jet pack");
 307         if(autocvar_g_powerups == 0)
 308                 modifications = strcat(modifications, ", No powerups");
 309         if(autocvar_g_powerups > 0)
 310                 modifications = strcat(modifications, ", Powerups");
 311         modifications = substring(modifications, 2, strlen(modifications) - 2);
 312
 313         string versionmessage;
 314         versionmessage = GetClientVersionMessage();
 315
 316         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 317         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 318
 319         if(modifications != "")
 320                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 321
 322         if (g_grappling_hook)
 323                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 324
 325         if (cvar("g_nades"))
 326                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 327
 328         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 329         {
 330                 if(cache_lastmutatormsg)
 331                         strunzone(cache_lastmutatormsg);
 332                 if(cache_mutatormsg)
 333                         strunzone(cache_mutatormsg);
 334                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 335                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 336         }
 337
 338         if (cache_mutatormsg != "") {
 339                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 340         }
 341
 342         motd = autocvar_sv_motd;
 343         if (motd != "") {
 344                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 345         }
 346         return s;
 347 }
 348
 349 void SetPlayerColors(entity pl, float _color)
 350 {
 351         /*string s;
 352         s = ftos(cl);
 353         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 354         pl.team = cl + 1;
 355         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 356         pl.clientcolors = 16*cl + cl;*/
 357
 358         float pants, shirt;
 359         pants = _color & 0x0F;
 360         shirt = _color & 0xF0;
 361
 362
 363         if(teamplay) {
 364                 setcolor(pl, 16*pants + pants);
 365         } else {
 366                 setcolor(pl, shirt + pants);
 367         }
 368 }
 369
 370 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 371 {
 372         float _color;
 373
 374         if(t == 4)
 375                 _color = NUM_TEAM_4 - 1;
 376         else if(t == 3)
 377                 _color = NUM_TEAM_3 - 1;
 378         else if(t == 2)
 379                 _color = NUM_TEAM_2 - 1;
 380         else
 381                 _color = NUM_TEAM_1 - 1;
 382
 383         SetPlayerColors(pl,_color);
 384
 385         if(t != s) {
 386                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 387
 388                 if(!noprint)
 389                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 390         }
 391
 392 }
 393
 394 // set c1...c4 to show what teams are allowed
 395 void CheckAllowedTeams (entity for_whom)
 396 {
 397         float dm;
 398         entity head;
 399         string teament_name;
 400
 401         c1 = c2 = c3 = c4 = -1;
 402         cb1 = cb2 = cb3 = cb4 = 0;
 403
 404         teament_name = string_null;
 405         if(g_onslaught)
 406         {
 407                 // onslaught is special
 408                 head = findchain(classname, "onslaught_generator");
 409                 while (head)
 410                 {
 411                         if (head.team == NUM_TEAM_1) c1 = 0;
 412                         if (head.team == NUM_TEAM_2) c2 = 0;
 413                         if (head.team == NUM_TEAM_3) c3 = 0;
 414                         if (head.team == NUM_TEAM_4) c4 = 0;
 415                         head = head.chain;
 416                 }
 417         }
 418         else if(g_domination)
 419                 teament_name = "dom_team";
 420         else if(g_ctf)
 421                 teament_name = "ctf_team";
 422         else if(g_tdm)
 423                 teament_name = "tdm_team";
 424         else if(g_nexball)
 425                 teament_name = "nexball_team";
 426         else if(g_assault)
 427                 c1 = c2 = 0; // Assault always has 2 teams
 428         else
 429         {
 430                 // cover anything else by treating it like tdm with no teams spawned
 431                 dm = 2;
 432
 433                 ret_float = dm;
 434                 MUTATOR_CALLHOOK(GetTeamCount);
 435                 dm = ret_float;
 436
 437                 if(dm >= 4)
 438                         c1 = c2 = c3 = c4 = 0;
 439                 else if(dm >= 3)
 440                         c1 = c2 = c3 = 0;
 441                 else
 442                         c1 = c2 = 0;
 443         }
 444
 445         // find out what teams are allowed if necessary
 446         if(teament_name)
 447         {
 448                 head = find(world, classname, teament_name);
 449                 while(head)
 450                 {
 451                         if(!(g_domination && head.netname == ""))
 452                         {
 453                                 if(head.team == NUM_TEAM_1)
 454                                         c1 = 0;
 455                                 else if(head.team == NUM_TEAM_2)
 456                                         c2 = 0;
 457                                 else if(head.team == NUM_TEAM_3)
 458                                         c3 = 0;
 459                                 else if(head.team == NUM_TEAM_4)
 460                                         c4 = 0;
 461                         }
 462                         head = find(head, classname, teament_name);
 463                 }
 464         }
 465
 466         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 467         if(c3==-1 && c4==-1)
 468         if(autocvar_bot_vs_human && for_whom)
 469         {
 470                 if(autocvar_bot_vs_human > 0)
 471                 {
 472                         // bots are all blue
 473                         if(IS_BOT_CLIENT(for_whom))
 474                                 c1 = c3 = c4 = -1;
 475                         else
 476                                 c2 = -1;
 477                 }
 478                 else
 479                 {
 480                         // bots are all red
 481                         if(IS_BOT_CLIENT(for_whom))
 482                                 c2 = c3 = c4 = -1;
 483                         else
 484                                 c1 = -1;
 485                 }
 486         }
 487
 488         // if player has a forced team, ONLY allow that one
 489         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 490                 c2 = c3 = c4 = -1;
 491         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 492                 c1 = c3 = c4 = -1;
 493         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 494                 c1 = c2 = c4 = -1;
 495         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 496                 c1 = c2 = c3 = -1;
 497 }
 498
 499 float PlayerValue(entity p)
 500 {
 501         return 1;
 502         // FIXME: it always returns 1...
 503 }
 504
 505 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 506 // teams that are allowed will now have their player counts stored in c1...c4
 507 void GetTeamCounts(entity ignore)
 508 {
 509         entity head;
 510         float value, bvalue;
 511         // now count how many players are on each team already
 512
 513         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 514         // also remember the lowest-scoring player
 515
 516         FOR_EACH_CLIENT(head)
 517         {
 518                 float t;
 519                 if(IS_PLAYER(head) || head.caplayer)
 520                         t = head.team;
 521                 else if(head.team_forced > 0)
 522                         t = head.team_forced; // reserve the spot
 523                 else
 524                         continue;
 525                 if(head != ignore)// && head.netname != "")
 526                 {
 527                         value = PlayerValue(head);
 528                         if(IS_BOT_CLIENT(head))
 529                                 bvalue = value;
 530                         else
 531                                 bvalue = 0;
 532                         if(t == NUM_TEAM_1)
 533                         {
 534                                 if(c1 >= 0)
 535                                 {
 536                                         c1 = c1 + value;
 537                                         cb1 = cb1 + bvalue;
 538                                 }
 539                         }
 540                         if(t == NUM_TEAM_2)
 541                         {
 542                                 if(c2 >= 0)
 543                                 {
 544                                         c2 = c2 + value;
 545                                         cb2 = cb2 + bvalue;
 546                                 }
 547                         }
 548                         if(t == NUM_TEAM_3)
 549                         {
 550                                 if(c3 >= 0)
 551                                 {
 552                                         c3 = c3 + value;
 553                                         cb3 = cb3 + bvalue;
 554                                 }
 555                         }
 556                         if(t == NUM_TEAM_4)
 557                         {
 558                                 if(c4 >= 0)
 559                                 {
 560                                         c4 = c4 + value;
 561                                         cb4 = cb4 + bvalue;
 562                                 }
 563                         }
 564                 }
 565         }
 566
 567         // if the player who has a forced team has not joined yet, reserve the spot
 568         if(autocvar_g_campaign)
 569         {
 570                 switch(autocvar_g_campaign_forceteam)
 571                 {
 572                         case 1: if(c1 == cb1) ++c1; break;
 573                         case 2: if(c2 == cb2) ++c2; break;
 574                         case 3: if(c3 == cb3) ++c3; break;
 575                         case 4: if(c4 == cb4) ++c4; break;
 576                 }
 577         }
 578 }
 579
 580 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 581 {
 582         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 583         float f;
 584         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 585
 586         switch(ta)
 587         {
 588                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 589                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 590                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 591                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 592         }
 593         switch(tb)
 594         {
 595                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 596                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 597                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 598                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 599         }
 600
 601         // invalid
 602         if(ca < 0 || cb < 0)
 603                 return false;
 604
 605         // equal
 606         if(ta == tb)
 607                 return true;
 608
 609         if(IS_REAL_CLIENT(e))
 610         {
 611                 if(bots_would_leave)
 612                 {
 613                         ca -= cba * 0.999;
 614                         cb -= cbb * 0.999;
 615                 }
 616         }
 617
 618         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 619         if(ca < 1)
 620                 if(cb >= 1)
 621                         return true;
 622         if(ca >= 1)
 623                 if(cb < 1)
 624                         return false;
 625
 626         // first, normalize
 627         f = max(ca, cb, 1);
 628         ca /= f;
 629         cb /= f;
 630         f = max(sa, sb, 1);
 631         sa /= f;
 632         sb /= f;
 633
 634         // the more we're at the end of the match, the more take scores into account
 635         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 636         ca += (sa - ca) * f;
 637         cb += (sb - cb) * f;
 638
 639         return ca <= cb;
 640 }
 641
 642 // returns # of smallest team (1, 2, 3, 4)
 643 // NOTE: Assumes CheckAllowedTeams has already been called!
 644 float FindSmallestTeam(entity pl, float ignore_pl)
 645 {
 646         float totalteams, t;
 647         totalteams = 0;
 648
 649         // find out what teams are available
 650         //CheckAllowedTeams();
 651
 652         // make sure there are at least 2 teams to join
 653         if(c1 >= 0)
 654                 totalteams = totalteams + 1;
 655         if(c2 >= 0)
 656                 totalteams = totalteams + 1;
 657         if(c3 >= 0)
 658                 totalteams = totalteams + 1;
 659         if(c4 >= 0)
 660                 totalteams = totalteams + 1;
 661
 662         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 663                 totalteams += 1;
 664
 665         if(totalteams <= 1)
 666         {
 667                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 668                         return 1; // special case for campaign and player joining
 669                 else
 670                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 671         }
 672
 673         // count how many players are in each team
 674         if(ignore_pl)
 675                 GetTeamCounts(pl);
 676         else
 677                 GetTeamCounts(world);
 678
 679         RandomSelection_Init();
 680
 681         t = 1;
 682         if(TeamSmallerEqThanTeam(2, t, pl))
 683                 t = 2;
 684         if(TeamSmallerEqThanTeam(3, t, pl))
 685                 t = 3;
 686         if(TeamSmallerEqThanTeam(4, t, pl))
 687                 t = 4;
 688
 689         // now t is the minimum, or A minimum!
 690         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 691                 RandomSelection_Add(world, 1, string_null, 1, 1);
 692         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 693                 RandomSelection_Add(world, 2, string_null, 1, 1);
 694         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 695                 RandomSelection_Add(world, 3, string_null, 1, 1);
 696         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 697                 RandomSelection_Add(world, 4, string_null, 1, 1);
 698
 699         return RandomSelection_chosen_float;
 700 }
 701
 702 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 703 {
 704         float smallest, selectedteam;
 705
 706         // don't join a team if we're not playing a team game
 707         if(!teamplay)
 708                 return 0;
 709
 710         // find out what teams are available
 711         CheckAllowedTeams(pl);
 712
 713         // if we don't care what team he ends up on, put him on whatever team he entered as.
 714         // if he's not on a valid team, then let other code put him on the smallest team
 715         if(!forcebestteam)
 716         {
 717                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 718                         selectedteam = pl.team;
 719                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 720                         selectedteam = pl.team;
 721                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 722                         selectedteam = pl.team;
 723                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 724                         selectedteam = pl.team;
 725                 else
 726                         selectedteam = -1;
 727
 728                 if(selectedteam > 0)
 729                 {
 730                         if(!only_return_best)
 731                         {
 732                                 SetPlayerColors(pl, selectedteam - 1);
 733
 734                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 735                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 736                                 LogTeamchange(pl.playerid, pl.team, 99);
 737                         }
 738                         return selectedteam;
 739                 }
 740                 // otherwise end up on the smallest team (handled below)
 741         }
 742
 743         smallest = FindSmallestTeam(pl, true);
 744
 745         if(!only_return_best && !pl.bot_forced_team)
 746         {
 747                 TeamchangeFrags(self);
 748                 if(smallest == 1)
 749                 {
 750                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 751                 }
 752                 else if(smallest == 2)
 753                 {
 754                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 755                 }
 756                 else if(smallest == 3)
 757                 {
 758                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 759                 }
 760                 else if(smallest == 4)
 761                 {
 762                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 763                 }
 764                 else
 765                 {
 766                         error("smallest team: invalid team\n");
 767                 }
 768
 769                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 770
 771                 if(pl.deadflag == DEAD_NO)
 772                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 773         }
 774
 775         return smallest;
 776 }
 777
 778 //void() ctf_playerchanged;
 779 void SV_ChangeTeam(float _color)
 780 {
 781         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 782
 783         // in normal deathmatch we can just apply the color and we're done
 784         if(!teamplay) {
 785                 SetPlayerColors(self, _color);
 786                 return;
 787         }
 788
 789         scolor = self.clientcolors & 0x0F;
 790         dcolor = _color & 0x0F;
 791
 792         if(scolor == NUM_TEAM_1 - 1)
 793                 steam = 1;
 794         else if(scolor == NUM_TEAM_2 - 1)
 795                 steam = 2;
 796         else if(scolor == NUM_TEAM_3 - 1)
 797                 steam = 3;
 798         else // if(scolor == NUM_TEAM_4 - 1)
 799                 steam = 4;
 800         if(dcolor == NUM_TEAM_1 - 1)
 801                 dteam = 1;
 802         else if(dcolor == NUM_TEAM_2 - 1)
 803                 dteam = 2;
 804         else if(dcolor == NUM_TEAM_3 - 1)
 805                 dteam = 3;
 806         else // if(dcolor == NUM_TEAM_4 - 1)
 807                 dteam = 4;
 808
 809         CheckAllowedTeams(self);
 810
 811         if(dteam == 1 && c1 < 0) dteam = 4;
 812         if(dteam == 4 && c4 < 0) dteam = 3;
 813         if(dteam == 3 && c3 < 0) dteam = 2;
 814         if(dteam == 2 && c2 < 0) dteam = 1;
 815
 816         // not changing teams
 817         if(scolor == dcolor)
 818         {
 819                 //bprint("same team change\n");
 820                 SetPlayerTeam(self, dteam, steam, true);
 821                 return;
 822         }
 823
 824         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 825                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 826                 return; // changing teams is not allowed
 827         }
 828
 829         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 830         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 831         {
 832                 GetTeamCounts(self);
 833                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 834                 {
 835                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 836                         return;
 837                 }
 838         }
 839
 840 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 841
 842         if(IS_PLAYER(self) && steam != dteam)
 843         {
 844                 // reduce frags during a team change
 845                 TeamchangeFrags(self);
 846         }
 847
 848         SetPlayerTeam(self, dteam, steam, false);
 849
 850         if(IS_PLAYER(self) && steam != dteam)
 851         {
 852                 // kill player when changing teams
 853                 if(self.deadflag == DEAD_NO)
 854                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 855         }
 856 }
 857
 858 void ShufflePlayerOutOfTeam (float source_team)
 859 {
 860         float smallestteam, smallestteam_count, steam;
 861         float lowest_bot_score, lowest_player_score;
 862         entity head, lowest_bot, lowest_player, selected;
 863
 864         smallestteam = 0;
 865         smallestteam_count = 999999999;
 866
 867         if(c1 >= 0 && c1 < smallestteam_count)
 868         {
 869                 smallestteam = 1;
 870                 smallestteam_count = c1;
 871         }
 872         if(c2 >= 0 && c2 < smallestteam_count)
 873         {
 874                 smallestteam = 2;
 875                 smallestteam_count = c2;
 876         }
 877         if(c3 >= 0 && c3 < smallestteam_count)
 878         {
 879                 smallestteam = 3;
 880                 smallestteam_count = c3;
 881         }
 882         if(c4 >= 0 && c4 < smallestteam_count)
 883         {
 884                 smallestteam = 4;
 885                 smallestteam_count = c4;
 886         }
 887
 888         if(!smallestteam)
 889         {
 890                 bprint("warning: no smallest team\n");
 891                 return;
 892         }
 893
 894         if(source_team == 1)
 895                 steam = NUM_TEAM_1;
 896         else if(source_team == 2)
 897                 steam = NUM_TEAM_2;
 898         else if(source_team == 3)
 899                 steam = NUM_TEAM_3;
 900         else // if(source_team == 4)
 901                 steam = NUM_TEAM_4;
 902
 903         lowest_bot = world;
 904         lowest_bot_score = 999999999;
 905         lowest_player = world;
 906         lowest_player_score = 999999999;
 907
 908         // find the lowest-scoring player & bot of that team
 909         FOR_EACH_PLAYER(head)
 910         {
 911                 if(head.team == steam)
 912                 {
 913                         if(head.isbot)
 914                         {
 915                                 if(head.totalfrags < lowest_bot_score)
 916                                 {
 917                                         lowest_bot = head;
 918                                         lowest_bot_score = head.totalfrags;
 919                                 }
 920                         }
 921                         else
 922                         {
 923                                 if(head.totalfrags < lowest_player_score)
 924                                 {
 925                                         lowest_player = head;
 926                                         lowest_player_score = head.totalfrags;
 927                                 }
 928                         }
 929                 }
 930         }
 931
 932         // prefers to move a bot...
 933         if(lowest_bot != world)
 934                 selected = lowest_bot;
 935         // but it will move a player if it has to
 936         else
 937                 selected = lowest_player;
 938         // don't do anything if it couldn't find anyone
 939         if(!selected)
 940         {
 941                 bprint("warning: couldn't find a player to move from team\n");
 942                 return;
 943         }
 944
 945         // smallest team gains a member
 946         if(smallestteam == 1)
 947         {
 948                 c1 = c1 + 1;
 949         }
 950         else if(smallestteam == 2)
 951         {
 952                 c2 = c2 + 1;
 953         }
 954         else if(smallestteam == 3)
 955         {
 956                 c3 = c3 + 1;
 957         }
 958         else if(smallestteam == 4)
 959         {
 960                 c4 = c4 + 1;
 961         }
 962         else
 963         {
 964                 bprint("warning: destination team invalid\n");
 965                 return;
 966         }
 967         // source team loses a member
 968         if(source_team == 1)
 969         {
 970                 c1 = c1 + 1;
 971         }
 972         else if(source_team == 2)
 973         {
 974                 c2 = c2 + 2;
 975         }
 976         else if(source_team == 3)
 977         {
 978                 c3 = c3 + 3;
 979         }
 980         else if(source_team == 4)
 981         {
 982                 c4 = c4 + 4;
 983         }
 984         else
 985         {
 986                 bprint("warning: source team invalid\n");
 987                 return;
 988         }
 989
 990         // move the player to the new team
 991         TeamchangeFrags(selected);
 992         SetPlayerTeam(selected, smallestteam, source_team, false);
 993
 994         if(selected.deadflag == DEAD_NO)
 995                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 996         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
 997 }