qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162                 if(autocvar_g_race_teams)
 163                 {
 164                         ActivateTeamplay();
 165                         race_teams = bound(2, autocvar_g_race_teams, 4);
 166                         have_team_spawns = -1; // request team spawns
 167                 }
 168                 else
 169                         race_teams = 0;
 170
 171                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 172                 fraglimit_override = autocvar_g_race_laps_limit;
 173                 leadlimit_override = 0; // currently not supported by race
 174
 175                 MUTATOR_ADD(gamemode_race);
 176         }
 177
 178         if(g_cts)
 179         {
 180                 g_race_qualifying = 1;
 181                 fraglimit_override = 0;
 182                 leadlimit_override = 0;
 183                 MUTATOR_ADD(gamemode_cts);
 184         }
 185
 186         if(g_nexball)
 187         {
 188         fraglimit_override = autocvar_g_nexball_goallimit;
 189         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 190         ActivateTeamplay();
 191         have_team_spawns = -1; // request team spawns
 192             MUTATOR_ADD(gamemode_nexball);
 193         }
 194
 195         if(g_keepaway)
 196         {
 197                 MUTATOR_ADD(gamemode_keepaway);
 198         }
 199
 200         if(g_invasion)
 201         {
 202                 timelimit_override = 0; // no timelimit in invasion, round based
 203                 fraglimit_override = autocvar_g_invasion_round_limit;
 204                 MUTATOR_ADD(gamemode_invasion);
 205         }
 206
 207         if(teamplay)
 208                 entcs_init();
 209
 210         cache_mutatormsg = strzone("");
 211         cache_lastmutatormsg = strzone("");
 212
 213         // enforce the server's universal frag/time limits
 214         if(!autocvar_g_campaign)
 215         {
 216                 if(fraglimit_override >= 0)
 217                         cvar_set("fraglimit", ftos(fraglimit_override));
 218                 if(timelimit_override >= 0)
 219                         cvar_set("timelimit", ftos(timelimit_override));
 220                 if(leadlimit_override >= 0)
 221                         cvar_set("leadlimit", ftos(leadlimit_override));
 222                 if(qualifying_override >= 0)
 223                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 224         }
 225
 226         if(g_race)
 227         {
 228                 // we need to find out the correct value for g_race_qualifying
 229                 if(autocvar_g_campaign)
 230                 {
 231                         g_race_qualifying = 1;
 232                 }
 233                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 234                 {
 235                         g_race_qualifying = 2;
 236                         race_fraglimit = autocvar_fraglimit;
 237                         race_leadlimit = autocvar_leadlimit;
 238                         race_timelimit = autocvar_timelimit;
 239                         cvar_set("fraglimit", "0");
 240                         cvar_set("leadlimit", "0");
 241                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 242                 }
 243                 else
 244                         g_race_qualifying = 0;
 245         }
 246
 247         if(g_invasion)
 248         {
 249                 inv_maxrounds = cvar("fraglimit");
 250                 cvar_set("fraglimit", "0");
 251         }
 252
 253         if(g_race || g_cts)
 254         if(g_race_qualifying)
 255                 independent_players = 1;
 256
 257         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 258 }
 259
 260 string GetClientVersionMessage() {
 261         string versionmsg;
 262         if (self.version_mismatch) {
 263                 if(self.version < autocvar_gameversion) {
 264                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 265                 } else {
 266                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 267                 }
 268         } else {
 269                 versionmsg = "^2client version and server version are compatible.^8";
 270         }
 271         return versionmsg;
 272 }
 273
 274 string getwelcomemessage(void)
 275 {
 276         string s, modifications, motd;
 277
 278         ret_string = "";
 279         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 280         modifications = ret_string;
 281
 282         if(g_weaponarena)
 283         {
 284                 if(g_weaponarena_random)
 285                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 286                 else
 287                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 288         }
 289         if(autocvar_g_start_weapon_laser == 0)
 290                 modifications = strcat(modifications, ", No start weapons");
 291         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 292                 modifications = strcat(modifications, ", Low gravity");
 293         if(g_cloaked && !g_cts)
 294                 modifications = strcat(modifications, ", Cloaked");
 295         if(g_grappling_hook)
 296                 modifications = strcat(modifications, ", Hook");
 297         if(g_weapon_stay && !g_cts)
 298                 modifications = strcat(modifications, ", Weapons stay");
 299         if(g_jetpack)
 300                 modifications = strcat(modifications, ", Jet pack");
 301         if(autocvar_g_powerups == 0)
 302                 modifications = strcat(modifications, ", No powerups");
 303         if(autocvar_g_powerups > 0)
 304                 modifications = strcat(modifications, ", Powerups");
 305         modifications = substring(modifications, 2, strlen(modifications) - 2);
 306
 307         string versionmessage;
 308         versionmessage = GetClientVersionMessage();
 309
 310         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 311         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 312
 313         if(modifications != "")
 314                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 315
 316         if (g_grappling_hook)
 317                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 318
 319         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 320         {
 321                 if(cache_lastmutatormsg)
 322                         strunzone(cache_lastmutatormsg);
 323                 if(cache_mutatormsg)
 324                         strunzone(cache_mutatormsg);
 325                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 326                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 327         }
 328
 329         if (cache_mutatormsg != "") {
 330                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 331         }
 332
 333         motd = autocvar_sv_motd;
 334         if (motd != "") {
 335                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 336         }
 337         return s;
 338 }
 339
 340 void SetPlayerColors(entity pl, float _color)
 341 {
 342         /*string s;
 343         s = ftos(cl);
 344         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 345         pl.team = cl + 1;
 346         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 347         pl.clientcolors = 16*cl + cl;*/
 348
 349         float pants, shirt;
 350         pants = _color & 0x0F;
 351         shirt = _color & 0xF0;
 352
 353
 354         if(teamplay) {
 355                 setcolor(pl, 16*pants + pants);
 356         } else {
 357                 setcolor(pl, shirt + pants);
 358         }
 359 }
 360
 361 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 362 {
 363         float _color;
 364
 365         if(t == 4)
 366                 _color = NUM_TEAM_4 - 1;
 367         else if(t == 3)
 368                 _color = NUM_TEAM_3 - 1;
 369         else if(t == 2)
 370                 _color = NUM_TEAM_2 - 1;
 371         else
 372                 _color = NUM_TEAM_1 - 1;
 373
 374         SetPlayerColors(pl,_color);
 375
 376         if(t != s) {
 377                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 378
 379                 if(!noprint)
 380                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 381         }
 382
 383 }
 384
 385 // set c1...c4 to show what teams are allowed
 386 void CheckAllowedTeams (entity for_whom)
 387 {
 388         float dm;
 389         entity head;
 390         string teament_name;
 391
 392         c1 = c2 = c3 = c4 = -1;
 393         cb1 = cb2 = cb3 = cb4 = 0;
 394
 395         teament_name = string_null;
 396         if(g_onslaught)
 397         {
 398                 // onslaught is special
 399                 head = findchain(classname, "onslaught_generator");
 400                 while (head)
 401                 {
 402                         if (head.team == NUM_TEAM_1) c1 = 0;
 403                         if (head.team == NUM_TEAM_2) c2 = 0;
 404                         if (head.team == NUM_TEAM_3) c3 = 0;
 405                         if (head.team == NUM_TEAM_4) c4 = 0;
 406                         head = head.chain;
 407                 }
 408         }
 409         else if(g_domination)
 410                 teament_name = "dom_team";
 411         else if(g_ctf)
 412                 teament_name = "ctf_team";
 413         else if(g_tdm)
 414                 teament_name = "tdm_team";
 415         else if(g_nexball)
 416                 teament_name = "nexball_team";
 417         else if(g_assault)
 418                 c1 = c2 = 0; // Assault always has 2 teams
 419         else
 420         {
 421                 // cover anything else by treating it like tdm with no teams spawned
 422                 dm = 2;
 423
 424                 ret_float = dm;
 425                 MUTATOR_CALLHOOK(GetTeamCount);
 426                 dm = ret_float;
 427
 428                 if(dm >= 4)
 429                         c1 = c2 = c3 = c4 = 0;
 430                 else if(dm >= 3)
 431                         c1 = c2 = c3 = 0;
 432                 else
 433                         c1 = c2 = 0;
 434         }
 435
 436         // find out what teams are allowed if necessary
 437         if(teament_name)
 438         {
 439                 head = find(world, classname, teament_name);
 440                 while(head)
 441                 {
 442                         if(!(g_domination && head.netname == ""))
 443                         {
 444                                 if(head.team == NUM_TEAM_1)
 445                                         c1 = 0;
 446                                 else if(head.team == NUM_TEAM_2)
 447                                         c2 = 0;
 448                                 else if(head.team == NUM_TEAM_3)
 449                                         c3 = 0;
 450                                 else if(head.team == NUM_TEAM_4)
 451                                         c4 = 0;
 452                         }
 453                         head = find(head, classname, teament_name);
 454                 }
 455         }
 456
 457         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 458         if(c3==-1 && c4==-1)
 459         if(autocvar_bot_vs_human && for_whom)
 460         {
 461                 if(autocvar_bot_vs_human > 0)
 462                 {
 463                         // bots are all blue
 464                         if(IS_BOT_CLIENT(for_whom))
 465                                 c1 = c3 = c4 = -1;
 466                         else
 467                                 c2 = -1;
 468                 }
 469                 else
 470                 {
 471                         // bots are all red
 472                         if(IS_BOT_CLIENT(for_whom))
 473                                 c2 = c3 = c4 = -1;
 474                         else
 475                                 c1 = -1;
 476                 }
 477         }
 478
 479         // if player has a forced team, ONLY allow that one
 480         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 481                 c2 = c3 = c4 = -1;
 482         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 483                 c1 = c3 = c4 = -1;
 484         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 485                 c1 = c2 = c4 = -1;
 486         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 487                 c1 = c2 = c3 = -1;
 488 }
 489
 490 float PlayerValue(entity p)
 491 {
 492         return 1;
 493         // FIXME: it always returns 1...
 494 }
 495
 496 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 497 // teams that are allowed will now have their player counts stored in c1...c4
 498 void GetTeamCounts(entity ignore)
 499 {
 500         entity head;
 501         float value, bvalue;
 502         // now count how many players are on each team already
 503
 504         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 505         // also remember the lowest-scoring player
 506
 507         FOR_EACH_CLIENT(head)
 508         {
 509                 float t;
 510                 if(IS_PLAYER(head))
 511                         t = head.team;
 512                 else if(head.team_forced > 0)
 513                         t = head.team_forced; // reserve the spot
 514                 else
 515                         continue;
 516                 if(head != ignore)// && head.netname != "")
 517                 {
 518                         value = PlayerValue(head);
 519                         if(IS_BOT_CLIENT(head))
 520                                 bvalue = value;
 521                         else
 522                                 bvalue = 0;
 523                         if(t == NUM_TEAM_1)
 524                         {
 525                                 if(c1 >= 0)
 526                                 {
 527                                         c1 = c1 + value;
 528                                         cb1 = cb1 + bvalue;
 529                                 }
 530                         }
 531                         if(t == NUM_TEAM_2)
 532                         {
 533                                 if(c2 >= 0)
 534                                 {
 535                                         c2 = c2 + value;
 536                                         cb2 = cb2 + bvalue;
 537                                 }
 538                         }
 539                         if(t == NUM_TEAM_3)
 540                         {
 541                                 if(c3 >= 0)
 542                                 {
 543                                         c3 = c3 + value;
 544                                         cb3 = cb3 + bvalue;
 545                                 }
 546                         }
 547                         if(t == NUM_TEAM_4)
 548                         {
 549                                 if(c4 >= 0)
 550                                 {
 551                                         c4 = c4 + value;
 552                                         cb4 = cb4 + bvalue;
 553                                 }
 554                         }
 555                 }
 556         }
 557
 558         // if the player who has a forced team has not joined yet, reserve the spot
 559         if(autocvar_g_campaign)
 560         {
 561                 switch(autocvar_g_campaign_forceteam)
 562                 {
 563                         case 1: if(c1 == cb1) ++c1; break;
 564                         case 2: if(c2 == cb2) ++c2; break;
 565                         case 3: if(c3 == cb3) ++c3; break;
 566                         case 4: if(c4 == cb4) ++c4; break;
 567                 }
 568         }
 569 }
 570
 571 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 572 {
 573         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 574         float f;
 575         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 576
 577         switch(ta)
 578         {
 579                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 580                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 581                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 582                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 583         }
 584         switch(tb)
 585         {
 586                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 587                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 588                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 589                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 590         }
 591
 592         // invalid
 593         if(ca < 0 || cb < 0)
 594                 return FALSE;
 595
 596         // equal
 597         if(ta == tb)
 598                 return TRUE;
 599
 600         if(IS_REAL_CLIENT(e))
 601         {
 602                 if(bots_would_leave)
 603                 {
 604                         ca -= cba * 0.999;
 605                         cb -= cbb * 0.999;
 606                 }
 607         }
 608
 609         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 610         if(ca < 1)
 611                 if(cb >= 1)
 612                         return TRUE;
 613         if(ca >= 1)
 614                 if(cb < 1)
 615                         return FALSE;
 616
 617         // first, normalize
 618         f = max(ca, cb, 1);
 619         ca /= f;
 620         cb /= f;
 621         f = max(sa, sb, 1);
 622         sa /= f;
 623         sb /= f;
 624
 625         // the more we're at the end of the match, the more take scores into account
 626         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 627         ca += (sa - ca) * f;
 628         cb += (sb - cb) * f;
 629
 630         return ca <= cb;
 631 }
 632
 633 // returns # of smallest team (1, 2, 3, 4)
 634 // NOTE: Assumes CheckAllowedTeams has already been called!
 635 float FindSmallestTeam(entity pl, float ignore_pl)
 636 {
 637         float totalteams, t;
 638         totalteams = 0;
 639
 640         // find out what teams are available
 641         //CheckAllowedTeams();
 642
 643         // make sure there are at least 2 teams to join
 644         if(c1 >= 0)
 645                 totalteams = totalteams + 1;
 646         if(c2 >= 0)
 647                 totalteams = totalteams + 1;
 648         if(c3 >= 0)
 649                 totalteams = totalteams + 1;
 650         if(c4 >= 0)
 651                 totalteams = totalteams + 1;
 652
 653         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 654                 totalteams += 1;
 655
 656         if(totalteams <= 1)
 657         {
 658                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 659                         return 1; // special case for campaign and player joining
 660                 else if(g_domination)
 661                         error("Too few teams available for domination\n");
 662                 else if(g_ctf)
 663                         error("Too few teams available for ctf\n");
 664                 else if(g_keyhunt)
 665                         error("Too few teams available for key hunt\n");
 666                 else if(g_freezetag)
 667                         error("Too few teams available for freeze tag\n");
 668                 else
 669                         error("Too few teams available for team deathmatch\n");
 670         }
 671
 672         // count how many players are in each team
 673         if(ignore_pl)
 674                 GetTeamCounts(pl);
 675         else
 676                 GetTeamCounts(world);
 677
 678         RandomSelection_Init();
 679
 680         t = 1;
 681         if(TeamSmallerEqThanTeam(2, t, pl))
 682                 t = 2;
 683         if(TeamSmallerEqThanTeam(3, t, pl))
 684                 t = 3;
 685         if(TeamSmallerEqThanTeam(4, t, pl))
 686                 t = 4;
 687
 688         // now t is the minimum, or A minimum!
 689         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 690                 RandomSelection_Add(world, 1, string_null, 1, 1);
 691         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 692                 RandomSelection_Add(world, 2, string_null, 1, 1);
 693         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 694                 RandomSelection_Add(world, 3, string_null, 1, 1);
 695         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 696                 RandomSelection_Add(world, 4, string_null, 1, 1);
 697
 698         return RandomSelection_chosen_float;
 699 }
 700
 701 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 702 {
 703         float smallest, selectedteam;
 704
 705         // don't join a team if we're not playing a team game
 706         if(!teamplay)
 707                 return 0;
 708
 709         // find out what teams are available
 710         CheckAllowedTeams(pl);
 711
 712         // if we don't care what team he ends up on, put him on whatever team he entered as.
 713         // if he's not on a valid team, then let other code put him on the smallest team
 714         if(!forcebestteam)
 715         {
 716                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 717                         selectedteam = pl.team;
 718                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 719                         selectedteam = pl.team;
 720                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 721                         selectedteam = pl.team;
 722                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 723                         selectedteam = pl.team;
 724                 else
 725                         selectedteam = -1;
 726
 727                 if(selectedteam > 0)
 728                 {
 729                         if(!only_return_best)
 730                         {
 731                                 SetPlayerColors(pl, selectedteam - 1);
 732
 733                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 734                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 735                                 LogTeamchange(pl.playerid, pl.team, 99);
 736                         }
 737                         return selectedteam;
 738                 }
 739                 // otherwise end up on the smallest team (handled below)
 740         }
 741
 742         smallest = FindSmallestTeam(pl, TRUE);
 743
 744         if(!only_return_best && !pl.bot_forced_team)
 745         {
 746                 TeamchangeFrags(self);
 747                 if(smallest == 1)
 748                 {
 749                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 750                 }
 751                 else if(smallest == 2)
 752                 {
 753                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 754                 }
 755                 else if(smallest == 3)
 756                 {
 757                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 758                 }
 759                 else if(smallest == 4)
 760                 {
 761                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 762                 }
 763                 else
 764                 {
 765                         error("smallest team: invalid team\n");
 766                 }
 767
 768                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 769
 770                 if(pl.deadflag == DEAD_NO)
 771                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 772         }
 773
 774         return smallest;
 775 }
 776
 777 //void() ctf_playerchanged;
 778 void SV_ChangeTeam(float _color)
 779 {
 780         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 781
 782         // in normal deathmatch we can just apply the color and we're done
 783         if(!teamplay) {
 784                 SetPlayerColors(self, _color);
 785                 return;
 786         }
 787
 788         scolor = self.clientcolors & 0x0F;
 789         dcolor = _color & 0x0F;
 790
 791         if(scolor == NUM_TEAM_1 - 1)
 792                 steam = 1;
 793         else if(scolor == NUM_TEAM_2 - 1)
 794                 steam = 2;
 795         else if(scolor == NUM_TEAM_3 - 1)
 796                 steam = 3;
 797         else // if(scolor == NUM_TEAM_4 - 1)
 798                 steam = 4;
 799         if(dcolor == NUM_TEAM_1 - 1)
 800                 dteam = 1;
 801         else if(dcolor == NUM_TEAM_2 - 1)
 802                 dteam = 2;
 803         else if(dcolor == NUM_TEAM_3 - 1)
 804                 dteam = 3;
 805         else // if(dcolor == NUM_TEAM_4 - 1)
 806                 dteam = 4;
 807
 808         CheckAllowedTeams(self);
 809
 810         if(dteam == 1 && c1 < 0) dteam = 4;
 811         if(dteam == 4 && c4 < 0) dteam = 3;
 812         if(dteam == 3 && c3 < 0) dteam = 2;
 813         if(dteam == 2 && c2 < 0) dteam = 1;
 814
 815         // not changing teams
 816         if(scolor == dcolor)
 817         {
 818                 //bprint("same team change\n");
 819                 SetPlayerTeam(self, dteam, steam, TRUE);
 820                 return;
 821         }
 822
 823         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 824                 sprint(self, "Team changes not allowed\n");
 825                 return; // changing teams is not allowed
 826         }
 827
 828         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 829         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 830         {
 831                 GetTeamCounts(self);
 832                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 833                 {
 834                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 835                         return;
 836                 }
 837         }
 838
 839 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 840
 841         if(IS_PLAYER(self) && steam != dteam)
 842         {
 843                 // reduce frags during a team change
 844                 TeamchangeFrags(self);
 845         }
 846
 847         SetPlayerTeam(self, dteam, steam, FALSE);
 848
 849         if(IS_PLAYER(self) && steam != dteam)
 850         {
 851                 // kill player when changing teams
 852                 if(self.deadflag == DEAD_NO)
 853                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 854         }
 855 }
 856
 857 void ShufflePlayerOutOfTeam (float source_team)
 858 {
 859         float smallestteam, smallestteam_count, steam;
 860         float lowest_bot_score, lowest_player_score;
 861         entity head, lowest_bot, lowest_player, selected;
 862
 863         smallestteam = 0;
 864         smallestteam_count = 999999999;
 865
 866         if(c1 >= 0 && c1 < smallestteam_count)
 867         {
 868                 smallestteam = 1;
 869                 smallestteam_count = c1;
 870         }
 871         if(c2 >= 0 && c2 < smallestteam_count)
 872         {
 873                 smallestteam = 2;
 874                 smallestteam_count = c2;
 875         }
 876         if(c3 >= 0 && c3 < smallestteam_count)
 877         {
 878                 smallestteam = 3;
 879                 smallestteam_count = c3;
 880         }
 881         if(c4 >= 0 && c4 < smallestteam_count)
 882         {
 883                 smallestteam = 4;
 884                 smallestteam_count = c4;
 885         }
 886
 887         if(!smallestteam)
 888         {
 889                 bprint("warning: no smallest team\n");
 890                 return;
 891         }
 892
 893         if(source_team == 1)
 894                 steam = NUM_TEAM_1;
 895         else if(source_team == 2)
 896                 steam = NUM_TEAM_2;
 897         else if(source_team == 3)
 898                 steam = NUM_TEAM_3;
 899         else // if(source_team == 4)
 900                 steam = NUM_TEAM_4;
 901
 902         lowest_bot = world;
 903         lowest_bot_score = 999999999;
 904         lowest_player = world;
 905         lowest_player_score = 999999999;
 906
 907         // find the lowest-scoring player & bot of that team
 908         FOR_EACH_PLAYER(head)
 909         {
 910                 if(head.team == steam)
 911                 {
 912                         if(head.isbot)
 913                         {
 914                                 if(head.totalfrags < lowest_bot_score)
 915                                 {
 916                                         lowest_bot = head;
 917                                         lowest_bot_score = head.totalfrags;
 918                                 }
 919                         }
 920                         else
 921                         {
 922                                 if(head.totalfrags < lowest_player_score)
 923                                 {
 924                                         lowest_player = head;
 925                                         lowest_player_score = head.totalfrags;
 926                                 }
 927                         }
 928                 }
 929         }
 930
 931         // prefers to move a bot...
 932         if(lowest_bot != world)
 933                 selected = lowest_bot;
 934         // but it will move a player if it has to
 935         else
 936                 selected = lowest_player;
 937         // don't do anything if it couldn't find anyone
 938         if(!selected)
 939         {
 940                 bprint("warning: couldn't find a player to move from team\n");
 941                 return;
 942         }
 943
 944         // smallest team gains a member
 945         if(smallestteam == 1)
 946         {
 947                 c1 = c1 + 1;
 948         }
 949         else if(smallestteam == 2)
 950         {
 951                 c2 = c2 + 1;
 952         }
 953         else if(smallestteam == 3)
 954         {
 955                 c3 = c3 + 1;
 956         }
 957         else if(smallestteam == 4)
 958         {
 959                 c4 = c4 + 1;
 960         }
 961         else
 962         {
 963                 bprint("warning: destination team invalid\n");
 964                 return;
 965         }
 966         // source team loses a member
 967         if(source_team == 1)
 968         {
 969                 c1 = c1 + 1;
 970         }
 971         else if(source_team == 2)
 972         {
 973                 c2 = c2 + 2;
 974         }
 975         else if(source_team == 3)
 976         {
 977                 c3 = c3 + 3;
 978         }
 979         else if(source_team == 4)
 980         {
 981                 c4 = c4 + 4;
 982         }
 983         else
 984         {
 985                 bprint("warning: source team invalid\n");
 986                 return;
 987         }
 988
 989         // move the player to the new team
 990         TeamchangeFrags(selected);
 991         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 992
 993         if(selected.deadflag == DEAD_NO)
 994                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 995         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
 996 }
 997
 998 // code from here on is just to support maps that don't have team entities
 999 void tdm_spawnteam (string teamname, float teamcolor)
1000 {
1001         entity e;
1002         e = spawn();
1003         e.classname = "tdm_team";
1004         e.netname = teamname;
1005         e.cnt = teamcolor;
1006         e.team = e.cnt + 1;
1007 }
1008
1009 // spawn some default teams if the map is not set up for tdm
1010 void tdm_spawnteams()
1011 {
1012         float numteams;
1013
1014         numteams = autocvar_g_tdm_teams_override;
1015         if(numteams < 2)
1016                 numteams = autocvar_g_tdm_teams;
1017         numteams = bound(2, numteams, 4);
1018
1019         tdm_spawnteam("Red", NUM_TEAM_1-1);
1020         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1021         if(numteams >= 3)
1022                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1023         if(numteams >= 4)
1024                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1025 }
1026
1027 void tdm_delayedinit()
1028 {
1029         // if no teams are found, spawn defaults
1030         if (find(world, classname, "tdm_team") == world)
1031                 tdm_spawnteams();
1032 }
1033
1034 void tdm_init()
1035 {
1036         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1037 }