qcsrc/server/tturrets/units/unit_flac.qc

   1 void spawnfunc_turret_flac();
   2 void turret_flac_dinit();
   3 void turret_flac_attack();
   4
   5 void turret_flac_projectile_think_explode()
   6 {
   7     if(self.enemy != world)
   8     if(vlen(self.origin - self.enemy.origin) < self.owner.shot_radius * 3)
   9         setorigin(self,self.enemy.origin + randomvec() * self.owner.shot_radius);
  10
  11     self.takedamage = DAMAGE_NO;
  12     self.event_damage = SUB_Null;
  13
  14 #ifdef TURRET_DEBUG
  15     float d;
  16     d = RadiusDamage (self, self.owner, self.owner.shot_dmg, self.owner.shot_dmg, self.owner.shot_radius, self, self.owner.shot_force, self.totalfrags, world);
  17     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + d;
  18     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;
  19 #else
  20     RadiusDamage (self, self.realowner, self.owner.shot_dmg, self.owner.shot_dmg, self.owner.shot_radius, self, self.owner.shot_force, self.totalfrags, world);
  21 #endif
  22     remove(self);
  23 }
  24
  25 void turret_flac_attack()
  26 {
  27     entity proj;
  28
  29     turret_tag_fire_update();
  30
  31     proj = turret_projectile("weapons/hagar_fire.wav", 5, 0, DEATH_TURRET_FLAC, PROJECTILE_HAGAR, TRUE, TRUE);
  32     pointparticles(particleeffectnum("laser_muzzleflash"), self.tur_shotorg, self.tur_shotdir_updated * 1000, 1);
  33     proj.think      = turret_flac_projectile_think_explode;
  34     proj.nextthink  = time + self.tur_impacttime + (random() * 0.01 - random() * 0.01);
  35
  36     self.tur_head.frame = self.tur_head.frame + 1;
  37     if (self.tur_head.frame >= 4)
  38         self.tur_head.frame = 0;
  39
  40 }
  41
  42 void turret_flac_dinit()
  43 {
  44     if (self.netname == "")
  45         self.netname  = "FLAC Cannon";
  46
  47     self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_FASTPROJ | TFL_TURRCAPS_MISSILEKILL;
  48     self.ammo_flags     = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;
  49     self.aim_flags      = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;
  50
  51     if (turret_stdproc_init("flac_std", "models/turrets/base.md3", "models/turrets/flac.md3", TID_FLAC) == 0)
  52     {
  53         remove(self);
  54         return;
  55     }
  56     setsize(self.tur_head,'-32 -32 0','32 32 64');
  57
  58     self.damage_flags |= TFL_DMG_HEADSHAKE;
  59     self.target_select_flags |= TFL_TARGETSELECT_NOTURRETS | TFL_TARGETSELECT_MISSILESONLY;
  60
  61     // Our fire routine
  62     self.turret_firefunc  = turret_flac_attack;
  63
  64 }
  65 /*QUAKED turret_flac (0 .5 .8) ?
  66 */
  67
  68 void spawnfunc_turret_flac()
  69 {
  70     precache_model ("models/turrets/base.md3");
  71     precache_model ("models/turrets/flac.md3");
  72
  73     self.think = turret_flac_dinit;
  74     self.nextthink = time + 0.5;
  75 }
  76