qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2
   3 #include "client.qh"
   4 #include "race.qh"
   5 #include "scores.qh"
   6 #include "scores_rules.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/vote.qh"
  11
  12 #include "mutators/_mod.qh"
  13
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/gamemodes/_mod.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit(entity this)
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         VoteReset();
  50
  51         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  52         get_mi_min_max(1);
  53         world.mins = mi_min;
  54         world.maxs = mi_max;
  55         // currently, NetRadiant's limit is 131072 qu for each side
  56         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
  57         // set the distance according to map size but don't go over the limit to avoid issues with float precision
  58         // in case somebody makes extremely large maps
  59         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
  60
  61         MapInfo_LoadMapSettings(mapname);
  62         serverflags &= ~SERVERFLAG_TEAMPLAY;
  63         teamplay = 0;
  64         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  65
  66         if (!cvar_value_issafe(world.fog))
  67         {
  68                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
  69                 world.fog = string_null;
  70         }
  71         if(MapInfo_Map_fog != "")
  72                 if(MapInfo_Map_fog == "none")
  73                         world.fog = string_null;
  74                 else
  75                         world.fog = strzone(MapInfo_Map_fog);
  76         clientstuff = strzone(MapInfo_Map_clientstuff);
  77
  78         MapInfo_ClearTemps();
  79
  80         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  81
  82         cache_mutatormsg = strzone("");
  83         cache_lastmutatormsg = strzone("");
  84
  85         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
  86 }
  87
  88 string GetClientVersionMessage(entity this)
  89 {
  90         if (this.version_mismatch) {
  91                 if(this.version < autocvar_gameversion) {
  92                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
  93                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
  94                 } else {
  95                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
  96                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
  97                 }
  98         } else {
  99                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 100         }
 101 }
 102
 103 string getwelcomemessage(entity this)
 104 {
 105         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 106         string modifications = M_ARGV(0, string);
 107
 108         if(g_weaponarena)
 109         {
 110                 if(g_weaponarena_random)
 111                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 112                 else
 113                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 114         }
 115         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
 116                 modifications = strcat(modifications, ", No start weapons");
 117         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 118                 modifications = strcat(modifications, ", Low gravity");
 119         if(g_weapon_stay && !g_cts)
 120                 modifications = strcat(modifications, ", Weapons stay");
 121         if(g_jetpack)
 122                 modifications = strcat(modifications, ", Jet pack");
 123         if(autocvar_g_powerups == 0)
 124                 modifications = strcat(modifications, ", No powerups");
 125         if(autocvar_g_powerups > 0)
 126                 modifications = strcat(modifications, ", Powerups");
 127         modifications = substring(modifications, 2, strlen(modifications) - 2);
 128
 129         string versionmessage = GetClientVersionMessage(this);
 130         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
 131
 132         if(modifications != "")
 133                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 134
 135         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 136         {
 137                 if(cache_lastmutatormsg)
 138                         strunzone(cache_lastmutatormsg);
 139                 if(cache_mutatormsg)
 140                         strunzone(cache_mutatormsg);
 141                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 142                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 143         }
 144
 145         if (cache_mutatormsg != "") {
 146                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 147         }
 148
 149         string mutator_msg = "";
 150         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
 151         mutator_msg = M_ARGV(0, string);
 152
 153         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
 154
 155         string motd = autocvar_sv_motd;
 156         if (motd != "") {
 157                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 158         }
 159         return s;
 160 }
 161
 162 void setcolor(entity this, int clr)
 163 {
 164 #if 0
 165         this.clientcolors = clr;
 166         this.team = (clr & 15) + 1;
 167 #else
 168         builtin_setcolor(this, clr);
 169 #endif
 170 }
 171
 172 void SetPlayerColors(entity pl, float _color)
 173 {
 174         /*string s;
 175         s = ftos(cl);
 176         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 177         pl.team = cl + 1;
 178         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 179         pl.clientcolors = 16*cl + cl;*/
 180
 181         float pants, shirt;
 182         pants = _color & 0x0F;
 183         shirt = _color & 0xF0;
 184
 185
 186         if(teamplay) {
 187                 setcolor(pl, 16*pants + pants);
 188         } else {
 189                 setcolor(pl, shirt + pants);
 190         }
 191 }
 192
 193 bool SetPlayerTeamSimple(entity player, int teamnum)
 194 {
 195         if (player.team == teamnum)
 196         {
 197                 return true;
 198         }
 199         if (MUTATOR_CALLHOOK(Player_ChangeTeam, player, Team_TeamToNumber(
 200                 player.team), Team_TeamToNumber(teamnum)) == true)
 201         {
 202                 // Mutator has blocked team change.
 203                 return false;
 204         }
 205         int oldteam = player.team;
 206         SetPlayerColors(player, teamnum - 1);
 207         MUTATOR_CALLHOOK(Player_ChangedTeam, player, oldteam, player.team);
 208         return true;
 209 }
 210
 211 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 212 {
 213         if (t == s)
 214         {
 215                 return;
 216         }
 217         float teamnum = Team_NumberToTeam(t);
 218         SetPlayerTeamSimple(pl, teamnum);
 219         LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 220         if (noprint)
 221         {
 222                 return;
 223         }
 224         bprint(playername(pl, false), "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 225 }
 226
 227 // set c1...c4 to show what teams are allowed
 228 void CheckAllowedTeams (entity for_whom)
 229 {
 230         int teams_mask = 0;
 231
 232         c1 = c2 = c3 = c4 = -1;
 233         cb1 = cb2 = cb3 = cb4 = 0;
 234
 235         string teament_name = string_null;
 236
 237         bool mutator_returnvalue = MUTATOR_CALLHOOK(CheckAllowedTeams, teams_mask, teament_name, for_whom);
 238         teams_mask = M_ARGV(0, float);
 239         teament_name = M_ARGV(1, string);
 240
 241         if(!mutator_returnvalue)
 242         {
 243                 if(teams_mask & BIT(0)) c1 = 0;
 244                 if(teams_mask & BIT(1)) c2 = 0;
 245                 if(teams_mask & BIT(2)) c3 = 0;
 246                 if(teams_mask & BIT(3)) c4 = 0;
 247         }
 248
 249         // find out what teams are allowed if necessary
 250         if(teament_name)
 251         {
 252                 entity head = find(NULL, classname, teament_name);
 253                 while(head)
 254                 {
 255                         switch(head.team)
 256                         {
 257                                 case NUM_TEAM_1: c1 = 0; break;
 258                                 case NUM_TEAM_2: c2 = 0; break;
 259                                 case NUM_TEAM_3: c3 = 0; break;
 260                                 case NUM_TEAM_4: c4 = 0; break;
 261                         }
 262
 263                         head = find(head, classname, teament_name);
 264                 }
 265         }
 266
 267         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 268         if(AvailableTeams() == 2)
 269         if(autocvar_bot_vs_human && for_whom)
 270         {
 271                 if(autocvar_bot_vs_human > 0)
 272                 {
 273                         // find last team available
 274
 275                         if(IS_BOT_CLIENT(for_whom))
 276                         {
 277                                 if(c4 >= 0) { c3 = c2 = c1 = -1; }
 278                                 else if(c3 >= 0) { c4 = c2 = c1 = -1; }
 279                                 else { c4 = c3 = c1 = -1; }
 280                                 // no further cases, we know at least 2 teams exist
 281                         }
 282                         else
 283                         {
 284                                 if(c1 >= 0) { c2 = c3 = c4 = -1; }
 285                                 else if(c2 >= 0) { c1 = c3 = c4 = -1; }
 286                                 else { c1 = c2 = c4 = -1; }
 287                                 // no further cases, bots have one of the teams
 288                         }
 289                 }
 290                 else
 291                 {
 292                         // find first team available
 293
 294                         if(IS_BOT_CLIENT(for_whom))
 295                         {
 296                                 if(c1 >= 0) { c2 = c3 = c4 = -1; }
 297                                 else if(c2 >= 0) { c1 = c3 = c4 = -1; }
 298                                 else { c1 = c2 = c4 = -1; }
 299                                 // no further cases, we know at least 2 teams exist
 300                         }
 301                         else
 302                         {
 303                                 if(c4 >= 0) { c3 = c2 = c1 = -1; }
 304                                 else if(c3 >= 0) { c4 = c2 = c1 = -1; }
 305                                 else { c4 = c3 = c1 = -1; }
 306                                 // no further cases, bots have one of the teams
 307                         }
 308                 }
 309         }
 310
 311         if(!for_whom)
 312                 return;
 313
 314         // if player has a forced team, ONLY allow that one
 315         if(for_whom.team_forced == NUM_TEAM_1 && c1 >= 0)
 316                 c2 = c3 = c4 = -1;
 317         else if(for_whom.team_forced == NUM_TEAM_2 && c2 >= 0)
 318                 c1 = c3 = c4 = -1;
 319         else if(for_whom.team_forced == NUM_TEAM_3 && c3 >= 0)
 320                 c1 = c2 = c4 = -1;
 321         else if(for_whom.team_forced == NUM_TEAM_4 && c4 >= 0)
 322                 c1 = c2 = c3 = -1;
 323 }
 324
 325 float PlayerValue(entity p)
 326 {
 327         return 1;
 328         // FIXME: it always returns 1...
 329 }
 330
 331 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 332 // teams that are allowed will now have their player counts stored in c1...c4
 333 void GetTeamCounts(entity ignore)
 334 {
 335         float value, bvalue;
 336         // now count how many players are on each team already
 337
 338         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 339         // also remember the lowest-scoring player
 340
 341         FOREACH_CLIENT(true, LAMBDA(
 342                 float t;
 343                 if(IS_PLAYER(it) || it.caplayer)
 344                         t = it.team;
 345                 else if(it.team_forced > 0)
 346                         t = it.team_forced; // reserve the spot
 347                 else
 348                         continue;
 349                 if(it != ignore)// && it.netname != "")
 350                 {
 351                         value = PlayerValue(it);
 352                         if(IS_BOT_CLIENT(it))
 353                                 bvalue = value;
 354                         else
 355                                 bvalue = 0;
 356                         if(t == NUM_TEAM_1)
 357                         {
 358                                 if(c1 >= 0)
 359                                 {
 360                                         c1 = c1 + value;
 361                                         cb1 = cb1 + bvalue;
 362                                 }
 363                         }
 364                         if(t == NUM_TEAM_2)
 365                         {
 366                                 if(c2 >= 0)
 367                                 {
 368                                         c2 = c2 + value;
 369                                         cb2 = cb2 + bvalue;
 370                                 }
 371                         }
 372                         if(t == NUM_TEAM_3)
 373                         {
 374                                 if(c3 >= 0)
 375                                 {
 376                                         c3 = c3 + value;
 377                                         cb3 = cb3 + bvalue;
 378                                 }
 379                         }
 380                         if(t == NUM_TEAM_4)
 381                         {
 382                                 if(c4 >= 0)
 383                                 {
 384                                         c4 = c4 + value;
 385                                         cb4 = cb4 + bvalue;
 386                                 }
 387                         }
 388                 }
 389         ));
 390
 391         // if the player who has a forced team has not joined yet, reserve the spot
 392         if(autocvar_g_campaign)
 393         {
 394                 switch(autocvar_g_campaign_forceteam)
 395                 {
 396                         case 1: if(c1 == cb1) ++c1; break;
 397                         case 2: if(c2 == cb2) ++c2; break;
 398                         case 3: if(c3 == cb3) ++c3; break;
 399                         case 4: if(c4 == cb4) ++c4; break;
 400                 }
 401         }
 402 }
 403
 404 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 405 {
 406         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 407         float f;
 408         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 409
 410         switch(ta)
 411         {
 412                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 413                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 414                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 415                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 416         }
 417         switch(tb)
 418         {
 419                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 420                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 421                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 422                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 423         }
 424
 425         // invalid
 426         if(ca < 0 || cb < 0)
 427                 return false;
 428
 429         // equal
 430         if(ta == tb)
 431                 return true;
 432
 433         if(IS_REAL_CLIENT(e))
 434         {
 435                 if(bots_would_leave)
 436                 {
 437                         ca -= cba * 0.999;
 438                         cb -= cbb * 0.999;
 439                 }
 440         }
 441
 442         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 443         if(ca < 1)
 444                 if(cb >= 1)
 445                         return true;
 446         if(ca >= 1)
 447                 if(cb < 1)
 448                         return false;
 449
 450         // first, normalize
 451         f = max(ca, cb, 1);
 452         ca /= f;
 453         cb /= f;
 454         f = max(sa, sb, 1);
 455         sa /= f;
 456         sb /= f;
 457
 458         // the more we're at the end of the match, the more take scores into account
 459         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 460         ca += (sa - ca) * f;
 461         cb += (sb - cb) * f;
 462
 463         return ca <= cb;
 464 }
 465
 466 // returns # of smallest team (1, 2, 3, 4)
 467 // NOTE: Assumes CheckAllowedTeams has already been called!
 468 float FindSmallestTeam(entity pl, float ignore_pl)
 469 {
 470         int totalteams = 0;
 471         int t = 1; // initialize with a random team?
 472         if(c4 >= 0) t = 4;
 473         if(c3 >= 0) t = 3;
 474         if(c2 >= 0) t = 2;
 475         if(c1 >= 0) t = 1;
 476
 477         // find out what teams are available
 478         //CheckAllowedTeams();
 479
 480         // make sure there are at least 2 teams to join
 481         if(c1 >= 0)
 482                 totalteams = totalteams + 1;
 483         if(c2 >= 0)
 484                 totalteams = totalteams + 1;
 485         if(c3 >= 0)
 486                 totalteams = totalteams + 1;
 487         if(c4 >= 0)
 488                 totalteams = totalteams + 1;
 489
 490         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 491                 totalteams += 1;
 492
 493         if(totalteams <= 1)
 494         {
 495                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 496                         return 1; // special case for campaign and player joining
 497                 else if(totalteams == 1) // single team
 498                         LOG_TRACEF("Only 1 team available for %s, you may need to fix your map", MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 499                 else // no teams, major no no
 500                         error(sprintf("No teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 501         }
 502
 503         // count how many players are in each team
 504         if(ignore_pl)
 505                 GetTeamCounts(pl);
 506         else
 507                 GetTeamCounts(NULL);
 508
 509         RandomSelection_Init();
 510
 511         if(TeamSmallerEqThanTeam(1, t, pl))
 512                 t = 1;
 513         if(TeamSmallerEqThanTeam(2, t, pl))
 514                 t = 2;
 515         if(TeamSmallerEqThanTeam(3, t, pl))
 516                 t = 3;
 517         if(TeamSmallerEqThanTeam(4, t, pl))
 518                 t = 4;
 519
 520         // now t is the minimum, or A minimum!
 521         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 522                 RandomSelection_AddFloat(1, 1, 1);
 523         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 524                 RandomSelection_AddFloat(2, 1, 1);
 525         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 526                 RandomSelection_AddFloat(3, 1, 1);
 527         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 528                 RandomSelection_AddFloat(4, 1, 1);
 529
 530         return RandomSelection_chosen_float;
 531 }
 532
 533 int JoinBestTeam(entity this, bool only_return_best, bool forcebestteam)
 534 {
 535         float smallest, selectedteam;
 536
 537         // don't join a team if we're not playing a team game
 538         if(!teamplay)
 539                 return 0;
 540
 541         // find out what teams are available
 542         CheckAllowedTeams(this);
 543
 544         // if we don't care what team he ends up on, put him on whatever team he entered as.
 545         // if he's not on a valid team, then let other code put him on the smallest team
 546         if(!forcebestteam)
 547         {
 548                 if(     c1 >= 0 && this.team == NUM_TEAM_1)
 549                         selectedteam = this.team;
 550                 else if(c2 >= 0 && this.team == NUM_TEAM_2)
 551                         selectedteam = this.team;
 552                 else if(c3 >= 0 && this.team == NUM_TEAM_3)
 553                         selectedteam = this.team;
 554                 else if(c4 >= 0 && this.team == NUM_TEAM_4)
 555                         selectedteam = this.team;
 556                 else
 557                         selectedteam = -1;
 558
 559                 if(selectedteam > 0)
 560                 {
 561                         if(!only_return_best)
 562                         {
 563                                 SetPlayerTeamSimple(this, selectedteam);
 564
 565                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 566                                 // when JoinBestTeam is called by client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 567                                 LogTeamchange(this.playerid, this.team, 99);
 568                         }
 569                         return selectedteam;
 570                 }
 571                 // otherwise end up on the smallest team (handled below)
 572         }
 573
 574         smallest = FindSmallestTeam(this, true);
 575
 576         if(!only_return_best && !this.bot_forced_team)
 577         {
 578                 smallest = Team_NumberToTeam(smallest);
 579                 if (smallest != -1)
 580                 {
 581                         TeamchangeFrags(this);
 582                         SetPlayerTeamSimple(this, smallest);
 583                 }
 584                 else
 585                 {
 586                         error("smallest team: invalid team\n");
 587                 }
 588
 589                 LogTeamchange(this.playerid, this.team, 2); // log auto join
 590
 591                 if(!IS_DEAD(this))
 592                         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
 593         }
 594
 595         return smallest;
 596 }
 597
 598 //void() ctf_playerchanged;
 599 void SV_ChangeTeam(entity this, float _color)
 600 {
 601         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 602
 603         // in normal deathmatch we can just apply the color and we're done
 604         if(!teamplay)
 605                 SetPlayerColors(this, _color);
 606
 607         if(!IS_CLIENT(this))
 608         {
 609                 // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 610                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 611                 return;
 612         }
 613
 614         if(!teamplay)
 615                 return;
 616
 617         scolor = this.clientcolors & 0x0F;
 618         dcolor = _color & 0x0F;
 619
 620         if(scolor == NUM_TEAM_1 - 1)
 621                 steam = 1;
 622         else if(scolor == NUM_TEAM_2 - 1)
 623                 steam = 2;
 624         else if(scolor == NUM_TEAM_3 - 1)
 625                 steam = 3;
 626         else // if(scolor == NUM_TEAM_4 - 1)
 627                 steam = 4;
 628         if(dcolor == NUM_TEAM_1 - 1)
 629                 dteam = 1;
 630         else if(dcolor == NUM_TEAM_2 - 1)
 631                 dteam = 2;
 632         else if(dcolor == NUM_TEAM_3 - 1)
 633                 dteam = 3;
 634         else // if(dcolor == NUM_TEAM_4 - 1)
 635                 dteam = 4;
 636
 637         CheckAllowedTeams(this);
 638
 639         if(dteam == 1 && c1 < 0) dteam = 4;
 640         if(dteam == 4 && c4 < 0) dteam = 3;
 641         if(dteam == 3 && c3 < 0) dteam = 2;
 642         if(dteam == 2 && c2 < 0) dteam = 1;
 643
 644         // not changing teams
 645         if(scolor == dcolor)
 646         {
 647                 SetPlayerTeam(this, dteam, steam, true);
 648                 return;
 649         }
 650
 651         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && this.wasplayer)) {
 652                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 653                 return; // changing teams is not allowed
 654         }
 655
 656         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 657         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 658         {
 659                 GetTeamCounts(this);
 660                 if(!TeamSmallerEqThanTeam(dteam, steam, this))
 661                 {
 662                         Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 663                         return;
 664                 }
 665         }
 666
 667 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 668
 669         if(IS_PLAYER(this) && steam != dteam)
 670         {
 671                 // reduce frags during a team change
 672                 TeamchangeFrags(this);
 673         }
 674
 675         SetPlayerTeam(this, dteam, steam, !IS_CLIENT(this));
 676
 677         if(IS_PLAYER(this) && steam != dteam)
 678         {
 679                 // kill player when changing teams
 680                 if(!IS_DEAD(this))
 681                         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
 682         }
 683 }
 684
 685 void ShufflePlayerOutOfTeam (float source_team)
 686 {
 687         float smallestteam, smallestteam_count, steam;
 688         float lowest_bot_score, lowest_player_score;
 689         entity lowest_bot, lowest_player, selected;
 690
 691         smallestteam = 0;
 692         smallestteam_count = 999999999;
 693
 694         if(c1 >= 0 && c1 < smallestteam_count)
 695         {
 696                 smallestteam = 1;
 697                 smallestteam_count = c1;
 698         }
 699         if(c2 >= 0 && c2 < smallestteam_count)
 700         {
 701                 smallestteam = 2;
 702                 smallestteam_count = c2;
 703         }
 704         if(c3 >= 0 && c3 < smallestteam_count)
 705         {
 706                 smallestteam = 3;
 707                 smallestteam_count = c3;
 708         }
 709         if(c4 >= 0 && c4 < smallestteam_count)
 710         {
 711                 smallestteam = 4;
 712                 smallestteam_count = c4;
 713         }
 714
 715         if(!smallestteam)
 716         {
 717                 bprint("warning: no smallest team\n");
 718                 return;
 719         }
 720
 721         if(source_team == 1)
 722                 steam = NUM_TEAM_1;
 723         else if(source_team == 2)
 724                 steam = NUM_TEAM_2;
 725         else if(source_team == 3)
 726                 steam = NUM_TEAM_3;
 727         else // if(source_team == 4)
 728                 steam = NUM_TEAM_4;
 729
 730         lowest_bot = NULL;
 731         lowest_bot_score = 999999999;
 732         lowest_player = NULL;
 733         lowest_player_score = 999999999;
 734
 735         // find the lowest-scoring player & bot of that team
 736         FOREACH_CLIENT(IS_PLAYER(it) && it.team == steam, LAMBDA(
 737                 if(it.isbot)
 738                 {
 739                         if(it.totalfrags < lowest_bot_score)
 740                         {
 741                                 lowest_bot = it;
 742                                 lowest_bot_score = it.totalfrags;
 743                         }
 744                 }
 745                 else
 746                 {
 747                         if(it.totalfrags < lowest_player_score)
 748                         {
 749                                 lowest_player = it;
 750                                 lowest_player_score = it.totalfrags;
 751                         }
 752                 }
 753         ));
 754
 755         // prefers to move a bot...
 756         if(lowest_bot != NULL)
 757                 selected = lowest_bot;
 758         // but it will move a player if it has to
 759         else
 760                 selected = lowest_player;
 761         // don't do anything if it couldn't find anyone
 762         if(!selected)
 763         {
 764                 bprint("warning: couldn't find a player to move from team\n");
 765                 return;
 766         }
 767
 768         // smallest team gains a member
 769         if(smallestteam == 1)
 770         {
 771                 c1 = c1 + 1;
 772         }
 773         else if(smallestteam == 2)
 774         {
 775                 c2 = c2 + 1;
 776         }
 777         else if(smallestteam == 3)
 778         {
 779                 c3 = c3 + 1;
 780         }
 781         else if(smallestteam == 4)
 782         {
 783                 c4 = c4 + 1;
 784         }
 785         else
 786         {
 787                 bprint("warning: destination team invalid\n");
 788                 return;
 789         }
 790         // source team loses a member
 791         if(source_team == 1)
 792         {
 793                 c1 = c1 + 1;
 794         }
 795         else if(source_team == 2)
 796         {
 797                 c2 = c2 + 2;
 798         }
 799         else if(source_team == 3)
 800         {
 801                 c3 = c3 + 3;
 802         }
 803         else if(source_team == 4)
 804         {
 805                 c4 = c4 + 4;
 806         }
 807         else
 808         {
 809                 bprint("warning: source team invalid\n");
 810                 return;
 811         }
 812
 813         // move the player to the new team
 814         TeamchangeFrags(selected);
 815         SetPlayerTeam(selected, smallestteam, source_team, false);
 816
 817         if(!IS_DEAD(selected))
 818                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE.m_id, selected.origin, '0 0 0');
 819         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
 820 }