qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3
   4 #ifdef SVQC
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19 float autocvar_g_vehicle_racer_friction;
  20
  21 float autocvar_g_vehicle_racer_hovertype;
  22 float autocvar_g_vehicle_racer_hoverpower;
  23
  24 float autocvar_g_vehicle_racer_turnroll;
  25 float autocvar_g_vehicle_racer_turnspeed;
  26 float autocvar_g_vehicle_racer_pitchspeed;
  27
  28 float autocvar_g_vehicle_racer_energy;
  29 float autocvar_g_vehicle_racer_energy_regen;
  30 float autocvar_g_vehicle_racer_energy_regen_pause;
  31
  32 float autocvar_g_vehicle_racer_health;
  33 float autocvar_g_vehicle_racer_health_regen;
  34 float autocvar_g_vehicle_racer_health_regen_pause;
  35
  36 float autocvar_g_vehicle_racer_shield;
  37 float autocvar_g_vehicle_racer_shield_regen;
  38 float autocvar_g_vehicle_racer_shield_regen_pause;
  39
  40 float autocvar_g_vehicle_racer_cannon_cost;
  41 float autocvar_g_vehicle_racer_cannon_damage;
  42 float autocvar_g_vehicle_racer_cannon_radius;
  43 float autocvar_g_vehicle_racer_cannon_refire;
  44 float autocvar_g_vehicle_racer_cannon_speed;
  45 float autocvar_g_vehicle_racer_cannon_spread;
  46 float autocvar_g_vehicle_racer_cannon_force;
  47
  48 float autocvar_g_vehicle_racer_rocket_accel;
  49 float autocvar_g_vehicle_racer_rocket_damage;
  50 float autocvar_g_vehicle_racer_rocket_radius;
  51 float autocvar_g_vehicle_racer_rocket_force;
  52 float autocvar_g_vehicle_racer_rocket_refire;
  53 float autocvar_g_vehicle_racer_rocket_speed;
  54 float autocvar_g_vehicle_racer_rocket_turnrate;
  55
  56 float autocvar_g_vehicle_racer_rocket_locktarget;
  57 float autocvar_g_vehicle_racer_rocket_locking_time;
  58 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  59 float autocvar_g_vehicle_racer_rocket_locked_time;
  60 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  61
  62 float autocvar_g_vehicle_racer_respawntime;
  63
  64 float autocvar_g_vehicle_racer_blowup_radius;
  65 float autocvar_g_vehicle_racer_blowup_coredamage;
  66 float autocvar_g_vehicle_racer_blowup_edgedamage;
  67 float autocvar_g_vehicle_racer_blowup_forceintensity;
  68
  69 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  70
  71 void racer_align4point()
  72 {
  73     vector push_vector, v_add;
  74     float fl_push, fr_push, bl_push, br_push;
  75
  76
  77     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  78     fr_push      = force_fromtag_normpower;
  79     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  80
  81     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  82     fl_push      = force_fromtag_normpower;
  83     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  84
  85     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  86     br_push      = force_fromtag_normpower;
  87     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  88
  89     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90     bl_push      = force_fromtag_normpower;
  91     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93     self.velocity += (push_vector * frametime);
  94
  95     // Anti ocilation
  96     if(self.velocity_z  > 0)
  97         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  98
  99     self.velocity   += v_add;
 100     //self.velocity_z -= autocvar_sv_gravity * frametime;
 101
 102     push_vector_x =  (fl_push - bl_push);
 103     push_vector_x += (fr_push - br_push);
 104     push_vector_x *= 360;
 105
 106     push_vector_z = (fr_push - fl_push);
 107     push_vector_z += (br_push - bl_push);
 108     push_vector_z *= 360;
 109
 110     // Apply angle diffrance
 111     self.angles_z += push_vector_z * frametime;
 112     self.angles_x += push_vector_x * frametime;
 113
 114     // Apply stabilizer
 115     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 116     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117 }
 118
 119 void racer_fire_cannon(string tagname)
 120 {
 121     vector v;
 122     entity bolt;
 123
 124     v = gettaginfo(self, gettagindex(self, tagname));
 125     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 126                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 127                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 128                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 129
 130         // Fix z-aim (for chase mode)
 131     v = normalize(trace_endpos - bolt.origin);
 132     v_forward_z = v_z * 0.5;
 133     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 134 }
 135
 136 void racer_rocket_groundhugger()
 137 {
 138     vector olddir, newdir;
 139     float oldvel, newvel;
 140
 141     self.nextthink  = time;
 142
 143     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 144     {
 145         self.use();
 146         return;
 147     }
 148
 149     if not (self.realowner.vehicle)
 150     {
 151         UpdateCSQCProjectile(self);
 152         return;
 153     }
 154
 155     olddir = normalize(self.velocity);
 156     oldvel = vlen(self.velocity);
 157     newvel = oldvel + self.lip;
 158
 159     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 160     if(trace_fraction <= 0.5)
 161     {
 162         // Hitting somethign soon, just speed ahead
 163         self.velocity = olddir * newvel;
 164         UpdateCSQCProjectile(self);
 165         return;
 166     }
 167
 168     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 169     if(trace_fraction != 1.0)
 170     {
 171         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 172         self.velocity = normalize(olddir + newdir) * newvel;
 173     }
 174     else
 175     {
 176         self.velocity = olddir * newvel;
 177         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 178     }
 179
 180     UpdateCSQCProjectile(self);
 181     return;
 182 }
 183
 184 void racer_rocket_tracker()
 185 {
 186     vector olddir, newdir;
 187     float oldvel, newvel;
 188
 189     self.nextthink  = time;
 190
 191     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 192     {
 193         self.use();
 194         return;
 195     }
 196
 197     if not (self.realowner.vehicle)
 198     {
 199         UpdateCSQCProjectile(self);
 200         return;
 201     }
 202
 203     olddir = normalize(self.velocity);
 204     oldvel = vlen(self.velocity);
 205     newvel = oldvel + self.lip;
 206     makevectors(vectoangles(olddir));
 207
 208     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 209     newdir = normalize(self.enemy.origin - self.origin);
 210
 211     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 212     {
 213         //bprint("Target lost!\n");
 214         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 215         self.think = racer_rocket_groundhugger;
 216         return;
 217     }
 218
 219     if(trace_fraction != 1.0)
 220         newdir_z += 16 * sys_frametime;
 221
 222     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 223     self.velocity_z -= 800 * sys_frametime;
 224
 225     UpdateCSQCProjectile(self);
 226     return;
 227 }
 228
 229 void racer_fire_rocket(string tagname, entity trg)
 230 {
 231     vector v;
 232     entity rocket;
 233
 234     v = gettaginfo(self, gettagindex(self, tagname));
 235     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 236                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 237                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 238                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 239
 240     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 241     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 242     rocket.nextthink        = time;
 243     rocket.enemy            = trg;
 244     rocket.cnt              = time + 15;
 245
 246     if(trg)
 247         rocket.think            = racer_rocket_tracker;
 248     else
 249         rocket.think            = racer_rocket_groundhugger;
 250 }
 251
 252 float racer_frame()
 253 {
 254     entity player, racer;
 255     vector df;
 256     float ftmp;
 257
 258         if(intermission_running)
 259                 return 1;
 260
 261     player  = self;
 262     racer   = self.vehicle;
 263     self    = racer;
 264
 265     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 266
 267     vehicles_painframe();
 268
 269     if(racer.deadflag != DEAD_NO)
 270     {
 271         self = player;
 272         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 273         return 1;
 274     }
 275
 276     racer_align4point();
 277
 278     crosshair_trace(player);
 279
 280     racer.angles_x *= -1;
 281
 282     // Yaw
 283     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 284     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 285     racer.angles_y = anglemods(racer.angles_y + ftmp);
 286
 287     // Roll
 288     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 289
 290     // Pitch
 291     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 292     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 293     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 294
 295     makevectors(racer.angles);
 296     racer.angles_x *= -1;
 297
 298
 299     ftmp = racer.velocity_z;
 300     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 301     racer.velocity_z = ftmp;
 302
 303     if(player.movement_x != 0)
 304     {
 305         if(player.movement_x > 0)
 306             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 307         else if(player.movement_x < 0)
 308             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 309     }
 310
 311     if(player.movement_y != 0)
 312     {
 313         if(player.movement_y < 0)
 314             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 315         else if(player.movement_y > 0)
 316             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 317     }
 318
 319     if(vlen(player.movement) != 0)
 320     {
 321         if(self.sound_nexttime < time || self.sounds != 1)
 322         {
 323             self.sounds = 1;
 324             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 325             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 326         }
 327     }
 328     else
 329     {
 330         if(self.sound_nexttime < time || self.sounds != 0)
 331         {
 332             self.sounds = 0;
 333             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 334             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 335         }
 336     }
 337
 338     // Afterburn
 339     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 340     {
 341         if(time - racer.wait > 0.2)
 342             pointparticles(particleeffectnum("wakizashi_booster_smoke"), self.origin, '0 0 0', 1);
 343
 344         racer.wait = time;
 345         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 346         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 347
 348         if(self.invincible_finished < time)
 349         {
 350             traceline(self.origin, self.origin - '0 0 256', MOVE_NORMAL, self);
 351             if(trace_fraction != 1.0)
 352                 pointparticles(particleeffectnum("smoke_small"), trace_endpos, '0 0 0', 1);
 353
 354             self.invincible_finished = time + 0.1 + (random() * 0.1);
 355         }
 356
 357         if(self.strength_finished < time)
 358         {
 359             //self.sounds = 2;
 360             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 361             sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 362         }
 363     }
 364     else
 365     {
 366         self.strength_finished = 0;
 367         sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 368     }
 369
 370
 371     racer.velocity  += df * frametime;
 372
 373     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 374     racer.velocity  = racer.velocity - df;
 375     player.movement = racer.velocity;
 376
 377     if(player.BUTTON_ATCK)
 378     if(time > racer.attack_finished_single)
 379     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 380     {
 381         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 382         racer.wait = time;
 383
 384         crosshair_trace(player);
 385         if(racer.cnt)
 386         {
 387             racer_fire_cannon("tag_fire1");
 388             racer.cnt = 0;
 389         }
 390         else
 391         {
 392             racer_fire_cannon("tag_fire2");
 393             racer.cnt = 1;
 394         }
 395         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 396         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 397     }
 398
 399     if(autocvar_g_vehicle_racer_rocket_locktarget)
 400     {
 401         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 402                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 403                          autocvar_g_vehicle_racer_rocket_locked_time);
 404
 405         if(self.lock_target)
 406         {
 407             if(racer.lock_strength == 1)
 408                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 409             else if(self.lock_strength > 0.5)
 410                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 411             else if(self.lock_strength < 0.5)
 412                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 413         }
 414     }
 415
 416     if(time > racer.delay)
 417     if(player.BUTTON_ATCK2)
 418     {
 419         self.misc_bulletcounter += 1;
 420         racer.delay = time + 0.3;
 421         if(self.misc_bulletcounter == 1)
 422             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 423         else if(self.misc_bulletcounter == 2)
 424         {
 425             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 426             self.lock_strength  = 0;
 427             self.lock_target    = world;
 428             self.misc_bulletcounter = 0;
 429
 430             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 431             racer.lip = time;
 432         }
 433     }
 434     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 435
 436     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 437         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 438
 439     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 440         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 441
 442     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 443         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 444
 445
 446     VEHICLE_UPDATE_PLAYER(health, racer);
 447     VEHICLE_UPDATE_PLAYER(energy, racer);
 448
 449     if(self.vehicle_flags & VHF_HASSHIELD)
 450         VEHICLE_UPDATE_PLAYER(shield, racer);
 451
 452
 453     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 454     setorigin(player,racer.origin + '0 0 32');
 455     player.velocity = racer.velocity;
 456
 457     self = player;
 458     return 1;
 459 }
 460
 461 void racer_think()
 462 {
 463     /*
 464     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 465     b = autocvar_g_vehicle_racer_springlength;
 466     c = autocvar_g_vehicle_racer_hoverpower;
 467
 468     autocvar_g_vehicle_racer_anglestabilizer = 36;
 469     autocvar_g_vehicle_racer_springlength = 96;
 470     autocvar_g_vehicle_racer_hoverpower = 300;
 471     */
 472
 473     racer_align4point(); //time - self.nextthink);
 474
 475     /*
 476     //if(self.velocity_z > 0)
 477     //    self.velocity_z *= 0.95;
 478
 479     autocvar_g_vehicle_racer_anglestabilizer = a;
 480     autocvar_g_vehicle_racer_springlength = b;
 481     autocvar_g_vehicle_racer_hoverpower = c;
 482     */
 483
 484     self.velocity_x *= 0.9;
 485     self.velocity_y *= 0.9;
 486     self.velocity_z *= 0.8;
 487     self.velocity_z += sin(time * 2) * 16;
 488     self.nextthink = time; // + 0.05;
 489 }
 490
 491 void racer_enter()
 492 {
 493     self.movetype = MOVETYPE_BOUNCE;
 494     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 495     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 496
 497     if(self.owner.flagcarried)
 498        setorigin(self.owner.flagcarried, '-190 0 96');
 499 }
 500
 501 void racer_exit(float eject)
 502 {
 503     vector spot;
 504
 505     self.think      = racer_think;
 506     self.nextthink  = time;
 507     self.movetype   = MOVETYPE_TOSS;
 508     sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 509
 510     if not (self.owner)
 511         return;
 512
 513         makevectors(self.angles);
 514         if(eject)
 515         {
 516             spot = self.origin + v_forward * 100 + '0 0 64';
 517             spot = vehicles_findgoodexit(spot);
 518             setorigin(self.owner , spot);
 519             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 520         }
 521         else
 522         {
 523             spot = self.origin - v_forward * 200 + '0 0 64';
 524             spot = vehicles_findgoodexit(spot);
 525             setorigin(self.owner , spot);
 526         }
 527
 528     self.owner = world;
 529 }
 530
 531 void racer_spawn()
 532 {
 533     self.think          = racer_think;
 534     self.nextthink      = time;
 535     self.vehicle_health = autocvar_g_vehicle_racer_health;
 536     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 537
 538     self.movetype       = MOVETYPE_TOSS;
 539     self.solid          = SOLID_SLIDEBOX;
 540     self.delay          = time;
 541     self.scale          = 0.5;
 542
 543     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 544 }
 545
 546
 547 void racer_blowup()
 548 {
 549     self.deadflag    = DEAD_DEAD;
 550     self.vehicle_exit(VHEF_NORMAL);
 551
 552     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 553                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 554                                         autocvar_g_vehicle_racer_blowup_radius, world,
 555                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 556                                         DEATH_WAKIBLOWUP, world);
 557
 558     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 559     self.think      = racer_spawn;
 560     self.movetype   = MOVETYPE_NONE;
 561     self.effects    = EF_NODRAW;
 562
 563     self.colormod  = '0 0 0';
 564     self.avelocity = '0 0 0';
 565     self.velocity  = '0 0 0';
 566
 567     setorigin(self, self.pos1);
 568         self.think     = racer_spawn;
 569         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 570 }
 571
 572 void racer_deadtouch()
 573 {
 574     self.avelocity_x *= 0.7;
 575     self.cnt -= 1;
 576     if(self.cnt <= 0)
 577         racer_blowup();
 578 }
 579
 580 void racer_die()
 581 {
 582     self.health       = 0;
 583     self.event_damage = SUB_Null;
 584     self.solid        = SOLID_CORPSE;
 585     self.takedamage   = DAMAGE_NO;
 586     self.deadflag     = DEAD_DYING;
 587     self.movetype     = MOVETYPE_BOUNCE;
 588     self.wait         = time;
 589     self.cnt          = 1 + random() * 2;
 590     self.touch        = racer_deadtouch;
 591
 592     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 593
 594     if(random() < 0.5)
 595         self.avelocity_z  = 32;
 596     else
 597         self.avelocity_z  = -32;
 598
 599     self.avelocity_x = -vlen(self.velocity) * 0.2;
 600     self.velocity   += '0 0 700';
 601     self.colormod    = '-0.5 -0.5 -0.5';
 602
 603         self.think     = racer_blowup;
 604         self.nextthink = 2 + time + random() * 3;
 605 }
 606
 607 void racer_dinit()
 608 {
 609     if not (vehicle_initialize(
 610              "Wakizashi",
 611              "models/vehicles/wakizashi.dpm",
 612              "null", // we need this so tur_head is networked and usable for sounds
 613              "models/vehicles/wakizashi_cockpit.dpm",
 614              "", "", "tag_viewport",
 615              HUD_WAKIZASHI,
 616              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 617              FALSE,
 618              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 619              racer_frame,
 620              racer_enter, racer_exit,
 621              racer_die,   racer_think,
 622              TRUE))
 623     {
 624         remove(self);
 625         return;
 626     }
 627
 628     if(autocvar_g_vehicle_racer_hovertype != 0)
 629         racer_force_from_tag = vehicles_force_fromtag_maglev;
 630     else
 631         racer_force_from_tag = vehicles_force_fromtag_hover;
 632
 633     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 634     self.scale = 0.5;
 635     setattachment(self.vehicle_hudmodel, self, "");
 636     setattachment(self.vehicle_viewport, self, "tag_viewport");
 637
 638     self.mass               = 900;
 639 }
 640
 641 void spawnfunc_vehicle_racer()
 642 {
 643     self.vehicle_flags |= VHF_DMGSHAKE;
 644     self.vehicle_flags |= VHF_DMGROLL;
 645
 646     precache_sound ("weapons/lasergun_fire.wav");
 647     precache_sound ("weapons/rocket_fire.wav");
 648
 649     precache_sound ("vehicles/racer_idle.wav");
 650     precache_sound ("vehicles/racer_move.wav");
 651     precache_sound ("vehicles/racer_boost.wav");
 652
 653     precache_model ("models/vhshield.md3");
 654     precache_model ("models/vehicles/wakizashi.dpm");
 655     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 656
 657     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 658     if(autocvar_g_vehicle_racer_energy)
 659         if(autocvar_g_vehicle_racer_energy_regen)
 660             self.vehicle_flags |= VHF_ENERGYREGEN;
 661
 662     if(autocvar_g_vehicle_racer_shield)
 663         self.vehicle_flags |= VHF_HASSHIELD;
 664
 665     if(autocvar_g_vehicle_racer_shield_regen)
 666         self.vehicle_flags |= VHF_SHIELDREGEN;
 667
 668     if(autocvar_g_vehicle_racer_health_regen)
 669         self.vehicle_flags |= VHF_HEALTHREGEN;
 670
 671     self.think = racer_dinit;
 672
 673     if(g_assault)
 674         self.nextthink = time + 0.5;
 675     else
 676         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 677 }
 678 #endif // SVQC