qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2
   3 #include "client.qh"
   4 #include "race.qh"
   5 #include "scores.qh"
   6 #include "scores_rules.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/vote.qh"
  11
  12 #include <server/mutators/_mod.qh>
  13
  14 #include "../common/deathtypes/all.qh"
  15 #include <common/gamemodes/_mod.qh>
  16 #include "../common/teams.qh"
  17
  18 /// \brief Describes a state of team balance entity.
  19 enum
  20 {
  21         TEAM_BALANCE_UNINITIALIZED, ///< The team balance has not been initialized.
  22         /// \brief TeamBalance_CheckAllowedTeams has been called.
  23         TEAM_BALANCE_TEAMS_CHECKED,
  24         /// \brief TeamBalance_GetTeamCounts has been called.
  25         TEAM_BALANCE_TEAM_COUNTS_FILLED
  26 };
  27
  28 /// \brief Indicates that the player is not allowed to join a team.
  29 const int TEAM_NOT_ALLOWED = -1;
  30
  31 .float team_forced; // can be a team number to force a team, or 0 for default action, or -1 for forced spectator
  32
  33 .int m_team_balance_state; ///< Holds the state of the team balance entity.
  34 .entity m_team_balance_team[NUM_TEAMS]; ///< ???
  35
  36 .float m_team_score; ///< The score of the team.
  37 .int m_num_players; ///< Number of players (both humans and bots) in a team.
  38 .int m_num_bots; ///< Number of bots in a team.
  39 .int m_num_players_alive; ///< Number of alive players in a team.
  40 .int m_num_control_points; ///< Number of control points owned by a team.
  41
  42 string autocvar_g_forced_team_red;
  43 string autocvar_g_forced_team_blue;
  44 string autocvar_g_forced_team_yellow;
  45 string autocvar_g_forced_team_pink;
  46
  47 entity g_team_entities[NUM_TEAMS]; ///< Holds global team entities.
  48
  49 STATIC_INIT(g_team_entities)
  50 {
  51         for (int i = 0; i < NUM_TEAMS; ++i)
  52         {
  53                 g_team_entities[i] = spawn();
  54         }
  55 }
  56
  57 entity Team_GetTeamFromIndex(int index)
  58 {
  59         if (!Team_IsValidIndex(index))
  60         {
  61                 LOG_FATALF("Team_GetTeamFromIndex: Index is invalid: %f", index);
  62         }
  63         return g_team_entities[index - 1];
  64 }
  65
  66 entity Team_GetTeam(int team_num)
  67 {
  68         if (!Team_IsValidTeam(team_num))
  69         {
  70                 LOG_FATALF("Team_GetTeam: Value is invalid: %f", team_num);
  71         }
  72         return g_team_entities[Team_TeamToIndex(team_num) - 1];
  73 }
  74
  75 float Team_GetTeamScore(entity team_ent)
  76 {
  77         return team_ent.m_team_score;
  78 }
  79
  80 void Team_SetTeamScore(entity team_ent, float score)
  81 {
  82         team_ent.m_team_score = score;
  83 }
  84
  85 int Team_GetNumberOfAlivePlayers(entity team_ent)
  86 {
  87         return team_ent.m_num_players_alive;
  88 }
  89
  90 void Team_SetNumberOfAlivePlayers(entity team_ent, int number)
  91 {
  92         team_ent.m_num_players_alive = number;
  93 }
  94
  95 int Team_GetNumberOfAliveTeams()
  96 {
  97         int result = 0;
  98         for (int i = 0; i < NUM_TEAMS; ++i)
  99         {
 100                 if (g_team_entities[i].m_num_players_alive > 0)
 101                 {
 102                         ++result;
 103                 }
 104         }
 105         return result;
 106 }
 107
 108 int Team_GetNumberOfControlPoints(entity team_ent)
 109 {
 110         return team_ent.m_num_control_points;
 111 }
 112
 113 void Team_SetNumberOfControlPoints(entity team_ent, int number)
 114 {
 115         team_ent.m_num_control_points = number;
 116 }
 117
 118 int Team_GetNumberOfTeamsWithControlPoints()
 119 {
 120         int result = 0;
 121         for (int i = 0; i < NUM_TEAMS; ++i)
 122         {
 123                 if (g_team_entities[i].m_num_control_points > 0)
 124                 {
 125                         ++result;
 126                 }
 127         }
 128         return result;
 129 }
 130
 131 void setcolor(entity this, int clr)
 132 {
 133 #if 0
 134         this.clientcolors = clr;
 135         this.team = (clr & 15) + 1;
 136 #else
 137         builtin_setcolor(this, clr);
 138 #endif
 139 }
 140
 141 bool Entity_HasValidTeam(entity this)
 142 {
 143         return Team_IsValidTeam(this.team);
 144 }
 145
 146 int Entity_GetTeamIndex(entity this)
 147 {
 148         return Team_TeamToIndex(this.team);
 149 }
 150
 151 entity Entity_GetTeam(entity this)
 152 {
 153         int index = Entity_GetTeamIndex(this);
 154         if (!Team_IsValidIndex(index))
 155         {
 156                 return NULL;
 157         }
 158         return Team_GetTeamFromIndex(index);
 159 }
 160
 161 void SetPlayerColors(entity player, float _color)
 162 {
 163         float pants = _color & 0x0F;
 164         float shirt = _color & 0xF0;
 165         if (teamplay)
 166         {
 167                 setcolor(player, 16 * pants + pants);
 168         }
 169         else
 170         {
 171                 setcolor(player, shirt + pants);
 172         }
 173 }
 174
 175 bool Player_SetTeamIndex(entity player, int index)
 176 {
 177         int new_team = Team_IndexToTeam(index);
 178         if (player.team == new_team)
 179         {
 180                 if (new_team != -1)
 181                 {
 182                         // This is important when players join the game and one of their
 183                         // color matches the team color while other doesn't. For example
 184                         // [BOT]Lion.
 185                         SetPlayerColors(player, new_team - 1);
 186                 }
 187                 return true;
 188         }
 189         int old_index = Team_TeamToIndex(player.team);
 190         if (MUTATOR_CALLHOOK(Player_ChangeTeam, player, old_index, index) == true)
 191         {
 192                 // Mutator has blocked team change.
 193                 return false;
 194         }
 195         if (new_team == -1)
 196         {
 197                 player.team = -1;
 198         }
 199         else
 200         {
 201                 SetPlayerColors(player, new_team - 1);
 202         }
 203         MUTATOR_CALLHOOK(Player_ChangedTeam, player, old_index, index);
 204         return true;
 205 }
 206
 207 bool SetPlayerTeam(entity player, int team_index, int type)
 208 {
 209         int old_team_index = Entity_GetTeamIndex(player);
 210         if (!Player_SetTeamIndex(player, team_index))
 211         {
 212                 return false;
 213         }
 214         LogTeamChange(player.playerid, player.team, type);
 215         if (team_index != old_team_index)
 216         {
 217                 PlayerScore_Clear(player);
 218                 if (team_index != -1)
 219                 {
 220                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(
 221                                 player.team, INFO_JOIN_PLAY_TEAM), player.netname);
 222                 }
 223                 else
 224                 {
 225                         if (!CS(player).just_joined)
 226                         {
 227                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE,
 228                                         player.netname);
 229                         }
 230                         else
 231                         {
 232                                 CS(player).just_joined = false;
 233                         }
 234                 }
 235                 KillPlayerForTeamChange(player);
 236                 if (!IS_BOT_CLIENT(player))
 237                 {
 238                         TeamBalance_AutoBalanceBots();
 239                 }
 240         }
 241         return true;
 242 }
 243
 244 void Player_SetTeamIndexChecked(entity player, int team_index)
 245 {
 246         if (!teamplay)
 247         {
 248                 return;
 249         }
 250         if (!Team_IsValidIndex(team_index))
 251         {
 252                 return;
 253         }
 254         if ((autocvar_g_campaign) || (autocvar_g_changeteam_banned &&
 255                 CS(player).wasplayer))
 256         {
 257                 Send_Notification(NOTIF_ONE, player, MSG_INFO,
 258                         INFO_TEAMCHANGE_NOTALLOWED);
 259                 return;
 260         }
 261         entity balance = TeamBalance_CheckAllowedTeams(player);
 262         if (team_index == 1 && !TeamBalance_IsTeamAllowedInternal(balance, 1))
 263         {
 264                 team_index = 4;
 265         }
 266         if (team_index == 4 && !TeamBalance_IsTeamAllowedInternal(balance, 4))
 267         {
 268                 team_index = 3;
 269         }
 270         if (team_index == 3 && !TeamBalance_IsTeamAllowedInternal(balance, 3))
 271         {
 272                 team_index = 2;
 273         }
 274         if (team_index == 2 && !TeamBalance_IsTeamAllowedInternal(balance, 2))
 275         {
 276                 team_index = 1;
 277         }
 278         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 279         if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 280         {
 281                 TeamBalance_GetTeamCounts(balance, player);
 282                 if ((Team_IndexToBit(team_index) & TeamBalance_FindBestTeams(balance,
 283                         player, false)) == 0)
 284                 {
 285                         Send_Notification(NOTIF_ONE, player, MSG_INFO,
 286                                 INFO_TEAMCHANGE_LARGERTEAM);
 287                         TeamBalance_Destroy(balance);
 288                         return;
 289                 }
 290         }
 291         TeamBalance_Destroy(balance);
 292         SetPlayerTeam(player, team_index, TEAM_CHANGE_MANUAL);
 293 }
 294
 295 bool MoveToTeam(entity client, int team_index, int type)
 296 {
 297         //PrintToChatAll(sprintf("MoveToTeam: %s, %f", client.netname, team_index));
 298         int lockteams_backup = lockteams;  // backup any team lock
 299         lockteams = 0;  // disable locked teams
 300         if (!SetPlayerTeam(client, team_index, type))
 301         {
 302                 lockteams = lockteams_backup;  // restore the team lock
 303                 return false;
 304         }
 305         lockteams = lockteams_backup;  // restore the team lock
 306         return true;
 307 }
 308
 309 bool Player_HasRealForcedTeam(entity player)
 310 {
 311         return player.team_forced > TEAM_FORCE_DEFAULT;
 312 }
 313
 314 int Player_GetForcedTeamIndex(entity player)
 315 {
 316         return player.team_forced;
 317 }
 318
 319 void Player_SetForcedTeamIndex(entity player, int team_index)
 320 {
 321         switch (team_index)
 322         {
 323                 case TEAM_FORCE_SPECTATOR:
 324                 case TEAM_FORCE_DEFAULT:
 325                 {
 326                         player.team_forced = team_index;
 327                         break;
 328                 }
 329                 default:
 330                 {
 331                         if (!Team_IsValidIndex(team_index))
 332                         {
 333                                 LOG_FATAL("Player_SetForcedTeamIndex: Invalid team index.");
 334                         }
 335                         else
 336                         {
 337                                 player.team_forced = team_index;
 338                                 break;
 339                         }
 340                 }
 341         }
 342 }
 343
 344 void Player_DetermineForcedTeam(entity player)
 345 {
 346         if (autocvar_g_campaign)
 347         {
 348                 if (IS_REAL_CLIENT(player)) // only players, not bots
 349                 {
 350                         if (Team_IsValidIndex(autocvar_g_campaign_forceteam))
 351                         {
 352                                 player.team_forced = autocvar_g_campaign_forceteam;
 353                         }
 354                         else
 355                         {
 356                                 player.team_forced = TEAM_FORCE_DEFAULT;
 357                         }
 358                 }
 359         }
 360         else if (PlayerInList(player, autocvar_g_forced_team_red))
 361         {
 362                 player.team_forced = 1;
 363         }
 364         else if (PlayerInList(player, autocvar_g_forced_team_blue))
 365         {
 366                 player.team_forced = 2;
 367         }
 368         else if (PlayerInList(player, autocvar_g_forced_team_yellow))
 369         {
 370                 player.team_forced = 3;
 371         }
 372         else if (PlayerInList(player, autocvar_g_forced_team_pink))
 373         {
 374                 player.team_forced = 4;
 375         }
 376         else
 377         {
 378                 switch (autocvar_g_forced_team_otherwise)
 379                 {
 380                         case "red":
 381                         {
 382                                 player.team_forced = 1;
 383                                 break;
 384                         }
 385                         case "blue":
 386                         {
 387                                 player.team_forced = 2;
 388                                 break;
 389                         }
 390                         case "yellow":
 391                         {
 392                                 player.team_forced = 3;
 393                                 break;
 394                         }
 395                         case "pink":
 396                         {
 397                                 player.team_forced = 4;
 398                                 break;
 399                         }
 400                         case "spectate":
 401                         case "spectator":
 402                         {
 403                                 player.team_forced = TEAM_FORCE_SPECTATOR;
 404                                 break;
 405                         }
 406                         default:
 407                         {
 408                                 player.team_forced = TEAM_FORCE_DEFAULT;
 409                                 break;
 410                         }
 411                 }
 412         }
 413         if (!teamplay && Player_HasRealForcedTeam(player))
 414         {
 415                 player.team_forced = TEAM_FORCE_DEFAULT;
 416         }
 417 }
 418
 419 void TeamBalance_JoinBestTeam(entity player)
 420 {
 421         //PrintToChatAll(sprintf("TeamBalance_JoinBestTeam: %s", player.netname));
 422         if (!teamplay)
 423         {
 424                 return;
 425         }
 426         if (player.bot_forced_team)
 427         {
 428                 return;
 429         }
 430         entity balance = TeamBalance_CheckAllowedTeams(player);
 431         if (Player_HasRealForcedTeam(player))
 432         {
 433                 int forced_team_index = player.team_forced;
 434                 bool is_team_allowed = TeamBalance_IsTeamAllowedInternal(balance,
 435                         forced_team_index);
 436                 TeamBalance_Destroy(balance);
 437                 if (!is_team_allowed)
 438                 {
 439                         return;
 440                 }
 441                 if (!SetPlayerTeam(player, forced_team_index, TEAM_CHANGE_AUTO))
 442                 {
 443                         return;
 444                 }
 445                 return;
 446         }
 447         int best_team_index = TeamBalance_FindBestTeam(balance, player, true);
 448         TeamBalance_Destroy(balance);
 449         if (!SetPlayerTeam(player, best_team_index, TEAM_CHANGE_AUTO))
 450         {
 451                 return;
 452         }
 453 }
 454
 455 entity TeamBalance_CheckAllowedTeams(entity for_whom)
 456 {
 457         entity balance = spawn();
 458         for (int i = 0; i < NUM_TEAMS; ++i)
 459         {
 460                 entity team_ent = balance.m_team_balance_team[i] = spawn();
 461                 team_ent.m_team_score = g_team_entities[i].m_team_score;
 462                 team_ent.m_num_players = TEAM_NOT_ALLOWED;
 463                 team_ent.m_num_bots = 0;
 464         }
 465         setthink(balance, TeamBalance_Destroy);
 466
 467         int teams_mask = 0;
 468         string teament_name = string_null;
 469         bool mutator_returnvalue = MUTATOR_CALLHOOK(TeamBalance_CheckAllowedTeams,
 470                 teams_mask, teament_name, for_whom);
 471         teams_mask = M_ARGV(0, float);
 472         teament_name = M_ARGV(1, string);
 473         if (mutator_returnvalue)
 474         {
 475                 for (int i = 0; i < NUM_TEAMS; ++i)
 476                 {
 477                         if (teams_mask & BIT(i))
 478                         {
 479                                 balance.m_team_balance_team[i].m_num_players = 0;
 480                         }
 481                 }
 482         }
 483
 484         if (teament_name)
 485         {
 486                 entity head = find(NULL, classname, teament_name);
 487                 while (head)
 488                 {
 489                         if (Team_IsValidTeam(head.team))
 490                         {
 491                                 TeamBalance_GetTeam(balance, head.team).m_num_players = 0;
 492                         }
 493                         head = find(head, classname, teament_name);
 494                 }
 495         }
 496
 497         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 498         if (AvailableTeams() == 2)
 499         if (autocvar_bot_vs_human && for_whom)
 500         {
 501                 if (autocvar_bot_vs_human > 0)
 502                 {
 503                         // find last team available
 504                         if (IS_BOT_CLIENT(for_whom))
 505                         {
 506                                 if (TeamBalance_IsTeamAllowedInternal(balance, 4))
 507                                 {
 508                                         TeamBalance_BanTeamsExcept(balance, 4);
 509                                 }
 510                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 3))
 511                                 {
 512                                         TeamBalance_BanTeamsExcept(balance, 3);
 513                                 }
 514                                 else
 515                                 {
 516                                         TeamBalance_BanTeamsExcept(balance, 2);
 517                                 }
 518                                 // no further cases, we know at least 2 teams exist
 519                         }
 520                         else
 521                         {
 522                                 if (TeamBalance_IsTeamAllowedInternal(balance, 1))
 523                                 {
 524                                         TeamBalance_BanTeamsExcept(balance, 1);
 525                                 }
 526                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 2))
 527                                 {
 528                                         TeamBalance_BanTeamsExcept(balance, 2);
 529                                 }
 530                                 else
 531                                 {
 532                                         TeamBalance_BanTeamsExcept(balance, 3);
 533                                 }
 534                                 // no further cases, bots have one of the teams
 535                         }
 536                 }
 537                 else
 538                 {
 539                         // find first team available
 540                         if (IS_BOT_CLIENT(for_whom))
 541                         {
 542                                 if (TeamBalance_IsTeamAllowedInternal(balance, 1))
 543                                 {
 544                                         TeamBalance_BanTeamsExcept(balance, 1);
 545                                 }
 546                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 2))
 547                                 {
 548                                         TeamBalance_BanTeamsExcept(balance, 2);
 549                                 }
 550                                 else
 551                                 {
 552                                         TeamBalance_BanTeamsExcept(balance, 3);
 553                                 }
 554                                 // no further cases, we know at least 2 teams exist
 555                         }
 556                         else
 557                         {
 558                                 if (TeamBalance_IsTeamAllowedInternal(balance, 4))
 559                                 {
 560                                         TeamBalance_BanTeamsExcept(balance, 4);
 561                                 }
 562                                 else if (TeamBalance_IsTeamAllowedInternal(balance, 3))
 563                                 {
 564                                         TeamBalance_BanTeamsExcept(balance, 3);
 565                                 }
 566                                 else
 567                                 {
 568                                         TeamBalance_BanTeamsExcept(balance, 2);
 569                                 }
 570                                 // no further cases, bots have one of the teams
 571                         }
 572                 }
 573         }
 574
 575         if (!for_whom)
 576         {
 577                 balance.m_team_balance_state = TEAM_BALANCE_TEAMS_CHECKED;
 578                 return balance;
 579         }
 580
 581         // if player has a forced team, ONLY allow that one
 582         for (int i = 1; i <= NUM_TEAMS; ++i)
 583         {
 584                 if (for_whom.team_forced == i &&
 585                         TeamBalance_IsTeamAllowedInternal(balance, i))
 586                 {
 587                         TeamBalance_BanTeamsExcept(balance, i);
 588                         break;
 589                 }
 590         }
 591         balance.m_team_balance_state = TEAM_BALANCE_TEAMS_CHECKED;
 592         return balance;
 593 }
 594
 595 void TeamBalance_Destroy(entity balance)
 596 {
 597         if (balance == NULL)
 598         {
 599                 return;
 600         }
 601         for (int i = 0; i < NUM_TEAMS; ++i)
 602         {
 603                 delete(balance.(m_team_balance_team[i]));
 604         }
 605         delete(balance);
 606 }
 607
 608 int TeamBalance_GetAllowedTeams(entity balance)
 609 {
 610         if (balance == NULL)
 611         {
 612                 LOG_FATAL("TeamBalance_GetAllowedTeams: Team balance entity is NULL.");
 613         }
 614         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 615         {
 616                 LOG_FATAL("TeamBalance_GetAllowedTeams: "
 617                         "Team balance entity is not initialized.");
 618         }
 619         int result = 0;
 620         for (int i = 1; i <= NUM_TEAMS; ++i)
 621         {
 622                 if (TeamBalance_IsTeamAllowedInternal(balance, i))
 623                 {
 624                         result |= Team_IndexToBit(i);
 625                 }
 626         }
 627         return result;
 628 }
 629
 630 bool TeamBalance_IsTeamAllowed(entity balance, int index)
 631 {
 632         if (balance == NULL)
 633         {
 634                 LOG_FATAL("TeamBalance_IsTeamAllowed: Team balance entity is NULL.");
 635         }
 636         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 637         {
 638                 LOG_FATAL("TeamBalance_IsTeamAllowed: "
 639                         "Team balance entity is not initialized.");
 640         }
 641         if (!Team_IsValidIndex(index))
 642         {
 643                 LOG_FATALF("TeamBalance_IsTeamAllowed: Team index is invalid: %f",
 644                         index);
 645         }
 646         return TeamBalance_IsTeamAllowedInternal(balance, index);
 647 }
 648
 649 void TeamBalance_GetTeamCounts(entity balance, entity ignore)
 650 {
 651         if (balance == NULL)
 652         {
 653                 LOG_FATAL("TeamBalance_GetTeamCounts: Team balance entity is NULL.");
 654         }
 655         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 656         {
 657                 LOG_FATAL("TeamBalance_GetTeamCounts: "
 658                         "Team balance entity is not initialized.");
 659         }
 660         if (MUTATOR_CALLHOOK(TeamBalance_GetTeamCounts) == true)
 661         {
 662                 // Mutator has overriden the configuration.
 663                 for (int i = 1; i <= NUM_TEAMS; ++i)
 664                 {
 665                         entity team_ent = TeamBalance_GetTeamFromIndex(balance, i);
 666                         if (TeamBalanceTeam_IsAllowed(team_ent))
 667                         {
 668                                 MUTATOR_CALLHOOK(TeamBalance_GetTeamCount, i, ignore);
 669                                 team_ent.m_num_players = M_ARGV(2, float);
 670                                 team_ent.m_num_bots = M_ARGV(3, float);
 671                         }
 672                 }
 673         }
 674         else
 675         {
 676                 // Manually count all players.
 677                 FOREACH_CLIENT(true,
 678                 {
 679                         if (it == ignore)
 680                         {
 681                                 continue;
 682                         }
 683                         int team_num;
 684                         // TODO: Reconsider when the player is truly on the team.
 685                         if (IS_CLIENT(it) || (it.caplayer))
 686                         {
 687                                 team_num = it.team;
 688                         }
 689                         else if (Player_HasRealForcedTeam(it))
 690                         {
 691                                 // Do we really need this? Probably not.
 692                                 team_num = Team_IndexToTeam(it.team_forced); // reserve the spot
 693                         }
 694                         else
 695                         {
 696                                 continue;
 697                         }
 698                         if (!Team_IsValidTeam(team_num))
 699                         {
 700                                 continue;
 701                         }
 702                         entity team_ent = TeamBalance_GetTeam(balance, team_num);
 703                         if (!TeamBalanceTeam_IsAllowed(team_ent))
 704                         {
 705                                 continue;
 706                         }
 707                         ++team_ent.m_num_players;
 708                         if (IS_BOT_CLIENT(it))
 709                         {
 710                                 ++team_ent.m_num_bots;
 711                         }
 712                 });
 713         }
 714
 715         // if the player who has a forced team has not joined yet, reserve the spot
 716         if (autocvar_g_campaign)
 717         {
 718                 if (Team_IsValidIndex(autocvar_g_campaign_forceteam))
 719                 {
 720                         entity team_ent = TeamBalance_GetTeamFromIndex(balance,
 721                                 autocvar_g_campaign_forceteam);
 722                         if (team_ent.m_num_players == team_ent.m_num_bots)
 723                         {
 724                                 ++team_ent.m_num_players;
 725                         }
 726                 }
 727         }
 728         balance.m_team_balance_state = TEAM_BALANCE_TEAM_COUNTS_FILLED;
 729 }
 730
 731 int TeamBalance_GetNumberOfPlayers(entity balance, int index)
 732 {
 733         if (balance == NULL)
 734         {
 735                 LOG_FATAL("TeamBalance_GetNumberOfPlayers: "
 736                         "Team balance entity is NULL.");
 737         }
 738         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 739         {
 740                 LOG_FATAL("TeamBalance_GetNumberOfPlayers: "
 741                         "TeamBalance_GetTeamCounts has not been called.");
 742         }
 743         if (!Team_IsValidIndex(index))
 744         {
 745                 LOG_FATALF("TeamBalance_GetNumberOfPlayers: Team index is invalid: %f",
 746                         index);
 747         }
 748         return balance.m_team_balance_team[index - 1].m_num_players;
 749 }
 750
 751 int TeamBalance_FindBestTeam(entity balance, entity player, bool ignore_player)
 752 {
 753         if (balance == NULL)
 754         {
 755                 LOG_FATAL("TeamBalance_FindBestTeam: Team balance entity is NULL.");
 756         }
 757         if (balance.m_team_balance_state == TEAM_BALANCE_UNINITIALIZED)
 758         {
 759                 LOG_FATAL("TeamBalance_FindBestTeam: "
 760                         "Team balance entity is not initialized.");
 761         }
 762         // count how many players are in each team
 763         if (ignore_player)
 764         {
 765                 TeamBalance_GetTeamCounts(balance, player);
 766         }
 767         else
 768         {
 769                 TeamBalance_GetTeamCounts(balance, NULL);
 770         }
 771         int team_bits = TeamBalance_FindBestTeams(balance, player, true);
 772         if (team_bits == 0)
 773         {
 774                 LOG_FATALF("TeamBalance_FindBestTeam: No teams available for %s\n",
 775                         MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 776         }
 777         RandomSelection_Init();
 778         for (int i = 1; i <= NUM_TEAMS; ++i)
 779         {
 780                 if (team_bits & Team_IndexToBit(i))
 781                 {
 782                         RandomSelection_AddFloat(i, 1, 1);
 783                 }
 784         }
 785         return RandomSelection_chosen_float;
 786 }
 787
 788 int TeamBalance_FindBestTeams(entity balance, entity player, bool use_score)
 789 {
 790         if (balance == NULL)
 791         {
 792                 LOG_FATAL("TeamBalance_FindBestTeams: Team balance entity is NULL.");
 793         }
 794         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 795         {
 796                 LOG_FATAL("TeamBalance_FindBestTeams: "
 797                         "TeamBalance_GetTeamCounts has not been called.");
 798         }
 799         if (MUTATOR_CALLHOOK(TeamBalance_FindBestTeams, player) == true)
 800         {
 801                 return M_ARGV(1, float);
 802         }
 803         int team_bits = 0;
 804         int previous_team = 0;
 805         for (int i = 1; i <= NUM_TEAMS; ++i)
 806         {
 807                 if (!TeamBalance_IsTeamAllowedInternal(balance, i))
 808                 {
 809                         continue;
 810                 }
 811                 if (previous_team == 0)
 812                 {
 813                         team_bits = Team_IndexToBit(i);
 814                         previous_team = i;
 815                         continue;
 816                 }
 817                 int compare = TeamBalance_CompareTeams(balance, i, previous_team,
 818                         player, use_score);
 819                 if (compare == TEAMS_COMPARE_LESS)
 820                 {
 821                         team_bits = Team_IndexToBit(i);
 822                         previous_team = i;
 823                         continue;
 824                 }
 825                 if (compare == TEAMS_COMPARE_EQUAL)
 826                 {
 827                         team_bits |= Team_IndexToBit(i);
 828                         previous_team = i;
 829                 }
 830         }
 831         return team_bits;
 832 }
 833
 834 int TeamBalance_CompareTeams(entity balance, int team_index_a, int team_index_b,
 835         entity player, bool use_score)
 836 {
 837         if (balance == NULL)
 838         {
 839                 LOG_FATAL("TeamBalance_CompareTeams: Team balance entity is NULL.");
 840         }
 841         if (balance.m_team_balance_state != TEAM_BALANCE_TEAM_COUNTS_FILLED)
 842         {
 843                 LOG_FATAL("TeamBalance_CompareTeams: "
 844                         "TeamBalance_GetTeamCounts has not been called.");
 845         }
 846         if (!Team_IsValidIndex(team_index_a))
 847         {
 848                 LOG_FATALF("TeamBalance_CompareTeams: team_index_a is invalid: %f",
 849                         team_index_a);
 850         }
 851         if (!Team_IsValidIndex(team_index_b))
 852         {
 853                 LOG_FATALF("TeamBalance_CompareTeams: team_index_b is invalid: %f",
 854                         team_index_b);
 855         }
 856         if (team_index_a == team_index_b)
 857         {
 858                 return TEAMS_COMPARE_EQUAL;
 859         }
 860         entity team_a = TeamBalance_GetTeamFromIndex(balance, team_index_a);
 861         entity team_b = TeamBalance_GetTeamFromIndex(balance, team_index_b);
 862         return TeamBalance_CompareTeamsInternal(team_a, team_b, player, use_score);
 863 }
 864
 865 void TeamBalance_AutoBalanceBots()
 866 {
 867         if (!autocvar_g_balance_teams ||
 868                 !autocvar_g_balance_teams_prevent_imbalance)
 869         {
 870                 return;
 871         }
 872         //PrintToChatAll("TeamBalance_AutoBalanceBots");
 873         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 874         TeamBalance_GetTeamCounts(balance, NULL);
 875         int smallest_team_index = 0;
 876         int smallest_team_player_count = 0;
 877         for (int i = 1; i <= NUM_TEAMS; ++i)
 878         {
 879                 entity team_ = TeamBalance_GetTeamFromIndex(balance, i);
 880                 if (!TeamBalanceTeam_IsAllowed(team_))
 881                 {
 882                         continue;
 883                 }
 884                 int playercount = TeamBalanceTeam_GetNumberOfPlayers(team_);
 885                 if (smallest_team_index == 0)
 886                 {
 887                         smallest_team_index = i;
 888                         smallest_team_player_count = playercount;
 889                 }
 890                 else if (playercount < smallest_team_player_count)
 891                 {
 892                         smallest_team_index = i;
 893                         smallest_team_player_count = playercount;
 894                 }
 895         }
 896         //PrintToChatAll(sprintf("Smallest team: %f", smallest_team_index));
 897         //PrintToChatAll(sprintf("Smallest team players: %f", smallest_team_player_count));
 898         entity switchable_bot = NULL;
 899         int teams = BITS(NUM_TEAMS);
 900         while (teams != 0)
 901         {
 902                 int largest_team_index = TeamBalance_GetLargestTeamIndex(balance,
 903                         teams);
 904                 if (smallest_team_index == largest_team_index)
 905                 {
 906                         TeamBalance_Destroy(balance);
 907                         return;
 908                 }
 909                 entity largest_team = TeamBalance_GetTeamFromIndex(balance,
 910                         largest_team_index);
 911                 int largest_team_player_count = TeamBalanceTeam_GetNumberOfPlayers(
 912                         largest_team);
 913                 if (largest_team_player_count - smallest_team_player_count < 2)
 914                 {
 915                         TeamBalance_Destroy(balance);
 916                         return;
 917                 }
 918                 //PrintToChatAll(sprintf("Largest team: %f", largest_team_index));
 919                 //PrintToChatAll(sprintf("Largest team players: %f", largest_team_player_count));
 920                 switchable_bot = TeamBalance_GetPlayerForTeamSwitch(largest_team_index,
 921                         smallest_team_index, true);
 922                 if (switchable_bot != NULL)
 923                 {
 924                         break;
 925                 }
 926                 teams &= ~Team_IndexToBit(largest_team_index);
 927         }
 928         TeamBalance_Destroy(balance);
 929         if (switchable_bot == NULL)
 930         {
 931                 //PrintToChatAll("No bot found after searching through all the teams");
 932                 return;
 933         }
 934         SetPlayerTeam(switchable_bot, smallest_team_index, TEAM_CHANGE_AUTO);
 935 }
 936
 937 int TeamBalance_GetLargestTeamIndex(entity balance, int teams)
 938 {
 939         int largest_team_index = 0;
 940         int largest_team_player_count = 0;
 941         for (int i = 1; i <= NUM_TEAMS; ++i)
 942         {
 943                 if (!(Team_IndexToBit(i) & teams))
 944                 {
 945                         continue;
 946                 }
 947                 entity team_ = TeamBalance_GetTeamFromIndex(balance, i);
 948                 if (!TeamBalanceTeam_IsAllowed(team_))
 949                 {
 950                         continue;
 951                 }
 952                 int playercount = TeamBalanceTeam_GetNumberOfPlayers(team_);
 953                 if (largest_team_index == 0)
 954                 {
 955                         largest_team_index = i;
 956                         largest_team_player_count = playercount;
 957                 }
 958                 else if (playercount > largest_team_player_count)
 959                 {
 960                         largest_team_index = i;
 961                         largest_team_player_count = playercount;
 962                 }
 963         }
 964         return largest_team_index;
 965 }
 966
 967 entity TeamBalance_GetPlayerForTeamSwitch(int source_team_index,
 968         int destination_team_index, bool is_bot)
 969 {
 970         if (MUTATOR_CALLHOOK(TeamBalance_GetPlayerForTeamSwitch, source_team_index,
 971                 destination_team_index, is_bot))
 972         {
 973                 return M_ARGV(3, entity);
 974         }
 975         entity lowest_player = NULL;
 976         float lowest_score = FLOAT_MAX;
 977         FOREACH_CLIENT(Entity_GetTeamIndex(it) == source_team_index,
 978         {
 979                 if (IS_BOT_CLIENT(it) != is_bot)
 980                 {
 981                         continue;
 982                 }
 983                 float temp_score = PlayerScore_Get(it, SP_SCORE);
 984                 if (temp_score >= lowest_score)
 985                 {
 986                         continue;
 987                 }
 988                 //PrintToChatAll(sprintf(
 989                 //      "Found %s with lowest score, checking allowed teams", it.netname));
 990                 entity balance = TeamBalance_CheckAllowedTeams(it);
 991                 if (TeamBalance_IsTeamAllowed(balance, source_team_index))
 992                 {
 993                         //PrintToChatAll("Allowed");
 994                         lowest_player = it;
 995                         lowest_score = temp_score;
 996                 }
 997                 else
 998                 {
 999                         //PrintToChatAll("Not allowed");
1000                 }
1001                 TeamBalance_Destroy(balance);
1002         });
1003         return lowest_player;
1004 }
1005
1006 void LogTeamChange(float player_id, float team_number, int type)
1007 {
1008         if (!autocvar_sv_eventlog)
1009         {
1010                 return;
1011         }
1012         if (player_id < 1)
1013         {
1014                 return;
1015         }
1016         GameLogEcho(sprintf(":team:%f:%f:%f", player_id, team_number, type));
1017 }
1018
1019 void KillPlayerForTeamChange(entity player)
1020 {
1021         if (IS_DEAD(player))
1022         {
1023                 return;
1024         }
1025         if (MUTATOR_CALLHOOK(Player_ChangeTeamKill, player) == true)
1026         {
1027                 return;
1028         }
1029         Damage(player, player, player, 100000, DEATH_TEAMCHANGE.m_id, DMG_NOWEP,
1030                 player.origin, '0 0 0');
1031 }
1032
1033 bool TeamBalance_IsTeamAllowedInternal(entity balance, int index)
1034 {
1035         return balance.m_team_balance_team[index - 1].m_num_players !=
1036                 TEAM_NOT_ALLOWED;
1037 }
1038
1039 void TeamBalance_BanTeamsExcept(entity balance, int index)
1040 {
1041         for (int i = 1; i <= NUM_TEAMS; ++i)
1042         {
1043                 if (i != index)
1044                 {
1045                         balance.m_team_balance_team[i - 1].m_num_players = TEAM_NOT_ALLOWED;
1046                 }
1047         }
1048 }
1049
1050 entity TeamBalance_GetTeamFromIndex(entity balance, int index)
1051 {
1052         if (!Team_IsValidIndex(index))
1053         {
1054                 LOG_FATALF("TeamBalance_GetTeamFromIndex: Index is invalid: %f", index);
1055         }
1056         return balance.m_team_balance_team[index - 1];
1057 }
1058
1059 entity TeamBalance_GetTeam(entity balance, int team_num)
1060 {
1061         return TeamBalance_GetTeamFromIndex(balance, Team_TeamToIndex(team_num));
1062 }
1063
1064 bool TeamBalanceTeam_IsAllowed(entity team_ent)
1065 {
1066         return team_ent.m_num_players != TEAM_NOT_ALLOWED;
1067 }
1068
1069 int TeamBalanceTeam_GetNumberOfPlayers(entity team_ent)
1070 {
1071         return team_ent.m_num_players;
1072 }
1073
1074 int TeamBalanceTeam_GetNumberOfBots(entity team_ent)
1075 {
1076         return team_ent.m_num_bots;
1077 }
1078
1079 int TeamBalance_CompareTeamsInternal(entity team_a, entity team_b,
1080         entity player, bool use_score)
1081 {
1082         if (team_a == team_b)
1083         {
1084                 return TEAMS_COMPARE_EQUAL;
1085         }
1086         if (!TeamBalanceTeam_IsAllowed(team_a) ||
1087                 !TeamBalanceTeam_IsAllowed(team_b))
1088         {
1089                 return TEAMS_COMPARE_INVALID;
1090         }
1091         int num_players_team_a = team_a.m_num_players;
1092         int num_players_team_b = team_b.m_num_players;
1093         if (IS_REAL_CLIENT(player) && bots_would_leave)
1094         {
1095                 num_players_team_a -= team_a.m_num_bots;
1096                 num_players_team_b -= team_b.m_num_bots;
1097         }
1098         if (num_players_team_a < num_players_team_b)
1099         {
1100                 return TEAMS_COMPARE_LESS;
1101         }
1102         if (num_players_team_a > num_players_team_b)
1103         {
1104                 return TEAMS_COMPARE_GREATER;
1105         }
1106         if (!use_score)
1107         {
1108                 return TEAMS_COMPARE_EQUAL;
1109         }
1110         if (team_a.m_team_score < team_b.m_team_score)
1111         {
1112                 return TEAMS_COMPARE_LESS;
1113         }
1114         if (team_a.m_team_score > team_b.m_team_score)
1115         {
1116                 return TEAMS_COMPARE_GREATER;
1117         }
1118         return TEAMS_COMPARE_EQUAL;
1119 }
1120
1121 void SV_ChangeTeam(entity player, int new_color)
1122 {
1123         if (!teamplay)
1124         {
1125                 SetPlayerColors(player, new_color);
1126         }
1127         // TODO: Should we really bother with this?
1128         if(!IS_CLIENT(player))
1129         {
1130                 // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
1131                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING,
1132                         player.netname);
1133                 return;
1134         }
1135         if (!teamplay)
1136         {
1137                 return;
1138         }
1139         Player_SetTeamIndexChecked(player, Team_TeamToIndex((new_color & 0x0F) +
1140                 1));
1141 }