qcsrc/server/vehicles/bumblebee.qc

   1 #define BRG_SETUP 2
   2 #define BRG_START 4
   3 #define BRG_END 8
   4
   5 #ifdef SVQC
   6 // Auto cvars
   7 float autocvar_g_vehicle_bumblebee_speed_forward;
   8 float autocvar_g_vehicle_bumblebee_speed_strafe;
   9 float autocvar_g_vehicle_bumblebee_speed_up;
  10 float autocvar_g_vehicle_bumblebee_speed_down;
  11 float autocvar_g_vehicle_bumblebee_turnspeed;
  12 float autocvar_g_vehicle_bumblebee_pitchspeed;
  13 float autocvar_g_vehicle_bumblebee_pitchlimit;
  14 float autocvar_g_vehicle_bumblebee_friction;
  15
  16 float autocvar_g_vehicle_bumblebee_energy;
  17 float autocvar_g_vehicle_bumblebee_energy_regen;
  18 float autocvar_g_vehicle_bumblebee_energy_regen_pause;
  19
  20 float autocvar_g_vehicle_bumblebee_health;
  21 float autocvar_g_vehicle_bumblebee_health_regen;
  22 float autocvar_g_vehicle_bumblebee_health_regen_pause;
  23
  24 float autocvar_g_vehicle_bumblebee_shield;
  25 float autocvar_g_vehicle_bumblebee_shield_regen;
  26 float autocvar_g_vehicle_bumblebee_shield_regen_pause;
  27
  28 float autocvar_g_vehicle_bumblebee_cannon_cost;
  29 float autocvar_g_vehicle_bumblebee_cannon_damage;
  30 float autocvar_g_vehicle_bumblebee_cannon_radius;
  31 float autocvar_g_vehicle_bumblebee_cannon_refire;
  32 float autocvar_g_vehicle_bumblebee_cannon_speed;
  33 float autocvar_g_vehicle_bumblebee_cannon_spread;
  34 float autocvar_g_vehicle_bumblebee_cannon_force;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo;
  37 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen;
  38 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause;
  39
  40 var float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  41
  42 float autocvar_g_vehicle_bumblebee_cannon_turnspeed;
  43 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down;
  44 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up;
  45 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  46 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  47
  48
  49 float autocvar_g_vehicle_bumblebee_raygun_turnspeed;
  50 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down;
  51 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up;
  52 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides;
  53
  54 float autocvar_g_vehicle_bumblebee_raygun_range;
  55 float autocvar_g_vehicle_bumblebee_raygun_dps;
  56 float autocvar_g_vehicle_bumblebee_raygun_aps;
  57 float autocvar_g_vehicle_bumblebee_raygun_fps;
  58
  59 float autocvar_g_vehicle_bumblebee_raygun;
  60 float autocvar_g_vehicle_bumblebee_healgun_hps;
  61 float autocvar_g_vehicle_bumblebee_healgun_hmax;
  62 float autocvar_g_vehicle_bumblebee_healgun_aps;
  63 float autocvar_g_vehicle_bumblebee_healgun_amax;
  64 float autocvar_g_vehicle_bumblebee_healgun_sps;
  65
  66 float autocvar_g_vehicle_bumblebee_respawntime;
  67
  68 float autocvar_g_vehicle_bumblebee_blowup_radius;
  69 float autocvar_g_vehicle_bumblebee_blowup_coredamage;
  70 float autocvar_g_vehicle_bumblebee_blowup_edgedamage;
  71 float autocvar_g_vehicle_bumblebee_blowup_forceintensity;
  72
  73 var float autocvar_g_vehicle_bumblebee = 0;
  74
  75
  76 float bumble_raygun_send(entity to, float sf);
  77
  78 #define BUMB_MIN '-120 -120 -120'
  79 #define BUMB_MAX '120 120 120'
  80
  81 void bumb_fire_cannon(entity _gun, string _tagname, entity _owner)
  82 {
  83         vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
  84         vehicles_projectile("bigplasma_muzzleflash", "weapons/flacexp3.wav",
  85                                                 v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  86                                                 autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  87                                                 DEATH_BUMB_GUN, PROJECTILE_BUMBLE_GUN, 0, TRUE, TRUE, _owner);
  88 }
  89
  90 float bumb_gunner_frame()
  91 {
  92         entity vehic    = self.vehicle.owner;
  93         entity gun      = self.vehicle;
  94         entity gunner   = self;
  95         self = vehic;
  96
  97         vehic.solid = SOLID_NOT;
  98         setorigin(gunner, vehic.origin);
  99         gunner.velocity = vehic.velocity;
 100         crosshair_trace(gunner);
 101         vector _ct = trace_endpos;
 102         vector ad;
 103
 104         float _in = ((gun == vehic.gun1) ? autocvar_g_vehicle_bumblebee_cannon_turnlimit_in : autocvar_g_vehicle_bumblebee_cannon_turnlimit_out);
 105         float _out = ((gun == vehic.gun1) ? autocvar_g_vehicle_bumblebee_cannon_turnlimit_out : autocvar_g_vehicle_bumblebee_cannon_turnlimit_in);
 106
 107         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 108         {
 109                 if(gun.lock_time < time)
 110                         gun.enemy = world;
 111
 112                 if(trace_ent)
 113                         if(trace_ent.movetype)
 114                                 if(trace_ent.takedamage)
 115                                         if(!trace_ent.deadflag)
 116                                         {
 117                                                 if(teamplay)
 118                                                 {
 119                                                         if(trace_ent.team != gunner.team)
 120                                                         {
 121                                                                 gun.enemy = trace_ent;
 122                                                                 gun.lock_time = time + 5;
 123                                                         }
 124                                                 }
 125                                                 else
 126                                                 {
 127                                                         gun.enemy = trace_ent;
 128                                                         gun.lock_time = time + 5;
 129                                                 }
 130                                         }
 131         }
 132
 133         if(gun.enemy)
 134         {
 135                 float i, distance, impact_time;
 136
 137                 vector vf = real_origin(gun.enemy);
 138                 vector _vel = gun.enemy.velocity;
 139                 if(gun.enemy.movetype == MOVETYPE_WALK)
 140                         _vel_z *= 0.1;
 141
 142
 143                 ad = vf;
 144                 for(i = 0; i < 4; ++i)
 145                 {
 146                         distance = vlen(ad - gunner.origin);
 147                         impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 148                         ad = vf + _vel * impact_time;
 149                 }
 150                 trace_endpos = ad;
 151
 152
 153                 UpdateAuxiliaryXhair(gunner, ad, '1 0 1', 1);
 154                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 155                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 156                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 157
 158         }
 159         else
 160                 vehicle_aimturret(vehic, _ct, gun, "fire",
 161                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 162                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 163
 164         if(gunner.BUTTON_ATCK)
 165                 if(time > gun.attack_finished_single)
 166                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 167                         {
 168                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 169                                 bumb_fire_cannon(gun, "fire", gunner);
 170                                 gun.delay = time;
 171                                 gun.attack_finished_single = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 172                         }
 173
 174         VEHICLE_UPDATE_PLAYER(gunner, health, bumblebee);
 175
 176         if(vehic.vehicle_flags & VHF_HASSHIELD)
 177                 VEHICLE_UPDATE_PLAYER(gunner, shield, bumblebee);
 178
 179         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 180         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 181
 182         UpdateAuxiliaryXhair(gunner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), 0);
 183
 184         if(vehic.owner)
 185                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), ((gunner == vehic.gunner1) ? 1 : 2));
 186
 187         vehic.solid = SOLID_BBOX;
 188         gunner.BUTTON_ATCK = gunner.BUTTON_ATCK2 = gunner.BUTTON_CROUCH = 0;
 189         gunner.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 190
 191         self = gunner;
 192         return 1;
 193 }
 194
 195 void bumb_gunner_exit(float _exitflag)
 196 {
 197         if(clienttype(self) == CLIENTTYPE_REAL)
 198         {
 199                 msg_entity = self;
 200                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 201                 WriteEntity(MSG_ONE, self);
 202
 203                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 204                 WriteAngle(MSG_ONE, 0);
 205                 WriteAngle(MSG_ONE, self.vehicle.angles_y);
 206                 WriteAngle(MSG_ONE, 0);
 207         }
 208
 209         CSQCVehicleSetup(self, HUD_NORMAL);
 210         setsize(self, PL_MIN, PL_MAX);
 211
 212         self.takedamage     = DAMAGE_AIM;
 213         self.solid          = SOLID_SLIDEBOX;
 214         self.movetype       = MOVETYPE_WALK;
 215         self.effects        &~= EF_NODRAW;
 216         self.alpha          = 1;
 217         self.PlayerPhysplug = SUB_Null;
 218         self.view_ofs       = PL_VIEW_OFS;
 219         self.event_damage   = PlayerDamage;
 220         self.hud            = HUD_NORMAL;
 221         self.switchweapon   = self.vehicle.switchweapon;
 222
 223         if(self.flagcarried)
 224         {
 225                 self.flagcarried.scale = 0.6;
 226                 setattachment(self.flagcarried, self, "");
 227                 setorigin(self.flagcarried, FLAG_CARRY_POS);
 228         }
 229
 230         self.vehicle.vehicle_hudmodel.viewmodelforclient = self.vehicle;
 231
 232         if(self == self.vehicle.owner.gunner1)
 233                 self.vehicle.owner.gunner1 = world;
 234         else if(self == self.vehicle.owner.gunner2)
 235                 self.vehicle.owner.gunner2 = world;
 236         else
 237                 dprint("^1self != gunner1 or gunner2, this is a BIG PROBLEM, tell tZork this happend.\n");
 238
 239         self.vehicle.phase = time + 5;
 240         self.vehicle        = world;
 241 }
 242
 243 float bumb_gunner_enter()
 244 {
 245         RemoveGrapplingHook(other);
 246         entity _gun, _gunner;
 247         if(!self.gunner1)
 248         {
 249                 _gun = self.gun1;
 250                 _gunner = self.gunner1;
 251                 self.gunner1 = other;
 252         }
 253         else if(!self.gunner2)
 254         {
 255                 _gun = self.gun2;
 256                 _gunner = self.gunner2;
 257                 self.gunner2 = other;
 258         }
 259         else
 260         {
 261                 dprint("^1ERROR:^7Tried to enter a fully occupied vehicle!\n");
 262                 return FALSE;
 263         }
 264
 265         _gunner            = other;
 266         _gunner.vehicle    = _gun;
 267         _gun.switchweapon  = other.switchweapon;
 268         _gun.vehicle_exit  = bumb_gunner_exit;
 269
 270         other.angles            = self.angles;
 271         other.takedamage        = DAMAGE_NO;
 272         other.solid             = SOLID_NOT;
 273         other.movetype          = MOVETYPE_NOCLIP;
 274         other.alpha             = -1;
 275         other.event_damage      = SUB_Null;
 276         other.view_ofs          = '0 0 0';
 277         other.hud               = _gun.hud;
 278         other.PlayerPhysplug    = _gun.PlayerPhysplug;
 279         other.vehicle_ammo1     = self.vehicle_ammo1;
 280         other.vehicle_ammo2     = self.vehicle_ammo2;
 281         other.vehicle_reload1   = self.vehicle_reload1;
 282         other.vehicle_reload2   = self.vehicle_reload2;
 283         other.vehicle_energy    = self.vehicle_energy;
 284         other.PlayerPhysplug    = bumb_gunner_frame;
 285         other.flags             &~= FL_ONGROUND;
 286
 287         msg_entity = other;
 288         WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 289         WriteEntity(MSG_ONE, _gun.vehicle_viewport);
 290         WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 291         WriteAngle(MSG_ONE, _gun.angles_x + self.angles_x);    // tilt
 292         WriteAngle(MSG_ONE, _gun.angles_y + self.angles_y);    // yaw
 293         WriteAngle(MSG_ONE, 0);                             // roll
 294         _gun.vehicle_hudmodel.viewmodelforclient = other;
 295
 296         CSQCVehicleSetup(other, other.hud);
 297
 298     if(other.flagcarried)
 299     {
 300         if(!autocvar_g_vehicles_allow_flagcarry)
 301             DropFlag(other.flagcarried, world, world);
 302         else
 303         {
 304             other.flagcarried.scale = 1;
 305             setattachment(other.flagcarried, self, "");
 306             setorigin(other.flagcarried, '0 0 1' * self.maxs_z);
 307         }
 308     }
 309
 310         return TRUE;
 311 }
 312
 313 float vehicles_valid_pilot()
 314 {
 315         if(other.classname != "player")
 316                 return FALSE;
 317
 318         if(other.deadflag != DEAD_NO)
 319                 return FALSE;
 320
 321         if(other.vehicle != world)
 322                 return FALSE;
 323
 324         if(clienttype(other) != CLIENTTYPE_REAL)
 325                 if(!autocvar_g_vehicles_allow_bots)
 326                         return FALSE;
 327
 328         if(teamplay && other.team != self.team)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 void bumb_touch()
 335 {
 336
 337         if(self.gunner1 != world && self.gunner2 != world)
 338         {
 339                 vehicles_touch();
 340                 return;
 341         }
 342
 343         if(vehicles_valid_pilot())
 344         {
 345                 if(self.gun1.phase <= time)
 346                         if(bumb_gunner_enter())
 347                                 return;
 348
 349                 if(self.gun2.phase <= time)
 350                         if(bumb_gunner_enter())
 351                                 return;
 352         }
 353
 354         vehicles_touch();
 355 }
 356
 357 void bumb_regen()
 358 {
 359         if(self.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 360                 self.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 361                                                                            self.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 362
 363         if(self.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 364                 self.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 365                                                                            self.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 366
 367         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 368                 vehicles_regen(self.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, TRUE);
 369
 370         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 371                 vehicles_regen(self.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, FALSE);
 372
 373         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 374                 vehicles_regen(self.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, FALSE);
 375
 376 }
 377
 378 float bumb_pilot_frame()
 379 {
 380         entity pilot, vehic;
 381         vector newvel;
 382
 383         pilot = self;
 384         vehic = self.vehicle;
 385         self   = vehic;
 386
 387
 388         if(vehic.deadflag != DEAD_NO)
 389         {
 390                 self = pilot;
 391                 pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = 0;
 392                 return 1;
 393         }
 394
 395         bumb_regen();
 396
 397         crosshair_trace(pilot);
 398
 399         vector vang;
 400         float ftmp;
 401
 402         vang = vehic.angles;
 403         newvel = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 404         vang_x *= -1;
 405         newvel_x *= -1;
 406         if(newvel_x > 180)  newvel_x -= 360;
 407         if(newvel_x < -180) newvel_x += 360;
 408         if(newvel_y > 180)  newvel_y -= 360;
 409         if(newvel_y < -180) newvel_y += 360;
 410
 411         ftmp = shortangle_f(pilot.v_angle_y - vang_y, vang_y);
 412         if(ftmp > 180)  ftmp -= 360;
 413         if(ftmp < -180) ftmp += 360;
 414         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 415
 416         // Pitch
 417         ftmp = 0;
 418         if(pilot.movement_x > 0 && vang_x < autocvar_g_vehicle_bumblebee_pitchlimit) ftmp = 5;
 419         else if(pilot.movement_x < 0 && vang_x > -autocvar_g_vehicle_bumblebee_pitchlimit) ftmp = -20;
 420
 421         newvel_x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x , autocvar_g_vehicle_bumblebee_pitchlimit);
 422         ftmp = vang_x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 423         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 424
 425         vehic.angles_x = anglemods(vehic.angles_x);
 426         vehic.angles_y = anglemods(vehic.angles_y);
 427         vehic.angles_z = anglemods(vehic.angles_z);
 428
 429         makevectors('0 1 0' * vehic.angles_y);
 430         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 431
 432         if(pilot.movement_x != 0)
 433         {
 434                 if(pilot.movement_x > 0)
 435                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 436                 else if(pilot.movement_x < 0)
 437                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 438         }
 439
 440         if(pilot.movement_y != 0)
 441         {
 442                 if(pilot.movement_y < 0)
 443                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 444                 else if(pilot.movement_y > 0)
 445                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 446                 ftmp = newvel * v_right;
 447                 ftmp *= frametime * 0.1;
 448                 vehic.angles_z = bound(-15, vehic.angles_z + ftmp, 15);
 449         }
 450         else
 451         {
 452                 vehic.angles_z *= 0.95;
 453                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 454                         vehic.angles_z = 0;
 455         }
 456
 457         if(pilot.BUTTON_CROUCH)
 458                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 459         else if(pilot.BUTTON_JUMP)
 460                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 461
 462         vehic.velocity  += newvel * frametime;
 463         pilot.velocity = pilot.movement  = vehic.velocity;
 464         setorigin(pilot, vehic.origin + '0 0 32');
 465
 466         if(vehic.tur_head.lock_time < time || vehic.tur_head.enemy.deadflag)
 467                 vehic.tur_head.enemy = world;
 468
 469         if(trace_ent)
 470         if(trace_ent.movetype)
 471         if(trace_ent.takedamage)
 472         if(!trace_ent.deadflag)
 473         {
 474                 if(teamplay)
 475                 {
 476                         if(trace_ent.team == pilot.team)
 477                         {
 478                                 vehic.tur_head.enemy = trace_ent;
 479                                 vehic.tur_head.lock_time = time + 1;
 480                         }
 481                 }
 482                 else
 483                 {
 484                         vehic.tur_head.enemy = trace_ent;
 485                         vehic.tur_head.lock_time = time + 0.5;
 486                 }
 487         }
 488
 489         if(vehic.tur_head.enemy)
 490         {
 491                 trace_endpos = real_origin(vehic.tur_head.enemy);
 492                 UpdateAuxiliaryXhair(pilot, trace_endpos, '0 0.5 0', 0);
 493         }
 494
 495         vang = vehicle_aimturret(vehic, trace_endpos, self.gun3, "fire",
 496                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 497                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 498
 499         if((pilot.BUTTON_ATCK || pilot.BUTTON_ATCK2) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 500         {
 501
 502
 503
 504                 if(vehic.gun3.enemy == world)
 505                 {
 506                         vehic.gun3.enemy = spawn();
 507                         Net_LinkEntity(vehic.gun3.enemy, FALSE, 0, bumble_raygun_send);
 508                         vehic.gun3.enemy.SendFlags = BRG_SETUP;
 509                         vehic.gun3.enemy.think = SUB_Remove;
 510                         vehic.gun3.enemy.realowner = pilot;
 511                         vehic.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 512                 }
 513
 514                 vehic.gun3.enemy.nextthink = time + 0.1;
 515                 setorigin(vehic.gun3.enemy, gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire")));
 516                 traceline(vehic.gun3.enemy.origin, vehic.gun3.enemy.origin + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 517                 if(trace_ent)
 518                 {
 519                         if(autocvar_g_vehicle_bumblebee_raygun)
 520                         {
 521                                 Damage(trace_ent, vehic, pilot, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 522                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 523                         }
 524                         else
 525                         {
 526                                 if(trace_ent.deadflag == DEAD_NO)
 527                                         if((teamplay && trace_ent.team == pilot.team) || !teamplay)
 528                                         {
 529
 530                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 531                                                 {
 532                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.tur_health)
 533                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.tur_health);
 534
 535                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 536                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 537                                                 }
 538                                                 else if(trace_ent.flags & FL_CLIENT)
 539                                                 {
 540                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 541                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 542
 543                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 544                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 545
 546                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 547                                                 }
 548                                                 else if(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 549                                                 {
 550                                                         if(trace_ent.health  <= trace_ent.tur_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 551                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 552                                                         //else ..hmmm what? ammo?
 553
 554                                                         trace_ent.SendFlags |= TNSF_STATUS;
 555                                                 }
 556                                         }
 557                         }
 558                 }
 559                 vehic.gun3.enemy.hook_end = trace_endpos;
 560                 vehic.gun3.enemy.SendFlags |= BRG_START;
 561                 vehic.gun3.enemy.SendFlags |= BRG_END;
 562                 vehic.wait = time + 1;
 563         }
 564         else
 565         {
 566                 if(vehic.gun3.enemy)
 567                         remove(vehic.gun3.enemy);
 568
 569                 vehic.gun3.enemy = world;
 570         }
 571
 572         VEHICLE_UPDATE_PLAYER(pilot, health, bumblebee);
 573         VEHICLE_UPDATE_PLAYER(pilot, energy, bumblebee);
 574
 575         pilot.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 576         pilot.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 577
 578         if(vehic.vehicle_flags & VHF_HASSHIELD)
 579                 VEHICLE_UPDATE_PLAYER(pilot, shield, bumblebee);
 580
 581
 582         pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = pilot.BUTTON_CROUCH = 0;
 583         self = pilot;
 584
 585         return 1;
 586 }
 587
 588 void bumb_think()
 589 {
 590         self.velocity = self.velocity * 0.5;
 591         self.nextthink = time + 0.1;
 592
 593         if(!self.owner)
 594         {
 595                 entity oldself = self;
 596                 if(self.gunner1)
 597                 {
 598                         self = self.gunner1;
 599                         oldself.gun1.vehicle_exit(VHEF_EJECT);
 600                         entity oldother = other;
 601                         other = self;
 602                         self = oldself;
 603                         self.phase = 0;
 604                         self.touch();
 605                         other = oldother;
 606                         return;
 607                 }
 608
 609                 if(self.gunner2)
 610                 {
 611                         self = self.gunner2;
 612                         oldself.gun2.vehicle_exit(VHEF_EJECT);
 613                         entity oldother = other;
 614                         other = self;
 615                         self = oldself;
 616                         self.phase = 0;
 617                         self.touch();
 618                         other = oldother;
 619                         return;
 620                 }
 621         }
 622 }
 623
 624 void bumb_enter()
 625 {
 626         self.touch = bumb_touch;
 627         self.nextthink = 0;
 628 }
 629
 630 void bumb_exit(float eject)
 631 {
 632
 633         self.owner = world;
 634         self.touch = vehicles_touch;
 635         self.think = bumb_think;
 636         self.nextthink = time;
 637 }
 638
 639 void bumb_blowup()
 640 {
 641         self.deadflag    = DEAD_DEAD;
 642
 643         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 644                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 645                                  autocvar_g_vehicle_bumblebee_blowup_radius, self,
 646                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 647                                  DEATH_WAKIBLOWUP, world);
 648
 649         self.movetype       = MOVETYPE_NONE;
 650         self.effects        = EF_NODRAW;
 651         self.colormod       = '0 0 0';
 652         self.avelocity      = '0 0 0';
 653         self.velocity       = '0 0 0';
 654
 655         //entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime)
 656         fixedmakevectors(self.angles);
 657         vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 300);
 658         vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 300);
 659         vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 660
 661         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 662         pointparticles(particleeffectnum("explosion_large"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 663
 664         setorigin(self, self.pos1);
 665         self.touch = SUB_Null;
 666         self.nextthink = 0;
 667 }
 668
 669 void bumb_diethink()
 670 {
 671         if(time >= self.wait)
 672                 self.think = bumb_blowup;
 673
 674         if(random() < 0.1)
 675         {
 676                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 677                 pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 678         }
 679
 680         self.nextthink = time + 0.1;
 681 }
 682
 683 void bumb_die()
 684 {
 685         entity oldself = self;
 686         if(self.gunner1)
 687         {
 688                 self = self.gunner1;
 689                 oldself.gun1.vehicle_exit(VHEF_EJECT);
 690                 self = oldself;
 691         }
 692
 693         if(self.gunner2)
 694         {
 695                 self = self.gunner2;
 696                 oldself.gun2.vehicle_exit(VHEF_EJECT);
 697                 self = oldself;
 698         }
 699
 700         self.vehicle_exit(VHEF_EJECT);
 701
 702         self.health       = 0;
 703         self.event_damage = SUB_Null;
 704         self.solid        = SOLID_CORPSE;
 705         self.takedamage   = DAMAGE_NO;
 706         self.deadflag     = DEAD_DYING;
 707         self.movetype     = MOVETYPE_BOUNCE;
 708         self.think        = bumb_diethink;
 709         self.nextthink    = time;
 710         self.wait         = time + 2 + (random() * 8);
 711
 712         self.avelocity = '0 0.5 1' * (random() * 400);
 713         self.avelocity -= '0 0.5 1' * (random() * 400);
 714
 715         self.colormod = '-0.5 -0.5 -0.5';
 716         self.touch     = bumb_blowup;
 717
 718         pointparticles(particleeffectnum("explosion_medium"), findbetterlocation(self.origin, 16), '0 0 0', 1);
 719 }
 720
 721
 722 void bumb_spawn(float _f)
 723 {
 724         /*
 725         float i;
 726         for(i=1; gettaginfo(self.gun1, i), gettaginfo_name; ++i)
 727         {
 728
 729             dprint(" ------- ^1gettaginfo_name^2(",ftos(i),") ^3=", gettaginfo_name, "\n");
 730         }
 731         */
 732
 733         if(!self.gun1)
 734         {
 735                 // for some reason, autosizing of the shiled entity refuses to work for this one so set it up in advance.
 736                 self.vehicle_shieldent = spawn();
 737                 self.vehicle_shieldent.effects = EF_LOWPRECISION;
 738                 setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 739                 setattachment(self.vehicle_shieldent, self, "");
 740                 setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 741                 self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 742                 self.vehicle_shieldent.think       = shieldhit_think;
 743                 self.vehicle_shieldent.alpha = -1;
 744                 self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 745
 746                 self.gun1 = spawn();
 747                 self.gun2 = spawn();
 748                 self.gun3 = spawn();
 749
 750                 self.vehicle_flags |= VHF_MULTISLOT;
 751
 752                 self.gun1.owner = self;
 753                 self.gun2.owner = self;
 754                 self.gun3.owner = self;
 755
 756                 setmodel(self.gun1, "models/vehicles/bumblebee_plasma_right.dpm");
 757                 setmodel(self.gun2, "models/vehicles/bumblebee_plasma_left.dpm");
 758                 setmodel(self.gun3, "models/vehicles/bumblebee_ray.dpm");
 759
 760                 setattachment(self.gun1, self, "cannon_right");
 761                 setattachment(self.gun2, self, "cannon_left");
 762
 763                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 764                 self.gun3.pos1 = self.angles;
 765                 self.angles = '0 0 0';
 766                 vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 767                 ofs -= self.origin;
 768                 setattachment(self.gun3, self, "");
 769                 setorigin(self.gun3, ofs);
 770                 self.angles = self.gun3.pos1;
 771
 772                 vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 773                 vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 774
 775                 setorigin(self.vehicle_hudmodel, '45 0 45');    // Move cockpit up-forward.
 776                 setorigin(self.vehicle_viewport, '8 0 5');    // Move camera up-forward too.
 777
 778                 //fixme-model-bones
 779                 setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 780                 setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 781                 //fixme-model-bones
 782                 setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 783                 setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 784
 785                 self.scale = 1.5;
 786         }
 787
 788         self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 789         self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 790         self.solid          = SOLID_BBOX;
 791         self.movetype           = MOVETYPE_BOUNCEMISSILE;
 792         setorigin(self, self.origin + '0 0 25');
 793 }
 794
 795 void spawnfunc_vehicle_bumblebee()
 796 {
 797         if(!autocvar_g_vehicle_bumblebee)
 798         {
 799                 remove(self);
 800                 return;
 801         }
 802
 803         precache_model("models/vehicles/bumblebee_body.dpm");
 804         precache_model("models/vehicles/bumblebee_plasma_left.dpm");
 805         precache_model("models/vehicles/bumblebee_plasma_right.dpm");
 806         precache_model("models/vehicles/bumblebee_ray.dpm");
 807         precache_model("models/vehicles/wakizashi_cockpit.dpm");
 808         precache_model("models/vehicles/spiderbot_cockpit.dpm");
 809         precache_model("models/vehicles/raptor_cockpit.dpm");
 810
 811         if(autocvar_g_vehicle_bumblebee_energy)
 812                 if(autocvar_g_vehicle_bumblebee_energy_regen)
 813                         self.vehicle_flags |= VHF_ENERGYREGEN;
 814
 815         if(autocvar_g_vehicle_bumblebee_shield)
 816                 self.vehicle_flags |= VHF_HASSHIELD;
 817
 818         if(autocvar_g_vehicle_bumblebee_shield_regen)
 819                 self.vehicle_flags |= VHF_SHIELDREGEN;
 820
 821         if(autocvar_g_vehicle_bumblebee_health_regen)
 822                 self.vehicle_flags |= VHF_HEALTHREGEN;
 823
 824         if not(vehicle_initialize(
 825                            "Bumblebee", "models/vehicles/bumblebee_body.dpm",
 826                            "", "models/vehicles/spiderbot_cockpit.dpm", "", "", "tag_viewport",
 827                            HUD_BUMBLEBEE, BUMB_MIN, BUMB_MAX, FALSE,
 828                            bumb_spawn, autocvar_g_vehicle_bumblebee_respawntime,
 829                            bumb_pilot_frame, bumb_enter, bumb_exit,
 830                            bumb_die, bumb_think, FALSE, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_shield))
 831         {
 832                 remove(self);
 833                 return;
 834         }
 835 }
 836
 837 float bumble_raygun_send(entity to, float sf)
 838 {
 839         WriteByte(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
 840
 841         WriteByte(MSG_ENTITY, sf);
 842         if(sf & BRG_SETUP)
 843         {
 844                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 845                 WriteByte(MSG_ENTITY, self.realowner.team);
 846                 WriteByte(MSG_ENTITY, self.cnt);
 847         }
 848
 849         if(sf & BRG_START)
 850         {
 851                 WriteCoord(MSG_ENTITY, self.origin_x);
 852                 WriteCoord(MSG_ENTITY, self.origin_y);
 853                 WriteCoord(MSG_ENTITY, self.origin_z);
 854         }
 855
 856         if(sf & BRG_END)
 857         {
 858                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 859                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 860                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 861         }
 862
 863         return TRUE;
 864 }
 865 #endif // SVQC
 866
 867 #ifdef CSQC
 868 /*
 869 .vector raygun_l1
 870 .vector raygun_l2;
 871 .vector raygun_l3;
 872 */
 873
 874 void bumble_raygun_draw()
 875 {
 876         float _len;
 877         vector _dir;
 878         vector _vtmp1, _vtmp2;
 879
 880         _len = vlen(self.origin - self.move_origin);
 881         _dir = normalize(self.move_origin - self.origin);
 882
 883         if(self.total_damages < time)
 884         {
 885                 boxparticles(self.traileffect, self, self.origin, self.origin + _dir * -64, _dir * -_len , _dir * -_len, 1, PARTICLES_USEALPHA);
 886                 boxparticles(self.lip, self, self.move_origin, self.move_origin + _dir * -64, _dir * -200 , _dir * -200, 1, PARTICLES_USEALPHA);
 887                 self.total_damages = time + 0.1;
 888         }
 889
 890         float i, df, sz, al;
 891         for(i = -0.1; i < 0.2; i += 0.1)
 892         {
 893                 df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
 894                 sz = 5 + random() * 5;
 895                 al = 0.25 + random() * 0.5;
 896                 _vtmp1 = self.origin + _dir * _len * (0.25 + i);
 897                 _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //self.raygun_l1;
 898                 Draw_CylindricLine(self.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 899
 900                 _vtmp2 = self.origin + _dir * _len * (0.5 + i);
 901                 _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //self.raygun_l2;
 902                 Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 903
 904                 _vtmp1 = self.origin + _dir * _len * (0.75 + i);
 905                 _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //self.raygun_l3;
 906                 Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 907
 908                 Draw_CylindricLine(_vtmp1, self.move_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
 909         }
 910 }
 911
 912 void bumble_raygun_read(float bIsNew)
 913 {
 914         float sf = ReadByte();
 915
 916         if(sf & BRG_SETUP)
 917         {
 918                 self.cnt  = ReadByte();
 919                 self.team = ReadByte();
 920                 self.cnt  = ReadByte();
 921
 922                 if(self.cnt)
 923                         self.colormod = '1 0 0';
 924                 else
 925                         self.colormod = '0 1 0';
 926
 927                 self.traileffect = particleeffectnum("healray_muzzleflash");
 928                 self.lip = particleeffectnum("healray_impact");
 929
 930                 self.draw = bumble_raygun_draw;
 931         }
 932
 933
 934         if(sf & BRG_START)
 935         {
 936                 self.origin_x = ReadCoord();
 937                 self.origin_y = ReadCoord();
 938                 self.origin_z = ReadCoord();
 939                 setorigin(self, self.origin);
 940         }
 941
 942         if(sf & BRG_END)
 943         {
 944                 self.move_origin_x = ReadCoord();
 945                 self.move_origin_y = ReadCoord();
 946                 self.move_origin_z = ReadCoord();
 947         }
 948 }
 949
 950 void bumblebee_draw()
 951 {
 952
 953 }
 954
 955 void bumblebee_draw2d()
 956 {
 957
 958 }
 959
 960 void bumblebee_read_extra()
 961 {
 962
 963 }
 964
 965 void vehicle_bumblebee_assemble()
 966 {
 967
 968 }
 969 #endif //CSQC