qcsrc/server/vehicles/bumblebee.qc

   1 #define BRG_SETUP 2
   2 #define BRG_START 4
   3 #define BRG_END 8
   4
   5 #ifdef SVQC
   6 // Auto cvars
   7 float autocvar_g_vehicle_bumblebee_speed_forward;
   8 float autocvar_g_vehicle_bumblebee_speed_strafe;
   9 float autocvar_g_vehicle_bumblebee_speed_up;
  10 float autocvar_g_vehicle_bumblebee_speed_down;
  11 float autocvar_g_vehicle_bumblebee_turnspeed;
  12 float autocvar_g_vehicle_bumblebee_pitchspeed;
  13 float autocvar_g_vehicle_bumblebee_pitchlimit;
  14 float autocvar_g_vehicle_bumblebee_friction;
  15
  16 float autocvar_g_vehicle_bumblebee_energy;
  17 float autocvar_g_vehicle_bumblebee_energy_regen;
  18 float autocvar_g_vehicle_bumblebee_energy_regen_pause;
  19
  20 float autocvar_g_vehicle_bumblebee_health;
  21 float autocvar_g_vehicle_bumblebee_health_regen;
  22 float autocvar_g_vehicle_bumblebee_health_regen_pause;
  23
  24 float autocvar_g_vehicle_bumblebee_shield;
  25 float autocvar_g_vehicle_bumblebee_shield_regen;
  26 float autocvar_g_vehicle_bumblebee_shield_regen_pause;
  27
  28 float autocvar_g_vehicle_bumblebee_cannon_cost;
  29 float autocvar_g_vehicle_bumblebee_cannon_damage;
  30 float autocvar_g_vehicle_bumblebee_cannon_radius;
  31 float autocvar_g_vehicle_bumblebee_cannon_refire;
  32 float autocvar_g_vehicle_bumblebee_cannon_speed;
  33 float autocvar_g_vehicle_bumblebee_cannon_spread;
  34 float autocvar_g_vehicle_bumblebee_cannon_force;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo;
  37 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen;
  38 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause;
  39
  40 var float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  41
  42 float autocvar_g_vehicle_bumblebee_cannon_turnspeed;
  43 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down;
  44 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up;
  45 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  46 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  47
  48
  49 float autocvar_g_vehicle_bumblebee_raygun_turnspeed;
  50 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down;
  51 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up;
  52 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides;
  53
  54 float autocvar_g_vehicle_bumblebee_raygun_range;
  55 float autocvar_g_vehicle_bumblebee_raygun_dps;
  56 float autocvar_g_vehicle_bumblebee_raygun_aps;
  57 float autocvar_g_vehicle_bumblebee_raygun_fps;
  58
  59 float autocvar_g_vehicle_bumblebee_raygun;
  60 float autocvar_g_vehicle_bumblebee_healgun_hps;
  61 float autocvar_g_vehicle_bumblebee_healgun_hmax;
  62 float autocvar_g_vehicle_bumblebee_healgun_aps;
  63 float autocvar_g_vehicle_bumblebee_healgun_amax;
  64 float autocvar_g_vehicle_bumblebee_healgun_sps;
  65
  66 float autocvar_g_vehicle_bumblebee_respawntime;
  67
  68 float autocvar_g_vehicle_bumblebee_blowup_radius;
  69 float autocvar_g_vehicle_bumblebee_blowup_coredamage;
  70 float autocvar_g_vehicle_bumblebee_blowup_edgedamage;
  71 float autocvar_g_vehicle_bumblebee_blowup_forceintensity;
  72 var vector autocvar_g_vehicle_bumblebee_bouncepain;
  73
  74 var float autocvar_g_vehicle_bumblebee = 0;
  75
  76
  77 float bumble_raygun_send(entity to, float sf);
  78
  79 #define BUMB_MIN '-130 -130 -130'
  80 #define BUMB_MAX '130 130 130'
  81
  82 void bumb_fire_cannon(entity _gun, string _tagname, entity _owner)
  83 {
  84         vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
  85         vehicles_projectile("bigplasma_muzzleflash", "weapons/flacexp3.wav",
  86                                                 v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  87                                                 autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  88                                                 DEATH_BUMB_GUN, PROJECTILE_BUMBLE_GUN, 0, TRUE, TRUE, _owner);
  89 }
  90
  91 float bumb_gunner_frame()
  92 {
  93         entity vehic    = self.vehicle.owner;
  94         entity gun      = self.vehicle;
  95         entity gunner   = self;
  96         self = vehic;
  97
  98         vehic.solid = SOLID_NOT;
  99         setorigin(gunner, vehic.origin);
 100         gunner.velocity = vehic.velocity;
 101         crosshair_trace(gunner);
 102         vector _ct = trace_endpos;
 103         vector ad;
 104
 105         float _in = ((gun == vehic.gun1) ? autocvar_g_vehicle_bumblebee_cannon_turnlimit_in : autocvar_g_vehicle_bumblebee_cannon_turnlimit_out);
 106         float _out = ((gun == vehic.gun1) ? autocvar_g_vehicle_bumblebee_cannon_turnlimit_out : autocvar_g_vehicle_bumblebee_cannon_turnlimit_in);
 107
 108         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 109         {
 110                 if(gun.lock_time < time)
 111                         gun.enemy = world;
 112
 113                 if(trace_ent)
 114                         if(trace_ent.movetype)
 115                                 if(trace_ent.takedamage)
 116                                         if(!trace_ent.deadflag)
 117                                         {
 118                                                 if(teamplay)
 119                                                 {
 120                                                         if(trace_ent.team != gunner.team)
 121                                                         {
 122                                                                 gun.enemy = trace_ent;
 123                                                                 gun.lock_time = time + 5;
 124                                                         }
 125                                                 }
 126                                                 else
 127                                                 {
 128                                                         gun.enemy = trace_ent;
 129                                                         gun.lock_time = time + 5;
 130                                                 }
 131                                         }
 132         }
 133
 134         if(gun.enemy)
 135         {
 136                 float i, distance, impact_time;
 137
 138                 vector vf = real_origin(gun.enemy);
 139                 vector _vel = gun.enemy.velocity;
 140                 if(gun.enemy.movetype == MOVETYPE_WALK)
 141                         _vel_z *= 0.1;
 142
 143
 144                 ad = vf;
 145                 for(i = 0; i < 4; ++i)
 146                 {
 147                         distance = vlen(ad - gunner.origin);
 148                         impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 149                         ad = vf + _vel * impact_time;
 150                 }
 151                 trace_endpos = ad;
 152
 153
 154                 UpdateAuxiliaryXhair(gunner, ad, '1 0 1', 1);
 155                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 156                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 157                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 158
 159         }
 160         else
 161                 vehicle_aimturret(vehic, _ct, gun, "fire",
 162                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 163                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 164
 165         if(gunner.BUTTON_ATCK)
 166                 if(time > gun.attack_finished_single)
 167                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 168                         {
 169                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 170                                 bumb_fire_cannon(gun, "fire", gunner);
 171                                 gun.delay = time;
 172                                 gun.attack_finished_single = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 173                         }
 174
 175         VEHICLE_UPDATE_PLAYER(gunner, health, bumblebee);
 176
 177         if(vehic.vehicle_flags & VHF_HASSHIELD)
 178                 VEHICLE_UPDATE_PLAYER(gunner, shield, bumblebee);
 179
 180         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 181         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 182
 183         UpdateAuxiliaryXhair(gunner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), 0);
 184
 185         if(vehic.owner)
 186                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), ((gunner == vehic.gunner1) ? 1 : 2));
 187
 188         vehic.solid = SOLID_BBOX;
 189         gunner.BUTTON_ATCK = gunner.BUTTON_ATCK2 = gunner.BUTTON_CROUCH = 0;
 190         gunner.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 191
 192         self = gunner;
 193         return 1;
 194 }
 195
 196 void bumb_gunner_exit(float _exitflag)
 197 {
 198         if(clienttype(self) == CLIENTTYPE_REAL)
 199         {
 200                 msg_entity = self;
 201                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 202                 WriteEntity(MSG_ONE, self);
 203
 204                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 205                 WriteAngle(MSG_ONE, 0);
 206                 WriteAngle(MSG_ONE, self.vehicle.angles_y);
 207                 WriteAngle(MSG_ONE, 0);
 208         }
 209
 210         CSQCVehicleSetup(self, HUD_NORMAL);
 211         setsize(self, PL_MIN, PL_MAX);
 212
 213         self.takedamage     = DAMAGE_AIM;
 214         self.solid          = SOLID_SLIDEBOX;
 215         self.movetype       = MOVETYPE_WALK;
 216         self.effects        &~= EF_NODRAW;
 217         self.alpha          = 1;
 218         self.PlayerPhysplug = SUB_Null;
 219         self.view_ofs       = PL_VIEW_OFS;
 220         self.event_damage   = PlayerDamage;
 221         self.hud            = HUD_NORMAL;
 222         self.switchweapon   = self.vehicle.switchweapon;
 223
 224         if(self.flagcarried)
 225         {
 226                 self.flagcarried.scale = 0.6;
 227                 setattachment(self.flagcarried, self, "");
 228                 setorigin(self.flagcarried, FLAG_CARRY_POS);
 229         }
 230
 231         self.vehicle.vehicle_hudmodel.viewmodelforclient = self.vehicle;
 232
 233         if(self == self.vehicle.owner.gunner1)
 234                 self.vehicle.owner.gunner1 = world;
 235         else if(self == self.vehicle.owner.gunner2)
 236                 self.vehicle.owner.gunner2 = world;
 237         else
 238                 dprint("^1self != gunner1 or gunner2, this is a BIG PROBLEM, tell tZork this happend.\n");
 239
 240         self.vehicle.phase = time + 5;
 241         self.vehicle        = world;
 242 }
 243
 244 float bumb_gunner_enter()
 245 {
 246         RemoveGrapplingHook(other);
 247         entity _gun, _gunner;
 248         if(!self.gunner1)
 249         {
 250                 _gun = self.gun1;
 251                 _gunner = self.gunner1;
 252                 self.gunner1 = other;
 253         }
 254         else if(!self.gunner2)
 255         {
 256                 _gun = self.gun2;
 257                 _gunner = self.gunner2;
 258                 self.gunner2 = other;
 259         }
 260         else
 261         {
 262                 dprint("^1ERROR:^7Tried to enter a fully occupied vehicle!\n");
 263                 return FALSE;
 264         }
 265
 266         _gunner            = other;
 267         _gunner.vehicle    = _gun;
 268         _gun.switchweapon  = other.switchweapon;
 269         _gun.vehicle_exit  = bumb_gunner_exit;
 270
 271         other.angles            = self.angles;
 272         other.takedamage        = DAMAGE_NO;
 273         other.solid             = SOLID_NOT;
 274         other.movetype          = MOVETYPE_NOCLIP;
 275         other.alpha             = -1;
 276         other.event_damage      = SUB_Null;
 277         other.view_ofs          = '0 0 0';
 278         other.hud               = _gun.hud;
 279         other.PlayerPhysplug    = _gun.PlayerPhysplug;
 280         other.vehicle_ammo1     = self.vehicle_ammo1;
 281         other.vehicle_ammo2     = self.vehicle_ammo2;
 282         other.vehicle_reload1   = self.vehicle_reload1;
 283         other.vehicle_reload2   = self.vehicle_reload2;
 284         other.vehicle_energy    = self.vehicle_energy;
 285         other.PlayerPhysplug    = bumb_gunner_frame;
 286         other.flags             &~= FL_ONGROUND;
 287
 288         msg_entity = other;
 289         WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 290         WriteEntity(MSG_ONE, _gun.vehicle_viewport);
 291         WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 292         WriteAngle(MSG_ONE, _gun.angles_x + self.angles_x);    // tilt
 293         WriteAngle(MSG_ONE, _gun.angles_y + self.angles_y);    // yaw
 294         WriteAngle(MSG_ONE, 0);                             // roll
 295         _gun.vehicle_hudmodel.viewmodelforclient = other;
 296
 297         CSQCVehicleSetup(other, other.hud);
 298
 299     if(other.flagcarried)
 300     {
 301         if(!autocvar_g_vehicles_allow_flagcarry)
 302             DropFlag(other.flagcarried, world, world);
 303         else
 304         {
 305             other.flagcarried.scale = 1;
 306             setattachment(other.flagcarried, self, "");
 307             setorigin(other.flagcarried, '0 0 1' * self.maxs_z);
 308         }
 309     }
 310
 311         return TRUE;
 312 }
 313
 314 float vehicles_valid_pilot()
 315 {
 316         if(other.classname != "player")
 317                 return FALSE;
 318
 319         if(other.deadflag != DEAD_NO)
 320                 return FALSE;
 321
 322         if(other.vehicle != world)
 323                 return FALSE;
 324
 325         if(clienttype(other) != CLIENTTYPE_REAL)
 326                 if(!autocvar_g_vehicles_allow_bots)
 327                         return FALSE;
 328
 329         if(teamplay && other.team != self.team)
 330                 return FALSE;
 331
 332         return TRUE;
 333 }
 334
 335 void bumb_touch()
 336 {
 337
 338         if(self.gunner1 != world && self.gunner2 != world)
 339         {
 340                 vehicles_touch();
 341                 return;
 342         }
 343
 344         if(vehicles_valid_pilot())
 345         {
 346                 if(self.gun1.phase <= time)
 347                         if(bumb_gunner_enter())
 348                                 return;
 349
 350                 if(self.gun2.phase <= time)
 351                         if(bumb_gunner_enter())
 352                                 return;
 353         }
 354
 355         vehicles_touch();
 356 }
 357
 358 void bumb_regen()
 359 {
 360         if(self.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 361                 self.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 362                                                                            self.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 363
 364         if(self.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 365                 self.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 366                                                                            self.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 367
 368         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 369                 vehicles_regen(self.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, TRUE);
 370
 371         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 372                 vehicles_regen(self.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, FALSE);
 373
 374         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 375                 vehicles_regen(self.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, FALSE);
 376
 377 }
 378
 379 float bumb_pilot_frame()
 380 {
 381         entity pilot, vehic;
 382         vector newvel;
 383
 384         pilot = self;
 385         vehic = self.vehicle;
 386         self   = vehic;
 387
 388
 389         if(vehic.deadflag != DEAD_NO)
 390         {
 391                 self = pilot;
 392                 pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = 0;
 393                 return 1;
 394         }
 395
 396         bumb_regen();
 397
 398         crosshair_trace(pilot);
 399
 400         vector vang;
 401         float ftmp;
 402
 403         vang = vehic.angles;
 404         newvel = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 405         vang_x *= -1;
 406         newvel_x *= -1;
 407         if(newvel_x > 180)  newvel_x -= 360;
 408         if(newvel_x < -180) newvel_x += 360;
 409         if(newvel_y > 180)  newvel_y -= 360;
 410         if(newvel_y < -180) newvel_y += 360;
 411
 412         ftmp = shortangle_f(pilot.v_angle_y - vang_y, vang_y);
 413         if(ftmp > 180)  ftmp -= 360;
 414         if(ftmp < -180) ftmp += 360;
 415         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 416
 417         // Pitch
 418         ftmp = 0;
 419         if(pilot.movement_x > 0 && vang_x < autocvar_g_vehicle_bumblebee_pitchlimit) ftmp = 5;
 420         else if(pilot.movement_x < 0 && vang_x > -autocvar_g_vehicle_bumblebee_pitchlimit) ftmp = -20;
 421
 422         newvel_x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x , autocvar_g_vehicle_bumblebee_pitchlimit);
 423         ftmp = vang_x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 424         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 425
 426         vehic.angles_x = anglemods(vehic.angles_x);
 427         vehic.angles_y = anglemods(vehic.angles_y);
 428         vehic.angles_z = anglemods(vehic.angles_z);
 429
 430         makevectors('0 1 0' * vehic.angles_y);
 431         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 432
 433         if(pilot.movement_x != 0)
 434         {
 435                 if(pilot.movement_x > 0)
 436                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 437                 else if(pilot.movement_x < 0)
 438                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 439         }
 440
 441         if(pilot.movement_y != 0)
 442         {
 443                 if(pilot.movement_y < 0)
 444                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 445                 else if(pilot.movement_y > 0)
 446                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 447                 ftmp = newvel * v_right;
 448                 ftmp *= frametime * 0.1;
 449                 vehic.angles_z = bound(-15, vehic.angles_z + ftmp, 15);
 450         }
 451         else
 452         {
 453                 vehic.angles_z *= 0.95;
 454                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 455                         vehic.angles_z = 0;
 456         }
 457
 458         if(pilot.BUTTON_CROUCH)
 459                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 460         else if(pilot.BUTTON_JUMP)
 461                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 462
 463         vehic.velocity  += newvel * frametime;
 464         pilot.velocity = pilot.movement  = vehic.velocity;
 465         setorigin(pilot, vehic.origin + '0 0 32');
 466
 467         if(vehic.tur_head.lock_time < time || vehic.tur_head.enemy.deadflag)
 468                 vehic.tur_head.enemy = world;
 469
 470         if(trace_ent)
 471         if(trace_ent.movetype)
 472         if(trace_ent.takedamage)
 473         if(!trace_ent.deadflag)
 474         {
 475                 if(teamplay)
 476                 {
 477                         if(trace_ent.team == pilot.team)
 478                         {
 479                                 vehic.tur_head.enemy = trace_ent;
 480                                 vehic.tur_head.lock_time = time + 1;
 481                         }
 482                 }
 483                 else
 484                 {
 485                         vehic.tur_head.enemy = trace_ent;
 486                         vehic.tur_head.lock_time = time + 0.5;
 487                 }
 488         }
 489
 490         if(vehic.tur_head.enemy)
 491         {
 492                 trace_endpos = real_origin(vehic.tur_head.enemy);
 493                 UpdateAuxiliaryXhair(pilot, trace_endpos, '0 0.5 0', 0);
 494         }
 495
 496         vang = vehicle_aimturret(vehic, trace_endpos, self.gun3, "fire",
 497                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 498                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 499
 500         if((pilot.BUTTON_ATCK || pilot.BUTTON_ATCK2) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 501         {
 502                 vehic.gun3.enemy.realowner = pilot;
 503                 vehic.gun3.enemy.effects &~= EF_NODRAW;
 504                 vehic.gun3.enemy.hook_start  = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 505
 506                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 507
 508                 if(trace_ent)
 509                 {
 510                         if(autocvar_g_vehicle_bumblebee_raygun)
 511                         {
 512                                 Damage(trace_ent, vehic, pilot, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 513                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 514                         }
 515                         else
 516                         {
 517                                 if(trace_ent.deadflag == DEAD_NO)
 518                                         if((teamplay && trace_ent.team == pilot.team) || !teamplay)
 519                                         {
 520
 521                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 522                                                 {
 523                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.tur_health)
 524                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.tur_health);
 525
 526                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 527                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 528                                                 }
 529                                                 else if(trace_ent.flags & FL_CLIENT)
 530                                                 {
 531                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 532                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 533
 534                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 535                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 536
 537                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 538                                                 }
 539                                                 else if(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 540                                                 {
 541                                                         if(trace_ent.health  <= trace_ent.tur_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 542                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 543                                                         //else ..hmmm what? ammo?
 544
 545                                                         trace_ent.SendFlags |= TNSF_STATUS;
 546                                                 }
 547                                         }
 548                         }
 549                 }
 550                 vehic.gun3.enemy.hook_end = trace_endpos;
 551                 setorigin(vehic.gun3.enemy, trace_endpos);
 552                 vehic.gun3.enemy.SendFlags |= BRG_START;
 553                 vehic.gun3.enemy.SendFlags |= BRG_END;
 554                 vehic.wait = time + 1;
 555         }
 556         else
 557                 vehic.gun3.enemy.effects |= EF_NODRAW;
 558         /*{
 559                 if(vehic.gun3.enemy)
 560                         remove(vehic.gun3.enemy);
 561
 562                 vehic.gun3.enemy = world;
 563         }
 564         */
 565
 566         VEHICLE_UPDATE_PLAYER(pilot, health, bumblebee);
 567         VEHICLE_UPDATE_PLAYER(pilot, energy, bumblebee);
 568
 569         pilot.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 570         pilot.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 571
 572         if(vehic.vehicle_flags & VHF_HASSHIELD)
 573                 VEHICLE_UPDATE_PLAYER(pilot, shield, bumblebee);
 574
 575
 576         pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = pilot.BUTTON_CROUCH = 0;
 577         self = pilot;
 578
 579         return 1;
 580 }
 581
 582 void bumb_think()
 583 {
 584         self.velocity = self.velocity * 0.5;
 585         self.nextthink = time + 0.1;
 586
 587         if(!self.owner)
 588         {
 589                 entity oldself = self;
 590                 if(self.gunner1)
 591                 {
 592                         self = self.gunner1;
 593                         oldself.gun1.vehicle_exit(VHEF_EJECT);
 594                         entity oldother = other;
 595                         other = self;
 596                         self = oldself;
 597                         self.phase = 0;
 598                         self.touch();
 599                         other = oldother;
 600                         return;
 601                 }
 602
 603                 if(self.gunner2)
 604                 {
 605                         self = self.gunner2;
 606                         oldself.gun2.vehicle_exit(VHEF_EJECT);
 607                         entity oldother = other;
 608                         other = self;
 609                         self = oldself;
 610                         self.phase = 0;
 611                         self.touch();
 612                         other = oldother;
 613                         return;
 614                 }
 615         }
 616 }
 617
 618 void bumb_enter()
 619 {
 620         self.touch = bumb_touch;
 621         self.nextthink = 0;
 622 }
 623
 624 void bumb_exit(float eject)
 625 {
 626
 627         self.owner = world;
 628         self.touch = vehicles_touch;
 629         self.think = bumb_think;
 630         self.nextthink = time;
 631 }
 632
 633 void bumb_blowup()
 634 {
 635         self.deadflag    = DEAD_DEAD;
 636
 637         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 638                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 639                                  autocvar_g_vehicle_bumblebee_blowup_radius, self,
 640                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 641                                  DEATH_WAKIBLOWUP, world);
 642
 643         self.movetype       = MOVETYPE_NONE;
 644         self.effects        = EF_NODRAW;
 645         self.colormod       = '0 0 0';
 646         self.avelocity      = '0 0 0';
 647         self.velocity       = '0 0 0';
 648
 649         //entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime)
 650         fixedmakevectors(self.angles);
 651         vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 300);
 652         vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 300);
 653         vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 654
 655         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 656         pointparticles(particleeffectnum("explosion_large"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 657
 658         setorigin(self, self.pos1);
 659         self.touch = SUB_Null;
 660         self.nextthink = 0;
 661 }
 662
 663 void bumb_diethink()
 664 {
 665         if(time >= self.wait)
 666                 self.think = bumb_blowup;
 667
 668         if(random() < 0.1)
 669         {
 670                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 671                 pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 672         }
 673
 674         self.nextthink = time + 0.1;
 675 }
 676
 677 void bumb_die()
 678 {
 679         entity oldself = self;
 680         if(self.gunner1)
 681         {
 682                 self = self.gunner1;
 683                 oldself.gun1.vehicle_exit(VHEF_EJECT);
 684                 self = oldself;
 685         }
 686
 687         if(self.gunner2)
 688         {
 689                 self = self.gunner2;
 690                 oldself.gun2.vehicle_exit(VHEF_EJECT);
 691                 self = oldself;
 692         }
 693
 694         self.vehicle_exit(VHEF_EJECT);
 695
 696         self.health       = 0;
 697         self.event_damage = SUB_Null;
 698         self.solid        = SOLID_CORPSE;
 699         self.takedamage   = DAMAGE_NO;
 700         self.deadflag     = DEAD_DYING;
 701         self.movetype     = MOVETYPE_BOUNCE;
 702         self.think        = bumb_diethink;
 703         self.nextthink    = time;
 704         self.wait         = time + 2 + (random() * 8);
 705
 706         self.avelocity = '0 0.5 1' * (random() * 400);
 707         self.avelocity -= '0 0.5 1' * (random() * 400);
 708
 709         self.colormod = '-0.5 -0.5 -0.5';
 710         self.touch     = bumb_blowup;
 711
 712         pointparticles(particleeffectnum("explosion_medium"), findbetterlocation(self.origin, 16), '0 0 0', 1);
 713 }
 714
 715 void bumb_impact()
 716 {
 717     if(autocvar_g_vehicle_bumblebee_bouncepain_x)
 718         vehilces_impact(autocvar_g_vehicle_bumblebee_bouncepain_x,
 719                                                 autocvar_g_vehicle_bumblebee_bouncepain_y,
 720                                                 autocvar_g_vehicle_bumblebee_bouncepain_z);
 721 }
 722
 723 void bumb_spawn(float _f)
 724 {
 725         /*
 726         float i;
 727         for(i=1; gettaginfo(self.gun1, i), gettaginfo_name; ++i)
 728         {
 729
 730             dprint(" ------- ^1gettaginfo_name^2(",ftos(i),") ^3=", gettaginfo_name, "\n");
 731         }
 732         */
 733         if(!self.gun1)
 734         {
 735                 // for some reason, autosizing of the shiled entity refuses to work for this one so set it up in advance.
 736                 self.vehicle_shieldent = spawn();
 737                 self.vehicle_shieldent.effects = EF_LOWPRECISION;
 738                 setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 739                 setattachment(self.vehicle_shieldent, self, "");
 740                 setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 741                 self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 742                 self.vehicle_shieldent.think       = shieldhit_think;
 743                 self.vehicle_shieldent.alpha = -1;
 744                 self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 745
 746                 self.gun1 = spawn();
 747                 self.gun2 = spawn();
 748                 self.gun3 = spawn();
 749
 750                 self.vehicle_flags |= VHF_MULTISLOT;
 751
 752                 self.gun1.owner = self;
 753                 self.gun2.owner = self;
 754                 self.gun3.owner = self;
 755
 756                 setmodel(self.gun1, "models/vehicles/bumblebee_plasma_right.dpm");
 757                 setmodel(self.gun2, "models/vehicles/bumblebee_plasma_left.dpm");
 758                 setmodel(self.gun3, "models/vehicles/bumblebee_ray.dpm");
 759
 760                 setattachment(self.gun1, self, "cannon_right");
 761                 setattachment(self.gun2, self, "cannon_left");
 762
 763                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 764                 self.gun3.pos1 = self.angles;
 765                 self.angles = '0 0 0';
 766                 vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 767                 ofs -= self.origin;
 768                 setattachment(self.gun3, self, "");
 769                 setorigin(self.gun3, ofs);
 770                 self.angles = self.gun3.pos1;
 771
 772                 vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 773                 vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 774
 775                 setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 776                 setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 777
 778                 //fixme-model-bones
 779                 setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 780                 setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 781                 //fixme-model-bones
 782                 setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 783                 setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 784
 785                 self.scale = 1.5;
 786
 787                 // Raygun beam
 788                 if(self.gun3.enemy == world)
 789                 {
 790                         self.gun3.enemy = spawn();
 791                         Net_LinkEntity(self.gun3.enemy, TRUE, 0, bumble_raygun_send);
 792                         self.gun3.enemy.SendFlags = BRG_SETUP;
 793                         self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 794                         self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 795                 }
 796         }
 797
 798         self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 799         self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 800         self.solid          = SOLID_BBOX;
 801         self.movetype           = MOVETYPE_BOUNCEMISSILE;
 802         self.vehicle_impact = bumb_impact;
 803         setorigin(self, self.origin + '0 0 25');
 804 }
 805
 806 void spawnfunc_vehicle_bumblebee()
 807 {
 808         if(!autocvar_g_vehicle_bumblebee)
 809         {
 810                 remove(self);
 811                 return;
 812         }
 813
 814         precache_model("models/vehicles/bumblebee_body.dpm");
 815         precache_model("models/vehicles/bumblebee_plasma_left.dpm");
 816         precache_model("models/vehicles/bumblebee_plasma_right.dpm");
 817         precache_model("models/vehicles/bumblebee_ray.dpm");
 818         precache_model("models/vehicles/wakizashi_cockpit.dpm");
 819         precache_model("models/vehicles/spiderbot_cockpit.dpm");
 820         precache_model("models/vehicles/raptor_cockpit.dpm");
 821
 822         if(autocvar_g_vehicle_bumblebee_energy)
 823                 if(autocvar_g_vehicle_bumblebee_energy_regen)
 824                         self.vehicle_flags |= VHF_ENERGYREGEN;
 825
 826         if(autocvar_g_vehicle_bumblebee_shield)
 827                 self.vehicle_flags |= VHF_HASSHIELD;
 828
 829         if(autocvar_g_vehicle_bumblebee_shield_regen)
 830                 self.vehicle_flags |= VHF_SHIELDREGEN;
 831
 832         if(autocvar_g_vehicle_bumblebee_health_regen)
 833                 self.vehicle_flags |= VHF_HEALTHREGEN;
 834
 835         if not(vehicle_initialize(
 836                            "Bumblebee", "models/vehicles/bumblebee_body.dpm",
 837                            "", "models/vehicles/spiderbot_cockpit.dpm", "", "", "tag_viewport",
 838                            HUD_BUMBLEBEE, BUMB_MIN, BUMB_MAX, FALSE,
 839                            bumb_spawn, autocvar_g_vehicle_bumblebee_respawntime,
 840                            bumb_pilot_frame, bumb_enter, bumb_exit,
 841                            bumb_die, bumb_think, FALSE, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_shield))
 842         {
 843                 remove(self);
 844                 return;
 845         }
 846 }
 847
 848 float bumble_raygun_send(entity to, float sf)
 849 {
 850         WriteByte(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
 851
 852         WriteByte(MSG_ENTITY, sf);
 853         if(sf & BRG_SETUP)
 854         {
 855                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 856                 WriteByte(MSG_ENTITY, self.realowner.team);
 857                 WriteByte(MSG_ENTITY, self.cnt);
 858         }
 859
 860         if(sf & BRG_START)
 861         {
 862                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 863                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 864                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 865         }
 866
 867         if(sf & BRG_END)
 868         {
 869                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 870                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 871                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 872         }
 873
 874         return TRUE;
 875 }
 876 #endif // SVQC
 877
 878 #ifdef CSQC
 879 /*
 880 .vector raygun_l1
 881 .vector raygun_l2;
 882 .vector raygun_l3;
 883 */
 884
 885 void bumble_raygun_draw()
 886 {
 887         float _len;
 888         vector _dir;
 889         vector _vtmp1, _vtmp2;
 890
 891         _len = vlen(self.origin - self.move_origin);
 892         _dir = normalize(self.move_origin - self.origin);
 893
 894         if(self.total_damages < time)
 895         {
 896                 boxparticles(self.traileffect, self, self.origin, self.origin + _dir * -64, _dir * -_len , _dir * -_len, 1, PARTICLES_USEALPHA);
 897                 boxparticles(self.lip, self, self.move_origin, self.move_origin + _dir * -64, _dir * -200 , _dir * -200, 1, PARTICLES_USEALPHA);
 898                 self.total_damages = time + 0.1;
 899         }
 900
 901         float i, df, sz, al;
 902         for(i = -0.1; i < 0.2; i += 0.1)
 903         {
 904                 df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
 905                 sz = 5 + random() * 5;
 906                 al = 0.25 + random() * 0.5;
 907                 _vtmp1 = self.origin + _dir * _len * (0.25 + i);
 908                 _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //self.raygun_l1;
 909                 Draw_CylindricLine(self.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 910
 911                 _vtmp2 = self.origin + _dir * _len * (0.5 + i);
 912                 _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //self.raygun_l2;
 913                 Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 914
 915                 _vtmp1 = self.origin + _dir * _len * (0.75 + i);
 916                 _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //self.raygun_l3;
 917                 Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 918
 919                 Draw_CylindricLine(_vtmp1, self.move_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 920         }
 921 }
 922
 923 void bumble_raygun_read(float bIsNew)
 924 {
 925         float sf = ReadByte();
 926
 927         if(sf & BRG_SETUP)
 928         {
 929                 self.cnt  = ReadByte();
 930                 self.team = ReadByte();
 931                 self.cnt  = ReadByte();
 932
 933                 if(self.cnt)
 934                         self.colormod = '1 0 0';
 935                 else
 936                         self.colormod = '0 1 0';
 937
 938                 self.traileffect = particleeffectnum("healray_muzzleflash");
 939                 self.lip = particleeffectnum("healray_impact");
 940
 941                 self.draw = bumble_raygun_draw;
 942         }
 943
 944
 945         if(sf & BRG_START)
 946         {
 947                 self.origin_x = ReadCoord();
 948                 self.origin_y = ReadCoord();
 949                 self.origin_z = ReadCoord();
 950                 setorigin(self, self.origin);
 951         }
 952
 953         if(sf & BRG_END)
 954         {
 955                 self.move_origin_x = ReadCoord();
 956                 self.move_origin_y = ReadCoord();
 957                 self.move_origin_z = ReadCoord();
 958         }
 959 }
 960
 961 void bumblebee_draw()
 962 {
 963
 964 }
 965
 966 void bumblebee_draw2d()
 967 {
 968
 969 }
 970
 971 void bumblebee_read_extra()
 972 {
 973
 974 }
 975
 976 void vehicle_bumblebee_assemble()
 977 {
 978
 979 }
 980 #endif //CSQC