qcsrc/server/vehicles/vehicles.qc

   1 #include "../../common/triggers/subs.qh"
   2
   3 float autocvar_g_vehicles_crush_dmg;
   4 float autocvar_g_vehicles_crush_force;
   5 float autocvar_g_vehicles_delayspawn;
   6 float autocvar_g_vehicles_delayspawn_jitter;
   7
   8 float autocvar_g_vehicles_vortex_damagerate = 0.5;
   9 float autocvar_g_vehicles_machinegun_damagerate = 0.5;
  10 float autocvar_g_vehicles_rifle_damagerate = 0.75;
  11 float autocvar_g_vehicles_vaporizer_damagerate = 0.001;
  12 float autocvar_g_vehicles_tag_damagerate = 5;
  13
  14 float autocvar_g_vehicles;
  15
  16 void vehicles_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  17 void vehicles_return();
  18 void vehicles_enter();
  19 void vehicles_touch();
  20 void vehicles_reset_colors();
  21 void vehicles_clearreturn();
  22 void vehicles_setreturn();
  23
  24
  25 /** AuxiliaryXhair*
  26     Send additional points of interest to be drawn, to vehicle owner
  27 **/
  28 const float MAX_AXH = 4;
  29 .entity AuxiliaryXhair[MAX_AXH];
  30
  31 float SendAuxiliaryXhair(entity to, int sf)
  32 {
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  35
  36         WriteByte(MSG_ENTITY, self.cnt);
  37
  38         WriteCoord(MSG_ENTITY, self.origin.x);
  39         WriteCoord(MSG_ENTITY, self.origin.y);
  40         WriteCoord(MSG_ENTITY, self.origin.z);
  41
  42     WriteByte(MSG_ENTITY, rint(self.colormod.x * 255));
  43     WriteByte(MSG_ENTITY, rint(self.colormod.y * 255));
  44     WriteByte(MSG_ENTITY, rint(self.colormod.z * 255));
  45
  46     return true;
  47 }
  48
  49 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  50 {
  51     if (!IS_REAL_CLIENT(own))
  52         return;
  53
  54     entity axh;
  55
  56     axh_id = bound(0, axh_id, MAX_AXH);
  57     axh = own.(AuxiliaryXhair[axh_id]);
  58
  59     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  60     {
  61         axh                     = spawn();
  62         axh.cnt                 = axh_id;
  63         axh.drawonlytoclient    = own;
  64         axh.owner               = own;
  65         Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  66     }
  67
  68     setorigin(axh, loc);
  69     axh.colormod            = clr;
  70     axh.SendFlags           = 0x01;
  71     own.(AuxiliaryXhair[axh_id]) = axh;
  72 }
  73
  74 /*
  75 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  76 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  77 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  78 {
  79         msgexntity = own;
  80
  81         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  82         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  83
  84         WriteByte(MSG_ONE, axh_id);
  85
  86         WriteCoord(MSG_ONE, loc_x);
  87         WriteCoord(MSG_ONE, loc_y);
  88         WriteCoord(MSG_ONE, loc_z);
  89
  90     WriteByte(MSG_ONE, rint(clr_x * 255));
  91     WriteByte(MSG_ONE, rint(clr_y * 255));
  92     WriteByte(MSG_ONE, rint(clr_z * 255));
  93
  94 }
  95 */
  96 // End AuxiliaryXhair
  97
  98 /**
  99     Notifies the client that he enterd a vehicle, and sends
 100     realavent data.
 101
 102     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 103 **/
 104 void CSQCVehicleSetup(entity own, float vehicle_id)
 105 {
 106     if (!IS_REAL_CLIENT(own))
 107         return;
 108
 109         msg_entity = own;
 110
 111         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 112         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 113         if(vehicle_id != 0)
 114             WriteByte(MSG_ONE, vehicle_id);
 115         else
 116         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 117 }
 118
 119 /** vehicles_locktarget
 120
 121     Generic target locking.
 122
 123     Figure out if what target is "locked" (if any), for missile tracking as such.
 124
 125     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 126     you have a locked in target.
 127
 128     Exspects a crosshair_trace() or equivalent to be
 129     dont before calling.
 130
 131 **/
 132 .entity lock_target;
 133 .float  lock_strength;
 134 .float  lock_time;
 135 .float  lock_soundtime;
 136 const float     DAMAGE_TARGETDRONE = 10;
 137
 138 vector targetdrone_getnewspot()
 139 {
 140
 141         vector spot;
 142         float i;
 143         for(i = 0; i < 100; ++i)
 144         {
 145                 spot = self.origin + randomvec() * 1024;
 146                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 147                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 148                         return spot;
 149         }
 150         return self.origin;
 151 }
 152
 153 #if 0
 154 void targetdrone_think();
 155 void targetdrone_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
 156 void targetdrone_renwe()
 157 {
 158         self.think = targetdrone_think;
 159         self.nextthink = time + 0.1;
 160         setorigin(self, targetdrone_getnewspot());
 161         self.health = 200;
 162         self.takedamage = DAMAGE_TARGETDRONE;
 163         self.event_damage = targetdrone_damage;
 164         self.solid = SOLID_BBOX;
 165         setmodel(self, "models/runematch/rune.mdl");
 166         self.effects = EF_LOWPRECISION;
 167         self.scale = 10;
 168         self.movetype = MOVETYPE_BOUNCEMISSILE;
 169         setsize(self, '-100 -100 -100', '100 100 100');
 170
 171 }
 172 void targetdrone_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 173 {
 174         self.health -= damage;
 175         if(self.health <= 0)
 176         {
 177                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 178
 179                 if(!self.cnt)
 180                         remove(self);
 181                 else
 182                 {
 183                         self.think = targetdrone_renwe;
 184                         self.nextthink = time + 1 + random() * 2;
 185                         self.solid = SOLID_NOT;
 186                         setmodel(self, "");
 187                 }
 188         }
 189 }
 190 entity targetdrone_getfear()
 191 {
 192         entity fear;
 193         float i;
 194
 195         for(i = 64; i <= 1024; i += 64)
 196         {
 197                 fear = findradius(self.origin, i);
 198                 while(fear)
 199                 {
 200                         if(fear.bot_dodge)
 201                                 return fear;
 202
 203                         fear = fear.chain;
 204                 }
 205         }
 206
 207         return world;
 208 }
 209 void targetdrone_think()
 210 {
 211         self.nextthink = time + 0.1;
 212
 213         if(self.wp00)
 214         if(self.wp00.deadflag != DEAD_NO)
 215                 self.wp00 = targetdrone_getfear();
 216
 217         if(!self.wp00)
 218                 self.wp00 = targetdrone_getfear();
 219
 220         vector newdir;
 221
 222         if(self.wp00)
 223                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 224         else
 225                 newdir = randomvec() * 0.75;
 226
 227         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 228
 229         if(self.wp00)
 230                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 231         else
 232                 self.velocity = normalize(newdir) * 750;
 233
 234         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 235         if(trace_fraction != 1.0)
 236                 self.velocity = self.velocity * -1;
 237
 238         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 239 }
 240
 241 void targetdrone_spawn(vector _where, float _autorenew)
 242 {
 243         entity drone = spawn();
 244         setorigin(drone, _where);
 245         drone.think = targetdrone_renwe;
 246         drone.nextthink = time + 0.1;
 247         drone.cnt = _autorenew;
 248 }
 249 #endif
 250
 251 void vehicles_locktarget(float incr, float decr, float _lock_time)
 252 {
 253     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 254     {
 255         self.lock_target    = world;
 256         self.lock_strength  = 0;
 257         self.lock_time      = 0;
 258     }
 259
 260     if(self.lock_time > time)
 261     {
 262         if(self.lock_target)
 263         if(self.lock_soundtime < time)
 264         {
 265             self.lock_soundtime = time + 0.5;
 266             play2(self.owner, "vehicles/locked.wav");
 267         }
 268
 269         return;
 270     }
 271
 272     if(trace_ent != world)
 273     {
 274         if(teamplay && trace_ent.team == self.team)
 275             trace_ent = world;
 276
 277         if(trace_ent.deadflag != DEAD_NO)
 278             trace_ent = world;
 279         if(!(
 280             (trace_ent.vehicle_flags & VHF_ISVEHICLE) ||
 281             (trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET) ||
 282             (trace_ent.takedamage == DAMAGE_TARGETDRONE)
 283             )) { trace_ent = world; }
 284     }
 285
 286     if(self.lock_target == world && trace_ent != world)
 287         self.lock_target = trace_ent;
 288
 289     if(self.lock_target && trace_ent == self.lock_target)
 290     {
 291         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 292         {
 293             play2(self.owner, "vehicles/lock.wav");
 294             self.lock_soundtime = time + 0.8;
 295         }
 296         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 297         {
 298             play2(self.owner, "vehicles/locking.wav");
 299             self.lock_soundtime = time + 0.3;
 300         }
 301
 302     }
 303
 304     // Have a locking target
 305     // Trace hit current target
 306     if(trace_ent == self.lock_target && trace_ent != world)
 307     {
 308         self.lock_strength = min(self.lock_strength + incr, 1);
 309         if(self.lock_strength == 1)
 310             self.lock_time = time + _lock_time;
 311     }
 312     else
 313     {
 314         if(trace_ent)
 315             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 316         else
 317             self.lock_strength = max(self.lock_strength - decr, 0);
 318
 319         if(self.lock_strength == 0)
 320             self.lock_target = world;
 321     }
 322 }
 323
 324 #define VEHICLE_UPDATE_PLAYER(ply,fld,vhname) \
 325 ply.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 326
 327 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 328 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 329 if(trace_fraction != 1) \
 330     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 331
 332 // Hover movement support
 333 float  force_fromtag_power;
 334 float  force_fromtag_normpower;
 335 vector force_fromtag_origin;
 336 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 337 {
 338     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 339     v_forward  = normalize(v_forward) * -1;
 340     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 341
 342     force_fromtag_power = (1 - trace_fraction) * max_power;
 343     force_fromtag_normpower = force_fromtag_power / max_power;
 344
 345     return v_forward  * force_fromtag_power;
 346 }
 347
 348 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 349 // Can possibly be use to move abt any surface (inclusing walls/celings)
 350 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 351 {
 352
 353     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 354     v_forward  = normalize(v_forward) * -1;
 355     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 356
 357     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 358     if(trace_fraction == 1.0)
 359     {
 360         force_fromtag_normpower = -0.25;
 361         return '0 0 -200';
 362     }
 363
 364     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 365     force_fromtag_normpower = force_fromtag_power / max_power;
 366
 367     return v_forward  * force_fromtag_power;
 368 }
 369
 370 // Generic vehile projectile system
 371 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 372 {
 373     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 374     if(inflictor.owner == self.owner)
 375         return;
 376
 377     self.health -= damage;
 378     self.velocity += force;
 379     if(self.health < 1)
 380     {
 381         self.takedamage = DAMAGE_NO;
 382         self.event_damage = func_null;
 383         self.think = self.use;
 384         self.nextthink = time;
 385     }
 386 }
 387
 388 void vehicles_projectile_explode()
 389 {
 390     if(self.owner && other != world)
 391     {
 392         if(other == self.owner.vehicle)
 393             return;
 394
 395         if(other == self.owner.vehicle.tur_head)
 396             return;
 397     }
 398
 399         PROJECTILE_TOUCH;
 400
 401         self.event_damage = func_null;
 402     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, world, self.shot_force, self.totalfrags, other);
 403
 404     remove (self);
 405 }
 406
 407 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 408                            vector _org, vector _vel,
 409                            float _dmg, float _radi, float _force,  float _size,
 410                            float _deahtype, float _projtype, float _health,
 411                            float _cull, float _clianim, entity _owner)
 412 {
 413     entity proj;
 414
 415     proj = spawn();
 416
 417     PROJECTILE_MAKETRIGGER(proj);
 418     setorigin(proj, _org);
 419
 420     proj.shot_dmg         = _dmg;
 421     proj.shot_radius      = _radi;
 422     proj.shot_force       = _force;
 423     proj.totalfrags       = _deahtype;
 424     proj.solid            = SOLID_BBOX;
 425     proj.movetype         = MOVETYPE_FLYMISSILE;
 426     proj.flags            = FL_PROJECTILE;
 427     proj.bot_dodge        = true;
 428     proj.bot_dodgerating  = _dmg;
 429     proj.velocity         = _vel;
 430     proj.touch            = vehicles_projectile_explode;
 431     proj.use              = vehicles_projectile_explode;
 432     proj.owner            = self;
 433     proj.realowner        = _owner;
 434     proj.think            = SUB_Remove;
 435     proj.nextthink        = time + 30;
 436
 437     if(_health)
 438     {
 439         proj.takedamage       = DAMAGE_AIM;
 440         proj.event_damage     = vehicles_projectile_damage;
 441         proj.health           = _health;
 442     }
 443     else
 444         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 445
 446     if(_mzlsound)
 447         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 448
 449     if(_mzlfx)
 450         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 451
 452
 453     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 454
 455     CSQCProjectile(proj, _clianim, _projtype, _cull);
 456
 457     return proj;
 458 }
 459 // End generic vehile projectile system
 460
 461 void vehicles_reset()
 462 {
 463         if(self.owner)
 464         {
 465                 entity oldself = self;
 466                 self = self.owner;
 467                 vehicles_exit(VHEF_RELESE);
 468                 self = oldself;
 469         }
 470         self.alpha      = -1;
 471         self.movetype   = MOVETYPE_NONE;
 472         self.effects    = EF_NODRAW;
 473         self.colormod  = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.velocity  = '0 0 0';
 476         self.event_damage = func_null;
 477         self.solid = SOLID_NOT;
 478         self.deadflag = DEAD_NO;
 479
 480         self.touch = func_null;
 481         self.nextthink = 0;
 482         vehicles_setreturn();
 483 }
 484
 485 /** vehicles_spawn
 486     Exetuted for all vehicles on (re)spawn.
 487     Sets defaults for newly spawned units.
 488 **/
 489 void vehicles_spawn()
 490 {
 491     dprint("Spawning vehicle: ", self.netname, "\n");
 492
 493     // De-own & reset
 494     self.vehicle_hudmodel.viewmodelforclient = self;
 495
 496     self.owner              = world;
 497     self.touch              = vehicles_touch;
 498     self.event_damage       = vehicles_damage;
 499     self.reset              = vehicles_reset;
 500     self.iscreature         = true;
 501     self.teleportable       = false; // no teleporting for vehicles, too buggy
 502     self.damagedbycontents      = true;
 503     self.movetype           = MOVETYPE_WALK;
 504     self.solid              = SOLID_SLIDEBOX;
 505     self.takedamage         = DAMAGE_AIM;
 506         self.deadflag           = DEAD_NO;
 507     self.bot_attack         = true;
 508     self.flags              = FL_NOTARGET;
 509     self.avelocity          = '0 0 0';
 510     self.velocity           = '0 0 0';
 511
 512     // Reset locking
 513     self.lock_strength      = 0;
 514     self.lock_target        = world;
 515     self.misc_bulletcounter = 0;
 516
 517     // Return to spawn
 518     self.angles             = self.pos2;
 519     setorigin(self, self.pos1 + '0 0 0');
 520     // Show it
 521     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 522
 523     if(self.vehicle_controller)
 524         self.team = self.vehicle_controller.team;
 525
 526     vehicles_reset_colors();
 527     self.vehicle_spawn(VHSF_NORMAL);
 528 }
 529
 530 // Better way of determening whats crushable needed! (fl_crushable?)
 531 float vehicles_crushable(entity e)
 532 {
 533     if(IS_PLAYER(e))
 534         return true;
 535
 536     if(e.flags & FL_MONSTER)
 537         return true;
 538
 539     return false;
 540 }
 541
 542 void vehicles_impact(float _minspeed, float _speedfac, float _maxpain)
 543 {
 544     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 545         return;
 546
 547     if(self.play_time < time)
 548     {
 549         float wc = vlen(self.velocity - self.oldvelocity);
 550         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 551         //dprint("vel: ", vtos(self.velocity), "\n");
 552         if(_minspeed < wc)
 553         {
 554             float take = min(_speedfac * wc, _maxpain);
 555             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 556             self.play_time = time + 0.25;
 557
 558             //dprint("wc: ", ftos(wc), "\n");
 559             //dprint("take: ", ftos(take), "\n");
 560         }
 561     }
 562 }
 563
 564 .void() vehicle_impact;
 565 void vehicles_touch()
 566 {
 567         if(MUTATOR_CALLHOOK(VehicleTouch))
 568                 return;
 569
 570     // Vehicle currently in use
 571     if(self.owner)
 572     {
 573         if(other != world)
 574         if(vehicles_crushable(other))
 575         {
 576             if(vlen(self.velocity) != 0)
 577                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 578
 579             return; // Dont do selfdamage when hitting "soft targets".
 580         }
 581
 582         if(self.play_time < time)
 583         if(self.vehicle_impact)
 584             self.vehicle_impact();
 585
 586         return;
 587     }
 588
 589     if (!IS_PLAYER(other))
 590         return;
 591
 592     if(other.deadflag != DEAD_NO)
 593         return;
 594
 595     if(other.vehicle != world)
 596         return;
 597
 598     vehicles_enter();
 599 }
 600 float autocvar_g_vehicles_allow_bots = 0;
 601 void vehicles_enter()
 602 {
 603    // Remove this when bots know how to use vehicles
 604
 605     if (IS_BOT_CLIENT(other))
 606         if (autocvar_g_vehicles_allow_bots)
 607             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 608         else
 609             return;
 610
 611     if(self.phase > time)
 612         return;
 613     if(other.frozen)
 614         return;
 615     if(other.vehicle)
 616         return;
 617     if(other.deadflag != DEAD_NO)
 618         return;
 619
 620     if(teamplay)
 621     if(self.team)
 622     if(self.team != other.team)
 623         return;
 624
 625     RemoveGrapplingHook(other);
 626
 627     self.vehicle_ammo1   = 0;
 628     self.vehicle_ammo2   = 0;
 629     self.vehicle_reload1 = 0;
 630     self.vehicle_reload2 = 0;
 631     self.vehicle_energy  = 0;
 632
 633     self.owner          = other;
 634     self.switchweapon   = other.switchweapon;
 635
 636     // .viewmodelforclient works better.
 637     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 638
 639     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 640
 641     self.event_damage         = vehicles_damage;
 642     self.nextthink            = 0;
 643     self.owner.angles         = self.angles;
 644     self.owner.takedamage     = DAMAGE_NO;
 645     self.owner.solid          = SOLID_NOT;
 646     self.owner.movetype       = MOVETYPE_NOCLIP;
 647     self.owner.alpha          = -1;
 648     self.owner.vehicle        = self;
 649     self.owner.event_damage   = func_null;
 650     self.owner.view_ofs       = '0 0 0';
 651     self.colormap             = self.owner.colormap;
 652     if(self.tur_head)
 653         self.tur_head.colormap    = self.owner.colormap;
 654
 655     self.owner.hud            = self.hud;
 656     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 657
 658     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 659     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 660     self.owner.vehicle_reload1  = self.vehicle_reload1;
 661     self.owner.vehicle_reload2  = self.vehicle_reload2;
 662
 663     // Cant do this, hides attached objects too.
 664     //self.exteriormodeltoclient = self.owner;
 665     //self.tur_head.exteriormodeltoclient = self.owner;
 666
 667     other.flags &= ~FL_ONGROUND;
 668     self.flags  &= ~FL_ONGROUND;
 669
 670     self.team                 = self.owner.team;
 671     self.flags               -= FL_NOTARGET;
 672     self.monster_attack       = true;
 673
 674     if (IS_REAL_CLIENT(other))
 675     {
 676         msg_entity = other;
 677         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 678         WriteEntity(MSG_ONE, self.vehicle_viewport);
 679
 680         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 681         if(self.tur_head)
 682         {
 683             WriteAngle(MSG_ONE, self.tur_head.angles.x + self.angles.x); // tilt
 684             WriteAngle(MSG_ONE, self.tur_head.angles.y + self.angles.y); // yaw
 685             WriteAngle(MSG_ONE, 0);                                      // roll
 686         }
 687         else
 688         {
 689             WriteAngle(MSG_ONE,  self.angles.x * -1); // tilt
 690             WriteAngle(MSG_ONE,  self.angles.y);      // yaw
 691             WriteAngle(MSG_ONE,  0);                  // roll
 692         }
 693     }
 694
 695     vehicles_clearreturn();
 696
 697     CSQCVehicleSetup(self.owner, self.hud);
 698
 699     vh_player = other;
 700     vh_vehicle = self;
 701     MUTATOR_CALLHOOK(VehicleEnter);
 702     other = vh_player;
 703     self = vh_vehicle;
 704
 705     self.vehicle_enter();
 706     antilag_clear(other);
 707 }
 708
 709 /** vehicles_findgoodexit
 710     Locates a valid location for the player to exit the vehicle.
 711     Will first try prefer_spot, then up 100 random spots arround the vehicle
 712     wich are in direct line of sight and empty enougth to hold a players bbox
 713 **/
 714 vector vehicles_findgoodexit(vector prefer_spot)
 715 {
 716     //vector exitspot;
 717     float mysize;
 718
 719     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 720     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 721         return prefer_spot;
 722
 723     mysize = 1.5 * vlen(self.maxs - self.mins);
 724     float i;
 725     vector v, v2;
 726     v2 = 0.5 * (self.absmin + self.absmax);
 727     for(i = 0; i < 100; ++i)
 728     {
 729         v = randomvec();
 730         v.z = 0;
 731         v = v2 + normalize(v) * mysize;
 732         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 733         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 734             return v;
 735     }
 736
 737     /*
 738     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 739     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 740     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 741         return exitspot;
 742
 743     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 744     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 745     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 746         return exitspot;
 747
 748     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 749     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 750     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 751         return exitspot;
 752
 753     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 754     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 755     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 756         return exitspot;
 757     */
 758
 759     return self.origin;
 760 }
 761
 762 /** vehicles_exit
 763     Standarrd vehicle release fucntion.
 764     custom code goes in self.vehicle_exit
 765 **/
 766 float vehicles_exit_running;
 767 void vehicles_exit(float eject)
 768 {
 769     entity _vehicle;
 770     entity _player;
 771     entity _oldself = self;
 772
 773     if(vehicles_exit_running)
 774     {
 775         dprint("^1vehicles_exit allready running! this is not good..\n");
 776         return;
 777     }
 778
 779     vehicles_exit_running = true;
 780     if(IS_CLIENT(self))
 781     {
 782         _vehicle = self.vehicle;
 783
 784         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 785         {
 786             _vehicle.vehicle_exit(eject);
 787             self = _oldself;
 788             vehicles_exit_running = false;
 789             return;
 790         }
 791     }
 792     else
 793         _vehicle = self;
 794
 795     _player = _vehicle.owner;
 796
 797     self = _vehicle;
 798
 799     if (_player)
 800     {
 801         if (IS_REAL_CLIENT(_player))
 802         {
 803             msg_entity = _player;
 804             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 805             WriteEntity( MSG_ONE, _player);
 806
 807             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 808             WriteAngle(MSG_ONE, 0);
 809             WriteAngle(MSG_ONE, _vehicle.angles.y);
 810             WriteAngle(MSG_ONE, 0);
 811         }
 812
 813         setsize(_player, PL_MIN,PL_MAX);
 814
 815         _player.takedamage     = DAMAGE_AIM;
 816         _player.solid          = SOLID_SLIDEBOX;
 817         _player.movetype       = MOVETYPE_WALK;
 818         _player.effects        &= ~EF_NODRAW;
 819         _player.alpha          = 1;
 820         _player.PlayerPhysplug = func_null;
 821         _player.vehicle        = world;
 822         _player.view_ofs       = PL_VIEW_OFS;
 823         _player.event_damage   = PlayerDamage;
 824         _player.hud            = HUD_NORMAL;
 825         _player.switchweapon   = _vehicle.switchweapon;
 826
 827         CSQCVehicleSetup(_player, HUD_NORMAL);
 828     }
 829     _vehicle.flags |= FL_NOTARGET;
 830
 831     if(_vehicle.deadflag == DEAD_NO)
 832         _vehicle.avelocity          = '0 0 0';
 833
 834     _vehicle.tur_head.nodrawtoclient             = world;
 835
 836     if(!teamplay)
 837         _vehicle.team = 0;
 838
 839     vh_player = _player;
 840     vh_vehicle = _vehicle;
 841     MUTATOR_CALLHOOK(VehicleExit);
 842     _player = vh_player;
 843     _vehicle = vh_vehicle;
 844
 845     _vehicle.team = _vehicle.tur_head.team;
 846
 847     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTEN_NORM);
 848     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 849     _vehicle.phase = time + 1;
 850     _vehicle.monster_attack = false;
 851
 852     _vehicle.vehicle_exit(eject);
 853
 854     vehicles_setreturn();
 855     vehicles_reset_colors();
 856     _vehicle.owner = world;
 857     self = _oldself;
 858
 859     vehicles_exit_running = false;
 860 }
 861
 862
 863 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 864 {
 865     if(self.regen_field < field_max)
 866     if(timer + rpause < time)
 867     {
 868         if(_healthscale)
 869             regen = regen * (self.vehicle_health / self.tur_health);
 870
 871         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 872
 873         if(self.owner)
 874             self.owner.regen_field = (self.regen_field / field_max) * 100;
 875     }
 876 }
 877
 878 void shieldhit_think()
 879 {
 880     self.alpha -= 0.1;
 881     if (self.alpha <= 0)
 882     {
 883         //setmodel(self, "");
 884         self.alpha = -1;
 885         self.effects |= EF_NODRAW;
 886     }
 887     else
 888     {
 889         self.nextthink = time + 0.1;
 890     }
 891 }
 892
 893 void vehicles_painframe()
 894 {
 895     if(self.owner.vehicle_health <= 50)
 896     if(self.pain_frame < time)
 897     {
 898         float _ftmp;
 899         _ftmp = self.owner.vehicle_health / 50;
 900         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 901         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 902
 903         if(self.vehicle_flags & VHF_DMGSHAKE)
 904             self.velocity += randomvec() * 30;
 905
 906         if(self.vehicle_flags & VHF_DMGROLL)
 907             if(self.vehicle_flags & VHF_DMGHEADROLL)
 908                 self.tur_head.angles += randomvec();
 909             else
 910                 self.angles += randomvec();
 911
 912     }
 913 }
 914
 915 void vehicles_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 916 {
 917     self.dmg_time = time;
 918
 919         // WEAPONTODO
 920     if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 921         damage *= autocvar_g_vehicles_vortex_damagerate;
 922
 923     if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 924         damage *= autocvar_g_vehicles_machinegun_damagerate;
 925
 926     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 927         damage *= autocvar_g_vehicles_rifle_damagerate;
 928
 929     if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 930         damage *= autocvar_g_vehicles_vaporizer_damagerate;
 931
 932     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 933         damage *= autocvar_g_vehicles_tag_damagerate;
 934
 935     self.enemy = attacker;
 936
 937     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 938     {
 939         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 940         {
 941             self.vehicle_shieldent = spawn();
 942             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 943
 944             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 945             setattachment(self.vehicle_shieldent, self, "");
 946             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 947             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 948             self.vehicle_shieldent.think       = shieldhit_think;
 949         }
 950
 951         self.vehicle_shieldent.colormod    = '1 1 1';
 952         self.vehicle_shieldent.alpha       = 0.45;
 953         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 954         self.vehicle_shieldent.nextthink   = time;
 955         self.vehicle_shieldent.effects &= ~EF_NODRAW;
 956
 957         self.vehicle_shield -= damage;
 958
 959         if(self.vehicle_shield < 0)
 960         {
 961             self.vehicle_health            -= fabs(self.vehicle_shield);
 962             self.vehicle_shieldent.colormod = '2 0 0';
 963             self.vehicle_shield             = 0;
 964             self.vehicle_shieldent.alpha    = 0.75;
 965
 966                 if(sound_allowed(MSG_BROADCAST, attacker))
 967                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 968         }
 969         else
 970                 if(sound_allowed(MSG_BROADCAST, attacker))
 971                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 972
 973     }
 974     else
 975     {
 976         self.vehicle_health -= damage;
 977
 978         if(sound_allowed(MSG_BROADCAST, attacker))
 979             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 980     }
 981
 982         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 983                 self.velocity += force * self.damageforcescale;
 984         else
 985                 self.velocity += force;
 986
 987     if(self.vehicle_health <= 0)
 988     {
 989         if(self.owner)
 990             if(self.vehicle_flags & VHF_DEATHEJECT)
 991                 vehicles_exit(VHEF_EJECT);
 992             else
 993                 vehicles_exit(VHEF_RELESE);
 994
 995
 996         antilag_clear(self);
 997
 998         self.vehicle_die();
 999         vehicles_setreturn();
1000     }
1001 }
1002
1003 void vehicles_clearreturn()
1004 {
1005     entity ret;
1006     // Remove "return helper", if any.
1007     ret = findchain(classname, "vehicle_return");
1008     while(ret)
1009     {
1010         if(ret.wp00 == self)
1011         {
1012             ret.classname   = "";
1013             ret.think       = SUB_Remove;
1014             ret.nextthink   = time + 0.1;
1015
1016             if(ret.waypointsprite_attached)
1017                 WaypointSprite_Kill(ret.waypointsprite_attached);
1018
1019             return;
1020         }
1021         ret = ret.chain;
1022     }
1023 }
1024
1025 void vehicles_return()
1026 {
1027     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
1028
1029     self.wp00.think     = vehicles_spawn;
1030     self.wp00.nextthink = time;
1031
1032     if(self.waypointsprite_attached)
1033         WaypointSprite_Kill(self.waypointsprite_attached);
1034
1035     remove(self);
1036 }
1037
1038 void vehicles_showwp_goaway()
1039 {
1040     if(self.waypointsprite_attached)
1041         WaypointSprite_Kill(self.waypointsprite_attached);
1042
1043     remove(self);
1044
1045 }
1046
1047 void vehicles_showwp()
1048 {
1049     entity oldself = world;
1050     vector rgb;
1051
1052     if(self.cnt)
1053     {
1054         self.think      = vehicles_return;
1055         self.nextthink  = self.cnt;
1056     }
1057     else
1058     {
1059         self.think      = vehicles_return;
1060         self.nextthink  = time +1;
1061
1062         oldself = self;
1063         self = spawn();
1064         setmodel(self, "null");
1065         self.team = oldself.wp00.team;
1066         self.wp00 = oldself.wp00;
1067         setorigin(self, oldself.wp00.pos1);
1068
1069         self.nextthink = time + 5;
1070         self.think = vehicles_showwp_goaway;
1071     }
1072
1073     if(teamplay && self.team)
1074             rgb = Team_ColorRGB(self.team);
1075     else
1076             rgb = '1 1 1';
1077     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
1078     if(self.waypointsprite_attached)
1079     {
1080         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1081         if(oldself == world)
1082             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1083         WaypointSprite_Ping(self.waypointsprite_attached);
1084     }
1085
1086     if(oldself != world)
1087         self = oldself;
1088 }
1089
1090 void vehicles_setreturn()
1091 {
1092     entity ret;
1093
1094     vehicles_clearreturn();
1095
1096     ret = spawn();
1097     ret.classname   = "vehicle_return";
1098     ret.wp00       = self;
1099     ret.team        = self.team;
1100     ret.think       = vehicles_showwp;
1101
1102         if(self.deadflag != DEAD_NO)
1103         {
1104                 ret.cnt = max(game_starttime, time) + self.vehicle_respawntime;
1105                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 5);
1106         }
1107         else
1108                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 1);
1109
1110     setmodel(ret, "null");
1111     setorigin(ret, self.pos1 + '0 0 96');
1112 }
1113
1114 void vehicles_reset_colors()
1115 {
1116     entity e;
1117     float _effects = 0, _colormap;
1118     vector _glowmod, _colormod;
1119
1120     if(autocvar_g_nodepthtestplayers)
1121         _effects |= EF_NODEPTHTEST;
1122
1123     if(autocvar_g_fullbrightplayers)
1124         _effects |= EF_FULLBRIGHT;
1125
1126     if(self.team)
1127         _colormap = 1024 + (self.team - 1) * 17;
1128     else
1129         _colormap = 1024;
1130
1131     _glowmod  = '0 0 0';
1132     _colormod = '0 0 0';
1133
1134     // Find all ents attacked to main model and setup effects, colormod etc.
1135     e = findchainentity(tag_entity, self);
1136     while(e)
1137     {
1138         if(e != self.vehicle_shieldent)
1139         {
1140             e.effects   = _effects; //  | EF_LOWPRECISION;
1141             e.colormod  = _colormod;
1142             e.colormap  = _colormap;
1143             e.alpha     = 1;
1144         }
1145         e = e.chain;
1146     }
1147
1148     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1149     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1150     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1151     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1152
1153     self.alpha     = 1;
1154     self.avelocity = '0 0 0';
1155     self.velocity  = '0 0 0';
1156     self.effects   = _effects;
1157 }
1158
1159 void vehicle_use()
1160 {
1161     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1162
1163     self.tur_head.team = activator.team;
1164
1165     if(self.tur_head.team == 0)
1166         self.active = ACTIVE_NOT;
1167     else
1168         self.active = ACTIVE_ACTIVE;
1169
1170     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1171     {
1172         dprint("^3Eat shit yall!\n");
1173         vehicles_setreturn();
1174         vehicles_reset_colors();
1175     }
1176     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1177     {
1178
1179     }
1180 }
1181
1182 float vehicle_addplayerslot(    entity _owner,
1183                                 entity _slot,
1184                                 float _hud,
1185                                 string _hud_model,
1186                                 float() _framefunc,
1187                                 void(float) _exitfunc)
1188 {
1189     if (!(_owner.vehicle_flags & VHF_MULTISLOT))
1190         _owner.vehicle_flags |= VHF_MULTISLOT;
1191
1192     _slot.PlayerPhysplug = _framefunc;
1193     _slot.vehicle_exit = _exitfunc;
1194     _slot.hud = _hud;
1195     _slot.vehicle_flags = VHF_PLAYERSLOT;
1196     _slot.vehicle_viewport = spawn();
1197     _slot.vehicle_hudmodel = spawn();
1198     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1199     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1200
1201     setmodel(_slot.vehicle_hudmodel, _hud_model);
1202     setmodel(_slot.vehicle_viewport, "null");
1203
1204     setattachment(_slot.vehicle_hudmodel, _slot, "");
1205     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1206
1207     return true;
1208 }
1209
1210 float vehicle_initialize(string  net_name,
1211                          string  bodymodel,
1212                          string  topmodel,
1213                          string  hudmodel,
1214                          string  toptag,
1215                          string  hudtag,
1216                          string  viewtag,
1217                          float   vhud,
1218                          vector  min_s,
1219                          vector  max_s,
1220                          float   nodrop,
1221                          void(float _spawnflag)  spawnproc,
1222                          float   _respawntime,
1223                          float() physproc,
1224                          void()  enterproc,
1225                          void(float extflag) exitfunc,
1226                          void() dieproc,
1227                          void() thinkproc,
1228                          float  use_csqc,
1229                          float _max_health,
1230                          float _max_shield)
1231 {
1232         if(!autocvar_g_vehicles)
1233                 return false;
1234
1235     if(self.targetname)
1236     {
1237         self.vehicle_controller = find(world, target, self.targetname);
1238         if(!self.vehicle_controller)
1239         {
1240             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1241         }
1242         else
1243         {
1244             self.team = self.vehicle_controller.team;
1245             self.use = vehicle_use;
1246
1247             if(teamplay)
1248             {
1249                 if(self.vehicle_controller.team == 0)
1250                     self.active = ACTIVE_NOT;
1251                 else
1252                     self.active = ACTIVE_ACTIVE;
1253             }
1254         }
1255     }
1256
1257     precache_sound("onslaught/ons_hit2.wav");
1258     precache_sound("onslaught/electricity_explode.wav");
1259
1260
1261     addstat(STAT_HUD, AS_INT,  hud);
1262         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1263         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1264         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1265
1266         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1267         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1268
1269         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1270         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1271
1272     if(bodymodel == "")
1273         error("vehicles: missing bodymodel!");
1274
1275     if(hudmodel == "")
1276         error("vehicles: missing hudmodel!");
1277
1278     if(net_name == "")
1279         self.netname = self.classname;
1280     else
1281         self.netname = net_name;
1282
1283     if(self.team && !teamplay)
1284         self.team = 0;
1285
1286     self.vehicle_flags |= VHF_ISVEHICLE;
1287
1288     setmodel(self, bodymodel);
1289
1290     self.vehicle_viewport   = spawn();
1291     self.vehicle_hudmodel   = spawn();
1292     self.tur_head           = spawn();
1293     self.tur_head.owner     = self;
1294     self.takedamage         = DAMAGE_AIM;
1295     self.bot_attack         = true;
1296     self.iscreature         = true;
1297     self.teleportable       = false; // no teleporting for vehicles, too buggy
1298     self.damagedbycontents      = true;
1299     self.hud                = vhud;
1300     self.tur_health          = _max_health;
1301     self.tur_head.tur_health = _max_shield;
1302     self.vehicle_die         = dieproc;
1303     self.vehicle_exit        = exitfunc;
1304     self.vehicle_enter       = enterproc;
1305     self.PlayerPhysplug      = physproc;
1306     self.event_damage        = func_null;
1307     self.touch               = vehicles_touch;
1308     self.think               = vehicles_spawn;
1309     self.vehicle_spawn       = spawnproc;
1310         self.vehicle_respawntime = max(0, _respawntime);
1311     self.effects             = EF_NODRAW;
1312         self.dphitcontentsmask   = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1313         if(!autocvar_g_vehicles_delayspawn || !self.vehicle_respawntime)
1314                 self.nextthink = time;
1315         else
1316                 self.nextthink = max(time, game_starttime) + max(0, self.vehicle_respawntime + ((random() * 2 - 1) * autocvar_g_vehicles_delayspawn_jitter));
1317
1318         if(autocvar_g_playerclip_collisions)
1319                 self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1320
1321     if(autocvar_g_nodepthtestplayers)
1322         self.effects = self.effects | EF_NODEPTHTEST;
1323
1324     if(autocvar_g_fullbrightplayers)
1325         self.effects = self.effects | EF_FULLBRIGHT;
1326
1327     setmodel(self.vehicle_hudmodel, hudmodel);
1328     setmodel(self.vehicle_viewport, "null");
1329
1330     if(topmodel != "")
1331     {
1332         setmodel(self.tur_head, topmodel);
1333         setattachment(self.tur_head, self, toptag);
1334         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1335         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1336     }
1337     else
1338     {
1339         setattachment(self.tur_head, self, "");
1340         setattachment(self.vehicle_hudmodel, self, hudtag);
1341         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1342     }
1343
1344     setsize(self, min_s, max_s);
1345     if (!nodrop)
1346     {
1347         setorigin(self, self.origin);
1348         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1349         setorigin(self, trace_endpos);
1350     }
1351
1352     self.pos1 = self.origin;
1353     self.pos2 = self.angles;
1354     self.tur_head.team = self.team;
1355
1356         if(MUTATOR_CALLHOOK(VehicleSpawn))
1357                 return false;
1358
1359     return true;
1360 }
1361
1362 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1363                          float _pichlimit_min, float _pichlimit_max,
1364                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1365 {
1366     vector vtmp, vtag;
1367     float ftmp;
1368     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1369     vtmp = vectoangles(normalize(_target - vtag));
1370     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1371     vtmp = AnglesTransform_Normalize(vtmp, true);
1372     ftmp = _aimspeed * frametime;
1373     vtmp.y = bound(-ftmp, vtmp.y, ftmp);
1374     vtmp.x = bound(-ftmp, vtmp.x, ftmp);
1375     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles.y + vtmp.y, _rotlimit_max);
1376     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles.x + vtmp.x, _pichlimit_max);
1377     return vtag;
1378 }
1379
1380 void vehicles_gib_explode()
1381 {
1382         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
1383         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1384         remove(self);
1385 }
1386
1387 void vehicles_gib_think()
1388 {
1389         self.alpha -= 0.1;
1390         if(self.cnt >= time)
1391                 remove(self);
1392         else
1393                 self.nextthink = time + 0.1;
1394 }
1395
1396 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1397 {
1398         entity _gib = spawn();
1399         setmodel(_gib, _template.model);
1400         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1401         _gib.velocity = _vel;
1402         _gib.movetype = MOVETYPE_TOSS;
1403         _gib.solid = SOLID_CORPSE;
1404         _gib.colormod = '-0.5 -0.5 -0.5';
1405         _gib.effects = EF_LOWPRECISION;
1406         _gib.avelocity = _rot;
1407
1408         if(_burn)
1409                 _gib.effects |= EF_FLAME;
1410
1411         if(_explode)
1412         {
1413                 _gib.think = vehicles_gib_explode;
1414                 _gib.nextthink = time + random() * _explode;
1415                 _gib.touch = vehicles_gib_explode;
1416         }
1417         else
1418         {
1419                 _gib.cnt = time + _maxtime;
1420                 _gib.think = vehicles_gib_think;
1421                 _gib.nextthink = time + _maxtime - 1;
1422                 _gib.alpha = 1;
1423         }
1424         return _gib;
1425 }
1426
1427 /*
1428 vector predict_target(entity _targ, vector _from, float _shot_speed)
1429 {
1430     float i;                // loop
1431     float _distance;        // How far to target
1432     float _impact_time;     // How long untill projectile impacts
1433     vector _predict_pos;    // Predicted enemy location
1434     vector _original_origin;// Where target is before predicted
1435
1436      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1437
1438     _predict_pos = _original_origin;
1439     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1440     {
1441         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1442         _impact_time = _distance / _shot_speed; // Calculate impact time
1443         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1444     }
1445
1446     return _predict_pos;
1447 }
1448 */