qcsrc/server/vehicles/bumblebee.qc

   1 #include "bumblebee.qh"
   2
   3 #ifdef SVQC
   4 #include "vehicle.qh"
   5 void bumb_fire_cannon(entity _gun, string _tagname, entity _owner)
   6 {
   7         vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
   8         vehicles_projectile("bigplasma_muzzleflash", "weapons/flacexp3.wav",
   9                                                 v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  10                                                 autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  11                                                 DEATH_VH_BUMB_GUN, PROJECTILE_BUMBLE_GUN, 0, true, true, _owner);
  12 }
  13
  14 float bumb_gunner_frame()
  15 {
  16         entity vehic    = self.vehicle.owner;
  17         entity gun      = self.vehicle;
  18         entity gunner   = self;
  19         self = vehic;
  20
  21
  22
  23
  24         vehic.solid = SOLID_NOT;
  25         //setorigin(gunner, vehic.origin);
  26         gunner.velocity = vehic.velocity;
  27
  28         float _in, _out;
  29         vehic.angles_x *= -1;
  30         makevectors(vehic.angles);
  31         vehic.angles_x *= -1;
  32         if((gun == vehic.gun1))
  33         {
  34                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  35                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  36                 setorigin(gunner, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
  37         }
  38         else
  39         {
  40                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  41                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  42                 setorigin(gunner, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
  43         }
  44
  45         crosshair_trace(gunner);
  46         vector _ct = trace_endpos;
  47         vector ad;
  48
  49         if(autocvar_g_vehicle_bumblebee_cannon_lock)
  50         {
  51                 if(gun.lock_time < time)
  52                         gun.enemy = world;
  53
  54                 if(trace_ent)
  55                         if(trace_ent.movetype)
  56                                 if(trace_ent.takedamage)
  57                                         if(!trace_ent.deadflag)
  58                                         {
  59                                                 if(teamplay)
  60                                                 {
  61                                                         if(trace_ent.team != gunner.team)
  62                                                         {
  63                                                                 gun.enemy = trace_ent;
  64                                                                 gun.lock_time = time + 5;
  65                                                         }
  66                                                 }
  67                                                 else
  68                                                 {
  69                                                         gun.enemy = trace_ent;
  70                                                         gun.lock_time = time + 5;
  71                                                 }
  72                                         }
  73         }
  74
  75         if(gun.enemy)
  76         {
  77                 float i, distance, impact_time;
  78
  79                 vector vf = real_origin(gun.enemy);
  80                 vector _vel = gun.enemy.velocity;
  81                 if(gun.enemy.movetype == MOVETYPE_WALK)
  82                         _vel.z *= 0.1;
  83
  84
  85                 ad = vf;
  86                 for(i = 0; i < 4; ++i)
  87                 {
  88                         distance = vlen(ad - gunner.origin);
  89                         impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
  90                         ad = vf + _vel * impact_time;
  91                 }
  92                 trace_endpos = ad;
  93
  94
  95                 UpdateAuxiliaryXhair(gunner, ad, '1 0 1', 1);
  96                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
  97                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
  98                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
  99
 100         }
 101         else
 102                 vehicle_aimturret(vehic, _ct, gun, "fire",
 103                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 104                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 105
 106         if(gunner.BUTTON_ATCK)
 107                 if(time > gun.attack_finished_single)
 108                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 109                         {
 110                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 111                                 bumb_fire_cannon(gun, "fire", gunner);
 112                                 gun.delay = time;
 113                                 gun.attack_finished_single = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 114                         }
 115
 116         VEHICLE_UPDATE_PLAYER(gunner, health, bumblebee);
 117
 118         if(vehic.vehicle_flags & VHF_HASSHIELD)
 119                 VEHICLE_UPDATE_PLAYER(gunner, shield, bumblebee);
 120
 121         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 122         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 123
 124         UpdateAuxiliaryXhair(gunner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), 0);
 125
 126         if(vehic.owner)
 127                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), ((gunner == vehic.gunner1) ? 1 : 2));
 128
 129         vehic.solid = SOLID_BBOX;
 130         gunner.BUTTON_ATCK = gunner.BUTTON_ATCK2 = gunner.BUTTON_CROUCH = 0;
 131         gunner.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 132
 133         self = gunner;
 134         return 1;
 135 }
 136
 137 void bumb_gunner_exit(float _exitflag)
 138 {
 139         if(IS_REAL_CLIENT(self))
 140         {
 141                 msg_entity = self;
 142                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 143                 WriteEntity(MSG_ONE, self);
 144
 145                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 146                 WriteAngle(MSG_ONE, 0);
 147                 WriteAngle(MSG_ONE, self.vehicle.angles.y);
 148                 WriteAngle(MSG_ONE, 0);
 149         }
 150
 151         CSQCVehicleSetup(self, HUD_NORMAL);
 152         setsize(self, PL_MIN, PL_MAX);
 153
 154         self.takedamage     = DAMAGE_AIM;
 155         self.solid          = SOLID_SLIDEBOX;
 156         self.movetype       = MOVETYPE_WALK;
 157         self.effects        &= ~EF_NODRAW;
 158         self.alpha          = 1;
 159         self.PlayerPhysplug = func_null;
 160         self.view_ofs       = PL_VIEW_OFS;
 161         self.event_damage   = PlayerDamage;
 162         self.hud            = HUD_NORMAL;
 163         self.switchweapon   = self.vehicle.switchweapon;
 164
 165     MUTATOR_CALLHOOK(VehicleExit, self, self.vehicle);
 166
 167         self.vehicle.vehicle_hudmodel.viewmodelforclient = self.vehicle;
 168
 169         fixedmakevectors(self.vehicle.owner.angles);
 170
 171         if(self == self.vehicle.owner.gunner1)
 172         {
 173                 self.vehicle.owner.gunner1 = world;
 174         }
 175         else if(self == self.vehicle.owner.gunner2)
 176         {
 177                 self.vehicle.owner.gunner2 = world;
 178                 v_right *= -1;
 179         }
 180         else
 181                 dprint("^1self != gunner1 or gunner2, this is a BIG PROBLEM, tell tZork this happend.\n");
 182
 183         vector spot = self.vehicle.owner.origin + + v_up * 128 + v_right * 300;
 184         spot = vehicles_findgoodexit(spot);
 185         //setorigin(self , spot);
 186
 187         self.velocity = 0.75 * self.vehicle.owner.velocity + normalize(spot - self.vehicle.owner.origin) * 200;
 188         self.velocity_z += 10;
 189
 190         self.vehicle.phase = time + 5;
 191         self.vehicle        = world;
 192 }
 193
 194 float bumb_gunner_enter()
 195 {
 196         RemoveGrapplingHook(other);
 197         entity _gun, _gunner;
 198         if(!self.gunner1)
 199         {
 200                 _gun = self.gun1;
 201                 _gunner = self.gunner1;
 202                 self.gunner1 = other;
 203         }
 204         else if(!self.gunner2)
 205         {
 206                 _gun = self.gun2;
 207                 _gunner = self.gunner2;
 208                 self.gunner2 = other;
 209         }
 210         else
 211         {
 212                 dprint("^1ERROR:^7Tried to enter a fully occupied vehicle!\n");
 213                 return false;
 214         }
 215
 216         _gunner            = other;
 217         _gunner.vehicle    = _gun;
 218         _gun.switchweapon  = other.switchweapon;
 219         _gun.vehicle_exit  = bumb_gunner_exit;
 220
 221         other.angles            = self.angles;
 222         other.takedamage        = DAMAGE_NO;
 223         other.solid             = SOLID_NOT;
 224         other.movetype          = MOVETYPE_NOCLIP;
 225         other.alpha             = -1;
 226         other.event_damage      = func_null;
 227         other.view_ofs          = '0 0 0';
 228         other.hud               = _gun.hud;
 229         other.PlayerPhysplug    = _gun.PlayerPhysplug;
 230         other.vehicle_ammo1     = self.vehicle_ammo1;
 231         other.vehicle_ammo2     = self.vehicle_ammo2;
 232         other.vehicle_reload1   = self.vehicle_reload1;
 233         other.vehicle_reload2   = self.vehicle_reload2;
 234         other.vehicle_energy    = self.vehicle_energy;
 235         other.PlayerPhysplug    = bumb_gunner_frame;
 236         other.flags             &= ~FL_ONGROUND;
 237
 238         msg_entity = other;
 239         WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 240         WriteEntity(MSG_ONE, _gun.vehicle_viewport);
 241         WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 242         WriteAngle(MSG_ONE, _gun.angles.x + self.angles.x);    // tilt
 243         WriteAngle(MSG_ONE, _gun.angles.y + self.angles.y);    // yaw
 244         WriteAngle(MSG_ONE, 0);                             // roll
 245         _gun.vehicle_hudmodel.viewmodelforclient = other;
 246
 247         CSQCVehicleSetup(other, other.hud);
 248
 249     MUTATOR_CALLHOOK(VehicleEnter, other, _gun);
 250
 251         return true;
 252 }
 253
 254 float vehicles_valid_pilot()
 255 {
 256         if (!IS_PLAYER(other))
 257                 return false;
 258
 259         if(other.deadflag != DEAD_NO)
 260                 return false;
 261
 262         if(other.vehicle != world)
 263                 return false;
 264
 265         if (!IS_REAL_CLIENT(other))
 266                 if(!autocvar_g_vehicles_allow_bots)
 267                         return false;
 268
 269         if(teamplay && other.team != self.team)
 270                 return false;
 271
 272         return true;
 273 }
 274
 275 void bumb_touch()
 276 {
 277
 278         if(self.gunner1 != world && self.gunner2 != world)
 279         {
 280                 vehicles_touch();
 281                 return;
 282         }
 283
 284         if(vehicles_valid_pilot())
 285         {
 286                 if(self.gun1.phase <= time)
 287                         if(bumb_gunner_enter())
 288                                 return;
 289
 290                 if(self.gun2.phase <= time)
 291                         if(bumb_gunner_enter())
 292                                 return;
 293         }
 294
 295         vehicles_touch();
 296 }
 297
 298 void bumb_regen()
 299 {
 300         if(self.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 301                 self.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 302                                                                            self.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 303
 304         if(self.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 305                 self.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 306                                                                            self.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 307
 308         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 309                 vehicles_regen(self.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, true);
 310
 311         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 312                 vehicles_regen(self.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, false);
 313
 314         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 315                 vehicles_regen(self.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, false);
 316
 317 }
 318
 319 .vector hook_start, hook_end;
 320 float bumb_pilot_frame()
 321 {
 322         entity pilot, vehic;
 323         vector newvel;
 324
 325         pilot = self;
 326         vehic = self.vehicle;
 327         self   = vehic;
 328
 329
 330         if(vehic.deadflag != DEAD_NO)
 331         {
 332                 self = pilot;
 333                 pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = 0;
 334                 return 1;
 335         }
 336
 337         bumb_regen();
 338
 339         crosshair_trace(pilot);
 340
 341         vector vang;
 342         float ftmp;
 343
 344         vang = vehic.angles;
 345         newvel = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 346         vang.x *= -1;
 347         newvel.x *= -1;
 348         if(newvel.x > 180)  newvel.x -= 360;
 349         if(newvel.x < -180) newvel.x += 360;
 350         if(newvel.y > 180)  newvel.y -= 360;
 351         if(newvel.y < -180) newvel.y += 360;
 352
 353         ftmp = shortangle_f(pilot.v_angle.y - vang.y, vang.y);
 354         if(ftmp > 180)  ftmp -= 360;
 355         if(ftmp < -180) ftmp += 360;
 356         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 357
 358         // Pitch
 359         ftmp = 0;
 360         if(pilot.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 361                 ftmp = 4;
 362         else if(pilot.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 363                 ftmp = -8;
 364
 365         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 366         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 367         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 368
 369         vehic.angles_x = anglemods(vehic.angles.x);
 370         vehic.angles_y = anglemods(vehic.angles.y);
 371         vehic.angles_z = anglemods(vehic.angles.z);
 372
 373         makevectors('0 1 0' * vehic.angles.y);
 374         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 375
 376         if(pilot.movement.x != 0)
 377         {
 378                 if(pilot.movement.x > 0)
 379                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 380                 else if(pilot.movement.x < 0)
 381                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 382         }
 383
 384         if(pilot.movement.y != 0)
 385         {
 386                 if(pilot.movement.y < 0)
 387                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 388                 else if(pilot.movement.y > 0)
 389                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 390                 ftmp = newvel * v_right;
 391                 ftmp *= frametime * 0.1;
 392                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 393         }
 394         else
 395         {
 396                 vehic.angles_z *= 0.95;
 397                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 398                         vehic.angles_z = 0;
 399         }
 400
 401         if(pilot.BUTTON_CROUCH)
 402                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 403         else if(pilot.BUTTON_JUMP)
 404                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 405
 406         vehic.velocity  += newvel * frametime;
 407         pilot.velocity = pilot.movement  = vehic.velocity;
 408
 409
 410         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 411         {
 412                 if(vehic.tur_head.lock_time < time || vehic.tur_head.enemy.deadflag)
 413                         vehic.tur_head.enemy = world;
 414
 415                 if(trace_ent)
 416                 if(trace_ent.movetype)
 417                 if(trace_ent.takedamage)
 418                 if(!trace_ent.deadflag)
 419                 {
 420                         if(teamplay)
 421                         {
 422                                 if(trace_ent.team == pilot.team)
 423                                 {
 424                                         vehic.tur_head.enemy = trace_ent;
 425                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 426                                 }
 427                         }
 428                         else
 429                         {
 430                                 vehic.tur_head.enemy = trace_ent;
 431                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 432                         }
 433                 }
 434
 435                 if(vehic.tur_head.enemy)
 436                 {
 437                         trace_endpos = real_origin(vehic.tur_head.enemy);
 438                         UpdateAuxiliaryXhair(pilot, trace_endpos, '0 0.75 0', 0);
 439                 }
 440         }
 441
 442         vang = vehicle_aimturret(vehic, trace_endpos, self.gun3, "fire",
 443                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 444                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 445
 446         if((pilot.BUTTON_ATCK || pilot.BUTTON_ATCK2) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 447         {
 448                 vehic.gun3.enemy.realowner = pilot;
 449                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 450
 451                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 452                 vehic.gun3.enemy.SendFlags |= BRG_START;
 453
 454                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 455
 456                 if(trace_ent)
 457                 {
 458                         if(autocvar_g_vehicle_bumblebee_raygun)
 459                         {
 460                                 Damage(trace_ent, vehic, pilot, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 461                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 462                         }
 463                         else
 464                         {
 465                                 if(trace_ent.deadflag == DEAD_NO)
 466                                         if((teamplay && trace_ent.team == pilot.team) || !teamplay)
 467                                         {
 468
 469                                                 if(IS_VEHICLE(trace_ent))
 470                                                 {
 471                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.tur_health)
 472                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.tur_health);
 473
 474                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 475                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 476                                                 }
 477                                                 else if(IS_CLIENT(trace_ent))
 478                                                 {
 479                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 480                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 481
 482                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 483                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 484
 485                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 486                                                 }
 487                                                 else if(IS_TURRET(trace_ent))
 488                                                 {
 489                                                         if(trace_ent.health  <= trace_ent.tur_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 490                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 491                                                         //else ..hmmm what? ammo?
 492
 493                                                         trace_ent.SendFlags |= TNSF_STATUS;
 494                                                 }
 495                                         }
 496                         }
 497                 }
 498
 499                 vehic.gun3.enemy.hook_end = trace_endpos;
 500                 setorigin(vehic.gun3.enemy, trace_endpos);
 501                 vehic.gun3.enemy.SendFlags |= BRG_END;
 502
 503                 vehic.wait = time + 1;
 504         }
 505         else
 506                 vehic.gun3.enemy.effects |= EF_NODRAW;
 507         /*{
 508                 if(vehic.gun3.enemy)
 509                         remove(vehic.gun3.enemy);
 510
 511                 vehic.gun3.enemy = world;
 512         }
 513         */
 514
 515         VEHICLE_UPDATE_PLAYER(pilot, health, bumblebee);
 516         VEHICLE_UPDATE_PLAYER(pilot, energy, bumblebee);
 517
 518         pilot.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 519         pilot.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 520
 521         if(vehic.vehicle_flags & VHF_HASSHIELD)
 522                 VEHICLE_UPDATE_PLAYER(pilot, shield, bumblebee);
 523
 524         vehic.angles_x *= -1;
 525         makevectors(vehic.angles);
 526         vehic.angles_x *= -1;
 527         setorigin(pilot, vehic.origin + v_up * 48 + v_forward * 160);
 528
 529         pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = pilot.BUTTON_CROUCH = 0;
 530         self = pilot;
 531
 532         return 1;
 533 }
 534
 535 void bumb_think()
 536 {
 537         self.movetype = MOVETYPE_TOSS;
 538
 539                 //self.velocity = self.velocity * 0.5;
 540         self.angles_z *= 0.8;
 541         self.angles_x *= 0.8;
 542
 543         self.nextthink = time + 0.05;
 544
 545         if(!self.owner)
 546         {
 547                 entity oldself = self;
 548                 if(self.gunner1)
 549                 {
 550                         self = self.gunner1;
 551                         oldself.gun1.vehicle_exit(VHEF_EJECT);
 552                         entity oldother = other;
 553                         other = self;
 554                         self = oldself;
 555                         self.phase = 0;
 556                         self.touch();
 557                         other = oldother;
 558                         return;
 559                 }
 560
 561                 if(self.gunner2)
 562                 {
 563                         self = self.gunner2;
 564                         oldself.gun2.vehicle_exit(VHEF_EJECT);
 565                         entity oldother = other;
 566                         other = self;
 567                         self = oldself;
 568                         self.phase = 0;
 569                         self.touch();
 570                         other = oldother;
 571                         return;
 572                 }
 573         }
 574
 575 }
 576
 577 void bumb_enter()
 578 {
 579         self.touch = bumb_touch;
 580         self.nextthink = 0;
 581         self.movetype = MOVETYPE_BOUNCEMISSILE;
 582         //setattachment(self.owner, self.vehicle_viewport, "");
 583 }
 584
 585 void bumb_exit(float eject)
 586 {
 587         self.touch = vehicles_touch;
 588         self.think = bumb_think;
 589         self.nextthink = time;
 590
 591         if(!self.owner)
 592                 return;
 593
 594         fixedmakevectors(self.angles);
 595         vector spot;
 596         if(vlen(self.velocity) > autocvar_g_vehicle_bumblebee_speed_forward * 0.5)
 597                 spot = self.origin + v_up * 128 + v_forward * 200;
 598         else
 599                 spot = self.origin + v_up * 128 - v_forward * 200;
 600
 601         spot = vehicles_findgoodexit(spot);
 602
 603         // Hide beam
 604         if(self.gun3.enemy || !wasfreed(self.gun3.enemy)) {
 605                 self.gun3.enemy.effects |= EF_NODRAW;
 606     }
 607
 608         self.owner.velocity = 0.75 * self.vehicle.velocity + normalize(spot - self.vehicle.origin) * 200;
 609         self.owner.velocity_z += 10;
 610         setorigin(self.owner, spot);
 611
 612         antilag_clear(self.owner);
 613     self.owner = world;
 614 }
 615
 616 void bumb_blowup()
 617 {
 618         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 619                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 620                                  autocvar_g_vehicle_bumblebee_blowup_radius, self, world,
 621                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 622                                  DEATH_VH_BUMB_DEATH, world);
 623
 624         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 625         Send_Effect("explosion_large", randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 626
 627         if(self.owner.deadflag == DEAD_DYING)
 628                 self.owner.deadflag = DEAD_DEAD;
 629
 630         remove(self);
 631 }
 632
 633 void bumb_diethink()
 634 {
 635         if(time >= self.wait)
 636                 self.think = bumb_blowup;
 637
 638         if(random() < 0.1)
 639         {
 640                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 641                 Send_Effect("explosion_small", randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 642         }
 643
 644         self.nextthink = time + 0.1;
 645 }
 646
 647 void bumb_die()
 648 {
 649         entity oldself = self;
 650
 651         // Hide beam
 652         if(self.gun3.enemy || !wasfreed(self.gun3.enemy))
 653                 self.gun3.enemy.effects |= EF_NODRAW;
 654
 655         if(self.gunner1)
 656         {
 657                 self = self.gunner1;
 658                 oldself.gun1.vehicle_exit(VHEF_EJECT);
 659                 self = oldself;
 660         }
 661
 662         if(self.gunner2)
 663         {
 664                 self = self.gunner2;
 665                 oldself.gun2.vehicle_exit(VHEF_EJECT);
 666                 self = oldself;
 667         }
 668
 669         self.vehicle_exit(VHEF_EJECT);
 670
 671         fixedmakevectors(self.angles);
 672         vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 673         vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 674         vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 675
 676         entity _body = vehicle_tossgib(self, self.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 677
 678         if(random() > 0.5)
 679                 _body.touch = bumb_blowup;
 680         else
 681                 _body.touch = func_null;
 682
 683         _body.think = bumb_diethink;
 684         _body.nextthink = time;
 685         _body.wait = time + 2 + (random() * 8);
 686         _body.owner = self;
 687         _body.enemy = self.enemy;
 688
 689         Send_Effect("explosion_medium", findbetterlocation(self.origin, 16), '0 0 0', 1);
 690
 691         self.health                     = 0;
 692         self.event_damage       = func_null;
 693         self.solid                      = SOLID_CORPSE;
 694         self.takedamage         = DAMAGE_NO;
 695         self.deadflag           = DEAD_DYING;
 696         self.movetype           = MOVETYPE_NONE;
 697         self.effects            = EF_NODRAW;
 698         self.colormod           = '0 0 0';
 699         self.avelocity          = '0 0 0';
 700         self.velocity           = '0 0 0';
 701         self.touch                      = func_null;
 702         self.nextthink          = 0;
 703
 704         setorigin(self, self.pos1);
 705 }
 706
 707 void bumb_impact()
 708 {
 709         if(autocvar_g_vehicle_bumblebee_bouncepain.x)
 710                 vehicles_impact(autocvar_g_vehicle_bumblebee_bouncepain.x, autocvar_g_vehicle_bumblebee_bouncepain.y, autocvar_g_vehicle_bumblebee_bouncepain.z);
 711 }
 712
 713 void bumb_spawn(float _f)
 714 {
 715         /*
 716         float i;
 717         for(i=1; gettaginfo(self.gun1, i), gettaginfo_name; ++i)
 718         {
 719
 720             dprint(" ------- ^1gettaginfo_name^2(",ftos(i),") ^3=", gettaginfo_name, "\n");
 721         }
 722         */
 723         if(!self.gun1)
 724         {
 725                 // for some reason, autosizing of the shiled entity refuses to work for this one so set it up in advance.
 726                 self.vehicle_shieldent = spawn();
 727                 self.vehicle_shieldent.effects = EF_LOWPRECISION;
 728                 setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 729                 setattachment(self.vehicle_shieldent, self, "");
 730                 setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 731                 self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 732                 self.vehicle_shieldent.think       = shieldhit_think;
 733                 self.vehicle_shieldent.alpha = -1;
 734                 self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 735
 736                 self.gun1 = spawn();
 737                 self.gun2 = spawn();
 738                 self.gun3 = spawn();
 739
 740                 self.vehicle_flags |= VHF_MULTISLOT;
 741
 742                 self.gun1.owner = self;
 743                 self.gun2.owner = self;
 744                 self.gun3.owner = self;
 745
 746                 setmodel(self.gun1, "models/vehicles/bumblebee_plasma_right.dpm");
 747                 setmodel(self.gun2, "models/vehicles/bumblebee_plasma_left.dpm");
 748                 setmodel(self.gun3, "models/vehicles/bumblebee_ray.dpm");
 749
 750                 setattachment(self.gun1, self, "cannon_right");
 751                 setattachment(self.gun2, self, "cannon_left");
 752
 753                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 754                 self.gun3.pos1 = self.angles;
 755                 self.angles = '0 0 0';
 756                 vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 757                 ofs -= self.origin;
 758                 setattachment(self.gun3, self, "");
 759                 setorigin(self.gun3, ofs);
 760                 self.angles = self.gun3.pos1;
 761
 762                 vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 763                 vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 764
 765                 setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 766                 setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 767
 768                 //fixme-model-bones
 769                 setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 770                 setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 771                 //fixme-model-bones
 772                 setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 773                 setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 774
 775                 self.scale = 1.5;
 776
 777                 // Raygun beam
 778                 if(self.gun3.enemy == world)
 779                 {
 780                         self.gun3.enemy = spawn();
 781                         Net_LinkEntity(self.gun3.enemy, true, 0, bumble_raygun_send);
 782                         self.gun3.enemy.SendFlags = BRG_SETUP;
 783                         self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 784                         self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 785                 }
 786         }
 787
 788         self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 789         self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 790         self.solid          = SOLID_BBOX;
 791         //self.movetype         = MOVETYPE_BOUNCEMISSILE;
 792         self.movetype           = MOVETYPE_TOSS;
 793         self.vehicle_impact = bumb_impact;
 794         self.damageforcescale = 0.025;
 795
 796         setorigin(self, self.origin + '0 0 25');
 797 }
 798
 799 void spawnfunc_vehicle_bumblebee()
 800 {
 801         if(!autocvar_g_vehicle_bumblebee)
 802         {
 803                 remove(self);
 804                 return;
 805         }
 806
 807         precache_model("models/vehicles/bumblebee_body.dpm");
 808         precache_model("models/vehicles/bumblebee_plasma_left.dpm");
 809         precache_model("models/vehicles/bumblebee_plasma_right.dpm");
 810         precache_model("models/vehicles/bumblebee_ray.dpm");
 811         precache_model("models/vehicles/wakizashi_cockpit.dpm");
 812         precache_model("models/vehicles/spiderbot_cockpit.dpm");
 813         precache_model("models/vehicles/raptor_cockpit.dpm");
 814
 815         if(autocvar_g_vehicle_bumblebee_energy)
 816                 if(autocvar_g_vehicle_bumblebee_energy_regen)
 817                         self.vehicle_flags |= VHF_ENERGYREGEN;
 818
 819         if(autocvar_g_vehicle_bumblebee_shield)
 820                 self.vehicle_flags |= VHF_HASSHIELD;
 821
 822         if(autocvar_g_vehicle_bumblebee_shield_regen)
 823                 self.vehicle_flags |= VHF_SHIELDREGEN;
 824
 825         if(autocvar_g_vehicle_bumblebee_health_regen)
 826                 self.vehicle_flags |= VHF_HEALTHREGEN;
 827
 828         if(!vehicle_initialize(
 829                            "Bumblebee", "models/vehicles/bumblebee_body.dpm",
 830                            "", "models/vehicles/spiderbot_cockpit.dpm", "", "", "tag_viewport",
 831                            HUD_BUMBLEBEE, BUMB_MIN, BUMB_MAX, false,
 832                            bumb_spawn, autocvar_g_vehicle_bumblebee_respawntime,
 833                            bumb_pilot_frame, bumb_enter, bumb_exit,
 834                            bumb_die, bumb_think, false, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_shield))
 835         {
 836                 remove(self);
 837                 return;
 838         }
 839 }
 840
 841 float bumble_raygun_send(entity to, int sf)
 842 {
 843         WriteByte(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
 844
 845         WriteByte(MSG_ENTITY, sf);
 846         if(sf & BRG_SETUP)
 847         {
 848                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 849                 WriteByte(MSG_ENTITY, self.realowner.team);
 850                 WriteByte(MSG_ENTITY, self.cnt);
 851         }
 852
 853         if(sf & BRG_START)
 854         {
 855                 WriteCoord(MSG_ENTITY, self.hook_start.x);
 856                 WriteCoord(MSG_ENTITY, self.hook_start.y);
 857                 WriteCoord(MSG_ENTITY, self.hook_start.z);
 858         }
 859
 860         if(sf & BRG_END)
 861         {
 862                 WriteCoord(MSG_ENTITY, self.hook_end.x);
 863                 WriteCoord(MSG_ENTITY, self.hook_end.y);
 864                 WriteCoord(MSG_ENTITY, self.hook_end.z);
 865         }
 866
 867         return true;
 868 }
 869 #endif // SVQC
 870
 871 #ifdef CSQC
 872 /*
 873 .vector raygun_l1
 874 .vector raygun_l2;
 875 .vector raygun_l3;
 876 */
 877
 878 void bumble_raygun_draw()
 879 {
 880         float _len;
 881         vector _dir;
 882         vector _vtmp1, _vtmp2;
 883
 884         _len = vlen(self.origin - self.move_origin);
 885         _dir = normalize(self.move_origin - self.origin);
 886
 887         if(self.total_damages < time)
 888         {
 889                 boxparticles(self.traileffect, self, self.origin, self.origin + _dir * -64, _dir * -_len , _dir * -_len, 1, PARTICLES_USEALPHA);
 890                 boxparticles(self.lip, self, self.move_origin, self.move_origin + _dir * -64, _dir * -200 , _dir * -200, 1, PARTICLES_USEALPHA);
 891                 self.total_damages = time + 0.1;
 892         }
 893
 894         float i, df, sz, al;
 895         for(i = -0.1; i < 0.2; i += 0.1)
 896         {
 897                 df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
 898                 sz = 5 + random() * 5;
 899                 al = 0.25 + random() * 0.5;
 900                 _vtmp1 = self.origin + _dir * _len * (0.25 + i);
 901                 _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //self.raygun_l1;
 902                 Draw_CylindricLine(self.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 903
 904                 _vtmp2 = self.origin + _dir * _len * (0.5 + i);
 905                 _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //self.raygun_l2;
 906                 Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 907
 908                 _vtmp1 = self.origin + _dir * _len * (0.75 + i);
 909                 _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //self.raygun_l3;
 910                 Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 911
 912                 Draw_CylindricLine(_vtmp1, self.move_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 913         }
 914 }
 915
 916 void bumble_raygun_read(float bIsNew)
 917 {
 918         int sf = ReadByte();
 919
 920         if(sf & BRG_SETUP)
 921         {
 922                 self.cnt  = ReadByte();
 923                 self.team = ReadByte();
 924                 self.cnt  = ReadByte();
 925
 926                 if(self.cnt)
 927                         self.colormod = '1 0 0';
 928                 else
 929                         self.colormod = '0 1 0';
 930
 931                 self.traileffect = particleeffectnum("healray_muzzleflash");
 932                 self.lip = particleeffectnum("healray_impact");
 933
 934                 self.draw = bumble_raygun_draw;
 935         }
 936
 937
 938         if(sf & BRG_START)
 939         {
 940                 self.origin_x = ReadCoord();
 941                 self.origin_y = ReadCoord();
 942                 self.origin_z = ReadCoord();
 943                 setorigin(self, self.origin);
 944         }
 945
 946         if(sf & BRG_END)
 947         {
 948                 self.move_origin_x = ReadCoord();
 949                 self.move_origin_y = ReadCoord();
 950                 self.move_origin_z = ReadCoord();
 951         }
 952 }
 953
 954 void bumblebee_draw()
 955 {
 956
 957 }
 958
 959 void bumblebee_draw2d()
 960 {
 961
 962 }
 963
 964 void bumblebee_read_extra()
 965 {
 966
 967 }
 968
 969 void vehicle_bumblebee_assemble()
 970 {
 971
 972 }
 973 #endif //CSQC