qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(cvar("bot_vs_human") && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!cvar("g_balance_teams_force"))
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void nb_init();
  75 void entcs_init();
  76
  77 void LogTeamchange(float player_id, float team_number, float type)
  78 {
  79         if(!cvar("sv_eventlog"))
  80                 return;
  81
  82         if(player_id < 1)
  83                 return;
  84
  85         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  86 }
  87
  88 void WriteGameCvars()
  89 {
  90         cvar_set("g_dm", ftos(g_dm));
  91         cvar_set("g_tdm", ftos(g_tdm));
  92         cvar_set("g_domination", ftos(g_domination));
  93         cvar_set("g_ctf", ftos(g_ctf));
  94         cvar_set("g_runematch", ftos(g_runematch));
  95         cvar_set("g_lms", ftos(g_lms));
  96         cvar_set("g_arena", ftos(g_arena));
  97         cvar_set("g_ca", ftos(g_ca));
  98         cvar_set("g_keyhunt", ftos(g_keyhunt));
  99         cvar_set("g_assault", ftos(g_assault));
 100         cvar_set("g_onslaught", ftos(g_onslaught));
 101         cvar_set("g_race", ftos(g_race));
 102         cvar_set("g_nexball", ftos(g_nexball));
 103         cvar_set("g_cts", ftos(g_cts));
 104 }
 105
 106 void ReadGameCvars()
 107 {
 108         float found;
 109         float prev;
 110         float i;
 111
 112         found = 0;
 113         prev = cvar("gamecfg");
 114         for(i = 0; i < 2; ++i)
 115         {
 116                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 117                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 118                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 119                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 120                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 121                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 122                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 123                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 124                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 125                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 126                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 127                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 128                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 129                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 130
 131                 if(found)
 132                         break;
 133
 134                 prev = -1; // second attempt takes place WITHOUT prev set
 135         }
 136
 137         if(!found)
 138                 g_dm = 1;
 139
 140         if(g_dm && cvar("deathmatch_force_teamplay"))
 141         {
 142                 g_dm = 0;
 143                 g_tdm = 1;
 144         }
 145
 146         teams_matter = 0;
 147 }
 148
 149 void default_delayedinit()
 150 {
 151         if(!scores_initialized)
 152                 ScoreRules_generic();
 153 }
 154
 155 void ActivateTeamplay()
 156 {
 157         float teamplay_default;
 158         teamplay_default = cvar("teamplay_default");
 159
 160         if(teamplay_default)
 161                 teamplay = teamplay_default;
 162         else
 163                 teamplay = 3;
 164         cvar_set("teamplay", ftos(teamplay));
 165
 166         teams_matter = 1;
 167 }
 168
 169 void InitGameplayMode()
 170 {
 171         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 172
 173         qualifying_override = -1;
 174
 175         VoteReset();
 176
 177         teams_matter = 0;
 178         cvar_set("teamplay", "0");
 179
 180         // make sure only ONE type is selected
 181         ReadGameCvars();
 182         WriteGameCvars();
 183
 184         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 185         get_mi_min_max(1);
 186         world.mins = mi_min;
 187         world.maxs = mi_max;
 188
 189         MapInfo_LoadMapSettings(mapname);
 190
 191         if not(cvar_value_issafe(world.fog))
 192         {
 193                 print("The current map contains a potentially harmful fog setting, ignored\n");
 194                 world.fog = string_null;
 195         }
 196         if(MapInfo_Map_fog != "")
 197                 if(MapInfo_Map_fog == "none")
 198                         world.fog = string_null;
 199                 else
 200                         world.fog = strzone(MapInfo_Map_fog);
 201         clientstuff = strzone(MapInfo_Map_clientstuff);
 202
 203         MapInfo_ClearTemps();
 204
 205         // in case mapinfo switched the type
 206         ReadGameCvars();
 207
 208         // set both here, gamemode can override it later
 209         timelimit_override = cvar("timelimit_override");
 210         fraglimit_override = cvar("fraglimit_override");
 211         leadlimit_override = cvar("leadlimit_override");
 212
 213         if(cvar("g_dodging"))
 214                 MUTATOR_ADD(dodging);
 215
 216         if(g_dm)
 217         {
 218                 game = GAME_DEATHMATCH;
 219                 gamemode_name = "Deathmatch";
 220         }
 221
 222         if(g_tdm)
 223         {
 224                 game = GAME_TEAM_DEATHMATCH;
 225                 gamemode_name = "Team Deathmatch";
 226                 ActivateTeamplay();
 227                 tdm_init();
 228                 if(cvar("g_tdm_team_spawns"))
 229                         have_team_spawns = -1; // request team spawns
 230         }
 231
 232         if(g_domination)
 233         {
 234                 game = GAME_DOMINATION;
 235                 gamemode_name = "Domination";
 236                 ActivateTeamplay();
 237                 fraglimit_override = cvar("g_domination_point_limit");
 238                 leadlimit_override = cvar("g_domination_point_leadlimit");
 239                 dom_init();
 240                 have_team_spawns = -1; // request team spawns
 241         }
 242
 243         if(g_ctf)
 244         {
 245                 game = GAME_CTF;
 246                 gamemode_name = "Capture the Flag";
 247                 ActivateTeamplay();
 248                 if(cvar("g_campaign"))
 249                         g_ctf_win_mode = 2;
 250                 else
 251                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 252                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 253                 if(g_ctf_win_mode == 2)
 254                 {
 255                         fraglimit_override = cvar("g_ctf_capture_limit");
 256                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 257                 }
 258                 else
 259                 {
 260                         fraglimit_override = cvar("capturelimit_override");
 261                         leadlimit_override = cvar("captureleadlimit_override");
 262                 }
 263                 ctf_init();
 264                 have_team_spawns = -1; // request team spawns
 265         }
 266
 267         if(g_runematch)
 268         {
 269                 game = GAME_RUNEMATCH;
 270                 gamemode_name = "Rune Match";
 271                 if(cvar("deathmatch_force_teamplay"))
 272                         ActivateTeamplay();
 273                 fraglimit_override = cvar("g_runematch_point_limit");
 274                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 275                 runematch_init();
 276         }
 277
 278         if(g_lms)
 279         {
 280                 game = GAME_LMS;
 281                 gamemode_name = "Last Man Standing";
 282                 fraglimit_override = cvar("g_lms_lives_override");
 283                 leadlimit_override = 0; // not supported by LMS
 284                 if(fraglimit_override == 0)
 285                         fraglimit_override = -1;
 286                 lms_lowest_lives = 9999;
 287                 lms_next_place = 0;
 288                 ScoreRules_lms();
 289         }
 290
 291         if(g_arena)
 292         {
 293                 game = GAME_ARENA;
 294                 gamemode_name = "Arena";
 295                 fraglimit_override = cvar("g_arena_point_limit");
 296                 leadlimit_override = cvar("g_arena_point_leadlimit");
 297                 maxspawned = cvar("g_arena_maxspawned");
 298                 if(maxspawned < 2)
 299                         maxspawned = 2;
 300                 arena_roundbased = cvar("g_arena_roundbased");
 301         }
 302
 303         if(g_ca)
 304         {
 305                 game = GAME_CA;
 306                 gamemode_name = "Clan Arena";
 307                 ActivateTeamplay();
 308                 fraglimit_override = cvar("g_ca_point_limit");
 309                 leadlimit_override = cvar("g_ca_point_leadlimit");
 310                 precache_sound("ctf/red_capture.wav");
 311                 precache_sound("ctf/blue_capture.wav");
 312         }
 313         if(g_keyhunt)
 314         {
 315                 game = GAME_KEYHUNT;
 316                 gamemode_name = "Key Hunt";
 317                 ActivateTeamplay();
 318                 fraglimit_override = cvar("g_keyhunt_point_limit");
 319                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 320                 MUTATOR_ADD(gamemode_keyhunt);
 321         }
 322
 323         if(g_assault)
 324         {
 325                 game = GAME_ASSAULT;
 326                 gamemode_name = "Assault";
 327                 ActivateTeamplay();
 328                 ScoreRules_assault();
 329                 have_team_spawns = -1; // request team spawns
 330         }
 331
 332         if(g_onslaught)
 333         {
 334                 game = GAME_ONSLAUGHT;
 335                 gamemode_name = "Onslaught";
 336                 ActivateTeamplay();
 337                 have_team_spawns = -1; // request team spawns
 338         }
 339
 340         if(g_race)
 341         {
 342                 game = GAME_RACE;
 343                 gamemode_name = "Race";
 344
 345                 if(cvar("g_race_teams"))
 346                 {
 347                         ActivateTeamplay();
 348                         race_teams = bound(2, cvar("g_race_teams"), 4);
 349                         have_team_spawns = -1; // request team spawns
 350                 }
 351                 else
 352                         race_teams = 0;
 353
 354                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 355                 fraglimit_override = cvar("g_race_laps_limit");
 356                 leadlimit_override = 0; // currently not supported by race
 357         }
 358
 359         if(g_cts)
 360         {
 361                 game = GAME_CTS;
 362                 gamemode_name = "CTS";
 363                 g_race_qualifying = 1;
 364                 fraglimit_override = 0;
 365                 leadlimit_override = 0;
 366         }
 367
 368         if(g_nexball)
 369         {
 370                 game = GAME_NEXBALL;
 371                 gamemode_name = "Nexball";
 372                 fraglimit_override = cvar("g_nexball_goallimit");
 373                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 374                 ActivateTeamplay();
 375                 nb_init();
 376                 have_team_spawns = -1; // request team spawns
 377         }
 378
 379         if(teams_matter)
 380                 entcs_init();
 381
 382         // save it (for the next startup)
 383         cvar_set("gamecfg", ftos(game));
 384
 385         cache_mutatormsg = strzone("");
 386         cache_lastmutatormsg = strzone("");
 387
 388         // enforce the server's universal frag/time limits
 389         if(!cvar("g_campaign"))
 390         {
 391                 if(fraglimit_override >= 0)
 392                         cvar_set("fraglimit", ftos(fraglimit_override));
 393                 if(timelimit_override >= 0)
 394                         cvar_set("timelimit", ftos(timelimit_override));
 395                 if(leadlimit_override >= 0)
 396                         cvar_set("leadlimit", ftos(leadlimit_override));
 397                 if(qualifying_override >= 0)
 398                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 399         }
 400
 401         if(g_race)
 402         {
 403                 // we need to find out the correct value for g_race_qualifying
 404                 if(cvar("g_campaign"))
 405                 {
 406                         g_race_qualifying = 1;
 407                 }
 408                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 409                 {
 410                         g_race_qualifying = 2;
 411                         race_fraglimit = cvar("fraglimit");
 412                         race_leadlimit = cvar("leadlimit");
 413                         race_timelimit = cvar("timelimit");
 414                         cvar_set("fraglimit", "0");
 415                         cvar_set("leadlimit", "0");
 416                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 417                 }
 418                 else
 419                         g_race_qualifying = 0;
 420         }
 421
 422         if(g_race || g_cts)
 423         {
 424                 if(g_race_qualifying)
 425                         independent_players = 1;
 426
 427                 ScoreRules_race();
 428         }
 429
 430         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 431 }
 432
 433 string GetClientVersionMessage() {
 434         local string versionmsg;
 435         if (self.version_mismatch) {
 436                 if(self.version < cvar("gameversion")) {
 437                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 438                 } else {
 439                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 440                 }
 441         } else {
 442                 versionmsg = "^2client version and server version are compatible.^8";
 443         }
 444         return versionmsg;
 445 }
 446
 447
 448 void PrintWelcomeMessage(entity pl)
 449 {
 450         string s, modifications, motd;
 451
 452         if(self.cvar_scr_centertime == 0) return;
 453
 454         if(cvar("g_campaign"))
 455         {
 456                 if(self.classname == "player" && !self.BUTTON_INFO)
 457                         return;
 458         }
 459         else
 460         {
 461                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 462                         return;
 463         }
 464
 465         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 466                 if(self.welcomemessage_time > time) return;
 467                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 468         }
 469
 470         if(cvar("g_campaign"))
 471         {
 472                 centerprint(pl, campaign_message);
 473                 return;
 474         }
 475
 476 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 477         if(!self.BUTTON_INFO)
 478         {
 479                 // TODO get rid of this too
 480                 local string specString;
 481                 specString = NEWLINES;
 482                 //if(time < game_starttime) //also show the countdown when being a spectator
 483                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 484                 //else
 485                 if (timeoutStatus != 0)
 486                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 487                 else
 488                 {
 489                         if(self.classname == "player")
 490                                 return;
 491                         goto normal;
 492                 }
 493                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 494         }
 495
 496 :normal
 497         ret_string = "";
 498         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 499         modifications = ret_string;
 500
 501         if(g_minstagib)
 502                 modifications = strcat(modifications, ", MinstaGib");
 503         if(g_weaponarena)
 504         {
 505                 if(g_weaponarena_random)
 506                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 507                 else
 508                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 509         }
 510         if(cvar("g_start_weapon_laser") == 0)
 511                 modifications = strcat(modifications, ", No start weapons");
 512         if(cvar("sv_gravity") < 800)
 513                 modifications = strcat(modifications, ", Low gravity");
 514         if(g_cloaked)
 515                 modifications = strcat(modifications, ", Cloaked");
 516         if(g_grappling_hook)
 517                 modifications = strcat(modifications, ", Hook");
 518         if(g_laserguided_missile)
 519                 modifications = strcat(modifications, ", LG missiles");
 520         if(g_midair)
 521                 modifications = strcat(modifications, ", Midair");
 522         if(g_vampire)
 523                 modifications = strcat(modifications, ", Vampire");
 524         if(g_pinata)
 525                 modifications = strcat(modifications, ", Pinata");
 526         if(g_weapon_stay)
 527                 modifications = strcat(modifications, ", Weapons stay");
 528         if(g_bloodloss > 0)
 529                 modifications = strcat(modifications, ", Bloodloss");
 530         if(g_jetpack)
 531                 modifications = strcat(modifications, ", Jet pack");
 532         modifications = substring(modifications, 2, strlen(modifications) - 2);
 533
 534         local string versionmessage;
 535         versionmessage = GetClientVersionMessage();
 536
 537         s = strcat(s, NEWLINES, "This is Xonotic ", cvar_string("g_xonoticversion"), "\n", versionmessage);
 538         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 539
 540         if(modifications != "")
 541                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 542
 543         if(timeoutStatus != 0)
 544                 s = strcat(s, "\n\n", getTimeoutText(1));
 545
 546         if (g_grappling_hook)
 547                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 548
 549         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 550         {
 551                 if(cache_lastmutatormsg)
 552                         strunzone(cache_lastmutatormsg);
 553                 if(cache_mutatormsg)
 554                         strunzone(cache_mutatormsg);
 555                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 556                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 557         }
 558
 559         if (cache_mutatormsg != "") {
 560                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 561         }
 562
 563         motd = cvar_string("sv_motd");
 564         if (motd != "") {
 565                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 566         }
 567         s = strcat(s, "\n");
 568
 569         centerprint(pl, s);
 570 }
 571
 572
 573 void SetPlayerColors(entity pl, float _color)
 574 {
 575         /*string s;
 576         s = ftos(cl);
 577         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 578         pl.team = cl + 1;
 579         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 580         pl.clientcolors = 16*cl + cl;*/
 581
 582         float pants, shirt;
 583         pants = _color & 0x0F;
 584         shirt = _color & 0xF0;
 585
 586
 587         if(teams_matter) {
 588                 setcolor(pl, 16*pants + pants);
 589         } else {
 590                 setcolor(pl, shirt + pants);
 591         }
 592 }
 593
 594 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 595 {
 596         float _color;
 597
 598         if(t == 4)
 599                 _color = COLOR_TEAM4 - 1;
 600         else if(t == 3)
 601                 _color = COLOR_TEAM3 - 1;
 602         else if(t == 2)
 603                 _color = COLOR_TEAM2 - 1;
 604         else
 605                 _color = COLOR_TEAM1 - 1;
 606
 607         SetPlayerColors(pl,_color);
 608
 609         if(t != s) {
 610                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 611
 612                 if(!noprint)
 613                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 614         }
 615
 616 }
 617
 618 // set c1...c4 to show what teams are allowed
 619 void CheckAllowedTeams (entity for_whom)
 620 {
 621         float dm;
 622         entity head;
 623         string teament_name;
 624
 625         c1 = c2 = c3 = c4 = -1;
 626         cb1 = cb2 = cb3 = cb4 = 0;
 627
 628         if(cvar("g_campaign") && for_whom && clienttype(for_whom) == CLIENTTYPE_REAL)
 629         {
 630                 c1 = 0; // only allow RED team for player joining
 631         }
 632         else if(g_onslaught)
 633         {
 634                 // onslaught is special
 635                 head = findchain(classname, "onslaught_generator");
 636                 while (head)
 637                 {
 638                         if (head.team == COLOR_TEAM1) c1 = 0;
 639                         if (head.team == COLOR_TEAM2) c2 = 0;
 640                         if (head.team == COLOR_TEAM3) c3 = 0;
 641                         if (head.team == COLOR_TEAM4) c4 = 0;
 642                         head = head.chain;
 643                 }
 644         }
 645         else if(g_domination)
 646                 teament_name = "dom_team";
 647         else if(g_ctf)
 648                 teament_name = "ctf_team";
 649         else if(g_tdm)
 650                 teament_name = "tdm_team";
 651         else if(g_nexball)
 652                 teament_name = "nexball_team";
 653         else if(g_assault)
 654                 c1 = c2 = 0; // Assault always has 2 teams
 655         else
 656         {
 657                 // cover anything else by treating it like tdm with no teams spawned
 658                 if(g_race)
 659                         dm = race_teams;
 660                 else
 661                         dm = 2;
 662
 663                 ret_float = dm;
 664                 MUTATOR_CALLHOOK(GetTeamCount);
 665                 dm = ret_float;
 666
 667                 if(dm >= 4)
 668                         c1 = c2 = c3 = c4 = 0;
 669                 else if(dm >= 3)
 670                         c1 = c2 = c3 = 0;
 671                 else
 672                         c1 = c2 = 0;
 673         }
 674
 675         // find out what teams are allowed if necessary
 676         if(teament_name)
 677         {
 678                 head = find(world, classname, teament_name);
 679                 while(head)
 680                 {
 681                         if(!(g_domination && head.netname == ""))
 682                         {
 683                                 if(head.team == COLOR_TEAM1)
 684                                         c1 = 0;
 685                                 else if(head.team == COLOR_TEAM2)
 686                                         c2 = 0;
 687                                 else if(head.team == COLOR_TEAM3)
 688                                         c3 = 0;
 689                                 else if(head.team == COLOR_TEAM4)
 690                                         c4 = 0;
 691                         }
 692                         head = find(head, classname, teament_name);
 693                 }
 694         }
 695
 696         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 697         if(c3==-1 && c4==-1)
 698         if(cvar("bot_vs_human") && for_whom)
 699         {
 700                 if(cvar("bot_vs_human") > 0)
 701                 {
 702                         // bots are all blue
 703                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 704                                 c1 = c3 = c4 = -1;
 705                         else
 706                                 c2 = -1;
 707                 }
 708                 else
 709                 {
 710                         // bots are all red
 711                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 712                                 c2 = c3 = c4 = -1;
 713                         else
 714                                 c1 = -1;
 715                 }
 716         }
 717 }
 718
 719 float PlayerValue(entity p)
 720 {
 721         if(IsTeamBalanceForced() == 1)
 722                 return 1;
 723         return 1;
 724         // FIXME: it always returns 1...
 725 }
 726
 727 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 728 // teams that are allowed will now have their player counts stored in c1...c4
 729 void GetTeamCounts(entity ignore)
 730 {
 731         entity head;
 732         float value, bvalue;
 733         // now count how many players are on each team already
 734
 735         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 736         // also remember the lowest-scoring player
 737
 738         FOR_EACH_PLAYER(head)
 739         {
 740                 if(head != ignore)// && head.netname != "")
 741                 {
 742                         value = PlayerValue(head);
 743                         if(clienttype(head) == CLIENTTYPE_BOT)
 744                                 bvalue = value;
 745                         else
 746                                 bvalue = 0;
 747                         if(head.team == COLOR_TEAM1)
 748                         {
 749                                 if(c1 >= 0)
 750                                 {
 751                                         c1 = c1 + value;
 752                                         cb1 = cb1 + bvalue;
 753                                 }
 754                         }
 755                         if(head.team == COLOR_TEAM2)
 756                         {
 757                                 if(c2 >= 0)
 758                                 {
 759                                         c2 = c2 + value;
 760                                         cb2 = cb2 + bvalue;
 761                                 }
 762                         }
 763                         if(head.team == COLOR_TEAM3)
 764                         {
 765                                 if(c3 >= 0)
 766                                 {
 767                                         c3 = c3 + value;
 768                                         cb3 = cb3 + bvalue;
 769                                 }
 770                         }
 771                         if(head.team == COLOR_TEAM4)
 772                         {
 773                                 if(c4 >= 0)
 774                                 {
 775                                         c4 = c4 + value;
 776                                         cb4 = cb4 + bvalue;
 777                                 }
 778                         }
 779                 }
 780         }
 781 }
 782
 783 // returns # of smallest team (1, 2, 3, 4)
 784 // NOTE: Assumes CheckAllowedTeams has already been called!
 785 float FindSmallestTeam(entity pl, float ignore_pl)
 786 {
 787         float totalteams, balance_type, maxc;
 788         totalteams = 0;
 789
 790         // find out what teams are available
 791         //CheckAllowedTeams();
 792
 793         // make sure there are at least 2 teams to join
 794         if(c1 >= 0)
 795                 totalteams = totalteams + 1;
 796         if(c2 >= 0)
 797                 totalteams = totalteams + 1;
 798         if(c3 >= 0)
 799                 totalteams = totalteams + 1;
 800         if(c4 >= 0)
 801                 totalteams = totalteams + 1;
 802
 803         if(cvar("bot_vs_human") && totalteams == 1)
 804                 totalteams += 1;
 805
 806         if(totalteams <= 1)
 807         {
 808                 if(cvar("g_campaign") && pl && clienttype(pl) == CLIENTTYPE_REAL)
 809                         return 1; // special case for campaign and player joining
 810                 else if(g_domination)
 811                         error("Too few teams available for domination\n");
 812                 else if(g_ctf)
 813                         error("Too few teams available for ctf\n");
 814                 else if(g_keyhunt)
 815                         error("Too few teams available for key hunt\n");
 816                 else
 817                         error("Too few teams available for team deathmatch\n");
 818         }
 819
 820         // count how many players are in each team
 821         if(ignore_pl)
 822                 GetTeamCounts(pl);
 823         else
 824                 GetTeamCounts(world);
 825
 826         // c1...c4 now have counts of each team
 827         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 828
 829         // 2 gives priority to what team you're already on, 1 goes in order
 830         // 2 doesn't seem to work though...
 831         balance_type = 1;
 832
 833         if(bots_would_leave)
 834         //if(pl.classname != "player")
 835         if(clienttype(pl) != CLIENTTYPE_BOT)
 836         {
 837                 c1 -= cb1 * 255.0/256.0;
 838                 c2 -= cb2 * 255.0/256.0;
 839                 c3 -= cb3 * 255.0/256.0;
 840                 c4 -= cb4 * 255.0/256.0;
 841         }
 842         maxc = max4(c1, c2, c3, c4);
 843
 844         RandomSelection_Init();
 845         if(balance_type == 1)
 846         {
 847                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 848                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 849                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 850                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 851                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 852         }
 853         else if(balance_type == 2)
 854         {
 855                 // 1: use team count, if equal prefer own team
 856                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 857                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 858                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 859                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 860         }
 861         else if(balance_type == 3)
 862         {
 863                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 864                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 865                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 866                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 867                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 868         }
 869         return RandomSelection_chosen_float;
 870 }
 871
 872 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 873 {
 874         float smallest, selectedteam;
 875
 876         // don't join a team if we're not playing a team game
 877         if(!teams_matter)
 878                 return 0;
 879
 880         // find out what teams are available
 881         CheckAllowedTeams(pl);
 882
 883         // if we want the player in a certain team for campaign, force him there
 884         if(cvar("g_campaign"))
 885         if(clienttype(pl) == CLIENTTYPE_REAL) // only players, not bots
 886         {
 887                 switch(cvar("g_campaign_forceteam"))
 888                 {
 889                         case 1:
 890                                 SetPlayerColors(pl, COLOR_TEAM1 - 1);
 891                                 LogTeamchange(pl.playerid, pl.team, 2);
 892                                 return COLOR_TEAM1;
 893                         case 2:
 894                                 SetPlayerColors(pl, COLOR_TEAM2 - 1);
 895                                 LogTeamchange(pl.playerid, pl.team, 2);
 896                                 return COLOR_TEAM2;
 897                         case 3:
 898                                 SetPlayerColors(pl, COLOR_TEAM3 - 1);
 899                                 LogTeamchange(pl.playerid, pl.team, 2);
 900                                 return COLOR_TEAM3;
 901                         case 4:
 902                                 SetPlayerColors(pl, COLOR_TEAM4 - 1);
 903                                 LogTeamchange(pl.playerid, pl.team, 2);
 904                                 return COLOR_TEAM4;
 905                         default:
 906                                 break;
 907                 }
 908         }
 909
 910         // if we don't care what team he ends up on, put him on whatever team he entered as.
 911         // if he's not on a valid team, then let other code put him on the smallest team
 912         if(!forcebestteam)
 913         {
 914                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 915                         selectedteam = pl.team;
 916                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 917                         selectedteam = pl.team;
 918                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 919                         selectedteam = pl.team;
 920                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 921                         selectedteam = pl.team;
 922                 else
 923                         selectedteam = -1;
 924
 925                 if(selectedteam > 0)
 926                 {
 927                         if(!only_return_best)
 928                         {
 929                                 SetPlayerColors(pl, selectedteam - 1);
 930
 931                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 932                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 933                                 LogTeamchange(pl.playerid, pl.team, 99);
 934                         }
 935                         return selectedteam;
 936                 }
 937                 // otherwise end up on the smallest team (handled below)
 938         }
 939
 940         smallest = FindSmallestTeam(pl, TRUE);
 941
 942         if(!only_return_best && !pl.bot_forced_team)
 943         {
 944                 TeamchangeFrags(self);
 945                 if(smallest == 1)
 946                 {
 947                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 948                 }
 949                 else if(smallest == 2)
 950                 {
 951                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 952                 }
 953                 else if(smallest == 3)
 954                 {
 955                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 956                 }
 957                 else if(smallest == 4)
 958                 {
 959                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 960                 }
 961                 else
 962                 {
 963                         error("smallest team: invalid team\n");
 964                 }
 965
 966                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 967
 968                 if(pl.deadflag == DEAD_NO)
 969                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 970         }
 971
 972         return smallest;
 973 }
 974
 975 //void() ctf_playerchanged;
 976 void SV_ChangeTeam(float _color)
 977 {
 978         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 979
 980         // in normal deathmatch we can just apply the color and we're done
 981         if(!teams_matter) {
 982                 SetPlayerColors(self, _color);
 983                 return;
 984         }
 985
 986         scolor = self.clientcolors & 0x0F;
 987         dcolor = _color & 0x0F;
 988
 989         if(scolor == COLOR_TEAM1 - 1)
 990                 steam = 1;
 991         else if(scolor == COLOR_TEAM2 - 1)
 992                 steam = 2;
 993         else if(scolor == COLOR_TEAM3 - 1)
 994                 steam = 3;
 995         else // if(scolor == COLOR_TEAM4 - 1)
 996                 steam = 4;
 997         if(dcolor == COLOR_TEAM1 - 1)
 998                 dteam = 1;
 999         else if(dcolor == COLOR_TEAM2 - 1)
1000                 dteam = 2;
1001         else if(dcolor == COLOR_TEAM3 - 1)
1002                 dteam = 3;
1003         else // if(dcolor == COLOR_TEAM4 - 1)
1004                 dteam = 4;
1005
1006         CheckAllowedTeams(self);
1007
1008         if(dteam == 1 && c1 < 0) dteam = 4;
1009         if(dteam == 4 && c4 < 0) dteam = 3;
1010         if(dteam == 3 && c3 < 0) dteam = 2;
1011         if(dteam == 2 && c2 < 0) dteam = 1;
1012
1013         // not changing teams
1014         if(scolor == dcolor)
1015         {
1016                 //bprint("same team change\n");
1017                 SetPlayerTeam(self, dteam, steam, TRUE);
1018                 return;
1019         }
1020
1021         if((cvar("g_campaign")) || (cvar("g_changeteam_banned") && self.wasplayer)) {
1022                 sprint(self, "Team changes not allowed\n");
1023                 return; // changing teams is not allowed
1024         }
1025
1026         if(cvar("g_balance_teams_prevent_imbalance"))
1027         {
1028                 // only allow changing to a smaller or equal size team
1029
1030                 // find out what teams are available
1031                 //CheckAllowedTeams();
1032                 // count how many players on each team
1033                 GetTeamCounts(world);
1034
1035                 // get desired team
1036                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1037                 {
1038                         dcount = c1;
1039                         dbotcount = cb1;
1040                 }
1041                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1042                 {
1043                         dcount = c2;
1044                         dbotcount = cb2;
1045                 }
1046                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1047                 {
1048                         dcount = c3;
1049                         dbotcount = cb3;
1050                 }
1051                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1052                 {
1053                         dcount = c4;
1054                         dbotcount = cb4;
1055                 }
1056                 else
1057                 {
1058                         sprint(self, "Cannot change to an invalid team\n");
1059
1060                         return;
1061                 }
1062
1063                 // get starting team
1064                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1065                         scount = c1;
1066                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1067                         scount = c2;
1068                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1069                         scount = c3;
1070                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1071                         scount = c4;
1072
1073                 if(scount) // started at a valid, nonempty team
1074                 {
1075                         // check if we're trying to change to a larger team that doens't have bots to swap with
1076                         if(dcount >= scount && dbotcount <= 0)
1077                         {
1078                                 sprint(self, "Cannot change to a larger team\n");
1079                                 return; // can't change to a larger team
1080                         }
1081                 }
1082         }
1083
1084 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1085
1086         if(self.classname == "player" && steam != dteam)
1087         {
1088                 // reduce frags during a team change
1089                 TeamchangeFrags(self);
1090         }
1091
1092         SetPlayerTeam(self, dteam, steam, FALSE);
1093
1094         if(self.classname == "player" && steam != dteam)
1095         {
1096                 // kill player when changing teams
1097                 if(self.deadflag == DEAD_NO)
1098                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1099         }
1100         //ctf_playerchanged();
1101 }
1102
1103 void ShufflePlayerOutOfTeam (float source_team)
1104 {
1105         float smallestteam, smallestteam_count, steam;
1106         float lowest_bot_score, lowest_player_score;
1107         entity head, lowest_bot, lowest_player, selected;
1108
1109         smallestteam = 0;
1110         smallestteam_count = 999999999;
1111
1112         if(c1 >= 0 && c1 < smallestteam_count)
1113         {
1114                 smallestteam = 1;
1115                 smallestteam_count = c1;
1116         }
1117         if(c2 >= 0 && c2 < smallestteam_count)
1118         {
1119                 smallestteam = 2;
1120                 smallestteam_count = c2;
1121         }
1122         if(c3 >= 0 && c3 < smallestteam_count)
1123         {
1124                 smallestteam = 3;
1125                 smallestteam_count = c3;
1126         }
1127         if(c4 >= 0 && c4 < smallestteam_count)
1128         {
1129                 smallestteam = 4;
1130                 smallestteam_count = c4;
1131         }
1132
1133         if(!smallestteam)
1134         {
1135                 bprint("warning: no smallest team\n");
1136                 return;
1137         }
1138
1139         if(source_team == 1)
1140                 steam = COLOR_TEAM1;
1141         else if(source_team == 2)
1142                 steam = COLOR_TEAM2;
1143         else if(source_team == 3)
1144                 steam = COLOR_TEAM3;
1145         else if(source_team == 4)
1146                 steam = COLOR_TEAM4;
1147
1148         lowest_bot = world;
1149         lowest_bot_score = 999999999;
1150         lowest_player = world;
1151         lowest_player_score = 999999999;
1152
1153         // find the lowest-scoring player & bot of that team
1154         FOR_EACH_PLAYER(head)
1155         {
1156                 if(head.team == steam)
1157                 {
1158                         if(head.isbot)
1159                         {
1160                                 if(head.totalfrags < lowest_bot_score)
1161                                 {
1162                                         lowest_bot = head;
1163                                         lowest_bot_score = head.totalfrags;
1164                                 }
1165                         }
1166                         else
1167                         {
1168                                 if(head.totalfrags < lowest_player_score)
1169                                 {
1170                                         lowest_player = head;
1171                                         lowest_player_score = head.totalfrags;
1172                                 }
1173                         }
1174                 }
1175         }
1176
1177         // prefers to move a bot...
1178         if(lowest_bot != world)
1179                 selected = lowest_bot;
1180         // but it will move a player if it has to
1181         else
1182                 selected = lowest_player;
1183         // don't do anything if it couldn't find anyone
1184         if(!selected)
1185         {
1186                 bprint("warning: couldn't find a player to move from team\n");
1187                 return;
1188         }
1189
1190         // smallest team gains a member
1191         if(smallestteam == 1)
1192         {
1193                 c1 = c1 + 1;
1194         }
1195         else if(smallestteam == 2)
1196         {
1197                 c2 = c2 + 1;
1198         }
1199         else if(smallestteam == 3)
1200         {
1201                 c3 = c3 + 1;
1202         }
1203         else if(smallestteam == 4)
1204         {
1205                 c4 = c4 + 1;
1206         }
1207         else
1208         {
1209                 bprint("warning: destination team invalid\n");
1210                 return;
1211         }
1212         // source team loses a member
1213         if(source_team == 1)
1214         {
1215                 c1 = c1 + 1;
1216         }
1217         else if(source_team == 2)
1218         {
1219                 c2 = c2 + 2;
1220         }
1221         else if(source_team == 3)
1222         {
1223                 c3 = c3 + 3;
1224         }
1225         else if(source_team == 4)
1226         {
1227                 c4 = c4 + 4;
1228         }
1229         else
1230         {
1231                 bprint("warning: source team invalid\n");
1232                 return;
1233         }
1234
1235         // move the player to the new team
1236         TeamchangeFrags(selected);
1237         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1238
1239         if(selected.deadflag == DEAD_NO)
1240                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1241         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1242 }
1243
1244 void CauseRebalance(float source_team, float howmany_toomany)
1245 {
1246         if(IsTeamBalanceForced() == 1)
1247         {
1248                 bprint("Rebalancing Teams\n");
1249                 ShufflePlayerOutOfTeam(source_team);
1250         }
1251 }
1252
1253 // part of g_balance_teams_force
1254 // occasionally perform an audit of the teams to make
1255 // sure they're more or less balanced in player count.
1256 void AuditTeams()
1257 {
1258         float numplayers, numteams, smallest, toomany;
1259         float balance;
1260         balance = IsTeamBalanceForced();
1261         if(balance == 0)
1262                 return;
1263
1264         if(audit_teams_time > time)
1265                 return;
1266
1267         audit_teams_time = time + 4 + random();
1268
1269 //      bprint("Auditing teams\n");
1270
1271         CheckAllowedTeams(world);
1272         GetTeamCounts(world);
1273
1274
1275         numteams = numplayers = smallest = 0;
1276         if(c1 >= 0)
1277         {
1278                 numteams = numteams + 1;
1279                 numplayers = numplayers + c1;
1280                 smallest = c1;
1281         }
1282         if(c2 >= 0)
1283         {
1284                 numteams = numteams + 1;
1285                 numplayers = numplayers + c2;
1286                 if(c2 < smallest)
1287                         smallest = c2;
1288         }
1289         if(c3 >= 0)
1290         {
1291                 numteams = numteams + 1;
1292                 numplayers = numplayers + c3;
1293                 if(c3 < smallest)
1294                         smallest = c3;
1295         }
1296         if(c4 >= 0)
1297         {
1298                 numteams = numteams + 1;
1299                 numplayers = numplayers + c4;
1300                 if(c4 < smallest)
1301                         smallest = c4;
1302         }
1303
1304         if(numplayers <= 0)
1305                 return; // no players to move around
1306         if(numteams < 2)
1307                 return; // don't bother shuffling if for some reason there aren't any teams
1308
1309         toomany = smallest + 1;
1310
1311         if(c1 && c1 > toomany)
1312                 CauseRebalance(1, c1 - toomany);
1313         if(c2 && c2 > toomany)
1314                 CauseRebalance(2, c2 - toomany);
1315         if(c3 && c3 > toomany)
1316                 CauseRebalance(3, c3 - toomany);
1317         if(c4 && c4 > toomany)
1318                 CauseRebalance(4, c4 - toomany);
1319
1320         // if teams are still unbalanced, balance them further in the next audit,
1321         // which will happen sooner (keep doing rapid audits until things are in order)
1322         audit_teams_time = time + 0.7 + random()*0.3;
1323 }
1324
1325 // code from here on is just to support maps that don't have team entities
1326 void tdm_spawnteam (string teamname, float teamcolor)
1327 {
1328         local entity e;
1329         e = spawn();
1330         e.classname = "tdm_team";
1331         e.netname = teamname;
1332         e.cnt = teamcolor;
1333         e.team = e.cnt + 1;
1334 };
1335
1336 // spawn some default teams if the map is not set up for tdm
1337 void tdm_spawnteams()
1338 {
1339         float numteams;
1340
1341         numteams = cvar("g_tdm_teams_override");
1342         if(numteams < 2)
1343                 numteams = cvar("g_tdm_teams");
1344         numteams = bound(2, numteams, 4);
1345
1346         tdm_spawnteam("Red", COLOR_TEAM1-1);
1347         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1348         if(numteams >= 3)
1349                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1350         if(numteams >= 4)
1351                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1352 };
1353
1354 void tdm_delayedinit()
1355 {
1356         // if no teams are found, spawn defaults
1357         if (find(world, classname, "tdm_team") == world)
1358                 tdm_spawnteams();
1359 };
1360
1361 void tdm_init()
1362 {
1363         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1364 };