qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(float player_id, float team_number, float type)
  76 {
  77         if(!cvar("sv_eventlog"))
  78                 return;
  79
  80         if(player_id < 1)
  81                 return;
  82
  83         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  84 }
  85
  86 void WriteGameCvars()
  87 {
  88         cvar_set("g_dm", ftos(g_dm));
  89         cvar_set("g_tdm", ftos(g_tdm));
  90         cvar_set("g_domination", ftos(g_domination));
  91         cvar_set("g_ctf", ftos(g_ctf));
  92         cvar_set("g_runematch", ftos(g_runematch));
  93         cvar_set("g_lms", ftos(g_lms));
  94         cvar_set("g_arena", ftos(g_arena));
  95         cvar_set("g_ca", ftos(g_ca));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101         cvar_set("g_cts", ftos(g_cts));
 102 }
 103
 104 void ReadGameCvars()
 105 {
 106         float found;
 107         float prev;
 108         float i;
 109
 110         found = 0;
 111         prev = cvar("gamecfg");
 112         for(i = 0; i < 2; ++i)
 113         {
 114                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 115                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 116                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 117                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 118                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 119                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 120                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 121                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 122                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 123                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 124                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 125                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 126                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 127                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 128
 129                 if(found)
 130                         break;
 131
 132                 prev = -1; // second attempt takes place WITHOUT prev set
 133         }
 134
 135         if(!found)
 136                 g_dm = 1;
 137
 138         if(g_dm && cvar("deathmatch_force_teamplay"))
 139         {
 140                 g_dm = 0;
 141                 g_tdm = 1;
 142         }
 143
 144         teams_matter = 0;
 145 }
 146
 147 void default_delayedinit()
 148 {
 149         if(!scores_initialized)
 150                 ScoreRules_generic();
 151 }
 152
 153 void ActivateTeamplay()
 154 {
 155         float teamplay_default;
 156         teamplay_default = cvar("teamplay_default");
 157
 158         if(teamplay_default)
 159                 teamplay = teamplay_default;
 160         else
 161                 teamplay = 3;
 162         cvar_set("teamplay", ftos(teamplay));
 163
 164         teams_matter = 1;
 165 }
 166
 167 void InitGameplayMode()
 168 {
 169         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 170
 171         qualifying_override = -1;
 172
 173         VoteReset();
 174
 175         teams_matter = 0;
 176         cvar_set("teamplay", "0");
 177
 178         // make sure only ONE type is selected
 179         ReadGameCvars();
 180         WriteGameCvars();
 181
 182         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 183         get_mi_min_max(1);
 184         world.mins = mi_min;
 185         world.maxs = mi_max;
 186
 187         MapInfo_LoadMapSettings(mapname);
 188
 189         if not(cvar_value_issafe(world.fog))
 190         {
 191                 print("The current map contains a potentially harmful fog setting, ignored\n");
 192                 world.fog = string_null;
 193         }
 194         if(MapInfo_Map_fog != "")
 195                 if(MapInfo_Map_fog == "none")
 196                         world.fog = string_null;
 197                 else
 198                         world.fog = strzone(MapInfo_Map_fog);
 199         clientstuff = strzone(MapInfo_Map_clientstuff);
 200
 201         MapInfo_ClearTemps();
 202
 203         // in case mapinfo switched the type
 204         ReadGameCvars();
 205
 206         // set both here, gamemode can override it later
 207         timelimit_override = cvar("timelimit_override");
 208         fraglimit_override = cvar("fraglimit_override");
 209         leadlimit_override = cvar("leadlimit_override");
 210
 211         if(cvar("g_dodging"))
 212                 MUTATOR_ADD(dodging);
 213
 214         if(g_dm)
 215         {
 216                 game = GAME_DEATHMATCH;
 217                 gamemode_name = "Deathmatch";
 218         }
 219
 220         if(g_tdm)
 221         {
 222                 game = GAME_TEAM_DEATHMATCH;
 223                 gamemode_name = "Team Deathmatch";
 224                 ActivateTeamplay();
 225                 tdm_init();
 226                 if(cvar("g_tdm_team_spawns"))
 227                         have_team_spawns = -1; // request team spawns
 228         }
 229
 230         if(g_domination)
 231         {
 232                 game = GAME_DOMINATION;
 233                 gamemode_name = "Domination";
 234                 ActivateTeamplay();
 235                 fraglimit_override = cvar("g_domination_point_limit");
 236                 leadlimit_override = cvar("g_domination_point_leadlimit");
 237                 dom_init();
 238                 have_team_spawns = -1; // request team spawns
 239         }
 240
 241         if(g_ctf)
 242         {
 243                 game = GAME_CTF;
 244                 gamemode_name = "Capture the Flag";
 245                 ActivateTeamplay();
 246                 if(cvar("g_campaign"))
 247                         g_ctf_win_mode = 2;
 248                 else
 249                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 250                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 251                 if(g_ctf_win_mode == 2)
 252                 {
 253                         fraglimit_override = cvar("g_ctf_capture_limit");
 254                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 255                 }
 256                 else
 257                 {
 258                         fraglimit_override = cvar("capturelimit_override");
 259                         leadlimit_override = cvar("captureleadlimit_override");
 260                 }
 261                 ctf_init();
 262                 have_team_spawns = -1; // request team spawns
 263         }
 264
 265         if(g_runematch)
 266         {
 267                 game = GAME_RUNEMATCH;
 268                 gamemode_name = "Rune Match";
 269                 if(cvar("deathmatch_force_teamplay"))
 270                         ActivateTeamplay();
 271                 fraglimit_override = cvar("g_runematch_point_limit");
 272                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 273                 runematch_init();
 274         }
 275
 276         if(g_lms)
 277         {
 278                 game = GAME_LMS;
 279                 gamemode_name = "Last Man Standing";
 280                 fraglimit_override = cvar("g_lms_lives_override");
 281                 leadlimit_override = 0; // not supported by LMS
 282                 if(fraglimit_override == 0)
 283                         fraglimit_override = -1;
 284                 lms_lowest_lives = 9999;
 285                 lms_next_place = 0;
 286                 ScoreRules_lms();
 287         }
 288
 289         if(g_arena)
 290         {
 291                 game = GAME_ARENA;
 292                 gamemode_name = "Arena";
 293                 fraglimit_override = cvar("g_arena_point_limit");
 294                 leadlimit_override = cvar("g_arena_point_leadlimit");
 295                 maxspawned = cvar("g_arena_maxspawned");
 296                 if(maxspawned < 2)
 297                         maxspawned = 2;
 298                 arena_roundbased = cvar("g_arena_roundbased");
 299         }
 300
 301         if(g_ca)
 302         {
 303                 game = GAME_CA;
 304                 gamemode_name = "Clan Arena";
 305                 ActivateTeamplay();
 306                 fraglimit_override = cvar("g_ca_point_limit");
 307                 leadlimit_override = cvar("g_ca_point_leadlimit");
 308                 precache_sound("ctf/red_capture.wav");
 309                 precache_sound("ctf/blue_capture.wav");
 310         }
 311         if(g_keyhunt)
 312         {
 313                 game = GAME_KEYHUNT;
 314                 gamemode_name = "Key Hunt";
 315                 ActivateTeamplay();
 316                 fraglimit_override = cvar("g_keyhunt_point_limit");
 317                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 318                 MUTATOR_ADD(gamemode_keyhunt);
 319         }
 320
 321         if(g_assault)
 322         {
 323                 game = GAME_ASSAULT;
 324                 gamemode_name = "Assault";
 325                 ActivateTeamplay();
 326                 ScoreRules_assault();
 327                 have_team_spawns = -1; // request team spawns
 328         }
 329
 330         if(g_onslaught)
 331         {
 332                 game = GAME_ONSLAUGHT;
 333                 gamemode_name = "Onslaught";
 334                 ActivateTeamplay();
 335                 have_team_spawns = -1; // request team spawns
 336         }
 337
 338         if(g_race)
 339         {
 340                 game = GAME_RACE;
 341                 gamemode_name = "Race";
 342
 343                 if(cvar("g_race_teams"))
 344                 {
 345                         ActivateTeamplay();
 346                         race_teams = bound(2, cvar("g_race_teams"), 4);
 347                         have_team_spawns = -1; // request team spawns
 348                 }
 349                 else
 350                         race_teams = 0;
 351
 352                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 353                 fraglimit_override = cvar("g_race_laps_limit");
 354                 leadlimit_override = 0; // currently not supported by race
 355         }
 356
 357         if(g_cts)
 358         {
 359                 game = GAME_CTS;
 360                 gamemode_name = "CTS";
 361                 g_race_qualifying = 1;
 362                 fraglimit_override = 0;
 363                 leadlimit_override = 0;
 364         }
 365
 366         if(g_nexball)
 367         {
 368                 game = GAME_NEXBALL;
 369                 gamemode_name = "Nexball";
 370                 fraglimit_override = cvar("g_nexball_goallimit");
 371                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 372                 ActivateTeamplay();
 373                 nb_init();
 374                 have_team_spawns = -1; // request team spawns
 375         }
 376
 377         if(teams_matter)
 378                 entcs_init();
 379
 380         // save it (for the next startup)
 381         cvar_set("gamecfg", ftos(game));
 382
 383         cache_mutatormsg = strzone("");
 384         cache_lastmutatormsg = strzone("");
 385
 386         // enforce the server's universal frag/time limits
 387         if(!cvar("g_campaign"))
 388         {
 389                 if(fraglimit_override >= 0)
 390                         cvar_set("fraglimit", ftos(fraglimit_override));
 391                 if(timelimit_override >= 0)
 392                         cvar_set("timelimit", ftos(timelimit_override));
 393                 if(leadlimit_override >= 0)
 394                         cvar_set("leadlimit", ftos(leadlimit_override));
 395                 if(qualifying_override >= 0)
 396                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 397         }
 398
 399         if(g_race)
 400         {
 401                 // we need to find out the correct value for g_race_qualifying
 402                 if(cvar("g_campaign"))
 403                 {
 404                         g_race_qualifying = 1;
 405                 }
 406                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 407                 {
 408                         g_race_qualifying = 2;
 409                         race_fraglimit = cvar("fraglimit");
 410                         race_leadlimit = cvar("leadlimit");
 411                         race_timelimit = cvar("timelimit");
 412                         cvar_set("fraglimit", "0");
 413                         cvar_set("leadlimit", "0");
 414                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 415                 }
 416                 else
 417                         g_race_qualifying = 0;
 418         }
 419
 420         if(g_race || g_cts)
 421         {
 422                 if(g_race_qualifying)
 423                         independent_players = 1;
 424
 425                 ScoreRules_race();
 426         }
 427
 428         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 429 }
 430
 431 string GetClientVersionMessage() {
 432         local string versionmsg;
 433         if (self.version_mismatch) {
 434                 if(self.version < cvar("gameversion")) {
 435                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 436                 } else {
 437                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 438                 }
 439         } else {
 440                 versionmsg = "^2client version and server version are compatible.^8";
 441         }
 442         return versionmsg;
 443 }
 444
 445
 446 void PrintWelcomeMessage(entity pl)
 447 {
 448         string s, modifications, motd;
 449
 450         if(self.cvar_scr_centertime == 0) return;
 451
 452         if(cvar("g_campaign"))
 453         {
 454                 if(self.classname == "player" && !self.BUTTON_INFO)
 455                         return;
 456         }
 457         else
 458         {
 459                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 460                         return;
 461         }
 462
 463         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 464                 if(self.welcomemessage_time > time) return;
 465                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 466         }
 467
 468         if(cvar("g_campaign"))
 469         {
 470                 centerprint(pl, campaign_message);
 471                 return;
 472         }
 473
 474 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 475         if(!self.BUTTON_INFO)
 476         {
 477                 // TODO get rid of this too
 478                 local string specString;
 479                 specString = NEWLINES;
 480                 //if(time < game_starttime) //also show the countdown when being a spectator
 481                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 482                 //else
 483                 if (timeoutStatus != 0)
 484                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 485                 else
 486                 {
 487                         if(self.classname == "player")
 488                                 return;
 489                         goto normal;
 490                 }
 491                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 492         }
 493
 494 :normal
 495         ret_string = "";
 496         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 497         modifications = ret_string;
 498
 499         if(g_minstagib)
 500                 modifications = strcat(modifications, ", MinstaGib");
 501         if(g_weaponarena)
 502         {
 503                 if(g_weaponarena_random)
 504                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 505                 else
 506                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 507         }
 508         if(cvar("g_start_weapon_laser") == 0)
 509                 modifications = strcat(modifications, ", No start weapons");
 510         if(cvar("sv_gravity") < 800)
 511                 modifications = strcat(modifications, ", Low gravity");
 512         if(g_cloaked)
 513                 modifications = strcat(modifications, ", Cloaked");
 514         if(g_footsteps)
 515                 modifications = strcat(modifications, ", Steps");
 516         if(g_grappling_hook)
 517                 modifications = strcat(modifications, ", Hook");
 518         if(g_laserguided_missile)
 519                 modifications = strcat(modifications, ", LG missiles");
 520         if(g_midair)
 521                 modifications = strcat(modifications, ", Midair");
 522         if(g_vampire)
 523                 modifications = strcat(modifications, ", Vampire");
 524         if(g_pinata)
 525                 modifications = strcat(modifications, ", Pinata");
 526         if(g_weapon_stay)
 527                 modifications = strcat(modifications, ", Weapons stay");
 528         if(g_bloodloss > 0)
 529                 modifications = strcat(modifications, ", Bloodloss");
 530         if(g_jetpack)
 531                 modifications = strcat(modifications, ", Jet pack");
 532         modifications = substring(modifications, 2, strlen(modifications) - 2);
 533
 534         local string versionmessage;
 535         versionmessage = GetClientVersionMessage();
 536
 537         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
 538         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 539
 540         if(modifications != "")
 541                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 542
 543         if(timeoutStatus != 0)
 544                 s = strcat(s, "\n\n", getTimeoutText(1));
 545
 546         if (g_grappling_hook)
 547                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 548
 549         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 550         {
 551                 if(cache_lastmutatormsg)
 552                         strunzone(cache_lastmutatormsg);
 553                 if(cache_mutatormsg)
 554                         strunzone(cache_mutatormsg);
 555                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 556                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 557         }
 558
 559         if (cache_mutatormsg != "") {
 560                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 561         }
 562
 563         motd = cvar_string("sv_motd");
 564         if (motd != "") {
 565                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 566         }
 567         s = strcat(s, "\n");
 568
 569         centerprint(pl, s);
 570 }
 571
 572
 573 void SetPlayerColors(entity pl, float _color)
 574 {
 575         /*string s;
 576         s = ftos(cl);
 577         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 578         pl.team = cl + 1;
 579         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 580         pl.clientcolors = 16*cl + cl;*/
 581
 582         float pants, shirt;
 583         pants = _color & 0x0F;
 584         shirt = _color & 0xF0;
 585
 586
 587         if(teams_matter) {
 588                 setcolor(pl, 16*pants + pants);
 589         } else {
 590                 setcolor(pl, shirt + pants);
 591         }
 592 }
 593
 594 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 595 {
 596         float _color;
 597
 598         if(t == 4)
 599                 _color = COLOR_TEAM4 - 1;
 600         else if(t == 3)
 601                 _color = COLOR_TEAM3 - 1;
 602         else if(t == 2)
 603                 _color = COLOR_TEAM2 - 1;
 604         else
 605                 _color = COLOR_TEAM1 - 1;
 606
 607         SetPlayerColors(pl,_color);
 608
 609         if(t != s) {
 610                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 611
 612                 if(!noprint)
 613                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 614         }
 615
 616 }
 617
 618 // set c1...c4 to show what teams are allowed
 619 void CheckAllowedTeams (entity for_whom)
 620 {
 621         float dm;
 622         entity head;
 623         string teament_name;
 624
 625         c1 = c2 = c3 = c4 = -1;
 626         cb1 = cb2 = cb3 = cb4 = 0;
 627
 628         if(cvar("g_campaign") && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
 629         {
 630                 c1 = 0; // only allow RED team for player joining
 631         }
 632         else if(g_onslaught)
 633         {
 634                 // onslaught is special
 635                 head = findchain(classname, "onslaught_generator");
 636                 while (head)
 637                 {
 638                         if (head.team == COLOR_TEAM1) c1 = 0;
 639                         if (head.team == COLOR_TEAM2) c2 = 0;
 640                         if (head.team == COLOR_TEAM3) c3 = 0;
 641                         if (head.team == COLOR_TEAM4) c4 = 0;
 642                         head = head.chain;
 643                 }
 644         }
 645         else if(g_domination)
 646                 teament_name = "dom_team";
 647         else if(g_ctf)
 648                 teament_name = "ctf_team";
 649         else if(g_tdm)
 650                 teament_name = "tdm_team";
 651         else if(g_nexball)
 652                 teament_name = "nexball_team";
 653         else if(g_assault)
 654                 c1 = c2 = 0; // Assault always has 2 teams
 655         else
 656         {
 657                 // cover anything else by treating it like tdm with no teams spawned
 658                 if(g_race)
 659                         dm = race_teams;
 660                 else
 661                         dm = 2;
 662
 663                 ret_float = dm;
 664                 MUTATOR_CALLHOOK(GetTeamCount);
 665                 dm = ret_float;
 666
 667                 if(dm >= 4)
 668                         c1 = c2 = c3 = c4 = 0;
 669                 else if(dm >= 3)
 670                         c1 = c2 = c3 = 0;
 671                 else
 672                         c1 = c2 = 0;
 673         }
 674
 675         // find out what teams are allowed if necessary
 676         if(teament_name)
 677         {
 678                 head = find(world, classname, teament_name);
 679                 while(head)
 680                 {
 681                         if(!(g_domination && head.netname == ""))
 682                         {
 683                                 if(head.team == COLOR_TEAM1)
 684                                         c1 = 0;
 685                                 else if(head.team == COLOR_TEAM2)
 686                                         c2 = 0;
 687                                 else if(head.team == COLOR_TEAM3)
 688                                         c3 = 0;
 689                                 else if(head.team == COLOR_TEAM4)
 690                                         c4 = 0;
 691                         }
 692                         head = find(head, classname, teament_name);
 693                 }
 694         }
 695
 696         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 697         if(c3==-1&&c4==-1)
 698         if(cvar("bot_vs_human") && for_whom)
 699         {
 700                 if(cvar("bot_vs_human") > 0)
 701                 {
 702                         // bots are all blue
 703                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 704                                 c1 = c3 = c4 = -1;
 705                         else
 706                                 c2 = -1;
 707                 }
 708                 else
 709                 {
 710                         // bots are all red
 711                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 712                                 c2 = c3 = c4 = -1;
 713                         else
 714                                 c1 = -1;
 715                 }
 716         }
 717 }
 718
 719 float PlayerValue(entity p)
 720 {
 721         if(IsTeamBalanceForced() == 1)
 722                 return 1;
 723         return 1;
 724 }
 725
 726 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 727 // teams that are allowed will now have their player counts stored in c1...c4
 728 void GetTeamCounts(entity ignore)
 729 {
 730         entity head;
 731         float value, bvalue;
 732         // now count how many players are on each team already
 733
 734         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 735         // also remember the lowest-scoring player
 736
 737         FOR_EACH_PLAYER(head)
 738         {
 739                 if(head != ignore)// && head.netname != "")
 740                 {
 741                         value = PlayerValue(head);
 742                         if(clienttype(head) == CLIENTTYPE_BOT)
 743                                 bvalue = value;
 744                         else
 745                                 bvalue = 0;
 746                         if(head.team == COLOR_TEAM1)
 747                         {
 748                                 if(c1 >= 0)
 749                                 {
 750                                         c1 = c1 + value;
 751                                         cb1 = cb1 + bvalue;
 752                                 }
 753                         }
 754                         if(head.team == COLOR_TEAM2)
 755                         {
 756                                 if(c2 >= 0)
 757                                 {
 758                                         c2 = c2 + value;
 759                                         cb2 = cb2 + bvalue;
 760                                 }
 761                         }
 762                         if(head.team == COLOR_TEAM3)
 763                         {
 764                                 if(c3 >= 0)
 765                                 {
 766                                         c3 = c3 + value;
 767                                         cb3 = cb3 + bvalue;
 768                                 }
 769                         }
 770                         if(head.team == COLOR_TEAM4)
 771                         {
 772                                 if(c4 >= 0)
 773                                 {
 774                                         c4 = c4 + value;
 775                                         cb4 = cb4 + bvalue;
 776                                 }
 777                         }
 778                 }
 779         }
 780 }
 781
 782 // returns # of smallest team (1, 2, 3, 4)
 783 // NOTE: Assumes CheckAllowedTeams has already been called!
 784 float FindSmallestTeam(entity pl, float ignore_pl)
 785 {
 786         float totalteams, balance_type, maxc;
 787         totalteams = 0;
 788
 789         // find out what teams are available
 790         //CheckAllowedTeams();
 791
 792         // make sure there are at least 2 teams to join
 793         if(c1 >= 0)
 794                 totalteams = totalteams + 1;
 795         if(c2 >= 0)
 796                 totalteams = totalteams + 1;
 797         if(c3 >= 0)
 798                 totalteams = totalteams + 1;
 799         if(c4 >= 0)
 800                 totalteams = totalteams + 1;
 801
 802         if(cvar("bot_vs_human"))
 803                 totalteams += 1;
 804
 805         if(totalteams <= 1)
 806         {
 807                 if(cvar("g_campaign") && pl && clienttype(pl) == CLIENTTYPE_REAL)
 808                         return 1; // special case for campaign and player joining
 809                 else if(g_domination)
 810                         error("Too few teams available for domination\n");
 811                 else if(g_ctf)
 812                         error("Too few teams available for ctf\n");
 813                 else if(g_keyhunt)
 814                         error("Too few teams available for key hunt\n");
 815                 else
 816                         error("Too few teams available for team deathmatch\n");
 817         }
 818
 819         // count how many players are in each team
 820         if(ignore_pl)
 821                 GetTeamCounts(pl);
 822         else
 823                 GetTeamCounts(world);
 824
 825         // c1...c4 now have counts of each team
 826         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 827
 828         // 2 gives priority to what team you're already on, 1 goes in order
 829         // 2 doesn't seem to work though...
 830         balance_type = 1;
 831
 832         if(bots_would_leave)
 833         //if(pl.classname != "player")
 834         if(clienttype(pl) != CLIENTTYPE_BOT)
 835         {
 836                 c1 -= cb1 * 255.0/256.0;
 837                 c2 -= cb2 * 255.0/256.0;
 838                 c3 -= cb3 * 255.0/256.0;
 839                 c4 -= cb4 * 255.0/256.0;
 840         }
 841         maxc = max4(c1, c2, c3, c4);
 842
 843         RandomSelection_Init();
 844         if(balance_type == 1)
 845         {
 846                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 847                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 848                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 849                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 850                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 851         }
 852         else if(balance_type == 2)
 853         {
 854                 // 1: use team count, if equal prefer own team
 855                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 856                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 857                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 858                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 859         }
 860         else if(balance_type == 3)
 861         {
 862                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 863                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 864                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 865                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 866                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 867         }
 868         return RandomSelection_chosen_float;
 869 }
 870
 871 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 872 {
 873         float smallest, selectedteam;
 874
 875         // don't join a team if we're not playing a team game
 876         if(!teams_matter)
 877                 return 0;
 878
 879         // find out what teams are available
 880         CheckAllowedTeams(pl);
 881
 882         // if we want the player in a certain team for campaign, force him there
 883         if(cvar("g_campaign"))
 884         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
 885         {
 886                 switch(cvar("g_campaign_forceteam"))
 887                 {
 888                         case 1:
 889                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
 890                                 LogTeamchange(pl.playerid, pl.team, 2);
 891                                 return COLOR_TEAM1;
 892                         case 2:
 893                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
 894                                 LogTeamchange(pl.playerid, pl.team, 2);
 895                                 return COLOR_TEAM2;
 896                         case 3:
 897                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
 898                                 LogTeamchange(pl.playerid, pl.team, 2);
 899                                 return COLOR_TEAM3;
 900                         case 4:
 901                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
 902                                 LogTeamchange(pl.playerid, pl.team, 2);
 903                                 return COLOR_TEAM4;
 904                         default:
 905                                 break;
 906                 }
 907         }
 908
 909         // if we don't care what team he ends up on, put him on whatever team he entered as.
 910         // if he's not on a valid team, then let other code put him on the smallest team
 911         if(!forcebestteam)
 912         {
 913                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 914                         selectedteam = pl.team;
 915                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 916                         selectedteam = pl.team;
 917                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 918                         selectedteam = pl.team;
 919                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 920                         selectedteam = pl.team;
 921                 else
 922                         selectedteam = -1;
 923
 924                 if(selectedteam > 0)
 925                 {
 926                         if(!only_return_best)
 927                         {
 928                                 SetPlayerColors(pl, selectedteam - 1);
 929
 930                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 931                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 932                                 LogTeamchange(pl.playerid, pl.team, 99);
 933                         }
 934                         return selectedteam;
 935                 }
 936                 // otherwise end up on the smallest team (handled below)
 937         }
 938
 939         smallest = FindSmallestTeam(pl, TRUE);
 940
 941         if(!only_return_best)
 942         {
 943                 TeamchangeFrags(self);
 944                 if(smallest == 1)
 945                 {
 946                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 947                 }
 948                 else if(smallest == 2)
 949                 {
 950                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 951                 }
 952                 else if(smallest == 3)
 953                 {
 954                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 955                 }
 956                 else if(smallest == 4)
 957                 {
 958                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 959                 }
 960                 else
 961                 {
 962                         error("smallest team: invalid team\n");
 963                 }
 964
 965                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 966
 967                 if(pl.deadflag == DEAD_NO)
 968                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 969         }
 970
 971         return smallest;
 972 }
 973
 974 //void() ctf_playerchanged;
 975 void SV_ChangeTeam(float _color)
 976 {
 977         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 978
 979         // in normal deathmatch we can just apply the color and we're done
 980         if(!teams_matter) {
 981                 SetPlayerColors(self, _color);
 982                 return;
 983         }
 984
 985         scolor = self.clientcolors & 0x0F;
 986         dcolor = _color & 0x0F;
 987
 988         if(scolor == COLOR_TEAM1 - 1)
 989                 steam = 1;
 990         else if(scolor == COLOR_TEAM2 - 1)
 991                 steam = 2;
 992         else if(scolor == COLOR_TEAM3 - 1)
 993                 steam = 3;
 994         else // if(scolor == COLOR_TEAM4 - 1)
 995                 steam = 4;
 996         if(dcolor == COLOR_TEAM1 - 1)
 997                 dteam = 1;
 998         else if(dcolor == COLOR_TEAM2 - 1)
 999                 dteam = 2;
1000         else if(dcolor == COLOR_TEAM3 - 1)
1001                 dteam = 3;
1002         else // if(dcolor == COLOR_TEAM4 - 1)
1003                 dteam = 4;
1004
1005         CheckAllowedTeams(self);
1006
1007         if(dteam == 1 && c1 < 0) dteam = 4;
1008         if(dteam == 4 && c4 < 0) dteam = 3;
1009         if(dteam == 3 && c3 < 0) dteam = 2;
1010         if(dteam == 2 && c2 < 0) dteam = 1;
1011
1012         // not changing teams
1013         if(scolor == dcolor)
1014         {
1015                 //bprint("same team change\n");
1016                 SetPlayerTeam(self, dteam, steam, TRUE);
1017                 return;
1018         }
1019
1020         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
1021                 sprint(self, "Team changes not allowed\n");
1022                 return; // changing teams is not allowed
1023         }
1024
1025         if(cvar("g_balance_teams_prevent_imbalance"))
1026         {
1027                 // only allow changing to a smaller or equal size team
1028
1029                 // find out what teams are available
1030                 //CheckAllowedTeams();
1031                 // count how many players on each team
1032                 GetTeamCounts(world);
1033
1034                 // get desired team
1035                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1036                 {
1037                         dcount = c1;
1038                         dbotcount = cb1;
1039                 }
1040                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1041                 {
1042                         dcount = c2;
1043                         dbotcount = cb2;
1044                 }
1045                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1046                 {
1047                         dcount = c3;
1048                         dbotcount = cb3;
1049                 }
1050                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1051                 {
1052                         dcount = c4;
1053                         dbotcount = cb4;
1054                 }
1055                 else
1056                 {
1057                         sprint(self, "Cannot change to an invalid team\n");
1058
1059                         return;
1060                 }
1061
1062                 // get starting team
1063                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1064                         scount = c1;
1065                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1066                         scount = c2;
1067                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1068                         scount = c3;
1069                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1070                         scount = c4;
1071
1072                 if(scount) // started at a valid, nonempty team
1073                 {
1074                         // check if we're trying to change to a larger team that doens't have bots to swap with
1075                         if(dcount >= scount && dbotcount <= 0)
1076                         {
1077                                 sprint(self, "Cannot change to a larger team\n");
1078                                 return; // can't change to a larger team
1079                         }
1080                 }
1081         }
1082
1083 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1084
1085         if(self.classname == "player" && steam != dteam)
1086         {
1087                 // reduce frags during a team change
1088                 TeamchangeFrags(self);
1089         }
1090
1091         SetPlayerTeam(self, dteam, steam, FALSE);
1092
1093         if(self.classname == "player" && steam != dteam)
1094         {
1095                 // kill player when changing teams
1096                 if(self.deadflag == DEAD_NO)
1097                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1098         }
1099         //ctf_playerchanged();
1100 }
1101
1102 void ShufflePlayerOutOfTeam (float source_team)
1103 {
1104         float smallestteam, smallestteam_count, steam;
1105         float lowest_bot_score, lowest_player_score;
1106         entity head, lowest_bot, lowest_player, selected;
1107
1108         smallestteam = 0;
1109         smallestteam_count = 999999999;
1110
1111         if(c1 >= 0 && c1 < smallestteam_count)
1112         {
1113                 smallestteam = 1;
1114                 smallestteam_count = c1;
1115         }
1116         if(c2 >= 0 && c2 < smallestteam_count)
1117         {
1118                 smallestteam = 2;
1119                 smallestteam_count = c2;
1120         }
1121         if(c3 >= 0 && c3 < smallestteam_count)
1122         {
1123                 smallestteam = 3;
1124                 smallestteam_count = c3;
1125         }
1126         if(c4 >= 0 && c4 < smallestteam_count)
1127         {
1128                 smallestteam = 4;
1129                 smallestteam_count = c4;
1130         }
1131
1132         if(!smallestteam)
1133         {
1134                 bprint("warning: no smallest team\n");
1135                 return;
1136         }
1137
1138         if(source_team == 1)
1139                 steam = COLOR_TEAM1;
1140         else if(source_team == 2)
1141                 steam = COLOR_TEAM2;
1142         else if(source_team == 3)
1143                 steam = COLOR_TEAM3;
1144         else if(source_team == 4)
1145                 steam = COLOR_TEAM4;
1146
1147         lowest_bot = world;
1148         lowest_bot_score = 999999999;
1149         lowest_player = world;
1150         lowest_player_score = 999999999;
1151
1152         // find the lowest-scoring player & bot of that team
1153         FOR_EACH_PLAYER(head)
1154         {
1155                 if(head.team == steam)
1156                 {
1157                         if(head.isbot)
1158                         {
1159                                 if(head.totalfrags < lowest_bot_score)
1160                                 {
1161                                         lowest_bot = head;
1162                                         lowest_bot_score = head.totalfrags;
1163                                 }
1164                         }
1165                         else
1166                         {
1167                                 if(head.totalfrags < lowest_player_score)
1168                                 {
1169                                         lowest_player = head;
1170                                         lowest_player_score = head.totalfrags;
1171                                 }
1172                         }
1173                 }
1174         }
1175
1176         // prefers to move a bot...
1177         if(lowest_bot != world)
1178                 selected = lowest_bot;
1179         // but it will move a player if it has to
1180         else
1181                 selected = lowest_player;
1182         // don't do anything if it couldn't find anyone
1183         if(!selected)
1184         {
1185                 bprint("warning: couldn't find a player to move from team\n");
1186                 return;
1187         }
1188
1189         // smallest team gains a member
1190         if(smallestteam == 1)
1191         {
1192                 c1 = c1 + 1;
1193         }
1194         else if(smallestteam == 2)
1195         {
1196                 c2 = c2 + 1;
1197         }
1198         else if(smallestteam == 3)
1199         {
1200                 c3 = c3 + 1;
1201         }
1202         else if(smallestteam == 4)
1203         {
1204                 c4 = c4 + 1;
1205         }
1206         else
1207         {
1208                 bprint("warning: destination team invalid\n");
1209                 return;
1210         }
1211         // source team loses a member
1212         if(source_team == 1)
1213         {
1214                 c1 = c1 + 1;
1215         }
1216         else if(source_team == 2)
1217         {
1218                 c2 = c2 + 2;
1219         }
1220         else if(source_team == 3)
1221         {
1222                 c3 = c3 + 3;
1223         }
1224         else if(source_team == 4)
1225         {
1226                 c4 = c4 + 4;
1227         }
1228         else
1229         {
1230                 bprint("warning: source team invalid\n");
1231                 return;
1232         }
1233
1234         // move the player to the new team
1235         TeamchangeFrags(selected);
1236         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1237
1238         if(selected.deadflag == DEAD_NO)
1239                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1240         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1241 }
1242
1243 void CauseRebalance(float source_team, float howmany_toomany)
1244 {
1245         if(IsTeamBalanceForced() == 1)
1246         {
1247                 bprint("Rebalancing Teams\n");
1248                 ShufflePlayerOutOfTeam(source_team);
1249         }
1250 }
1251
1252 // part of g_balance_teams_force
1253 // occasionally perform an audit of the teams to make
1254 // sure they're more or less balanced in player count.
1255 void AuditTeams()
1256 {
1257         float numplayers, numteams, smallest, toomany;
1258         float balance;
1259         balance = IsTeamBalanceForced();
1260         if(balance == 0)
1261                 return;
1262
1263         if(audit_teams_time > time)
1264                 return;
1265
1266         audit_teams_time = time + 4 + random();
1267
1268 //      bprint("Auditing teams\n");
1269
1270         CheckAllowedTeams(world);
1271         GetTeamCounts(world);
1272
1273
1274         numteams = numplayers = smallest = 0;
1275         if(c1 >= 0)
1276         {
1277                 numteams = numteams + 1;
1278                 numplayers = numplayers + c1;
1279                 smallest = c1;
1280         }
1281         if(c2 >= 0)
1282         {
1283                 numteams = numteams + 1;
1284                 numplayers = numplayers + c2;
1285                 if(c2 < smallest)
1286                         smallest = c2;
1287         }
1288         if(c3 >= 0)
1289         {
1290                 numteams = numteams + 1;
1291                 numplayers = numplayers + c3;
1292                 if(c3 < smallest)
1293                         smallest = c3;
1294         }
1295         if(c4 >= 0)
1296         {
1297                 numteams = numteams + 1;
1298                 numplayers = numplayers + c4;
1299                 if(c4 < smallest)
1300                         smallest = c4;
1301         }
1302
1303         if(numplayers <= 0)
1304                 return; // no players to move around
1305         if(numteams < 2)
1306                 return; // don't bother shuffling if for some reason there aren't any teams
1307
1308         toomany = smallest + 1;
1309
1310         if(c1 && c1 > toomany)
1311                 CauseRebalance(1, c1 - toomany);
1312         if(c2 && c2 > toomany)
1313                 CauseRebalance(2, c2 - toomany);
1314         if(c3 && c3 > toomany)
1315                 CauseRebalance(3, c3 - toomany);
1316         if(c4 && c4 > toomany)
1317                 CauseRebalance(4, c4 - toomany);
1318
1319         // if teams are still unbalanced, balance them further in the next audit,
1320         // which will happen sooner (keep doing rapid audits until things are in order)
1321         audit_teams_time = time + 0.7 + random()*0.3;
1322 }
1323
1324 // code from here on is just to support maps that don't have team entities
1325 void tdm_spawnteam (string teamname, float teamcolor)
1326 {
1327         local entity e;
1328         e = spawn();
1329         e.classname = "tdm_team";
1330         e.netname = teamname;
1331         e.cnt = teamcolor;
1332         e.team = e.cnt + 1;
1333 };
1334
1335 // spawn some default teams if the map is not set up for tdm
1336 void tdm_spawnteams()
1337 {
1338         float numteams;
1339
1340         numteams = cvar("g_tdm_teams_override");
1341         if(numteams < 2)
1342                 numteams = cvar("g_tdm_teams");
1343         numteams = bound(2, numteams, 4);
1344
1345         tdm_spawnteam("Red", COLOR_TEAM1-1);
1346         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1347         if(numteams >= 3)
1348                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1349         if(numteams >= 4)
1350                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1351 };
1352
1353 void tdm_delayedinit()
1354 {
1355         // if no teams are found, spawn defaults
1356         if (find(world, classname, "tdm_team") == world)
1357                 tdm_spawnteams();
1358 };
1359
1360 void tdm_init()
1361 {
1362         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1363 };