qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(float player_id, float team_number, float type)
  76 {
  77         if(!cvar("sv_eventlog"))
  78                 return;
  79
  80         if(player_id < 1)
  81                 return;
  82
  83         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  84 }
  85
  86 void WriteGameCvars()
  87 {
  88         cvar_set("g_dm", ftos(g_dm));
  89         cvar_set("g_tdm", ftos(g_tdm));
  90         cvar_set("g_domination", ftos(g_domination));
  91         cvar_set("g_ctf", ftos(g_ctf));
  92         cvar_set("g_runematch", ftos(g_runematch));
  93         cvar_set("g_lms", ftos(g_lms));
  94         cvar_set("g_arena", ftos(g_arena));
  95         cvar_set("g_ca", ftos(g_ca));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101         cvar_set("g_cts", ftos(g_cts));
 102 }
 103
 104 void ReadGameCvars()
 105 {
 106         float found;
 107         float prev;
 108         float i;
 109
 110         found = 0;
 111         prev = cvar("gamecfg");
 112         for(i = 0; i < 2; ++i)
 113         {
 114                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 115                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 116                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 117                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 118                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 119                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 120                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 121                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 122                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 123                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 124                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 125                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 126                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 127                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 128
 129                 if(found)
 130                         break;
 131
 132                 prev = -1; // second attempt takes place WITHOUT prev set
 133         }
 134
 135         if(!found)
 136                 g_dm = 1;
 137
 138         if(g_dm && cvar("deathmatch_force_teamplay"))
 139         {
 140                 g_dm = 0;
 141                 g_tdm = 1;
 142         }
 143
 144         teams_matter = 0;
 145 }
 146
 147 void default_delayedinit()
 148 {
 149         if(!scores_initialized)
 150                 ScoreRules_generic();
 151 }
 152
 153 void ActivateTeamplay()
 154 {
 155         float teamplay_default;
 156         teamplay_default = cvar("teamplay_default");
 157
 158         if(teamplay_default)
 159                 teamplay = teamplay_default;
 160         else
 161                 teamplay = 3;
 162         cvar_set("teamplay", ftos(teamplay));
 163
 164         teams_matter = 1;
 165 }
 166
 167 void InitGameplayMode()
 168 {
 169         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 170
 171         qualifying_override = -1;
 172
 173         VoteReset();
 174
 175         teams_matter = 0;
 176         cvar_set("teamplay", "0");
 177
 178         // make sure only ONE type is selected
 179         ReadGameCvars();
 180         WriteGameCvars();
 181
 182         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 183         get_mi_min_max(1);
 184         world.mins = mi_min;
 185         world.maxs = mi_max;
 186
 187         MapInfo_LoadMapSettings(mapname);
 188
 189         if not(cvar_value_issafe(world.fog))
 190         {
 191                 print("The current map contains a potentially harmful fog setting, ignored\n");
 192                 world.fog = string_null;
 193         }
 194         if(MapInfo_Map_fog != "")
 195                 if(MapInfo_Map_fog == "none")
 196                         world.fog = string_null;
 197                 else
 198                         world.fog = strzone(MapInfo_Map_fog);
 199         clientstuff = strzone(MapInfo_Map_clientstuff);
 200
 201         MapInfo_ClearTemps();
 202
 203         // in case mapinfo switched the type
 204         ReadGameCvars();
 205
 206         // set both here, gamemode can override it later
 207         timelimit_override = cvar("timelimit_override");
 208         fraglimit_override = cvar("fraglimit_override");
 209         leadlimit_override = cvar("leadlimit_override");
 210
 211         if(cvar("g_dodging"))
 212                 MUTATOR_ADD(dodging);
 213
 214         if(g_dm)
 215         {
 216                 game = GAME_DEATHMATCH;
 217                 gamemode_name = "Deathmatch";
 218         }
 219
 220         if(g_tdm)
 221         {
 222                 game = GAME_TEAM_DEATHMATCH;
 223                 gamemode_name = "Team Deathmatch";
 224                 ActivateTeamplay();
 225                 tdm_init();
 226                 if(cvar("g_tdm_team_spawns"))
 227                         have_team_spawns = -1; // request team spawns
 228         }
 229
 230         if(g_domination)
 231         {
 232                 game = GAME_DOMINATION;
 233                 gamemode_name = "Domination";
 234                 ActivateTeamplay();
 235                 fraglimit_override = cvar("g_domination_point_limit");
 236                 leadlimit_override = cvar("g_domination_point_leadlimit");
 237                 dom_init();
 238                 have_team_spawns = -1; // request team spawns
 239         }
 240
 241         if(g_ctf)
 242         {
 243                 game = GAME_CTF;
 244                 gamemode_name = "Capture the Flag";
 245                 ActivateTeamplay();
 246                 if(cvar("g_campaign"))
 247                         g_ctf_win_mode = 2;
 248                 else
 249                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 250                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 251                 if(g_ctf_win_mode == 2)
 252                 {
 253                         fraglimit_override = cvar("g_ctf_capture_limit");
 254                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 255                 }
 256                 else
 257                 {
 258                         fraglimit_override = cvar("capturelimit_override");
 259                         leadlimit_override = cvar("captureleadlimit_override");
 260                 }
 261                 ctf_init();
 262                 have_team_spawns = -1; // request team spawns
 263         }
 264
 265         if(g_runematch)
 266         {
 267                 game = GAME_RUNEMATCH;
 268                 gamemode_name = "Rune Match";
 269                 if(cvar("deathmatch_force_teamplay"))
 270                         ActivateTeamplay();
 271                 fraglimit_override = cvar("g_runematch_point_limit");
 272                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 273                 runematch_init();
 274         }
 275
 276         if(g_lms)
 277         {
 278                 game = GAME_LMS;
 279                 gamemode_name = "Last Man Standing";
 280                 fraglimit_override = cvar("g_lms_lives_override");
 281                 leadlimit_override = 0; // not supported by LMS
 282                 if(fraglimit_override == 0)
 283                         fraglimit_override = -1;
 284                 lms_lowest_lives = 9999;
 285                 lms_next_place = 0;
 286                 ScoreRules_lms();
 287         }
 288
 289         if(g_arena)
 290         {
 291                 game = GAME_ARENA;
 292                 gamemode_name = "Arena";
 293                 fraglimit_override = cvar("g_arena_point_limit");
 294                 leadlimit_override = cvar("g_arena_point_leadlimit");
 295                 maxspawned = cvar("g_arena_maxspawned");
 296                 if(maxspawned < 2)
 297                         maxspawned = 2;
 298                 arena_roundbased = cvar("g_arena_roundbased");
 299         }
 300
 301         if(g_ca)
 302         {
 303                 game = GAME_CA;
 304                 gamemode_name = "Clan Arena";
 305                 ActivateTeamplay();
 306                 fraglimit_override = cvar("g_ca_point_limit");
 307                 leadlimit_override = cvar("g_ca_point_leadlimit");
 308                 precache_sound("ctf/red_capture.wav");
 309                 precache_sound("ctf/blue_capture.wav");
 310         }
 311         if(g_keyhunt)
 312         {
 313                 game = GAME_KEYHUNT;
 314                 gamemode_name = "Key Hunt";
 315                 ActivateTeamplay();
 316                 fraglimit_override = cvar("g_keyhunt_point_limit");
 317                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 318                 MUTATOR_ADD(gamemode_keyhunt);
 319         }
 320
 321         if(g_assault)
 322         {
 323                 game = GAME_ASSAULT;
 324                 gamemode_name = "Assault";
 325                 ActivateTeamplay();
 326                 ScoreRules_assault();
 327                 have_team_spawns = -1; // request team spawns
 328         }
 329
 330         if(g_onslaught)
 331         {
 332                 game = GAME_ONSLAUGHT;
 333                 gamemode_name = "Onslaught";
 334                 ActivateTeamplay();
 335                 have_team_spawns = -1; // request team spawns
 336         }
 337
 338         if(g_race)
 339         {
 340                 game = GAME_RACE;
 341                 gamemode_name = "Race";
 342
 343                 if(cvar("g_race_teams"))
 344                 {
 345                         ActivateTeamplay();
 346                         race_teams = bound(2, cvar("g_race_teams"), 4);
 347                         have_team_spawns = -1; // request team spawns
 348                 }
 349                 else
 350                         race_teams = 0;
 351
 352                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 353                 fraglimit_override = cvar("g_race_laps_limit");
 354                 leadlimit_override = 0; // currently not supported by race
 355         }
 356
 357         if(g_cts)
 358         {
 359                 game = GAME_CTS;
 360                 gamemode_name = "CTS";
 361                 g_race_qualifying = 1;
 362                 fraglimit_override = 0;
 363                 leadlimit_override = 0;
 364         }
 365
 366         if(g_nexball)
 367         {
 368                 game = GAME_NEXBALL;
 369                 gamemode_name = "Nexball";
 370                 fraglimit_override = cvar("g_nexball_goallimit");
 371                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 372                 ActivateTeamplay();
 373                 nb_init();
 374                 have_team_spawns = -1; // request team spawns
 375         }
 376
 377         if(teams_matter)
 378                 entcs_init();
 379
 380         // save it (for the next startup)
 381         cvar_set("gamecfg", ftos(game));
 382
 383         cache_mutatormsg = strzone("");
 384         cache_lastmutatormsg = strzone("");
 385
 386         // enforce the server's universal frag/time limits
 387         if(!cvar("g_campaign"))
 388         {
 389                 if(fraglimit_override >= 0)
 390                         cvar_set("fraglimit", ftos(fraglimit_override));
 391                 if(timelimit_override >= 0)
 392                         cvar_set("timelimit", ftos(timelimit_override));
 393                 if(leadlimit_override >= 0)
 394                         cvar_set("leadlimit", ftos(leadlimit_override));
 395                 if(qualifying_override >= 0)
 396                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 397         }
 398
 399         if(g_race)
 400         {
 401                 // we need to find out the correct value for g_race_qualifying
 402                 if(cvar("g_campaign"))
 403                 {
 404                         g_race_qualifying = 1;
 405                 }
 406                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 407                 {
 408                         g_race_qualifying = 2;
 409                         race_fraglimit = cvar("fraglimit");
 410                         race_leadlimit = cvar("leadlimit");
 411                         race_timelimit = cvar("timelimit");
 412                         cvar_set("fraglimit", "0");
 413                         cvar_set("leadlimit", "0");
 414                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 415                 }
 416                 else
 417                         g_race_qualifying = 0;
 418         }
 419
 420         if(g_race || g_cts)
 421         {
 422                 if(g_race_qualifying)
 423                         independent_players = 1;
 424
 425                 ScoreRules_race();
 426         }
 427
 428         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 429 }
 430
 431 string GetClientVersionMessage() {
 432         local string versionmsg;
 433         if (self.version_mismatch) {
 434                 if(self.version < cvar("gameversion")) {
 435                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 436                 } else {
 437                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 438                 }
 439         } else {
 440                 versionmsg = "^2client version and server version are compatible.^8";
 441         }
 442         return versionmsg;
 443 }
 444
 445
 446 void PrintWelcomeMessage(entity pl)
 447 {
 448         string s, modifications, motd;
 449
 450         if(self.cvar_scr_centertime == 0) return;
 451
 452         if(cvar("g_campaign"))
 453         {
 454                 if(self.classname == "player" && !self.BUTTON_INFO)
 455                         return;
 456         }
 457         else
 458         {
 459                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 460                         return;
 461         }
 462
 463         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 464                 if(self.welcomemessage_time > time) return;
 465                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 466         }
 467
 468         if(cvar("g_campaign"))
 469         {
 470                 centerprint(pl, campaign_message);
 471                 return;
 472         }
 473
 474 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 475         if(!self.BUTTON_INFO)
 476         {
 477                 // TODO get rid of this too
 478                 local string specString;
 479                 specString = NEWLINES;
 480                 //if(time < game_starttime) //also show the countdown when being a spectator
 481                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 482                 //else
 483                 if (timeoutStatus != 0)
 484                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 485                 else
 486                 {
 487                         if(self.classname == "player")
 488                                 return;
 489                         goto normal;
 490                 }
 491                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 492         }
 493
 494 :normal
 495         ret_string = "";
 496         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 497         modifications = ret_string;
 498
 499         if(g_minstagib)
 500                 modifications = strcat(modifications, ", MinstaGib");
 501         if(g_weaponarena)
 502         {
 503                 if(g_weaponarena_random)
 504                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 505                 else
 506                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 507         }
 508         if(cvar("g_start_weapon_laser") == 0)
 509                 modifications = strcat(modifications, ", No start weapons");
 510         if(cvar("sv_gravity") < 800)
 511                 modifications = strcat(modifications, ", Low gravity");
 512         if(g_cloaked)
 513                 modifications = strcat(modifications, ", Cloaked");
 514         if(g_footsteps)
 515                 modifications = strcat(modifications, ", Steps");
 516         if(g_grappling_hook)
 517                 modifications = strcat(modifications, ", Hook");
 518         if(g_laserguided_missile)
 519                 modifications = strcat(modifications, ", LG missiles");
 520         if(g_midair)
 521                 modifications = strcat(modifications, ", Midair");
 522         if(g_vampire)
 523                 modifications = strcat(modifications, ", Vampire");
 524         if(g_pinata)
 525                 modifications = strcat(modifications, ", Pinata");
 526         if(g_weapon_stay)
 527                 modifications = strcat(modifications, ", Weapons stay");
 528         if(g_bloodloss > 0)
 529                 modifications = strcat(modifications, ", Bloodloss");
 530         if(g_jetpack)
 531                 modifications = strcat(modifications, ", Jet pack");
 532         modifications = substring(modifications, 2, strlen(modifications) - 2);
 533
 534         local string versionmessage;
 535         versionmessage = GetClientVersionMessage();
 536
 537         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
 538         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 539
 540         if(modifications != "")
 541                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 542
 543         if(timeoutStatus != 0)
 544                 s = strcat(s, "\n\n", getTimeoutText(1));
 545
 546         if (g_grappling_hook)
 547                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 548
 549         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 550         {
 551                 if(cache_lastmutatormsg)
 552                         strunzone(cache_lastmutatormsg);
 553                 if(cache_mutatormsg)
 554                         strunzone(cache_mutatormsg);
 555                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 556                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 557         }
 558
 559         if (cache_mutatormsg != "") {
 560                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 561         }
 562
 563         motd = cvar_string("sv_motd");
 564         if (motd != "") {
 565                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 566         }
 567         s = strcat(s, "\n");
 568
 569         centerprint(pl, s);
 570 }
 571
 572
 573 void SetPlayerColors(entity pl, float _color)
 574 {
 575         /*string s;
 576         s = ftos(cl);
 577         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 578         pl.team = cl + 1;
 579         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 580         pl.clientcolors = 16*cl + cl;*/
 581
 582         float pants, shirt;
 583         pants = _color & 0x0F;
 584         shirt = _color & 0xF0;
 585
 586
 587         if(teams_matter) {
 588                 setcolor(pl, 16*pants + pants);
 589         } else {
 590                 setcolor(pl, shirt + pants);
 591         }
 592 }
 593
 594 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 595 {
 596         float _color;
 597
 598         if(t == 4)
 599                 _color = COLOR_TEAM4 - 1;
 600         else if(t == 3)
 601                 _color = COLOR_TEAM3 - 1;
 602         else if(t == 2)
 603                 _color = COLOR_TEAM2 - 1;
 604         else
 605                 _color = COLOR_TEAM1 - 1;
 606
 607         SetPlayerColors(pl,_color);
 608
 609         if(t != s) {
 610                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 611
 612                 if(!noprint)
 613                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 614         }
 615
 616 }
 617
 618 // set c1...c4 to show what teams are allowed
 619 void CheckAllowedTeams (entity for_whom)
 620 {
 621         float dm;
 622         entity head;
 623         string teament_name;
 624
 625         c1 = c2 = c3 = c4 = -1;
 626         cb1 = cb2 = cb3 = cb4 = 0;
 627
 628         if(g_onslaught)
 629         {
 630                 // onslaught is special
 631                 head = findchain(classname, "onslaught_generator");
 632                 while (head)
 633                 {
 634                         if (head.team == COLOR_TEAM1) c1 = 0;
 635                         if (head.team == COLOR_TEAM2) c2 = 0;
 636                         if (head.team == COLOR_TEAM3) c3 = 0;
 637                         if (head.team == COLOR_TEAM4) c4 = 0;
 638                         head = head.chain;
 639                 }
 640         }
 641         else if(g_domination)
 642                 teament_name = "dom_team";
 643         else if(g_ctf)
 644                 teament_name = "ctf_team";
 645         else if(g_tdm)
 646                 teament_name = "tdm_team";
 647         else if(g_nexball)
 648                 teament_name = "nexball_team";
 649         else if(g_assault)
 650                 c1 = c2 = 0; // Assault always has 2 teams
 651         else
 652         {
 653                 // cover anything else by treating it like tdm with no teams spawned
 654                 if(g_race)
 655                         dm = race_teams;
 656                 else
 657                         dm = 2;
 658
 659                 ret_float = dm;
 660                 MUTATOR_CALLHOOK(GetTeamCount);
 661                 dm = ret_float;
 662
 663                 if(dm >= 4)
 664                         c1 = c2 = c3 = c4 = 0;
 665                 else if(dm >= 3)
 666                         c1 = c2 = c3 = 0;
 667                 else
 668                         c1 = c2 = 0;
 669         }
 670
 671         // find out what teams are allowed if necessary
 672         if(teament_name)
 673         {
 674                 head = find(world, classname, teament_name);
 675                 while(head)
 676                 {
 677                         if(!(g_domination && head.netname == ""))
 678                         {
 679                                 if(head.team == COLOR_TEAM1)
 680                                         c1 = 0;
 681                                 else if(head.team == COLOR_TEAM2)
 682                                         c2 = 0;
 683                                 else if(head.team == COLOR_TEAM3)
 684                                         c3 = 0;
 685                                 else if(head.team == COLOR_TEAM4)
 686                                         c4 = 0;
 687                         }
 688                         head = find(head, classname, teament_name);
 689                 }
 690         }
 691
 692         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 693         if(c3==-1&&c4==-1)
 694         if(cvar("bot_vs_human") && for_whom)
 695         {
 696                 if(cvar("bot_vs_human") > 0)
 697                 {
 698                         // bots are all blue
 699                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 700                                 c1 = c3 = c4 = -1;
 701                         else
 702                                 c2 = -1;
 703                 }
 704                 else
 705                 {
 706                         // bots are all red
 707                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 708                                 c2 = c3 = c4 = -1;
 709                         else
 710                                 c1 = -1;
 711                 }
 712         }
 713 }
 714
 715 float PlayerValue(entity p)
 716 {
 717         if(IsTeamBalanceForced() == 1)
 718                 return 1;
 719         return 1;
 720 }
 721
 722 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 723 // teams that are allowed will now have their player counts stored in c1...c4
 724 void GetTeamCounts(entity ignore)
 725 {
 726         entity head;
 727         float value, bvalue;
 728         // now count how many players are on each team already
 729
 730         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 731         // also remember the lowest-scoring player
 732
 733         FOR_EACH_PLAYER(head)
 734         {
 735                 if(head != ignore)// && head.netname != "")
 736                 {
 737                         value = PlayerValue(head);
 738                         if(clienttype(head) == CLIENTTYPE_BOT)
 739                                 bvalue = value;
 740                         else
 741                                 bvalue = 0;
 742                         if(head.team == COLOR_TEAM1)
 743                         {
 744                                 if(c1 >= 0)
 745                                 {
 746                                         c1 = c1 + value;
 747                                         cb1 = cb1 + bvalue;
 748                                 }
 749                         }
 750                         if(head.team == COLOR_TEAM2)
 751                         {
 752                                 if(c2 >= 0)
 753                                 {
 754                                         c2 = c2 + value;
 755                                         cb2 = cb2 + bvalue;
 756                                 }
 757                         }
 758                         if(head.team == COLOR_TEAM3)
 759                         {
 760                                 if(c3 >= 0)
 761                                 {
 762                                         c3 = c3 + value;
 763                                         cb3 = cb3 + bvalue;
 764                                 }
 765                         }
 766                         if(head.team == COLOR_TEAM4)
 767                         {
 768                                 if(c4 >= 0)
 769                                 {
 770                                         c4 = c4 + value;
 771                                         cb4 = cb4 + bvalue;
 772                                 }
 773                         }
 774                 }
 775         }
 776 }
 777
 778 // returns # of smallest team (1, 2, 3, 4)
 779 // NOTE: Assumes CheckAllowedTeams has already been called!
 780 float FindSmallestTeam(entity pl, float ignore_pl)
 781 {
 782         float totalteams, balance_type, maxc;
 783         totalteams = 0;
 784
 785         // find out what teams are available
 786         //CheckAllowedTeams();
 787
 788         // make sure there are at least 2 teams to join
 789         if(c1 >= 0)
 790                 totalteams = totalteams + 1;
 791         if(c2 >= 0)
 792                 totalteams = totalteams + 1;
 793         if(c3 >= 0)
 794                 totalteams = totalteams + 1;
 795         if(c4 >= 0)
 796                 totalteams = totalteams + 1;
 797
 798         if(cvar("bot_vs_human"))
 799                 totalteams += 1;
 800
 801         if(totalteams <= 1)
 802         {
 803                 if(g_domination)
 804                         error("Too few teams available for domination\n");
 805                 else if(g_ctf)
 806                         error("Too few teams available for ctf\n");
 807                 else if(g_keyhunt)
 808                         error("Too few teams available for key hunt\n");
 809                 else
 810                         error("Too few teams available for team deathmatch\n");
 811         }
 812
 813         // count how many players are in each team
 814         if(ignore_pl)
 815                 GetTeamCounts(pl);
 816         else
 817                 GetTeamCounts(world);
 818
 819         // c1...c4 now have counts of each team
 820         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 821
 822         // 2 gives priority to what team you're already on, 1 goes in order
 823         // 2 doesn't seem to work though...
 824         balance_type = 1;
 825
 826         if(bots_would_leave)
 827         //if(pl.classname != "player")
 828         if(clienttype(pl) != CLIENTTYPE_BOT)
 829         {
 830                 c1 -= cb1 * 255.0/256.0;
 831                 c2 -= cb2 * 255.0/256.0;
 832                 c3 -= cb3 * 255.0/256.0;
 833                 c4 -= cb4 * 255.0/256.0;
 834         }
 835         maxc = max4(c1, c2, c3, c4);
 836
 837         RandomSelection_Init();
 838         if(balance_type == 1)
 839         {
 840                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 841                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 842                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 843                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 844                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 845         }
 846         else if(balance_type == 2)
 847         {
 848                 // 1: use team count, if equal prefer own team
 849                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 850                 if(c2 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 851                 if(c3 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 852                 if(c4 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 853         }
 854         else if(balance_type == 3)
 855         {
 856                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 857                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 858                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 859                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 860                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 861         }
 862         return RandomSelection_chosen_float;
 863 }
 864
 865 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 866 {
 867         float smallest, selectedteam;
 868
 869         // don't join a team if we're not playing a team game
 870         if(!teams_matter)
 871                 return 0;
 872
 873         // find out what teams are available
 874         CheckAllowedTeams(pl);
 875
 876         // if we don't care what team he ends up on, put him on whatever team he entered as.
 877         // if he's not on a valid team, then let other code put him on the smallest team
 878         if(!forcebestteam)
 879         {
 880                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 881                         selectedteam = pl.team;
 882                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 883                         selectedteam = pl.team;
 884                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 885                         selectedteam = pl.team;
 886                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 887                         selectedteam = pl.team;
 888                 else
 889                         selectedteam = -1;
 890
 891                 if(selectedteam > 0)
 892                 {
 893                         if(!only_return_best)
 894                         {
 895                                 SetPlayerColors(pl, selectedteam - 1);
 896
 897                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 898                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 899                                 LogTeamchange(pl.playerid, pl.team, 99);
 900                         }
 901                         return selectedteam;
 902                 }
 903                 // otherwise end up on the smallest team (handled below)
 904         }
 905
 906         smallest = FindSmallestTeam(pl, TRUE);
 907
 908         if(!only_return_best)
 909         {
 910                 TeamchangeFrags(self);
 911                 if(smallest == 1)
 912                 {
 913                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 914                 }
 915                 else if(smallest == 2)
 916                 {
 917                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 918                 }
 919                 else if(smallest == 3)
 920                 {
 921                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 922                 }
 923                 else if(smallest == 4)
 924                 {
 925                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 926                 }
 927                 else
 928                 {
 929                         error("smallest team: invalid team\n");
 930                 }
 931
 932                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 933
 934                 if(pl.deadflag == DEAD_NO)
 935                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 936         }
 937
 938         return smallest;
 939 }
 940
 941 //void() ctf_playerchanged;
 942 void SV_ChangeTeam(float _color)
 943 {
 944         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 945
 946         // in normal deathmatch we can just apply the color and we're done
 947         if(!teams_matter) {
 948                 SetPlayerColors(self, _color);
 949                 return;
 950         }
 951
 952         scolor = self.clientcolors & 0x0F;
 953         dcolor = _color & 0x0F;
 954
 955         if(scolor == COLOR_TEAM1 - 1)
 956                 steam = 1;
 957         else if(scolor == COLOR_TEAM2 - 1)
 958                 steam = 2;
 959         else if(scolor == COLOR_TEAM3 - 1)
 960                 steam = 3;
 961         else // if(scolor == COLOR_TEAM4 - 1)
 962                 steam = 4;
 963         if(dcolor == COLOR_TEAM1 - 1)
 964                 dteam = 1;
 965         else if(dcolor == COLOR_TEAM2 - 1)
 966                 dteam = 2;
 967         else if(dcolor == COLOR_TEAM3 - 1)
 968                 dteam = 3;
 969         else // if(dcolor == COLOR_TEAM4 - 1)
 970                 dteam = 4;
 971
 972         CheckAllowedTeams(self);
 973
 974         if(dteam == 1 && c1 < 0) dteam = 4;
 975         if(dteam == 4 && c4 < 0) dteam = 3;
 976         if(dteam == 3 && c3 < 0) dteam = 2;
 977         if(dteam == 2 && c2 < 0) dteam = 1;
 978
 979         // not changing teams
 980         if(scolor == dcolor)
 981         {
 982                 //bprint("same team change\n");
 983                 SetPlayerTeam(self, dteam, steam, TRUE);
 984                 return;
 985         }
 986
 987         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
 988                 sprint(self, "Team changes not allowed\n");
 989                 return; // changing teams is not allowed
 990         }
 991
 992         if(cvar("g_balance_teams_prevent_imbalance"))
 993         {
 994                 // only allow changing to a smaller or equal size team
 995
 996                 // find out what teams are available
 997                 //CheckAllowedTeams();
 998                 // count how many players on each team
 999                 GetTeamCounts(world);
1000
1001                 // get desired team
1002                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1003                 {
1004                         dcount = c1;
1005                         dbotcount = cb1;
1006                 }
1007                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1008                 {
1009                         dcount = c2;
1010                         dbotcount = cb2;
1011                 }
1012                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1013                 {
1014                         dcount = c3;
1015                         dbotcount = cb3;
1016                 }
1017                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1018                 {
1019                         dcount = c4;
1020                         dbotcount = cb4;
1021                 }
1022                 else
1023                 {
1024                         sprint(self, "Cannot change to an invalid team\n");
1025
1026                         return;
1027                 }
1028
1029                 // get starting team
1030                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1031                         scount = c1;
1032                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1033                         scount = c2;
1034                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1035                         scount = c3;
1036                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1037                         scount = c4;
1038
1039                 if(scount) // started at a valid, nonempty team
1040                 {
1041                         // check if we're trying to change to a larger team that doens't have bots to swap with
1042                         if(dcount >= scount && dbotcount <= 0)
1043                         {
1044                                 sprint(self, "Cannot change to a larger team\n");
1045                                 return; // can't change to a larger team
1046                         }
1047                 }
1048         }
1049
1050 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1051
1052         if(self.classname == "player" && steam != dteam)
1053         {
1054                 // reduce frags during a team change
1055                 TeamchangeFrags(self);
1056         }
1057
1058         SetPlayerTeam(self, dteam, steam, FALSE);
1059
1060         if(self.classname == "player" && steam != dteam)
1061         {
1062                 // kill player when changing teams
1063                 if(self.deadflag == DEAD_NO)
1064                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1065         }
1066         //ctf_playerchanged();
1067 }
1068
1069 void ShufflePlayerOutOfTeam (float source_team)
1070 {
1071         float smallestteam, smallestteam_count, steam;
1072         float lowest_bot_score, lowest_player_score;
1073         entity head, lowest_bot, lowest_player, selected;
1074
1075         smallestteam = 0;
1076         smallestteam_count = 999999999;
1077
1078         if(c1 >= 0 && c1 < smallestteam_count)
1079         {
1080                 smallestteam = 1;
1081                 smallestteam_count = c1;
1082         }
1083         if(c2 >= 0 && c2 < smallestteam_count)
1084         {
1085                 smallestteam = 2;
1086                 smallestteam_count = c2;
1087         }
1088         if(c3 >= 0 && c3 < smallestteam_count)
1089         {
1090                 smallestteam = 3;
1091                 smallestteam_count = c3;
1092         }
1093         if(c4 >= 0 && c4 < smallestteam_count)
1094         {
1095                 smallestteam = 4;
1096                 smallestteam_count = c4;
1097         }
1098
1099         if(!smallestteam)
1100         {
1101                 bprint("warning: no smallest team\n");
1102                 return;
1103         }
1104
1105         if(source_team == 1)
1106                 steam = COLOR_TEAM1;
1107         else if(source_team == 2)
1108                 steam = COLOR_TEAM2;
1109         else if(source_team == 3)
1110                 steam = COLOR_TEAM3;
1111         else if(source_team == 4)
1112                 steam = COLOR_TEAM4;
1113
1114         lowest_bot = world;
1115         lowest_bot_score = 999999999;
1116         lowest_player = world;
1117         lowest_player_score = 999999999;
1118
1119         // find the lowest-scoring player & bot of that team
1120         FOR_EACH_PLAYER(head)
1121         {
1122                 if(head.team == steam)
1123                 {
1124                         if(head.isbot)
1125                         {
1126                                 if(head.totalfrags < lowest_bot_score)
1127                                 {
1128                                         lowest_bot = head;
1129                                         lowest_bot_score = head.totalfrags;
1130                                 }
1131                         }
1132                         else
1133                         {
1134                                 if(head.totalfrags < lowest_player_score)
1135                                 {
1136                                         lowest_player = head;
1137                                         lowest_player_score = head.totalfrags;
1138                                 }
1139                         }
1140                 }
1141         }
1142
1143         // prefers to move a bot...
1144         if(lowest_bot != world)
1145                 selected = lowest_bot;
1146         // but it will move a player if it has to
1147         else
1148                 selected = lowest_player;
1149         // don't do anything if it couldn't find anyone
1150         if(!selected)
1151         {
1152                 bprint("warning: couldn't find a player to move from team\n");
1153                 return;
1154         }
1155
1156         // smallest team gains a member
1157         if(smallestteam == 1)
1158         {
1159                 c1 = c1 + 1;
1160         }
1161         else if(smallestteam == 2)
1162         {
1163                 c2 = c2 + 1;
1164         }
1165         else if(smallestteam == 3)
1166         {
1167                 c3 = c3 + 1;
1168         }
1169         else if(smallestteam == 4)
1170         {
1171                 c4 = c4 + 1;
1172         }
1173         else
1174         {
1175                 bprint("warning: destination team invalid\n");
1176                 return;
1177         }
1178         // source team loses a member
1179         if(source_team == 1)
1180         {
1181                 c1 = c1 + 1;
1182         }
1183         else if(source_team == 2)
1184         {
1185                 c2 = c2 + 2;
1186         }
1187         else if(source_team == 3)
1188         {
1189                 c3 = c3 + 3;
1190         }
1191         else if(source_team == 4)
1192         {
1193                 c4 = c4 + 4;
1194         }
1195         else
1196         {
1197                 bprint("warning: source team invalid\n");
1198                 return;
1199         }
1200
1201         // move the player to the new team
1202         TeamchangeFrags(selected);
1203         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1204
1205         if(selected.deadflag == DEAD_NO)
1206                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1207         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1208 }
1209
1210 void CauseRebalance(float source_team, float howmany_toomany)
1211 {
1212         if(IsTeamBalanceForced() == 1)
1213         {
1214                 bprint("Rebalancing Teams\n");
1215                 ShufflePlayerOutOfTeam(source_team);
1216         }
1217 }
1218
1219 // part of g_balance_teams_force
1220 // occasionally perform an audit of the teams to make
1221 // sure they're more or less balanced in player count.
1222 void AuditTeams()
1223 {
1224         float numplayers, numteams, smallest, toomany;
1225         float balance;
1226         balance = IsTeamBalanceForced();
1227         if(balance == 0)
1228                 return;
1229
1230         if(audit_teams_time > time)
1231                 return;
1232
1233         audit_teams_time = time + 4 + random();
1234
1235 //      bprint("Auditing teams\n");
1236
1237         CheckAllowedTeams(world);
1238         GetTeamCounts(world);
1239
1240
1241         numteams = numplayers = smallest = 0;
1242         if(c1 >= 0)
1243         {
1244                 numteams = numteams + 1;
1245                 numplayers = numplayers + c1;
1246                 smallest = c1;
1247         }
1248         if(c2 >= 0)
1249         {
1250                 numteams = numteams + 1;
1251                 numplayers = numplayers + c2;
1252                 if(c2 < smallest)
1253                         smallest = c2;
1254         }
1255         if(c3 >= 0)
1256         {
1257                 numteams = numteams + 1;
1258                 numplayers = numplayers + c3;
1259                 if(c3 < smallest)
1260                         smallest = c3;
1261         }
1262         if(c4 >= 0)
1263         {
1264                 numteams = numteams + 1;
1265                 numplayers = numplayers + c4;
1266                 if(c4 < smallest)
1267                         smallest = c4;
1268         }
1269
1270         if(numplayers <= 0)
1271                 return; // no players to move around
1272         if(numteams < 2)
1273                 return; // don't bother shuffling if for some reason there aren't any teams
1274
1275         toomany = smallest + 1;
1276
1277         if(c1 && c1 > toomany)
1278                 CauseRebalance(1, c1 - toomany);
1279         if(c2 && c2 > toomany)
1280                 CauseRebalance(2, c2 - toomany);
1281         if(c3 && c3 > toomany)
1282                 CauseRebalance(3, c3 - toomany);
1283         if(c4 && c4 > toomany)
1284                 CauseRebalance(4, c4 - toomany);
1285
1286         // if teams are still unbalanced, balance them further in the next audit,
1287         // which will happen sooner (keep doing rapid audits until things are in order)
1288         audit_teams_time = time + 0.7 + random()*0.3;
1289 }
1290
1291 // code from here on is just to support maps that don't have team entities
1292 void tdm_spawnteam (string teamname, float teamcolor)
1293 {
1294         local entity e;
1295         e = spawn();
1296         e.classname = "tdm_team";
1297         e.netname = teamname;
1298         e.cnt = teamcolor;
1299         e.team = e.cnt + 1;
1300 };
1301
1302 // spawn some default teams if the map is not set up for tdm
1303 void tdm_spawnteams()
1304 {
1305         float numteams;
1306
1307         numteams = cvar("g_tdm_teams_override");
1308         if(numteams < 2)
1309                 numteams = cvar("g_tdm_teams");
1310         numteams = bound(2, numteams, 4);
1311
1312         tdm_spawnteam("Red", COLOR_TEAM1-1);
1313         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1314         if(numteams >= 3)
1315                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1316         if(numteams >= 4)
1317                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1318 };
1319
1320 void tdm_delayedinit()
1321 {
1322         // if no teams are found, spawn defaults
1323         if (find(world, classname, "tdm_team") == world)
1324                 tdm_spawnteams();
1325 };
1326
1327 void tdm_init()
1328 {
1329         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1330 };