Remove an old unused model
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / tturrets / system / system_main.qc
1 #define cvar_base "g_turrets_unit_"
2 .float clientframe;
3 void turrets_setframe(float _frame, float client_only)
4 {
5     if((client_only ? self.clientframe : self.frame ) != _frame)
6     {
7         self.SendFlags |= TNSF_ANIM;
8         self.anim_start_time = time;
9     }
10
11      if(client_only)
12         self.clientframe = _frame;
13     else
14         self.frame = _frame;
15
16 }
17
18 float turret_send(entity to, float sf)
19 {
20
21         WriteByte(MSG_ENTITY, ENT_CLIENT_TURRET);
22         WriteByte(MSG_ENTITY, sf);
23         if(sf & TNSF_SETUP)
24         {
25             WriteByte(MSG_ENTITY, self.turret_type);
26
27             WriteCoord(MSG_ENTITY, self.origin.x);
28             WriteCoord(MSG_ENTITY, self.origin.y);
29             WriteCoord(MSG_ENTITY, self.origin.z);
30
31             WriteAngle(MSG_ENTITY, self.angles.x);
32             WriteAngle(MSG_ENTITY, self.angles.y);
33     }
34
35     if(sf & TNSF_ANG)
36     {
37         WriteShort(MSG_ENTITY, rint(self.tur_head.angles.x));
38         WriteShort(MSG_ENTITY, rint(self.tur_head.angles.y));
39     }
40
41     if(sf & TNSF_AVEL)
42     {
43         WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity.x));
44         WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity.y));
45     }
46
47     if(sf & TNSF_MOVE)
48     {
49         WriteShort(MSG_ENTITY, rint(self.origin.x));
50         WriteShort(MSG_ENTITY, rint(self.origin.y));
51         WriteShort(MSG_ENTITY, rint(self.origin.z));
52
53         WriteShort(MSG_ENTITY, rint(self.velocity.x));
54         WriteShort(MSG_ENTITY, rint(self.velocity.y));
55         WriteShort(MSG_ENTITY, rint(self.velocity.z));
56
57         WriteShort(MSG_ENTITY, rint(self.angles.y));
58     }
59
60     if(sf & TNSF_ANIM)
61     {
62         WriteCoord(MSG_ENTITY, self.anim_start_time);
63         WriteByte(MSG_ENTITY, self.frame);
64     }
65
66     if(sf & TNSF_STATUS)
67     {
68         WriteByte(MSG_ENTITY, self.team);
69
70         if(self.health <= 0)
71             WriteByte(MSG_ENTITY, 0);
72         else
73             WriteByte(MSG_ENTITY, ceil((self.health / self.tur_health) * 255));
74     }
75
76         return true;
77 }
78
79 void load_unit_settings(entity ent, string unitname, float is_reload)
80 {
81     string sbase;
82
83     if (ent == world)
84         return;
85
86     if (!ent.turret_scale_damage)    ent.turret_scale_damage  = 1;
87     if (!ent.turret_scale_range)     ent.turret_scale_range   = 1;
88     if (!ent.turret_scale_refire)    ent.turret_scale_refire  = 1;
89     if (!ent.turret_scale_ammo)      ent.turret_scale_ammo    = 1;
90     if (!ent.turret_scale_aim)       ent.turret_scale_aim     = 1;
91     if (!ent.turret_scale_health)    ent.turret_scale_health  = 1;
92     if (!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
93
94     sbase = strcat(cvar_base,unitname);
95     if (is_reload)
96     {
97         ent.enemy = world;
98         ent.tur_head.avelocity = '0 0 0';
99
100         ent.tur_head.angles = '0 0 0';
101     }
102
103     ent.health      = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
104     ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
105
106     ent.shot_dmg          = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
107     ent.shot_refire       = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
108     ent.shot_radius       = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
109     ent.shot_speed        = cvar(strcat(sbase,"_shot_speed"));
110     ent.shot_spread       = cvar(strcat(sbase,"_shot_spread"));
111     ent.shot_force        = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
112     ent.shot_volly        = cvar(strcat(sbase,"_shot_volly"));
113     ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
114
115     ent.target_range         = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
116     ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
117     ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
118     //ent.target_range_fire    = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
119
120     ent.target_select_rangebias  = cvar(strcat(sbase,"_target_select_rangebias"));
121     ent.target_select_samebias   = cvar(strcat(sbase,"_target_select_samebias"));
122     ent.target_select_anglebias  = cvar(strcat(sbase,"_target_select_anglebias"));
123     ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
124     //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
125
126     ent.ammo_max      = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
127     ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
128
129     ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
130     ent.aim_speed    = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
131     ent.aim_maxrot   = cvar(strcat(sbase,"_aim_maxrot"));
132     ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
133
134     ent.track_type        = cvar(strcat(sbase,"_track_type"));
135     ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
136     ent.track_accel_rot   = cvar(strcat(sbase,"_track_accel_rot"));
137     ent.track_blendrate   = cvar(strcat(sbase,"_track_blendrate"));
138
139     if(is_reload)
140         if(ent.turret_respawnhook)
141             ent.turret_respawnhook();
142 }
143
144 void turret_projectile_explode()
145 {
146
147     self.takedamage = DAMAGE_NO;
148     self.event_damage = func_null;
149 #ifdef TURRET_DEBUG
150     float d;
151     d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
152     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + d;
153     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;
154 #else
155     RadiusDamage (self, self.realowner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
156 #endif
157     remove(self);
158 }
159
160 void turret_projectile_touch()
161 {
162     PROJECTILE_TOUCH;
163     turret_projectile_explode();
164 }
165
166 void turret_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector vforce)
167 {
168     self.velocity  += vforce;
169     self.health    -= damage;
170     //self.realowner  = attacker; // Dont change realowner, it does not make much sense for turrets
171     if(self.health <= 0)
172         W_PrepareExplosionByDamage(self.owner, turret_projectile_explode);
173 }
174
175 entity turret_projectile(string _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
176 {
177     entity proj;
178
179     sound (self, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
180     proj                 = spawn ();
181     setorigin(proj, self.tur_shotorg);
182     setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
183     proj.owner           = self;
184     proj.realowner       = self;
185     proj.bot_dodge       = true;
186     proj.bot_dodgerating = self.shot_dmg;
187     proj.think           = turret_projectile_explode;
188     proj.touch           = turret_projectile_touch;
189     proj.nextthink       = time + 9;
190     proj.movetype        = MOVETYPE_FLYMISSILE;
191     proj.velocity        = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
192     proj.flags           = FL_PROJECTILE;
193     proj.enemy           = self.enemy;
194     proj.totalfrags      = _death;
195     PROJECTILE_MAKETRIGGER(proj);
196     if(_health)
197     {
198         proj.health         = _health;
199         proj.takedamage     = DAMAGE_YES;
200         proj.event_damage   = turret_projectile_damage;
201     }
202     else
203         proj.flags |= FL_NOTARGET;
204
205     CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
206
207     return proj;
208 }
209
210 /**
211 ** updates enemy distances, predicted impact point/time
212 ** and updated aim<->predict impact distance.
213 **/
214 void turret_do_updates(entity t_turret)
215 {
216     vector enemy_pos;
217     entity oldself;
218
219     oldself = self;
220     self = t_turret;
221
222     enemy_pos = real_origin(self.enemy);
223
224     turret_tag_fire_update();
225
226     self.tur_shotdir_updated = v_forward;
227     self.tur_dist_enemy  = vlen(self.tur_shotorg - enemy_pos);
228     self.tur_dist_aimpos = vlen(self.tur_shotorg - self.tur_aimpos);
229
230     /*if((self.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (self.enemy))
231     {
232         oldpos = self.enemy.origin;
233         setorigin(self.enemy, self.tur_aimpos);
234         tracebox(self.tur_shotorg, '-1 -1 -1', '1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
235         setorigin(self.enemy, oldpos);
236
237         if(trace_ent == self.enemy)
238             self.tur_dist_impact_to_aimpos = 0;
239         else
240             self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos);
241     }
242     else*/
243         tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
244
245         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos) - (vlen(self.enemy.maxs - self.enemy.mins) * 0.5);
246         self.tur_impactent             = trace_ent;
247         self.tur_impacttime            = vlen(self.tur_shotorg - trace_endpos) / self.shot_speed;
248
249     self = oldself;
250 }
251
252 /*
253 vector turret_fovsearch_pingpong()
254 {
255     vector wish_angle;
256     if(self.phase < time)
257     {
258         if( self.tur_head.phase )
259             self.tur_head.phase = 0;
260         else
261             self.tur_head.phase = 1;
262         self.phase = time + 5;
263     }
264
265     if( self.tur_head.phase)
266         wish_angle = self.idle_aim + '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
267     else
268         wish_angle = self.idle_aim - '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
269
270     return wish_angle;
271 }
272
273 vector turret_fovsearch_steprot()
274 {
275     vector wish_angle;
276     //float rot_add;
277
278     wish_angle   = self.tur_head.angles;
279     wish_angle_x = self.idle_aim_x;
280
281     if (self.phase < time)
282     {
283         //rot_add = self.aim_maxrot / self.target_select_fov;
284         wish_angle_y += (self.target_select_fov * 2);
285
286         if(wish_angle_y > 360)
287             wish_angle_y = wish_angle_y - 360;
288
289          self.phase = time + 1.5;
290     }
291
292     return wish_angle;
293 }
294
295 vector turret_fovsearch_random()
296 {
297     vector wish_angle;
298
299     if (self.phase < time)
300     {
301         wish_angle_y = random() * self.aim_maxrot;
302         if(random() < 0.5)
303             wish_angle_y *= -1;
304
305         wish_angle_x = random() * self.aim_maxpitch;
306         if(random() < 0.5)
307             wish_angle_x *= -1;
308
309         self.phase = time + 5;
310
311         self.tur_aimpos = wish_angle;
312     }
313
314     return self.idle_aim + self.tur_aimpos;
315 }
316 */
317
318 /**
319 ** Handles head rotation according to
320 ** the units .track_type and .track_flags
321 **/
322 .float turret_framecounter;
323 void turret_stdproc_track()
324 {
325     vector target_angle; // This is where we want to aim
326     vector move_angle;   // This is where we can aim
327     float f_tmp;
328     vector v1, v2;
329     v1 = self.tur_head.angles;
330     v2 = self.tur_head.avelocity;
331
332     if (self.track_flags == TFL_TRACK_NO)
333         return;
334
335     if (!self.active)
336         target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
337     else if (self.enemy == world)
338     {
339         if(time > self.lip)
340             target_angle = self.idle_aim + self.angles;
341         else
342             target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
343     }
344     else
345     {
346         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
347     }
348
349     self.tur_head.angles_x = anglemods(self.tur_head.angles.x);
350     self.tur_head.angles_y = anglemods(self.tur_head.angles.y);
351
352     // Find the diffrence between where we currently aim and where we want to aim
353     //move_angle = target_angle - (self.angles + self.tur_head.angles);
354     //move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
355
356     move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(self.angles), AnglesTransform_FromAngles(target_angle))) - self.tur_head.angles;
357     move_angle = shortangle_vxy(move_angle, self.tur_head.angles);
358
359     switch(self.track_type)
360     {
361         case TFL_TRACKTYPE_STEPMOTOR:
362             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
363             if (self.track_flags & TFL_TRACK_PITCH)
364             {
365                 self.tur_head.angles_x += bound(-f_tmp,move_angle.x, f_tmp);
366                 if(self.tur_head.angles.x > self.aim_maxpitch)
367                     self.tur_head.angles_x = self.aim_maxpitch;
368
369                 if(self.tur_head.angles.x  < -self.aim_maxpitch)
370                     self.tur_head.angles_x = self.aim_maxpitch;
371             }
372
373             if (self.track_flags & TFL_TRACK_ROT)
374             {
375                 self.tur_head.angles_y += bound(-f_tmp, move_angle.y, f_tmp);
376                 if(self.tur_head.angles.y > self.aim_maxrot)
377                     self.tur_head.angles_y = self.aim_maxrot;
378
379                 if(self.tur_head.angles.y  < -self.aim_maxrot)
380                     self.tur_head.angles_y = self.aim_maxrot;
381             }
382
383             // CSQC
384             self.SendFlags  |= TNSF_ANG;
385
386             return;
387
388         case TFL_TRACKTYPE_FLUIDINERTIA:
389             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
390             move_angle.x = bound(-self.aim_speed, move_angle.x * self.track_accel_pitch * f_tmp, self.aim_speed);
391             move_angle.y = bound(-self.aim_speed, move_angle.y * self.track_accel_rot * f_tmp, self.aim_speed);
392             move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
393             break;
394
395         case TFL_TRACKTYPE_FLUIDPRECISE:
396
397             move_angle.y = bound(-self.aim_speed, move_angle.y, self.aim_speed);
398             move_angle.x = bound(-self.aim_speed, move_angle.x, self.aim_speed);
399
400             break;
401     }
402
403     //  pitch
404     if (self.track_flags & TFL_TRACK_PITCH)
405     {
406         self.tur_head.avelocity_x = move_angle.x;
407         if((self.tur_head.angles.x + self.tur_head.avelocity.x * self.ticrate) > self.aim_maxpitch)
408         {
409             self.tur_head.avelocity_x = 0;
410             self.tur_head.angles_x = self.aim_maxpitch;
411
412             self.SendFlags  |= TNSF_ANG;
413         }
414
415         if((self.tur_head.angles.x + self.tur_head.avelocity.x * self.ticrate) < -self.aim_maxpitch)
416         {
417             self.tur_head.avelocity_x = 0;
418             self.tur_head.angles_x = -self.aim_maxpitch;
419
420             self.SendFlags  |= TNSF_ANG;
421         }
422     }
423
424     //  rot
425     if (self.track_flags & TFL_TRACK_ROT)
426     {
427         self.tur_head.avelocity_y = move_angle.y;
428
429         if((self.tur_head.angles.y + self.tur_head.avelocity.y * self.ticrate) > self.aim_maxrot)
430         {
431             self.tur_head.avelocity_y = 0;
432             self.tur_head.angles_y = self.aim_maxrot;
433
434             self.SendFlags  |= TNSF_ANG;
435         }
436
437         if((self.tur_head.angles.y + self.tur_head.avelocity.y * self.ticrate) < -self.aim_maxrot)
438         {
439             self.tur_head.avelocity_y = 0;
440             self.tur_head.angles_y = -self.aim_maxrot;
441
442             self.SendFlags  |= TNSF_ANG;
443         }
444     }
445
446     self.SendFlags  |= TNSF_AVEL;
447
448     // Force a angle update every 10'th frame
449     self.turret_framecounter += 1;
450     if(self.turret_framecounter >= 10)
451     {
452         self.SendFlags |= TNSF_ANG;
453         self.turret_framecounter = 0;
454     }
455 }
456
457
458 /*
459  + = implemented
460  - = not implemented
461
462  + TFL_FIRECHECK_NO
463  + TFL_FIRECHECK_WORLD
464  + TFL_FIRECHECK_DEAD
465  + TFL_FIRECHECK_DISTANCES
466  - TFL_FIRECHECK_LOS
467  + TFL_FIRECHECK_AIMDIST
468  + TFL_FIRECHECK_REALDIST
469  - TFL_FIRECHECK_ANGLEDIST
470  - TFL_FIRECHECK_TEAMCECK
471  + TFL_FIRECHECK_AFF
472  + TFL_FIRECHECK_OWM_AMMO
473  + TFL_FIRECHECK_OTHER_AMMO
474  + TFL_FIRECHECK_REFIRE
475 */
476
477 /**
478 ** Preforms pre-fire checks based on the uints firecheck_flags
479 **/
480 float turret_stdproc_firecheck()
481 {
482     // This one just dont care =)
483     if (self.firecheck_flags & TFL_FIRECHECK_NO)
484         return 1;
485
486     if (self.enemy == world)
487         return 0;
488
489     // Ready?
490     if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
491         if (self.attack_finished_single > time) return 0;
492
493     // Special case: volly fire turret that has to fire a full volly if a shot was fired.
494     if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
495         if (self.volly_counter != self.shot_volly)
496                         if(self.ammo >= self.shot_dmg)
497                                 return 1;
498
499     // Lack of zombies makes shooting dead things unnecessary :P
500     if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
501         if (self.enemy.deadflag != DEAD_NO)
502             return 0;
503
504     // Own ammo?
505     if (self.firecheck_flags & TFL_FIRECHECK_OWM_AMMO)
506         if (self.ammo < self.shot_dmg)
507             return 0;
508
509     // Other's ammo? (support-supply units)
510     if (self.firecheck_flags & TFL_FIRECHECK_OTHER_AMMO)
511         if (self.enemy.ammo >= self.enemy.ammo_max)
512             return 0;
513
514         // Target of opertunity?
515         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
516         {
517                 self.enemy = self.tur_impactent;
518                 return 1;
519         }
520
521     if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
522     {
523         // To close?
524         if (self.tur_dist_aimpos < self.target_range_min)
525                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
526                                 return 1; // Target of opertunity?
527                         else
528                                 return 0;
529     }
530
531     // Try to avoid FF?
532     if (self.firecheck_flags & TFL_FIRECHECK_AFF)
533         if (self.tur_impactent.team == self.team)
534             return 0;
535
536     // aim<->predicted impact
537     if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
538         if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
539             return 0;
540
541     // Volly status
542     if (self.shot_volly > 1)
543         if (self.volly_counter == self.shot_volly)
544             if (self.ammo < (self.shot_dmg * self.shot_volly))
545                 return 0;
546
547     /*if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
548         if(self.tur_impactent != self.enemy)
549             return 0;*/
550
551     return 1;
552 }
553
554 /*
555  + TFL_TARGETSELECT_NO
556  + TFL_TARGETSELECT_LOS
557  + TFL_TARGETSELECT_PLAYERS
558  + TFL_TARGETSELECT_MISSILES
559  - TFL_TARGETSELECT_TRIGGERTARGET
560  + TFL_TARGETSELECT_ANGLELIMITS
561  + TFL_TARGETSELECT_RANGELIMTS
562  + TFL_TARGETSELECT_TEAMCHECK
563  - TFL_TARGETSELECT_NOBUILTIN
564  + TFL_TARGETSELECT_OWNTEAM
565 */
566
567 /**
568 ** Evaluate a entity for target valitity based on validate_flags
569 ** NOTE: the caller must check takedamage before calling this, to inline this check.
570 **/
571 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
572 {
573     vector v_tmp;
574
575     //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
576     //    return -0.5;
577
578     if(e_target.owner == e_turret)
579         return -0.5;
580
581     if (!checkpvs(e_target.origin, e_turret))
582         return -1;
583
584     if (!e_target)
585         return -2;
586
587         if(g_onslaught)
588                 if (substring(e_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
589                         return - 3;
590
591     if (validate_flags & TFL_TARGETSELECT_NO)
592         return -4;
593
594     // If only this was used more..
595     if (e_target.flags & FL_NOTARGET)
596         return -5;
597
598     // Cant touch this
599     if(e_target.vehicle_flags & VHF_ISVEHICLE)
600     {
601         if (e_target.vehicle_health <= 0)
602             return -6;
603     }
604     else if (e_target.health <= 0)
605         return -6;
606
607     // player
608     if (IS_CLIENT(e_target))
609     {
610         if (!(validate_flags & TFL_TARGETSELECT_PLAYERS))
611             return -7;
612
613         if (e_target.deadflag != DEAD_NO)
614             return -8;
615     }
616
617         // enemy turrets
618         if (validate_flags & TFL_TARGETSELECT_NOTURRETS)
619         if (e_target.turret_firefunc || e_target.owner.tur_head == e_target)
620             if(e_target.team != e_turret.team) // Dont break support units.
621                 return -9;
622
623     // Missile
624     if (e_target.flags & FL_PROJECTILE)
625         if (!(validate_flags & TFL_TARGETSELECT_MISSILES))
626             return -10;
627
628     if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
629         if (!(e_target.flags & FL_PROJECTILE))
630             return -10.5;
631
632     // Team check
633     if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
634     {
635         if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
636         {
637             if (e_target.team != e_turret.team)
638                 return -11;
639
640             if (e_turret.team != e_target.owner.team)
641                 return -12;
642         }
643         else
644         {
645             if (e_target.team == e_turret.team)
646                 return -13;
647
648             if (e_turret.team == e_target.owner.team)
649                 return -14;
650         }
651     }
652
653     // Range limits?
654     tvt_dist = vlen(e_turret.origin - real_origin(e_target));
655     if (validate_flags & TFL_TARGETSELECT_RANGELIMTS)
656     {
657         if (tvt_dist < e_turret.target_range_min)
658             return -15;
659
660         if (tvt_dist > e_turret.target_range)
661             return -16;
662     }
663
664     // Can we even aim this thing?
665     tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
666     tvt_tadv  = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
667     tvt_thadf = vlen(tvt_thadv);
668     tvt_tadf  = vlen(tvt_tadv);
669
670     /*
671     if(validate_flags & TFL_TARGETSELECT_FOV)
672     {
673         if(e_turret.target_select_fov < tvt_thadf)
674             return -21;
675     }
676     */
677
678     if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
679     {
680         if (fabs(tvt_tadv.x) > e_turret.aim_maxpitch)
681             return -17;
682
683         if (fabs(tvt_tadv.y) > e_turret.aim_maxrot)
684             return -18;
685     }
686
687     // Line of sight?
688     if (validate_flags & TFL_TARGETSELECT_LOS)
689     {
690         v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
691
692         traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
693
694         if (e_turret.aim_firetolerance_dist < vlen(v_tmp - trace_endpos))
695             return -19;
696     }
697
698     if (e_target.classname == "grapplinghook")
699         return -20;
700
701     /*
702     if (e_target.classname == "func_button")
703         return -21;
704     */
705
706 #ifdef TURRET_DEBUG_TARGETSELECT
707     dprint("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
708 #endif
709
710     return 1;
711 }
712
713 entity turret_select_target()
714 {
715     entity e;        // target looper entity
716     float  score;    // target looper entity score
717     entity e_enemy;  // currently best scoreing target
718     float  m_score;  // currently best scoreing target's score
719
720     m_score = 0;
721     if(self.enemy && self.enemy.takedamage && turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
722     {
723         e_enemy = self.enemy;
724         m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
725     }
726     else
727         e_enemy = self.enemy = world;
728
729     e = findradius(self.origin, self.target_range);
730
731     // Nothing to aim at?
732     if (!e)
733                 return world;
734
735     while (e)
736     {
737                 if(e.takedamage)
738                 {
739                     float f = turret_validate_target(self, e, self.target_select_flags);
740                     //dprint("F is: ", ftos(f), "\n");
741                         if ( f > 0)
742                         {
743                                 score = self.turret_score_target(self,e);
744                                 if ((score > m_score) && (score > 0))
745                                 {
746                                         e_enemy = e;
747                                         m_score = score;
748                                 }
749                         }
750                 }
751         e = e.chain;
752     }
753
754     return e_enemy;
755 }
756
757 void turret_think()
758 {
759     entity e;
760
761     self.nextthink = time + self.ticrate;
762
763     // ONS uses somewhat backwards linking.
764     if (teamplay)
765     {
766         if (g_onslaught)
767             if (self.target)
768             {
769                 e = find(world, targetname,self.target);
770                 if (e != world)
771                     self.team = e.team;
772             }
773
774         if (self.team != self.tur_head.team)
775             turret_stdproc_respawn();
776     }
777
778 #ifdef TURRET_DEBUG
779     if (self.tur_dbg_tmr1 < time)
780     {
781         if (self.enemy) paint_target (self.enemy,128,self.tur_dbg_rvec,0.9);
782         paint_target(self,256,self.tur_dbg_rvec,0.9);
783         self.tur_dbg_tmr1 = time + 1;
784     }
785 #endif
786
787     // Handle ammo
788     if (!(self.spawnflags & TSF_NO_AMMO_REGEN))
789     if (self.ammo < self.ammo_max)
790         self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
791
792     // Inactive turrets needs to run the think loop,
793     // So they can handle animation and wake up if need be.
794     if (!self.active)
795     {
796         turret_stdproc_track();
797         return;
798     }
799
800     // This is typicaly used for zaping every target in range
801     // turret_fusionreactor uses this to recharge friendlys.
802     if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
803     {
804         // Do a self.turret_fire for every valid target.
805         e = findradius(self.origin,self.target_range);
806         while (e)
807         {
808                         if(e.takedamage)
809                         {
810                                 if (turret_validate_target(self,e,self.target_validate_flags))
811                                 {
812                                         self.enemy = e;
813
814                                         turret_do_updates(self);
815
816                                         if (self.turret_firecheckfunc())
817                                                 turret_fire();
818                                 }
819                         }
820
821             e = e.chain;
822         }
823         self.enemy = world;
824     }
825     else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
826     {
827         // This one is doing something.. oddball. assume its handles what needs to be handled.
828
829         // Predict?
830         if (!(self.aim_flags & TFL_AIM_NO))
831             self.tur_aimpos = turret_stdproc_aim_generic();
832
833         // Turn & pitch?
834         if (!(self.track_flags & TFL_TRACK_NO))
835             turret_stdproc_track();
836
837         turret_do_updates(self);
838
839         // Fire?
840         if (self.turret_firecheckfunc())
841             turret_fire();
842     }
843     else
844     {
845         // Special case for volly always. if it fired once it must compleate the volly.
846         if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
847             if(self.volly_counter != self.shot_volly)
848             {
849                 // Predict or whatnot
850                 if (!(self.aim_flags & TFL_AIM_NO))
851                     self.tur_aimpos = turret_stdproc_aim_generic();
852
853                 // Turn & pitch
854                 if (!(self.track_flags & TFL_TRACK_NO))
855                     turret_stdproc_track();
856
857                 turret_do_updates(self);
858
859                 // Fire!
860                 if (self.turret_firecheckfunc() != 0)
861                     turret_fire();
862
863                 if(self.turret_postthink)
864                     self.turret_postthink();
865
866                 return;
867             }
868
869         // Check if we have a vailid enemy, and try to find one if we dont.
870
871         // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
872         float do_target_scan = 0;
873         if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
874             do_target_scan = 1;
875
876         // Old target (if any) invalid?
877         if(self.target_validate_time < time)
878         if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
879         {
880                 self.enemy = world;
881                 self.target_validate_time = time + 0.5;
882                 do_target_scan = 1;
883         }
884
885         // But never more often then g_turrets_targetscan_mindelay!
886         if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
887             do_target_scan = 0;
888
889         if(do_target_scan)
890         {
891             self.enemy = turret_select_target();
892             self.target_select_time = time;
893         }
894
895         // No target, just go to idle, do any custom stuff and bail.
896         if (self.enemy == world)
897         {
898             // Turn & pitch
899             if (!(self.track_flags & TFL_TRACK_NO))
900                 turret_stdproc_track();
901
902             // do any per-turret stuff
903             if(self.turret_postthink)
904                 self.turret_postthink();
905
906             // And bail.
907             return;
908         }
909         else
910             self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
911
912         // Predict?
913         if (!(self.aim_flags & TFL_AIM_NO))
914             self.tur_aimpos = turret_stdproc_aim_generic();
915
916         // Turn & pitch?
917         if (!(self.track_flags & TFL_TRACK_NO))
918             turret_stdproc_track();
919
920         turret_do_updates(self);
921
922         // Fire?
923         if (self.turret_firecheckfunc())
924             turret_fire();
925     }
926
927     // do any custom per-turret stuff
928     if(self.turret_postthink)
929         self.turret_postthink();
930 }
931
932 void turret_fire()
933 {
934     if (autocvar_g_turrets_nofire != 0)
935         return;
936
937     self.turret_firefunc();
938
939     self.attack_finished_single = time + self.shot_refire;
940     self.ammo -= self.shot_dmg;
941     self.volly_counter = self.volly_counter - 1;
942
943     if (self.volly_counter <= 0)
944     {
945         self.volly_counter = self.shot_volly;
946
947         if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
948             self.enemy = world;
949
950         if (self.shot_volly > 1)
951             self.attack_finished_single = time + self.shot_volly_refire;
952     }
953
954 #ifdef TURRET_DEBUG
955     if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_dbg_rvec, self.tur_impacttime + 0.25);
956 #endif
957 }
958
959 void turret_stdproc_fire()
960 {
961     dprint("^1Bang, ^3your dead^7 ",self.enemy.netname,"! ^1(turret with no real firefunc)\n");
962 }
963
964 /*
965     When .used a turret switch team to activator.team.
966     If activator is world, the turret go inactive.
967 */
968 void turret_stdproc_use()
969 {
970     dprint("Turret ",self.netname, " used by ", activator.classname, "\n");
971
972     self.team = activator.team;
973
974     if(self.team == 0)
975         self.active = ACTIVE_NOT;
976     else
977         self.active = ACTIVE_ACTIVE;
978
979 }
980
981 void turret_link()
982 {
983     Net_LinkEntity(self, true, 0, turret_send);
984     self.think      = turret_think;
985     self.nextthink  = time;
986     self.tur_head.effects = EF_NODRAW;
987 }
988
989 void turrets_manager_think()
990 {
991     self.nextthink = time + 1;
992
993     entity e;
994     if (autocvar_g_turrets_reloadcvars == 1)
995     {
996         e = nextent(world);
997         while (e)
998         {
999             if (e.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
1000             {
1001                 load_unit_settings(e,e.cvar_basename,1);
1002                 if(e.turret_postthink)
1003                     e.turret_postthink();
1004             }
1005
1006             e = nextent(e);
1007         }
1008         cvar_set("g_turrets_reloadcvars","0");
1009     }
1010 }
1011
1012 /*
1013 * Standard turret initialization. use this!
1014 * (unless you have a very good reason not to)
1015 * if the return value is 0, the turret should be removed.
1016 */
1017 float turret_stdproc_init (string cvar_base_name, string base, string head, float _turret_type)
1018 {
1019         entity e, ee = world;
1020
1021     // Are turrets allowed?
1022     if (autocvar_g_turrets == 0)
1023         return 0;
1024
1025     if(_turret_type < 1 || _turret_type > TID_LAST)
1026     {
1027         dprint("Invalid / Unkown turret type\"", ftos(_turret_type), "\", aborting!\n");
1028         return 0;
1029     }
1030     self.turret_type = _turret_type;
1031
1032     e = find(world, classname, "turret_manager");
1033     if (!e)
1034     {
1035         e = spawn();
1036         e.classname = "turret_manager";
1037         e.think = turrets_manager_think;
1038         e.nextthink = time + 2;
1039     }
1040
1041     if (!(self.spawnflags & TSF_SUSPENDED))
1042         builtin_droptofloor(); // why can't we use regular droptofloor here?
1043
1044     self.cvar_basename = cvar_base_name;
1045     load_unit_settings(self, self.cvar_basename, 0);
1046
1047     self.effects = EF_NODRAW;
1048
1049     // Handle turret teams.
1050     if (!teamplay)
1051                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
1052         else if(g_onslaught && self.targetname)
1053         {
1054                 e = find(world,target,self.targetname);
1055                 if(e != world)
1056                 {
1057                         self.team = e.team;
1058                         ee = e;
1059                 }
1060         }
1061         else if(!self.team)
1062                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
1063
1064     /*
1065     * Try to guess some reasonaly defaults
1066     * for missing params and do sanety checks
1067     * thise checks could produce some "interesting" results
1068     * if it hits a glitch in my logic :P so try to set as mutch
1069     * as possible beforehand.
1070     */
1071     if (!self.ticrate)
1072     {
1073         if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
1074             self.ticrate = 0.2;     // Support units generaly dont need to have a high speed ai-loop
1075         else
1076             self.ticrate = 0.1;     // 10 fps for normal turrets
1077     }
1078
1079     self.ticrate = bound(sys_frametime, self.ticrate, 60);  // keep it sane
1080
1081 // General stuff
1082     if (self.netname == "")
1083         self.netname = self.classname;
1084
1085     if (!self.respawntime)
1086         self.respawntime = 60;
1087     self.respawntime = max(-1, self.respawntime);
1088
1089     if (!self.health)
1090         self.health = 1000;
1091     self.tur_health = max(1, self.health);
1092     self.bot_attack = true;
1093     self.monster_attack = true;
1094
1095     if (!self.turrcaps_flags)
1096         self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL;
1097
1098     if (!self.damage_flags)
1099         self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE;
1100
1101 // Shot stuff.
1102     if (!self.shot_refire)
1103         self.shot_refire = 1;
1104     self.shot_refire = bound(0.01, self.shot_refire, 9999);
1105
1106     if (!self.shot_dmg)
1107         self.shot_dmg  = self.shot_refire * 50;
1108     self.shot_dmg = max(1, self.shot_dmg);
1109
1110     if (!self.shot_radius)
1111         self.shot_radius = self.shot_dmg * 0.5;
1112     self.shot_radius = max(1, self.shot_radius);
1113
1114     if (!self.shot_speed)
1115         self.shot_speed = 2500;
1116     self.shot_speed = max(1, self.shot_speed);
1117
1118     if (!self.shot_spread)
1119         self.shot_spread = 0.0125;
1120     self.shot_spread = bound(0.0001, self.shot_spread, 500);
1121
1122     if (!self.shot_force)
1123         self.shot_force = self.shot_dmg * 0.5 + self.shot_radius * 0.5;
1124     self.shot_force = bound(0.001, self.shot_force, 5000);
1125
1126     if (!self.shot_volly)
1127         self.shot_volly = 1;
1128     self.shot_volly = bound(1, self.shot_volly, floor(self.ammo_max / self.shot_dmg));
1129
1130     if (!self.shot_volly_refire)
1131         self.shot_volly_refire = self.shot_refire * self.shot_volly;
1132     self.shot_volly_refire = bound(self.shot_refire, self.shot_volly_refire, 60);
1133
1134     if (!self.firecheck_flags)
1135         self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES |
1136                                TFL_FIRECHECK_LOS | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCECK |
1137                                TFL_FIRECHECK_OWM_AMMO | TFL_FIRECHECK_REFIRE;
1138
1139 // Range stuff.
1140     if (!self.target_range)
1141         self.target_range = self.shot_speed * 0.5;
1142     self.target_range = bound(0, self.target_range, MAX_SHOT_DISTANCE);
1143
1144     if (!self.target_range_min)
1145         self.target_range_min = self.shot_radius * 2;
1146     self.target_range_min = bound(0, self.target_range_min, MAX_SHOT_DISTANCE);
1147
1148     if (!self.target_range_optimal)
1149         self.target_range_optimal = self.target_range * 0.5;
1150     self.target_range_optimal = bound(0, self.target_range_optimal, MAX_SHOT_DISTANCE);
1151
1152
1153 // Aim stuff.
1154     if (!self.aim_maxrot)
1155         self.aim_maxrot = 90;
1156     self.aim_maxrot = bound(0, self.aim_maxrot, 360);
1157
1158     if (!self.aim_maxpitch)
1159         self.aim_maxpitch = 20;
1160     self.aim_maxpitch = bound(0, self.aim_maxpitch, 90);
1161
1162     if (!self.aim_speed)
1163         self.aim_speed = 36;
1164     self.aim_speed  = bound(0.1, self.aim_speed, 1000);
1165
1166     if (!self.aim_firetolerance_dist)
1167         self.aim_firetolerance_dist  = 5 + (self.shot_radius * 2);
1168     self.aim_firetolerance_dist = bound(0.1, self.aim_firetolerance_dist, MAX_SHOT_DISTANCE);
1169
1170     if (!self.aim_flags)
1171     {
1172         self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;
1173         if(self.turrcaps_flags & TFL_TURRCAPS_RADIUSDMG)
1174             self.aim_flags |= TFL_AIM_GROUNDGROUND;
1175     }
1176
1177     if (!self.track_type)
1178         self.track_type = TFL_TRACKTYPE_STEPMOTOR;
1179
1180     if (self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1181     {
1182         // Fluid / Ineria mode. Looks mutch nicer.
1183         // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1184
1185         if (!self.aim_speed)
1186             self.aim_speed = 180;
1187         self.aim_speed = bound(0.1, self.aim_speed, 1000);
1188
1189         if (!self.track_accel_pitch)
1190             self.track_accel_pitch = 0.5;
1191
1192         if (!self.track_accel_rot)
1193             self.track_accel_rot   = 0.5;
1194
1195         if (!self.track_blendrate)
1196             self.track_blendrate   = 0.35;
1197     }
1198
1199     if (!self.track_flags)
1200         self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROT;
1201
1202
1203 // Target selection stuff.
1204     if (!self.target_select_rangebias)
1205         self.target_select_rangebias = 1;
1206     self.target_select_rangebias = bound(-10, self.target_select_rangebias, 10);
1207
1208     if (!self.target_select_samebias)
1209         self.target_select_samebias = 1;
1210     self.target_select_samebias = bound(-10, self.target_select_samebias, 10);
1211
1212     if (!self.target_select_anglebias)
1213         self.target_select_anglebias = 1;
1214     self.target_select_anglebias = bound(-10, self.target_select_anglebias, 10);
1215
1216     if (!self.target_select_missilebias)
1217         self.target_select_missilebias = -10;
1218
1219     self.target_select_missilebias = bound(-10, self.target_select_missilebias, 10);
1220     self.target_select_playerbias = bound(-10, self.target_select_playerbias, 10);
1221
1222     if (!self.target_select_flags)
1223     {
1224             self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK
1225                                      | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_ANGLELIMITS;
1226
1227         if (self.turrcaps_flags & TFL_TURRCAPS_MISSILEKILL)
1228             self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1229
1230         if (self.turrcaps_flags & TFL_TURRCAPS_PLAYERKILL)
1231             self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1232         //else
1233         //    self.target_select_flags = TFL_TARGETSELECT_NO;
1234     }
1235
1236     self.target_validate_flags = self.target_select_flags;
1237
1238 // Ammo stuff
1239     if (!self.ammo_max)
1240         self.ammo_max = self.shot_dmg * 10;
1241     self.ammo_max = max(self.shot_dmg, self.ammo_max);
1242
1243     if (!self.ammo)
1244         self.ammo = self.shot_dmg * 5;
1245     self.ammo = bound(0,self.ammo, self.ammo_max);
1246
1247     if (!self.ammo_recharge)
1248         self.ammo_recharge = self.shot_dmg * 0.5;
1249     self.ammo_recharge = max(0 ,self.ammo_recharge);
1250
1251     // Convert the recharge from X per sec to X per ticrate
1252     self.ammo_recharge = self.ammo_recharge * self.ticrate;
1253
1254     if (!self.ammo_flags)
1255         self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE;
1256
1257 // Damage stuff
1258     if(self.spawnflags & TSL_NO_RESPAWN)
1259         if (!(self.damage_flags & TFL_DMG_DEATH_NORESPAWN))
1260             self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1261
1262 // Offsets & origins
1263     if (!self.tur_shotorg)   self.tur_shotorg = '50 0 50';
1264
1265     if (!self.health)
1266         self.health = 150;
1267
1268 // Game hooks
1269         if(MUTATOR_CALLHOOK(TurretSpawn))
1270                 return 0;
1271
1272 // End of default & sanety checks, start building the turret.
1273
1274 // Spawn extra bits
1275     self.tur_head         = spawn();
1276     self.tur_head.netname = self.tur_head.classname = "turret_head";
1277     self.tur_head.team    = self.team;
1278     self.tur_head.owner   = self;
1279
1280     setmodel(self, base);
1281     setmodel(self.tur_head, head);
1282
1283     setsize(self, '-32 -32 0', '32 32 64');
1284     setsize(self.tur_head, '0 0 0', '0 0 0');
1285
1286     setorigin(self.tur_head, '0 0 0');
1287     setattachment(self.tur_head, self, "tag_head");
1288
1289     self.tur_health          = self.health;
1290     self.solid               = SOLID_BBOX;
1291     self.tur_head.solid      = SOLID_NOT;
1292     self.takedamage          = DAMAGE_AIM;
1293     self.tur_head.takedamage = DAMAGE_NO;
1294     self.movetype            = MOVETYPE_NOCLIP;
1295     self.tur_head.movetype   = MOVETYPE_NOCLIP;
1296
1297     // Defend mode?
1298     if (!self.tur_defend)
1299     if (self.target != "")
1300     {
1301         self.tur_defend = find(world, targetname, self.target);
1302         if (self.tur_defend == world)
1303         {
1304             self.target = "";
1305             dprint("Turret has invalid defendpoint!\n");
1306         }
1307     }
1308
1309     // In target defend mode, aim on the spot to defend when idle.
1310     if (self.tur_defend)
1311         self.idle_aim  = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1312     else
1313         self.idle_aim  = '0 0 0';
1314
1315     // Attach stdprocs. override when and what needed
1316     self.turret_firecheckfunc   = turret_stdproc_firecheck;
1317     self.turret_firefunc        = turret_stdproc_fire;
1318     self.event_damage           = turret_stdproc_damage;
1319
1320     if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
1321         self.turret_score_target    = turret_stdproc_targetscore_support;
1322     else
1323         self.turret_score_target    = turret_stdproc_targetscore_generic;
1324
1325     self.use = turret_stdproc_use;
1326
1327     ++turret_count;
1328     self.nextthink = time + 1;
1329     self.nextthink +=  turret_count * sys_frametime;
1330
1331     self.tur_head.team = self.team;
1332     self.view_ofs = '0 0 0';
1333
1334 #ifdef TURRET_DEBUG
1335     self.tur_dbg_start = self.nextthink;
1336     while (vlen(self.tur_dbg_rvec) < 2)
1337         self.tur_dbg_rvec  = randomvec() * 4;
1338
1339     self.tur_dbg_rvec_x = fabs(self.tur_dbg_rvec.x);
1340     self.tur_dbg_rvec_y = fabs(self.tur_dbg_rvec.y);
1341     self.tur_dbg_rvec_z = fabs(self.tur_dbg_rvec.z);
1342 #endif
1343
1344     // Its all good.
1345     self.turrcaps_flags |= TFL_TURRCAPS_ISTURRET;
1346
1347     self.classname = "turret_main";
1348
1349     self.active = ACTIVE_ACTIVE;
1350
1351     // In ONS mode, and linked to a ONS ent. need to call the use to set team.
1352     if (g_onslaught && ee)
1353     {
1354         activator = ee;
1355         self.use();
1356     }
1357
1358         turret_link();
1359         turret_stdproc_respawn();
1360     turret_tag_fire_update();
1361
1362     return 1;
1363 }
1364
1365