qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2 #include "_all.qh"
   3
   4 #include "cl_client.qh"
   5 #include "race.qh"
   6 #include "scores.qh"
   7 #include "scores_rules.qh"
   8
   9 #include "bot/bot.qh"
  10
  11 #include "command/vote.qh"
  12
  13 #include "mutators/mutators_include.qh"
  14
  15 #include "../common/deathtypes.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit()
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  50
  51         qualifying_override = -1;
  52
  53         VoteReset();
  54
  55         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  56         get_mi_min_max(1);
  57         world.mins = mi_min;
  58         world.maxs = mi_max;
  59
  60         MapInfo_LoadMapSettings(mapname);
  61         serverflags &= ~SERVERFLAG_TEAMPLAY;
  62         teamplay = 0;
  63         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  64
  65         if (!cvar_value_issafe(world.fog))
  66         {
  67                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
  68                 world.fog = string_null;
  69         }
  70         if(MapInfo_Map_fog != "")
  71                 if(MapInfo_Map_fog == "none")
  72                         world.fog = string_null;
  73                 else
  74                         world.fog = strzone(MapInfo_Map_fog);
  75         clientstuff = strzone(MapInfo_Map_clientstuff);
  76
  77         MapInfo_ClearTemps();
  78
  79         // set both here, gamemode can override it later
  80         timelimit_override = autocvar_timelimit_override;
  81         fraglimit_override = autocvar_fraglimit_override;
  82         leadlimit_override = autocvar_leadlimit_override;
  83         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  84
  85         if(g_dm)
  86         {
  87                 MUTATOR_ADD(gamemode_deathmatch);
  88         }
  89
  90         if(g_tdm)
  91         {
  92                 ActivateTeamplay();
  93                 fraglimit_override = autocvar_g_tdm_point_limit;
  94                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
  95                 if(autocvar_g_tdm_team_spawns)
  96                         have_team_spawns = -1; // request team spawns
  97                 MUTATOR_ADD(gamemode_tdm);
  98         }
  99
 100         if(g_domination)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_g_domination_point_limit;
 104                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 105                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
 106                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
 107                 have_team_spawns = -1; // request team spawns
 108                 MUTATOR_ADD(gamemode_domination);
 109         }
 110
 111         if(g_ctf)
 112         {
 113                 ActivateTeamplay();
 114                 fraglimit_override = autocvar_capturelimit_override;
 115                 leadlimit_override = autocvar_captureleadlimit_override;
 116                 have_team_spawns = -1; // request team spawns
 117                 MUTATOR_ADD(gamemode_ctf);
 118         }
 119
 120         if(g_lms)
 121         {
 122                 fraglimit_override = autocvar_g_lms_lives_override;
 123                 leadlimit_override = 0; // not supported by LMS
 124                 if(fraglimit_override == 0)
 125                         fraglimit_override = -1;
 126                 MUTATOR_ADD(gamemode_lms);
 127         }
 128
 129         if(g_ca)
 130         {
 131                 ActivateTeamplay();
 132                 fraglimit_override = autocvar_g_ca_point_limit;
 133                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 134                 if(autocvar_g_ca_team_spawns)
 135                         have_team_spawns = -1; // request team spawns
 136                 MUTATOR_ADD(gamemode_ca);
 137         }
 138
 139         if(g_keyhunt)
 140         {
 141                 ActivateTeamplay();
 142                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 143                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 144                 if(autocvar_g_keyhunt_team_spawns)
 145                         have_team_spawns = -1; // request team spawns
 146                 MUTATOR_ADD(gamemode_keyhunt);
 147         }
 148
 149         if(g_freezetag)
 150         {
 151                 ActivateTeamplay();
 152                 fraglimit_override = autocvar_g_freezetag_point_limit;
 153                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 154                 if(autocvar_g_freezetag_team_spawns)
 155                         have_team_spawns = -1; // request team spawns
 156                 MUTATOR_ADD(gamemode_freezetag);
 157         }
 158
 159         if(g_assault)
 160         {
 161                 ActivateTeamplay();
 162                 have_team_spawns = -1; // request team spawns
 163                 MUTATOR_ADD(gamemode_assault);
 164         }
 165
 166         if(g_onslaught)
 167         {
 168                 ActivateTeamplay();
 169                 fraglimit_override = autocvar_g_onslaught_point_limit;
 170                 have_team_spawns = -1; // request team spawns
 171                 MUTATOR_ADD(gamemode_onslaught);
 172         }
 173
 174         if(g_race)
 175         {
 176                 if(autocvar_g_race_teams)
 177                 {
 178                         ActivateTeamplay();
 179                         race_teams = bound(2, autocvar_g_race_teams, 4);
 180                         have_team_spawns = -1; // request team spawns
 181                 }
 182                 else
 183                         race_teams = 0;
 184                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 185                 fraglimit_override = autocvar_g_race_laps_limit;
 186                 leadlimit_override = 0; // currently not supported by race
 187
 188                 // we need to find out the correct value for g_race_qualifying
 189                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 190
 191                 if(autocvar_g_campaign)
 192                 {
 193                         g_race_qualifying = 1;
 194                         independent_players = 1;
 195                 }
 196                 else if(!autocvar_g_campaign && want_qualifying)
 197                 {
 198                         g_race_qualifying = 2;
 199                         independent_players = 1;
 200                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
 201                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
 202                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
 203                         fraglimit_override = 0;
 204                         leadlimit_override = 0;
 205                         timelimit_override = autocvar_g_race_qualifying_timelimit;
 206                 }
 207                 else
 208                 {
 209                         g_race_qualifying = 0;
 210                 }
 211
 212                 MUTATOR_ADD(gamemode_race);
 213         }
 214
 215         if(g_cts)
 216         {
 217                 g_race_qualifying = 1;
 218                 fraglimit_override = 0;
 219                 leadlimit_override = 0;
 220                 independent_players = 1;
 221                 MUTATOR_ADD(gamemode_cts);
 222         }
 223
 224         if(g_nexball)
 225         {
 226                 fraglimit_override = autocvar_g_nexball_goallimit;
 227                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 228                 ActivateTeamplay();
 229                 have_team_spawns = -1; // request team spawns
 230                 MUTATOR_ADD(gamemode_nexball);
 231         }
 232
 233         if(g_keepaway)
 234         {
 235                 MUTATOR_ADD(gamemode_keepaway);
 236         }
 237
 238         if(g_invasion)
 239         {
 240                 fraglimit_override = autocvar_g_invasion_point_limit;
 241                 if(autocvar_g_invasion_teams >= 2)
 242                 {
 243                         ActivateTeamplay();
 244                         if(autocvar_g_invasion_team_spawns)
 245                                 have_team_spawns = -1; // request team spawns
 246                 }
 247                 MUTATOR_ADD(gamemode_invasion);
 248         }
 249
 250         if(teamplay)
 251                 entcs_init();
 252
 253         cache_mutatormsg = strzone("");
 254         cache_lastmutatormsg = strzone("");
 255
 256         // enforce the server's universal frag/time limits
 257         if(!autocvar_g_campaign)
 258         {
 259                 if(fraglimit_override >= 0)
 260                         cvar_set("fraglimit", ftos(fraglimit_override));
 261                 if(timelimit_override >= 0)
 262                         cvar_set("timelimit", ftos(timelimit_override));
 263                 if(leadlimit_override >= 0)
 264                         cvar_set("leadlimit", ftos(leadlimit_override));
 265                 if(qualifying_override >= 0)
 266                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 267         }
 268
 269         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 270 }
 271
 272 string GetClientVersionMessage() {
 273         string versionmsg;
 274         if (self.version_mismatch) {
 275                 if(self.version < autocvar_gameversion) {
 276                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 277                 } else {
 278                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 279                 }
 280         } else {
 281                 versionmsg = "^2client version and server version are compatible.^8";
 282         }
 283         return versionmsg;
 284 }
 285
 286 string getwelcomemessage(void)
 287 {
 288         string s, modifications, motd;
 289
 290         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 291         modifications = ret_string;
 292
 293         if(g_weaponarena)
 294         {
 295                 if(g_weaponarena_random)
 296                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 297                 else
 298                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 299         }
 300         else if(cvar("g_balance_blaster_weaponstart") == 0)
 301                 modifications = strcat(modifications, ", No start weapons");
 302         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 303                 modifications = strcat(modifications, ", Low gravity");
 304         if(g_cloaked && !g_cts)
 305                 modifications = strcat(modifications, ", Cloaked");
 306         if(g_grappling_hook)
 307                 modifications = strcat(modifications, ", Hook");
 308         if(g_weapon_stay && !g_cts)
 309                 modifications = strcat(modifications, ", Weapons stay");
 310         if(g_jetpack)
 311                 modifications = strcat(modifications, ", Jet pack");
 312         if(autocvar_g_powerups == 0)
 313                 modifications = strcat(modifications, ", No powerups");
 314         if(autocvar_g_powerups > 0)
 315                 modifications = strcat(modifications, ", Powerups");
 316         modifications = substring(modifications, 2, strlen(modifications) - 2);
 317
 318         string versionmessage;
 319         versionmessage = GetClientVersionMessage();
 320
 321         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 322         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 323
 324         if(modifications != "")
 325                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 326
 327         if (g_grappling_hook)
 328                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 329
 330         if (cvar("g_nades"))
 331                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 332
 333         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 334         {
 335                 if(cache_lastmutatormsg)
 336                         strunzone(cache_lastmutatormsg);
 337                 if(cache_mutatormsg)
 338                         strunzone(cache_mutatormsg);
 339                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 340                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 341         }
 342
 343         if (cache_mutatormsg != "") {
 344                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 345         }
 346
 347         string mutator_msg = "";
 348         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
 349         mutator_msg = ret_string;
 350
 351         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
 352
 353         motd = autocvar_sv_motd;
 354         if (motd != "") {
 355                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 356         }
 357         return s;
 358 }
 359
 360 void SetPlayerColors(entity pl, float _color)
 361 {
 362         /*string s;
 363         s = ftos(cl);
 364         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 365         pl.team = cl + 1;
 366         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 367         pl.clientcolors = 16*cl + cl;*/
 368
 369         float pants, shirt;
 370         pants = _color & 0x0F;
 371         shirt = _color & 0xF0;
 372
 373
 374         if(teamplay) {
 375                 setcolor(pl, 16*pants + pants);
 376         } else {
 377                 setcolor(pl, shirt + pants);
 378         }
 379 }
 380
 381 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 382 {
 383         float _color;
 384
 385         if(t == 4)
 386                 _color = NUM_TEAM_4 - 1;
 387         else if(t == 3)
 388                 _color = NUM_TEAM_3 - 1;
 389         else if(t == 2)
 390                 _color = NUM_TEAM_2 - 1;
 391         else
 392                 _color = NUM_TEAM_1 - 1;
 393
 394         SetPlayerColors(pl,_color);
 395
 396         if(t != s) {
 397                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 398
 399                 if(!noprint)
 400                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 401         }
 402
 403 }
 404
 405 // set c1...c4 to show what teams are allowed
 406 void CheckAllowedTeams (entity for_whom)
 407 {
 408         float dm;
 409         entity head;
 410         string teament_name;
 411
 412         c1 = c2 = c3 = c4 = -1;
 413         cb1 = cb2 = cb3 = cb4 = 0;
 414
 415         teament_name = string_null;
 416         if(g_onslaught)
 417         {
 418                 // onslaught is special
 419                 head = findchain(classname, "onslaught_generator");
 420                 while (head)
 421                 {
 422                         if (head.team == NUM_TEAM_1) c1 = 0;
 423                         if (head.team == NUM_TEAM_2) c2 = 0;
 424                         if (head.team == NUM_TEAM_3) c3 = 0;
 425                         if (head.team == NUM_TEAM_4) c4 = 0;
 426                         head = head.chain;
 427                 }
 428         }
 429         else if(g_domination)
 430                 teament_name = "dom_team";
 431         else if(g_ctf)
 432                 teament_name = "ctf_team";
 433         else if(g_tdm)
 434                 teament_name = "tdm_team";
 435         else if(g_nexball)
 436                 teament_name = "nexball_team";
 437         else if(g_assault)
 438                 c1 = c2 = 0; // Assault always has 2 teams
 439         else
 440         {
 441                 // cover anything else by treating it like tdm with no teams spawned
 442                 dm = 2;
 443
 444                 MUTATOR_CALLHOOK(GetTeamCount, dm);
 445                 dm = ret_float;
 446
 447                 if(dm >= 4)
 448                         c1 = c2 = c3 = c4 = 0;
 449                 else if(dm >= 3)
 450                         c1 = c2 = c3 = 0;
 451                 else
 452                         c1 = c2 = 0;
 453         }
 454
 455         // find out what teams are allowed if necessary
 456         if(teament_name)
 457         {
 458                 head = find(world, classname, teament_name);
 459                 while(head)
 460                 {
 461                         if(!(g_domination && head.netname == ""))
 462                         {
 463                                 if(head.team == NUM_TEAM_1)
 464                                         c1 = 0;
 465                                 else if(head.team == NUM_TEAM_2)
 466                                         c2 = 0;
 467                                 else if(head.team == NUM_TEAM_3)
 468                                         c3 = 0;
 469                                 else if(head.team == NUM_TEAM_4)
 470                                         c4 = 0;
 471                         }
 472                         head = find(head, classname, teament_name);
 473                 }
 474         }
 475
 476         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 477         if(c3==-1 && c4==-1)
 478         if(autocvar_bot_vs_human && for_whom)
 479         {
 480                 if(autocvar_bot_vs_human > 0)
 481                 {
 482                         // bots are all blue
 483                         if(IS_BOT_CLIENT(for_whom))
 484                                 c1 = c3 = c4 = -1;
 485                         else
 486                                 c2 = -1;
 487                 }
 488                 else
 489                 {
 490                         // bots are all red
 491                         if(IS_BOT_CLIENT(for_whom))
 492                                 c2 = c3 = c4 = -1;
 493                         else
 494                                 c1 = -1;
 495                 }
 496         }
 497
 498         // if player has a forced team, ONLY allow that one
 499         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 500                 c2 = c3 = c4 = -1;
 501         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 502                 c1 = c3 = c4 = -1;
 503         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 504                 c1 = c2 = c4 = -1;
 505         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 506                 c1 = c2 = c3 = -1;
 507 }
 508
 509 float PlayerValue(entity p)
 510 {
 511         return 1;
 512         // FIXME: it always returns 1...
 513 }
 514
 515 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 516 // teams that are allowed will now have their player counts stored in c1...c4
 517 void GetTeamCounts(entity ignore)
 518 {
 519         entity head;
 520         float value, bvalue;
 521         // now count how many players are on each team already
 522
 523         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 524         // also remember the lowest-scoring player
 525
 526         FOR_EACH_CLIENT(head)
 527         {
 528                 float t;
 529                 if(IS_PLAYER(head) || head.caplayer)
 530                         t = head.team;
 531                 else if(head.team_forced > 0)
 532                         t = head.team_forced; // reserve the spot
 533                 else
 534                         continue;
 535                 if(head != ignore)// && head.netname != "")
 536                 {
 537                         value = PlayerValue(head);
 538                         if(IS_BOT_CLIENT(head))
 539                                 bvalue = value;
 540                         else
 541                                 bvalue = 0;
 542                         if(t == NUM_TEAM_1)
 543                         {
 544                                 if(c1 >= 0)
 545                                 {
 546                                         c1 = c1 + value;
 547                                         cb1 = cb1 + bvalue;
 548                                 }
 549                         }
 550                         if(t == NUM_TEAM_2)
 551                         {
 552                                 if(c2 >= 0)
 553                                 {
 554                                         c2 = c2 + value;
 555                                         cb2 = cb2 + bvalue;
 556                                 }
 557                         }
 558                         if(t == NUM_TEAM_3)
 559                         {
 560                                 if(c3 >= 0)
 561                                 {
 562                                         c3 = c3 + value;
 563                                         cb3 = cb3 + bvalue;
 564                                 }
 565                         }
 566                         if(t == NUM_TEAM_4)
 567                         {
 568                                 if(c4 >= 0)
 569                                 {
 570                                         c4 = c4 + value;
 571                                         cb4 = cb4 + bvalue;
 572                                 }
 573                         }
 574                 }
 575         }
 576
 577         // if the player who has a forced team has not joined yet, reserve the spot
 578         if(autocvar_g_campaign)
 579         {
 580                 switch(autocvar_g_campaign_forceteam)
 581                 {
 582                         case 1: if(c1 == cb1) ++c1; break;
 583                         case 2: if(c2 == cb2) ++c2; break;
 584                         case 3: if(c3 == cb3) ++c3; break;
 585                         case 4: if(c4 == cb4) ++c4; break;
 586                 }
 587         }
 588 }
 589
 590 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 591 {
 592         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 593         float f;
 594         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 595
 596         switch(ta)
 597         {
 598                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 599                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 600                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 601                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 602         }
 603         switch(tb)
 604         {
 605                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 606                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 607                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 608                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 609         }
 610
 611         // invalid
 612         if(ca < 0 || cb < 0)
 613                 return false;
 614
 615         // equal
 616         if(ta == tb)
 617                 return true;
 618
 619         if(IS_REAL_CLIENT(e))
 620         {
 621                 if(bots_would_leave)
 622                 {
 623                         ca -= cba * 0.999;
 624                         cb -= cbb * 0.999;
 625                 }
 626         }
 627
 628         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 629         if(ca < 1)
 630                 if(cb >= 1)
 631                         return true;
 632         if(ca >= 1)
 633                 if(cb < 1)
 634                         return false;
 635
 636         // first, normalize
 637         f = max(ca, cb, 1);
 638         ca /= f;
 639         cb /= f;
 640         f = max(sa, sb, 1);
 641         sa /= f;
 642         sb /= f;
 643
 644         // the more we're at the end of the match, the more take scores into account
 645         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 646         ca += (sa - ca) * f;
 647         cb += (sb - cb) * f;
 648
 649         return ca <= cb;
 650 }
 651
 652 // returns # of smallest team (1, 2, 3, 4)
 653 // NOTE: Assumes CheckAllowedTeams has already been called!
 654 float FindSmallestTeam(entity pl, float ignore_pl)
 655 {
 656         float totalteams, t;
 657         totalteams = 0;
 658
 659         // find out what teams are available
 660         //CheckAllowedTeams();
 661
 662         // make sure there are at least 2 teams to join
 663         if(c1 >= 0)
 664                 totalteams = totalteams + 1;
 665         if(c2 >= 0)
 666                 totalteams = totalteams + 1;
 667         if(c3 >= 0)
 668                 totalteams = totalteams + 1;
 669         if(c4 >= 0)
 670                 totalteams = totalteams + 1;
 671
 672         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 673                 totalteams += 1;
 674
 675         if(totalteams <= 1)
 676         {
 677                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 678                         return 1; // special case for campaign and player joining
 679                 else
 680                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 681         }
 682
 683         // count how many players are in each team
 684         if(ignore_pl)
 685                 GetTeamCounts(pl);
 686         else
 687                 GetTeamCounts(world);
 688
 689         RandomSelection_Init();
 690
 691         t = 1;
 692         if(TeamSmallerEqThanTeam(2, t, pl))
 693                 t = 2;
 694         if(TeamSmallerEqThanTeam(3, t, pl))
 695                 t = 3;
 696         if(TeamSmallerEqThanTeam(4, t, pl))
 697                 t = 4;
 698
 699         // now t is the minimum, or A minimum!
 700         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 701                 RandomSelection_Add(world, 1, string_null, 1, 1);
 702         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 703                 RandomSelection_Add(world, 2, string_null, 1, 1);
 704         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 705                 RandomSelection_Add(world, 3, string_null, 1, 1);
 706         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 707                 RandomSelection_Add(world, 4, string_null, 1, 1);
 708
 709         return RandomSelection_chosen_float;
 710 }
 711
 712 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 713 {
 714         float smallest, selectedteam;
 715
 716         // don't join a team if we're not playing a team game
 717         if(!teamplay)
 718                 return 0;
 719
 720         // find out what teams are available
 721         CheckAllowedTeams(pl);
 722
 723         // if we don't care what team he ends up on, put him on whatever team he entered as.
 724         // if he's not on a valid team, then let other code put him on the smallest team
 725         if(!forcebestteam)
 726         {
 727                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 728                         selectedteam = pl.team;
 729                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 730                         selectedteam = pl.team;
 731                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 732                         selectedteam = pl.team;
 733                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 734                         selectedteam = pl.team;
 735                 else
 736                         selectedteam = -1;
 737
 738                 if(selectedteam > 0)
 739                 {
 740                         if(!only_return_best)
 741                         {
 742                                 SetPlayerColors(pl, selectedteam - 1);
 743
 744                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 745                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 746                                 LogTeamchange(pl.playerid, pl.team, 99);
 747                         }
 748                         return selectedteam;
 749                 }
 750                 // otherwise end up on the smallest team (handled below)
 751         }
 752
 753         smallest = FindSmallestTeam(pl, true);
 754
 755         if(!only_return_best && !pl.bot_forced_team)
 756         {
 757                 TeamchangeFrags(self);
 758                 if(smallest == 1)
 759                 {
 760                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 761                 }
 762                 else if(smallest == 2)
 763                 {
 764                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 765                 }
 766                 else if(smallest == 3)
 767                 {
 768                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 769                 }
 770                 else if(smallest == 4)
 771                 {
 772                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 773                 }
 774                 else
 775                 {
 776                         error("smallest team: invalid team\n");
 777                 }
 778
 779                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 780
 781                 if(pl.deadflag == DEAD_NO)
 782                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 783         }
 784
 785         return smallest;
 786 }
 787
 788 //void() ctf_playerchanged;
 789 void SV_ChangeTeam(float _color)
 790 {
 791         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 792
 793         // in normal deathmatch we can just apply the color and we're done
 794         if(!teamplay) {
 795                 SetPlayerColors(self, _color);
 796                 return;
 797         }
 798
 799         scolor = self.clientcolors & 0x0F;
 800         dcolor = _color & 0x0F;
 801
 802         if(scolor == NUM_TEAM_1 - 1)
 803                 steam = 1;
 804         else if(scolor == NUM_TEAM_2 - 1)
 805                 steam = 2;
 806         else if(scolor == NUM_TEAM_3 - 1)
 807                 steam = 3;
 808         else // if(scolor == NUM_TEAM_4 - 1)
 809                 steam = 4;
 810         if(dcolor == NUM_TEAM_1 - 1)
 811                 dteam = 1;
 812         else if(dcolor == NUM_TEAM_2 - 1)
 813                 dteam = 2;
 814         else if(dcolor == NUM_TEAM_3 - 1)
 815                 dteam = 3;
 816         else // if(dcolor == NUM_TEAM_4 - 1)
 817                 dteam = 4;
 818
 819         CheckAllowedTeams(self);
 820
 821         if(dteam == 1 && c1 < 0) dteam = 4;
 822         if(dteam == 4 && c4 < 0) dteam = 3;
 823         if(dteam == 3 && c3 < 0) dteam = 2;
 824         if(dteam == 2 && c2 < 0) dteam = 1;
 825
 826         // not changing teams
 827         if(scolor == dcolor)
 828         {
 829                 //bprint("same team change\n");
 830                 SetPlayerTeam(self, dteam, steam, true);
 831                 return;
 832         }
 833
 834         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 835                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 836                 return; // changing teams is not allowed
 837         }
 838
 839         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 840         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 841         {
 842                 GetTeamCounts(self);
 843                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 844                 {
 845                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 846                         return;
 847                 }
 848         }
 849
 850 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 851
 852         if(IS_PLAYER(self) && steam != dteam)
 853         {
 854                 // reduce frags during a team change
 855                 TeamchangeFrags(self);
 856         }
 857
 858         // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 859         if(!IS_CLIENT(self))
 860                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_CONNECTING, self.netname);
 861
 862         SetPlayerTeam(self, dteam, steam, !IS_CLIENT(self));
 863
 864         if(IS_PLAYER(self) && steam != dteam)
 865         {
 866                 // kill player when changing teams
 867                 if(self.deadflag == DEAD_NO)
 868                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 869         }
 870 }
 871
 872 void ShufflePlayerOutOfTeam (float source_team)
 873 {
 874         float smallestteam, smallestteam_count, steam;
 875         float lowest_bot_score, lowest_player_score;
 876         entity head, lowest_bot, lowest_player, selected;
 877
 878         smallestteam = 0;
 879         smallestteam_count = 999999999;
 880
 881         if(c1 >= 0 && c1 < smallestteam_count)
 882         {
 883                 smallestteam = 1;
 884                 smallestteam_count = c1;
 885         }
 886         if(c2 >= 0 && c2 < smallestteam_count)
 887         {
 888                 smallestteam = 2;
 889                 smallestteam_count = c2;
 890         }
 891         if(c3 >= 0 && c3 < smallestteam_count)
 892         {
 893                 smallestteam = 3;
 894                 smallestteam_count = c3;
 895         }
 896         if(c4 >= 0 && c4 < smallestteam_count)
 897         {
 898                 smallestteam = 4;
 899                 smallestteam_count = c4;
 900         }
 901
 902         if(!smallestteam)
 903         {
 904                 bprint("warning: no smallest team\n");
 905                 return;
 906         }
 907
 908         if(source_team == 1)
 909                 steam = NUM_TEAM_1;
 910         else if(source_team == 2)
 911                 steam = NUM_TEAM_2;
 912         else if(source_team == 3)
 913                 steam = NUM_TEAM_3;
 914         else // if(source_team == 4)
 915                 steam = NUM_TEAM_4;
 916
 917         lowest_bot = world;
 918         lowest_bot_score = 999999999;
 919         lowest_player = world;
 920         lowest_player_score = 999999999;
 921
 922         // find the lowest-scoring player & bot of that team
 923         FOR_EACH_PLAYER(head)
 924         {
 925                 if(head.team == steam)
 926                 {
 927                         if(head.isbot)
 928                         {
 929                                 if(head.totalfrags < lowest_bot_score)
 930                                 {
 931                                         lowest_bot = head;
 932                                         lowest_bot_score = head.totalfrags;
 933                                 }
 934                         }
 935                         else
 936                         {
 937                                 if(head.totalfrags < lowest_player_score)
 938                                 {
 939                                         lowest_player = head;
 940                                         lowest_player_score = head.totalfrags;
 941                                 }
 942                         }
 943                 }
 944         }
 945
 946         // prefers to move a bot...
 947         if(lowest_bot != world)
 948                 selected = lowest_bot;
 949         // but it will move a player if it has to
 950         else
 951                 selected = lowest_player;
 952         // don't do anything if it couldn't find anyone
 953         if(!selected)
 954         {
 955                 bprint("warning: couldn't find a player to move from team\n");
 956                 return;
 957         }
 958
 959         // smallest team gains a member
 960         if(smallestteam == 1)
 961         {
 962                 c1 = c1 + 1;
 963         }
 964         else if(smallestteam == 2)
 965         {
 966                 c2 = c2 + 1;
 967         }
 968         else if(smallestteam == 3)
 969         {
 970                 c3 = c3 + 1;
 971         }
 972         else if(smallestteam == 4)
 973         {
 974                 c4 = c4 + 1;
 975         }
 976         else
 977         {
 978                 bprint("warning: destination team invalid\n");
 979                 return;
 980         }
 981         // source team loses a member
 982         if(source_team == 1)
 983         {
 984                 c1 = c1 + 1;
 985         }
 986         else if(source_team == 2)
 987         {
 988                 c2 = c2 + 2;
 989         }
 990         else if(source_team == 3)
 991         {
 992                 c3 = c3 + 3;
 993         }
 994         else if(source_team == 4)
 995         {
 996                 c4 = c4 + 4;
 997         }
 998         else
 999         {
1000                 bprint("warning: source team invalid\n");
1001                 return;
1002         }
1003
1004         // move the player to the new team
1005         TeamchangeFrags(selected);
1006         SetPlayerTeam(selected, smallestteam, source_team, false);
1007
1008         if(selected.deadflag == DEAD_NO)
1009                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1010         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
1011 }