qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5
   6 var float autocvar_g_vehicles_nex_damagerate = 0.5;
   7 var float autocvar_g_vehicles_uzi_damagerate = 0.5;
   8 var float autocvar_g_vehicles_rifle_damagerate = 0.75;
   9 var float autocvar_g_vehicles_minstanex_damagerate = 0.001;
  10 var float autocvar_g_vehicles_tag_damagerate = 5;
  11
  12 float autocvar_g_vehicles;
  13
  14 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  15 void vehicles_return();
  16 void vehicles_enter();
  17 void vehicles_touch();
  18 void vehicles_reset_colors();
  19 void vehicles_clearrturn();
  20 void vehicles_setreturn();
  21
  22
  23 /** AuxiliaryXhair*
  24     Send additional points of interest to be drawn, to vehicle owner
  25 **/
  26 float MAX_AXH = 4;
  27 .entity AuxiliaryXhair[MAX_AXH];
  28
  29 float SendAuxiliaryXhair(entity to, float sf)
  30 {
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  33
  34         WriteByte(MSG_ENTITY, self.cnt);
  35
  36         WriteCoord(MSG_ENTITY, self.origin_x);
  37         WriteCoord(MSG_ENTITY, self.origin_y);
  38         WriteCoord(MSG_ENTITY, self.origin_z);
  39
  40     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  41     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  42     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  43
  44     return TRUE;
  45 }
  46
  47 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  48 {
  49     if not(IS_REAL_CLIENT(own))
  50         return;
  51
  52     entity axh;
  53
  54     axh_id = bound(0, axh_id, MAX_AXH);
  55     axh = own.(AuxiliaryXhair[axh_id]);
  56
  57     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  58     {
  59         axh                     = spawn();
  60         axh.cnt                 = axh_id;
  61         axh.drawonlytoclient    = own;
  62         axh.owner               = own;
  63         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  64     }
  65
  66     setorigin(axh, loc);
  67     axh.colormod            = clr;
  68     axh.SendFlags           = 0x01;
  69     own.(AuxiliaryXhair[axh_id]) = axh;
  70 }
  71
  72 /*
  73 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  74 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  75 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  76 {
  77         msgexntity = own;
  78
  79         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  80         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  81
  82         WriteByte(MSG_ONE, axh_id);
  83
  84         WriteCoord(MSG_ONE, loc_x);
  85         WriteCoord(MSG_ONE, loc_y);
  86         WriteCoord(MSG_ONE, loc_z);
  87
  88     WriteByte(MSG_ONE, rint(clr_x * 255));
  89     WriteByte(MSG_ONE, rint(clr_y * 255));
  90     WriteByte(MSG_ONE, rint(clr_z * 255));
  91
  92 }
  93 */
  94 // End AuxiliaryXhair
  95
  96 /**
  97     Notifies the client that he enterd a vehicle, and sends
  98     realavent data.
  99
 100     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 101 **/
 102 void CSQCVehicleSetup(entity own, float vehicle_id)
 103 {
 104     if not(IS_REAL_CLIENT(own))
 105         return;
 106
 107         msg_entity = own;
 108
 109         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 110         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 111         if(vehicle_id != 0)
 112             WriteByte(MSG_ONE, vehicle_id);
 113         else
 114         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 115 }
 116
 117 /** vehicles_locktarget
 118
 119     Generic target locking.
 120
 121     Figure out if what target is "locked" (if any), for missile tracking as such.
 122
 123     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 124     you have a locked in target.
 125
 126     Exspects a crosshair_trace() or equivalent to be
 127     dont before calling.
 128
 129 **/
 130 .entity lock_target;
 131 .float  lock_strength;
 132 .float  lock_time;
 133 .float  lock_soundtime;
 134 float   DAMAGE_TARGETDRONE = 10;
 135
 136 vector targetdrone_getnewspot()
 137 {
 138
 139         vector spot;
 140         float i;
 141         for(i = 0; i < 100; ++i)
 142         {
 143                 spot = self.origin + randomvec() * 1024;
 144                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 145                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 146                         return spot;
 147         }
 148         return self.origin;
 149 }
 150
 151 #if 0
 152 void targetdrone_think();
 153 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
 154 void targetdrone_renwe()
 155 {
 156         self.think = targetdrone_think;
 157         self.nextthink = time + 0.1;
 158         setorigin(self, targetdrone_getnewspot());
 159         self.health = 200;
 160         self.takedamage = DAMAGE_TARGETDRONE;
 161         self.event_damage = targetdrone_damage;
 162         self.solid = SOLID_BBOX;
 163         setmodel(self, "models/runematch/rune.mdl");
 164         self.effects = EF_LOWPRECISION;
 165         self.scale = 10;
 166         self.movetype = MOVETYPE_BOUNCEMISSILE;
 167         setsize(self, '-100 -100 -100', '100 100 100');
 168
 169 }
 170 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 171 {
 172         self.health -= damage;
 173         if(self.health <= 0)
 174         {
 175                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 176
 177                 if(!self.cnt)
 178                         remove(self);
 179                 else
 180                 {
 181                         self.think = targetdrone_renwe;
 182                         self.nextthink = time + 1 + random() * 2;
 183                         self.solid = SOLID_NOT;
 184                         setmodel(self, "");
 185                 }
 186         }
 187 }
 188 entity targetdrone_getfear()
 189 {
 190         entity fear;
 191         float i;
 192
 193         for(i = 64; i <= 1024; i += 64)
 194         {
 195                 fear = findradius(self.origin, i);
 196                 while(fear)
 197                 {
 198                         if(fear.bot_dodge)
 199                                 return fear;
 200
 201                         fear = fear.chain;
 202                 }
 203         }
 204
 205         return world;
 206 }
 207 void targetdrone_think()
 208 {
 209         self.nextthink = time + 0.1;
 210
 211         if(self.wp00)
 212         if(self.wp00.deadflag != DEAD_NO)
 213                 self.wp00 = targetdrone_getfear();
 214
 215         if(!self.wp00)
 216                 self.wp00 = targetdrone_getfear();
 217
 218         vector newdir;
 219
 220         if(self.wp00)
 221                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 222         else
 223                 newdir = randomvec() * 0.75;
 224
 225         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 226
 227         if(self.wp00)
 228                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 229         else
 230                 self.velocity = normalize(newdir) * 750;
 231
 232         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 233         if(trace_fraction != 1.0)
 234                 self.velocity = self.velocity * -1;
 235
 236         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 237 }
 238
 239 void targetdrone_spawn(vector _where, float _autorenew)
 240 {
 241         entity drone = spawn();
 242         setorigin(drone, _where);
 243         drone.think = targetdrone_renwe;
 244         drone.nextthink = time + 0.1;
 245         drone.cnt = _autorenew;
 246 }
 247 #endif
 248
 249 void vehicles_locktarget(float incr, float decr, float _lock_time)
 250 {
 251     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 252     {
 253         self.lock_target    = world;
 254         self.lock_strength  = 0;
 255         self.lock_time      = 0;
 256     }
 257
 258     if(self.lock_time > time)
 259     {
 260         if(self.lock_target)
 261         if(self.lock_soundtime < time)
 262         {
 263             self.lock_soundtime = time + 0.5;
 264             play2(self.owner, "vehicles/locked.wav");
 265         }
 266
 267         return;
 268     }
 269
 270     if(trace_ent != world)
 271     {
 272         if(teamplay && trace_ent.team == self.team)
 273             trace_ent = world;
 274
 275         if(trace_ent.deadflag != DEAD_NO)
 276             trace_ent = world;
 277
 278         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE ||
 279                                 trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET ||
 280                                 trace_ent.takedamage == DAMAGE_TARGETDRONE)
 281             trace_ent = world;
 282     }
 283
 284     if(self.lock_target == world && trace_ent != world)
 285         self.lock_target = trace_ent;
 286
 287     if(self.lock_target && trace_ent == self.lock_target)
 288     {
 289         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 290         {
 291             play2(self.owner, "vehicles/lock.wav");
 292             self.lock_soundtime = time + 0.8;
 293         }
 294         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 295         {
 296             play2(self.owner, "vehicles/locking.wav");
 297             self.lock_soundtime = time + 0.3;
 298         }
 299
 300     }
 301
 302     // Have a locking target
 303     // Trace hit current target
 304     if(trace_ent == self.lock_target && trace_ent != world)
 305     {
 306         self.lock_strength = min(self.lock_strength + incr, 1);
 307         if(self.lock_strength == 1)
 308             self.lock_time = time + _lock_time;
 309     }
 310     else
 311     {
 312         if(trace_ent)
 313             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 314         else
 315             self.lock_strength = max(self.lock_strength - decr, 0);
 316
 317         if(self.lock_strength == 0)
 318             self.lock_target = world;
 319     }
 320 }
 321
 322 #define VEHICLE_UPDATE_PLAYER(ply,fld,vhname) \
 323 ply.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 324
 325 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 326 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 327 if(trace_fraction != 1) \
 328     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 329
 330 // Hover movement support
 331 float  force_fromtag_power;
 332 float  force_fromtag_normpower;
 333 vector force_fromtag_origin;
 334 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 335 {
 336     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 337     v_forward  = normalize(v_forward) * -1;
 338     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 339
 340     force_fromtag_power = (1 - trace_fraction) * max_power;
 341     force_fromtag_normpower = force_fromtag_power / max_power;
 342
 343     return v_forward  * force_fromtag_power;
 344 }
 345
 346 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 347 // Can possibly be use to move abt any surface (inclusing walls/celings)
 348 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 349 {
 350
 351     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 352     v_forward  = normalize(v_forward) * -1;
 353     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 354
 355     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 356     if(trace_fraction == 1.0)
 357     {
 358         force_fromtag_normpower = -0.25;
 359         return '0 0 -200';
 360     }
 361
 362     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 363     force_fromtag_normpower = force_fromtag_power / max_power;
 364
 365     return v_forward  * force_fromtag_power;
 366 }
 367
 368 // Generic vehile projectile system
 369 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 370 {
 371     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 372     if(inflictor.owner == self.owner)
 373         return;
 374
 375     self.health -= damage;
 376     self.velocity += force;
 377     if(self.health < 1)
 378     {
 379         self.takedamage = DAMAGE_NO;
 380         self.event_damage = func_null;
 381         self.think = self.use;
 382         self.nextthink = time;
 383     }
 384 }
 385
 386 void vehicles_projectile_explode()
 387 {
 388     if(self.owner && other != world)
 389     {
 390         if(other == self.owner.vehicle)
 391             return;
 392
 393         if(other == self.owner.vehicle.tur_head)
 394             return;
 395     }
 396
 397         PROJECTILE_TOUCH;
 398
 399         self.event_damage = func_null;
 400     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 401
 402     remove (self);
 403 }
 404
 405 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 406                            vector _org, vector _vel,
 407                            float _dmg, float _radi, float _force,  float _size,
 408                            float _deahtype, float _projtype, float _health,
 409                            float _cull, float _clianim, entity _owner)
 410 {
 411     entity proj;
 412
 413     proj = spawn();
 414
 415     PROJECTILE_MAKETRIGGER(proj);
 416     setorigin(proj, _org);
 417
 418     proj.shot_dmg         = _dmg;
 419     proj.shot_radius      = _radi;
 420     proj.shot_force       = _force;
 421     proj.totalfrags       = _deahtype;
 422     proj.solid            = SOLID_BBOX;
 423     proj.movetype         = MOVETYPE_FLYMISSILE;
 424     proj.flags            = FL_PROJECTILE;
 425     proj.bot_dodge        = TRUE;
 426     proj.bot_dodgerating  = _dmg;
 427     proj.velocity         = _vel;
 428     proj.touch            = vehicles_projectile_explode;
 429     proj.use              = vehicles_projectile_explode;
 430     proj.owner            = self;
 431     proj.realowner        = _owner;
 432     proj.think            = SUB_Remove;
 433     proj.nextthink        = time + 30;
 434
 435     if(_health)
 436     {
 437         proj.takedamage       = DAMAGE_AIM;
 438         proj.event_damage     = vehicles_projectile_damage;
 439         proj.health           = _health;
 440     }
 441     else
 442         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 443
 444     if(_mzlsound)
 445         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 446
 447     if(_mzlfx)
 448         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 449
 450
 451     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 452
 453     CSQCProjectile(proj, _clianim, _projtype, _cull);
 454
 455     return proj;
 456 }
 457 // End generic vehile projectile system
 458
 459 /** vehicles_spawn
 460     Exetuted for all vehicles on (re)spawn.
 461     Sets defaults for newly spawned units.
 462 **/
 463 void vehicles_spawn()
 464 {
 465     dprint("Spawning vehicle: ", self.netname, "\n");
 466
 467     // De-own & reset
 468     self.vehicle_hudmodel.viewmodelforclient = self;
 469
 470     self.owner              = world;
 471     self.touch              = vehicles_touch;
 472     self.event_damage       = vehicles_damage;
 473     self.iscreature         = TRUE;
 474     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
 475     self.damagedbycontents      = TRUE;
 476     self.movetype           = MOVETYPE_WALK;
 477     self.solid              = SOLID_SLIDEBOX;
 478     self.takedamage         = DAMAGE_AIM;
 479         self.deadflag           = DEAD_NO;
 480     self.bot_attack         = TRUE;
 481     self.flags              = FL_NOTARGET;
 482     self.avelocity          = '0 0 0';
 483     self.velocity           = '0 0 0';
 484
 485     // Reset locking
 486     self.lock_strength      = 0;
 487     self.lock_target        = world;
 488     self.misc_bulletcounter = 0;
 489
 490     // Return to spawn
 491     self.angles             = self.pos2;
 492     setorigin(self, self.pos1 + '0 0 0');
 493     // Show it
 494     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 495
 496     if(self.vehicle_controller)
 497         self.team = self.vehicle_controller.team;
 498
 499     vehicles_reset_colors();
 500     self.vehicle_spawn(VHSF_NORMAL);
 501 }
 502
 503 // Better way of determening whats crushable needed! (fl_crushable?)
 504 float vehicles_crushable(entity e)
 505 {
 506     if(IS_PLAYER(e))
 507         return TRUE;
 508
 509     if(e.flags & FL_MONSTER)
 510         return TRUE;
 511
 512     return FALSE;
 513 }
 514
 515 void vehilces_impact(float _minspeed, float _speedfac, float _maxpain)
 516 {
 517     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 518         return;
 519
 520     if(self.play_time < time)
 521     {
 522         float wc = vlen(self.velocity - self.oldvelocity);
 523         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 524         //dprint("vel: ", vtos(self.velocity), "\n");
 525         if(_minspeed < wc)
 526         {
 527             float take = min(_speedfac * wc, _maxpain);
 528             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 529             self.play_time = time + 0.25;
 530
 531             //dprint("wc: ", ftos(wc), "\n");
 532             //dprint("take: ", ftos(take), "\n");
 533         }
 534     }
 535 }
 536
 537 .void() vehicle_impact;
 538 void vehicles_touch()
 539 {
 540         if(MUTATOR_CALLHOOK(VehicleTouch))
 541                 return;
 542
 543     // Vehicle currently in use
 544     if(self.owner)
 545     {
 546         if(other != world)
 547         if(vehicles_crushable(other))
 548         {
 549             if(vlen(self.velocity) != 0)
 550                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 551
 552             return; // Dont do selfdamage when hitting "soft targets".
 553         }
 554
 555         if(self.play_time < time)
 556         if(self.vehicle_impact)
 557             self.vehicle_impact();
 558
 559         return;
 560     }
 561
 562     if not(IS_PLAYER(other))
 563         return;
 564
 565     if(other.deadflag != DEAD_NO)
 566         return;
 567
 568         if(other.frozen)
 569                 return;
 570
 571     if(other.vehicle != world)
 572         return;
 573
 574     vehicles_enter();
 575 }
 576 var float autocvar_g_vehicles_allow_bots = 0;
 577 void vehicles_enter()
 578 {
 579    // Remove this when bots know how to use vehicles
 580
 581     if (IS_BOT_CLIENT(other))
 582         if (autocvar_g_vehicles_allow_bots)
 583             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 584         else
 585             return;
 586
 587     if(self.phase > time)
 588         return;
 589
 590         if(other.frozen)
 591                 return;
 592
 593     if(teamplay)
 594     if(self.team)
 595     if(self.team != other.team)
 596         return;
 597
 598     RemoveGrapplingHook(other);
 599
 600     self.vehicle_ammo1   = 0;
 601     self.vehicle_ammo2   = 0;
 602     self.vehicle_reload1 = 0;
 603     self.vehicle_reload2 = 0;
 604     self.vehicle_energy  = 0;
 605
 606     self.owner          = other;
 607     self.switchweapon   = other.switchweapon;
 608
 609     // .viewmodelforclient works better.
 610     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 611
 612     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 613
 614     self.event_damage         = vehicles_damage;
 615     self.nextthink            = 0;
 616     self.owner.angles         = self.angles;
 617     self.owner.takedamage     = DAMAGE_NO;
 618     self.owner.solid          = SOLID_NOT;
 619     self.owner.movetype       = MOVETYPE_NOCLIP;
 620     self.owner.alpha          = -1;
 621     self.owner.vehicle        = self;
 622     self.owner.event_damage   = func_null;
 623     self.owner.view_ofs       = '0 0 0';
 624     self.colormap             = self.owner.colormap;
 625     if(self.tur_head)
 626         self.tur_head.colormap    = self.owner.colormap;
 627
 628     self.owner.hud            = self.hud;
 629     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 630
 631     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 632     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 633     self.owner.vehicle_reload1  = self.vehicle_reload1;
 634     self.owner.vehicle_reload2  = self.vehicle_reload2;
 635
 636     // Cant do this, hides attached objects too.
 637     //self.exteriormodeltoclient = self.owner;
 638     //self.tur_head.exteriormodeltoclient = self.owner;
 639
 640     other.flags &~= FL_ONGROUND;
 641     self.flags  &~= FL_ONGROUND;
 642
 643     self.team                 = self.owner.team;
 644     self.flags               -= FL_NOTARGET;
 645         self.monster_attack               = TRUE;
 646
 647     if (IS_REAL_CLIENT(other))
 648     {
 649         msg_entity = other;
 650         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 651         WriteEntity(MSG_ONE, self.vehicle_viewport);
 652
 653         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 654         if(self.tur_head)
 655         {
 656             WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 657             WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 658             WriteAngle(MSG_ONE, 0);                                      // roll
 659         }
 660         else
 661         {
 662             WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 663             WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 664             WriteAngle(MSG_ONE,  0);                  // roll
 665         }
 666     }
 667
 668     vehicles_clearrturn();
 669
 670     CSQCVehicleSetup(self.owner, self.hud);
 671
 672     vh_player = other;
 673     vh_vehicle = self;
 674     MUTATOR_CALLHOOK(VehicleEnter);
 675     other = vh_player;
 676     self = vh_vehicle;
 677
 678     self.vehicle_enter();
 679     antilag_clear(other);
 680 }
 681
 682 /** vehicles_findgoodexit
 683     Locates a valid location for the player to exit the vehicle.
 684     Will first try prefer_spot, then up 100 random spots arround the vehicle
 685     wich are in direct line of sight and empty enougth to hold a players bbox
 686 **/
 687 vector vehicles_findgoodexit(vector prefer_spot)
 688 {
 689     //vector exitspot;
 690     float mysize;
 691
 692     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 693     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 694         return prefer_spot;
 695
 696     mysize = 1.5 * vlen(self.maxs - self.mins);
 697     float i;
 698     vector v, v2;
 699     v2 = 0.5 * (self.absmin + self.absmax);
 700     for(i = 0; i < 100; ++i)
 701     {
 702         v = randomvec();
 703         v_z = 0;
 704         v = v2 + normalize(v) * mysize;
 705         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 706         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 707             return v;
 708     }
 709
 710     /*
 711     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 712     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 713     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 714         return exitspot;
 715
 716     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 717     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 718     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 719         return exitspot;
 720
 721     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 722     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 723     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 724         return exitspot;
 725
 726     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 727     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 728     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 729         return exitspot;
 730     */
 731
 732     return self.origin;
 733 }
 734
 735 /** vehicles_exit
 736     Standarrd vehicle release fucntion.
 737     custom code goes in self.vehicle_exit
 738 **/
 739 float vehicles_exit_running;
 740 void vehicles_exit(float eject)
 741 {
 742     entity _vehicle;
 743     entity _player;
 744     entity _oldself = self;
 745
 746     if(vehicles_exit_running)
 747     {
 748         dprint("^1vehicles_exit allready running! this is not good..\n");
 749         return;
 750     }
 751
 752     vehicles_exit_running = TRUE;
 753     if(IS_CLIENT(self))
 754     {
 755         _vehicle = self.vehicle;
 756
 757         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 758         {
 759             _vehicle.vehicle_exit(eject);
 760             self = _oldself;
 761             vehicles_exit_running = FALSE;
 762             return;
 763         }
 764     }
 765     else
 766         _vehicle = self;
 767
 768     _player = _vehicle.owner;
 769
 770     self = _vehicle;
 771
 772     if (_player)
 773     {
 774         if (IS_REAL_CLIENT(_player))
 775         {
 776             msg_entity = _player;
 777             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 778             WriteEntity( MSG_ONE, _player);
 779
 780             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 781             WriteAngle(MSG_ONE, 0);
 782             WriteAngle(MSG_ONE, _vehicle.angles_y);
 783             WriteAngle(MSG_ONE, 0);
 784         }
 785
 786         setsize(_player, PL_MIN,PL_MAX);
 787
 788         _player.takedamage     = DAMAGE_AIM;
 789         _player.solid          = SOLID_SLIDEBOX;
 790         _player.movetype       = MOVETYPE_WALK;
 791         _player.effects        &~= EF_NODRAW;
 792         _player.alpha          = 1;
 793         _player.PlayerPhysplug = func_null;
 794         _player.vehicle        = world;
 795         _player.view_ofs       = PL_VIEW_OFS;
 796         _player.event_damage   = PlayerDamage;
 797         _player.hud            = HUD_NORMAL;
 798         _player.switchweapon   = _vehicle.switchweapon;
 799
 800         CSQCVehicleSetup(_player, HUD_NORMAL);
 801     }
 802     _vehicle.flags |= FL_NOTARGET;
 803
 804     if(_vehicle.deadflag == DEAD_NO)
 805         _vehicle.avelocity          = '0 0 0';
 806
 807     _vehicle.tur_head.nodrawtoclient             = world;
 808
 809     if(!teamplay)
 810         _vehicle.team = 0;
 811
 812     vh_player = _player;
 813     vh_vehicle = _vehicle;
 814     MUTATOR_CALLHOOK(VehicleExit);
 815     _player = vh_player;
 816     _vehicle = vh_vehicle;
 817
 818     _vehicle.team = _vehicle.tur_head.team;
 819
 820     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 821     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 822     _vehicle.phase = time + 1;
 823         _vehicle.monster_attack = FALSE;
 824
 825     _vehicle.vehicle_exit(eject);
 826
 827     vehicles_setreturn();
 828     vehicles_reset_colors();
 829     _vehicle.owner = world;
 830     self = _oldself;
 831
 832     vehicles_exit_running = FALSE;
 833 }
 834
 835
 836 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 837 {
 838     if(self.regen_field < field_max)
 839     if(timer + rpause < time)
 840     {
 841         if(_healthscale)
 842             regen = regen * (self.vehicle_health / self.tur_health);
 843
 844         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 845
 846         if(self.owner)
 847             self.owner.regen_field = (self.regen_field / field_max) * 100;
 848     }
 849 }
 850
 851 void shieldhit_think()
 852 {
 853     self.alpha -= 0.1;
 854     if (self.alpha <= 0)
 855     {
 856         //setmodel(self, "");
 857         self.alpha = -1;
 858         self.effects |= EF_NODRAW;
 859     }
 860     else
 861     {
 862         self.nextthink = time + 0.1;
 863     }
 864 }
 865
 866 void vehicles_painframe()
 867 {
 868     if(self.owner.vehicle_health <= 50)
 869     if(self.pain_frame < time)
 870     {
 871         float _ftmp;
 872         _ftmp = self.owner.vehicle_health / 50;
 873         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 874         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 875
 876         if(self.vehicle_flags & VHF_DMGSHAKE)
 877             self.velocity += randomvec() * 30;
 878
 879         if(self.vehicle_flags & VHF_DMGROLL)
 880             if(self.vehicle_flags & VHF_DMGHEADROLL)
 881                 self.tur_head.angles += randomvec();
 882             else
 883                 self.angles += randomvec();
 884
 885     }
 886 }
 887
 888 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 889 {
 890     self.dmg_time = time;
 891
 892     if(DEATH_ISWEAPON(deathtype, WEP_NEX))
 893         damage *= autocvar_g_vehicles_nex_damagerate;
 894
 895     if(DEATH_ISWEAPON(deathtype, WEP_UZI))
 896         damage *= autocvar_g_vehicles_uzi_damagerate;
 897
 898     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 899         damage *= autocvar_g_vehicles_rifle_damagerate;
 900
 901     if(DEATH_ISWEAPON(deathtype, WEP_MINSTANEX))
 902         damage *= autocvar_g_vehicles_minstanex_damagerate;
 903
 904     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 905         damage *= autocvar_g_vehicles_tag_damagerate;
 906
 907     self.enemy = attacker;
 908
 909     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 910     {
 911         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 912         {
 913             self.vehicle_shieldent = spawn();
 914             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 915
 916             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 917             setattachment(self.vehicle_shieldent, self, "");
 918             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 919             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 920             self.vehicle_shieldent.think       = shieldhit_think;
 921         }
 922
 923         self.vehicle_shieldent.colormod    = '1 1 1';
 924         self.vehicle_shieldent.alpha       = 0.45;
 925         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 926         self.vehicle_shieldent.nextthink   = time;
 927         self.vehicle_shieldent.effects &~= EF_NODRAW;
 928
 929         self.vehicle_shield -= damage;
 930
 931         if(self.vehicle_shield < 0)
 932         {
 933             self.vehicle_health            -= fabs(self.vehicle_shield);
 934             self.vehicle_shieldent.colormod = '2 0 0';
 935             self.vehicle_shield             = 0;
 936             self.vehicle_shieldent.alpha    = 0.75;
 937
 938                 if(sound_allowed(MSG_BROADCAST, attacker))
 939                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 940         }
 941         else
 942                 if(sound_allowed(MSG_BROADCAST, attacker))
 943                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 944
 945     }
 946     else
 947     {
 948         self.vehicle_health -= damage;
 949
 950         if(sound_allowed(MSG_BROADCAST, attacker))
 951             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 952     }
 953
 954         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 955                 self.velocity += force * self.damageforcescale;
 956         else
 957                 self.velocity += force;
 958
 959     if(self.vehicle_health <= 0)
 960     {
 961         if(self.owner)
 962             if(self.vehicle_flags & VHF_DEATHEJECT)
 963                 vehicles_exit(VHEF_EJECT);
 964             else
 965                 vehicles_exit(VHEF_RELESE);
 966
 967
 968         antilag_clear(self);
 969
 970         self.vehicle_die();
 971         vehicles_setreturn();
 972     }
 973 }
 974
 975 void vehicles_clearrturn()
 976 {
 977     entity ret;
 978     // Remove "return helper", if any.
 979     ret = findchain(classname, "vehicle_return");
 980     while(ret)
 981     {
 982         if(ret.wp00 == self)
 983         {
 984             ret.classname   = "";
 985             ret.think       = SUB_Remove;
 986             ret.nextthink   = time + 0.1;
 987
 988             if(ret.waypointsprite_attached)
 989                 WaypointSprite_Kill(ret.waypointsprite_attached);
 990
 991             return;
 992         }
 993         ret = ret.chain;
 994     }
 995 }
 996
 997 void vehicles_return()
 998 {
 999     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
1000
1001     self.wp00.think     = vehicles_spawn;
1002     self.wp00.nextthink = time;
1003
1004     if(self.waypointsprite_attached)
1005         WaypointSprite_Kill(self.waypointsprite_attached);
1006
1007     remove(self);
1008 }
1009
1010 void vehicles_showwp_goaway()
1011 {
1012     if(self.waypointsprite_attached)
1013         WaypointSprite_Kill(self.waypointsprite_attached);
1014
1015     remove(self);
1016
1017 }
1018
1019 void vehicles_showwp()
1020 {
1021     entity oldself = world;
1022     vector rgb;
1023
1024     if(self.cnt)
1025     {
1026         self.think      = vehicles_return;
1027         self.nextthink  = self.cnt;
1028     }
1029     else
1030     {
1031         self.think      = vehicles_return;
1032         self.nextthink  = time +1;
1033
1034         oldself = self;
1035         self = spawn();
1036         setmodel(self, "null");
1037         self.team = oldself.wp00.team;
1038         self.wp00 = oldself.wp00;
1039         setorigin(self, oldself.wp00.pos1);
1040
1041         self.nextthink = time + 5;
1042         self.think = vehicles_showwp_goaway;
1043     }
1044
1045     if(teamplay && self.team)
1046             rgb = Team_ColorRGB(self.team);
1047     else
1048             rgb = '1 1 1';
1049     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
1050     if(self.waypointsprite_attached)
1051     {
1052         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1053         if(oldself == world)
1054             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1055         WaypointSprite_Ping(self.waypointsprite_attached);
1056     }
1057
1058     if(oldself != world)
1059         self = oldself;
1060 }
1061
1062 void vehicles_setreturn()
1063 {
1064     entity ret;
1065
1066     vehicles_clearrturn();
1067
1068     ret = spawn();
1069     ret.classname   = "vehicle_return";
1070     ret.wp00       = self;
1071     ret.team        = self.team;
1072     ret.think       = vehicles_showwp;
1073
1074     if(self.deadflag != DEAD_NO)
1075     {
1076         ret.cnt         = time + self.vehicle_respawntime;
1077         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
1078     }
1079     else
1080     {
1081         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
1082     }
1083
1084     setmodel(ret, "null");
1085     setorigin(ret, self.pos1 + '0 0 96');
1086
1087 }
1088
1089 void vehicles_reset_colors()
1090 {
1091     entity e;
1092     float _effects = 0, _colormap;
1093     vector _glowmod, _colormod;
1094
1095     if(autocvar_g_nodepthtestplayers)
1096         _effects |= EF_NODEPTHTEST;
1097
1098     if(autocvar_g_fullbrightplayers)
1099         _effects |= EF_FULLBRIGHT;
1100
1101     if(self.team)
1102         _colormap = 1024 + (self.team - 1) * 17;
1103     else
1104         _colormap = 1024;
1105
1106     _glowmod  = '0 0 0';
1107     _colormod = '0 0 0';
1108
1109     // Find all ents attacked to main model and setup effects, colormod etc.
1110     e = findchainentity(tag_entity, self);
1111     while(e)
1112     {
1113         if(e != self.vehicle_shieldent)
1114         {
1115             e.effects   = _effects; //  | EF_LOWPRECISION;
1116             e.colormod  = _colormod;
1117             e.colormap  = _colormap;
1118             e.alpha     = 1;
1119         }
1120         e = e.chain;
1121     }
1122
1123     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1124     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1125     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1126     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1127
1128     self.alpha     = 1;
1129     self.avelocity = '0 0 0';
1130     self.velocity  = '0 0 0';
1131     self.effects   = _effects;
1132 }
1133
1134 void vehicle_use()
1135 {
1136     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1137
1138     self.tur_head.team = activator.team;
1139
1140     if(self.tur_head.team == 0)
1141         self.active = ACTIVE_NOT;
1142     else
1143         self.active = ACTIVE_ACTIVE;
1144
1145     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1146     {
1147         dprint("^3Eat shit yall!\n");
1148         vehicles_setreturn();
1149         vehicles_reset_colors();
1150     }
1151     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1152     {
1153
1154     }
1155 }
1156
1157 float vehicle_addplayerslot(    entity _owner,
1158                                 entity _slot,
1159                                 float _hud,
1160                                 string _hud_model,
1161                                 float() _framefunc,
1162                                 void(float) _exitfunc)
1163 {
1164     if not (_owner.vehicle_flags & VHF_MULTISLOT)
1165         _owner.vehicle_flags |= VHF_MULTISLOT;
1166
1167     _slot.PlayerPhysplug = _framefunc;
1168     _slot.vehicle_exit = _exitfunc;
1169     _slot.hud = _hud;
1170     _slot.vehicle_flags = VHF_PLAYERSLOT;
1171     _slot.vehicle_viewport = spawn();
1172     _slot.vehicle_hudmodel = spawn();
1173     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1174     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1175
1176     setmodel(_slot.vehicle_hudmodel, _hud_model);
1177     setmodel(_slot.vehicle_viewport, "null");
1178
1179     setattachment(_slot.vehicle_hudmodel, _slot, "");
1180     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1181
1182     return TRUE;
1183 }
1184
1185 float vehicle_initialize(string  net_name,
1186                          string  bodymodel,
1187                          string  topmodel,
1188                          string  hudmodel,
1189                          string  toptag,
1190                          string  hudtag,
1191                          string  viewtag,
1192                          float   vhud,
1193                          vector  min_s,
1194                          vector  max_s,
1195                          float   nodrop,
1196                          void(float _spawnflag)  spawnproc,
1197                          float   _respawntime,
1198                          float() physproc,
1199                          void()  enterproc,
1200                          void(float extflag) exitfunc,
1201                          void() dieproc,
1202                          void() thinkproc,
1203                          float  use_csqc,
1204                          float _max_health,
1205                          float _max_shield)
1206 {
1207         if(!autocvar_g_vehicles)
1208                 return FALSE;
1209
1210     if(self.targetname)
1211     {
1212         self.vehicle_controller = find(world, target, self.targetname);
1213         if(!self.vehicle_controller)
1214         {
1215             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1216         }
1217         else
1218         {
1219             self.team = self.vehicle_controller.team;
1220             self.use = vehicle_use;
1221
1222             if(teamplay)
1223             {
1224                 if(self.vehicle_controller.team == 0)
1225                     self.active = ACTIVE_NOT;
1226                 else
1227                     self.active = ACTIVE_ACTIVE;
1228             }
1229         }
1230     }
1231
1232     precache_sound("onslaught/ons_hit2.wav");
1233     precache_sound("onslaught/electricity_explode.wav");
1234
1235
1236     addstat(STAT_HUD, AS_INT,  hud);
1237         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1238         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1239         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1240
1241         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1242         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1243
1244         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1245         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1246
1247     if(bodymodel == "")
1248         error("vehicles: missing bodymodel!");
1249
1250     if(hudmodel == "")
1251         error("vehicles: missing hudmodel!");
1252
1253     if(net_name == "")
1254         self.netname = self.classname;
1255     else
1256         self.netname = net_name;
1257
1258     if(self.team && !teamplay)
1259         self.team = 0;
1260
1261     self.vehicle_flags |= VHF_ISVEHICLE;
1262
1263     setmodel(self, bodymodel);
1264
1265     self.vehicle_viewport   = spawn();
1266     self.vehicle_hudmodel   = spawn();
1267     self.tur_head           = spawn();
1268     self.tur_head.owner     = self;
1269     self.takedamage         = DAMAGE_AIM;
1270     self.bot_attack         = TRUE;
1271     self.iscreature         = TRUE;
1272     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
1273     self.damagedbycontents      = TRUE;
1274     self.hud                = vhud;
1275     self.tur_health          = _max_health;
1276     self.tur_head.tur_health = _max_shield;
1277     self.vehicle_die         = dieproc;
1278     self.vehicle_exit        = exitfunc;
1279     self.vehicle_enter       = enterproc;
1280     self.PlayerPhysplug      = physproc;
1281     self.event_damage        = func_null;
1282     self.touch               = vehicles_touch;
1283     self.think               = vehicles_spawn;
1284     self.nextthink           = time;
1285     self.vehicle_respawntime = _respawntime;
1286     self.vehicle_spawn       = spawnproc;
1287     self.effects             = EF_NODRAW;
1288         self.dphitcontentsmask   = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1289     if(!autocvar_g_vehicles_delayspawn)
1290         self.nextthink = time + game_starttime;
1291     else
1292         self.nextthink = time + _respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1293
1294         if(autocvar_g_playerclip_collisions)
1295                 self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1296
1297     if(autocvar_g_nodepthtestplayers)
1298         self.effects = self.effects | EF_NODEPTHTEST;
1299
1300     if(autocvar_g_fullbrightplayers)
1301         self.effects = self.effects | EF_FULLBRIGHT;
1302
1303     setmodel(self.vehicle_hudmodel, hudmodel);
1304     setmodel(self.vehicle_viewport, "null");
1305
1306     if(topmodel != "")
1307     {
1308         setmodel(self.tur_head, topmodel);
1309         setattachment(self.tur_head, self, toptag);
1310         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1311         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1312     }
1313     else
1314     {
1315         setattachment(self.tur_head, self, "");
1316         setattachment(self.vehicle_hudmodel, self, hudtag);
1317         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1318     }
1319
1320     setsize(self, min_s, max_s);
1321     if not (nodrop)
1322     {
1323         setorigin(self, self.origin);
1324         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1325         setorigin(self, trace_endpos);
1326     }
1327
1328     self.pos1 = self.origin;
1329     self.pos2 = self.angles;
1330     self.tur_head.team = self.team;
1331
1332         if(MUTATOR_CALLHOOK(VehicleSpawn))
1333                 return FALSE;
1334
1335     return TRUE;
1336 }
1337
1338 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1339                          float _pichlimit_min, float _pichlimit_max,
1340                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1341 {
1342     vector vtmp, vtag;
1343     float ftmp;
1344     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1345     vtmp = vectoangles(normalize(_target - vtag));
1346     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1347     vtmp = AnglesTransform_Normalize(vtmp, TRUE);
1348     ftmp = _aimspeed * frametime;
1349     vtmp_y = bound(-ftmp, vtmp_y, ftmp);
1350     vtmp_x = bound(-ftmp, vtmp_x, ftmp);
1351     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
1352     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
1353     return vtag;
1354 }
1355
1356 void vehicles_gib_explode()
1357 {
1358         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
1359         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1360         remove(self);
1361 }
1362
1363 void vehicles_gib_think()
1364 {
1365         self.alpha -= 0.1;
1366         if(self.cnt >= time)
1367                 remove(self);
1368         else
1369                 self.nextthink = time + 0.1;
1370 }
1371
1372 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1373 {
1374         entity _gib = spawn();
1375         setmodel(_gib, _template.model);
1376         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1377         _gib.velocity = _vel;
1378         _gib.movetype = MOVETYPE_TOSS;
1379         _gib.solid = SOLID_CORPSE;
1380         _gib.colormod = '-0.5 -0.5 -0.5';
1381         _gib.effects = EF_LOWPRECISION;
1382         _gib.avelocity = _rot;
1383
1384         if(_burn)
1385                 _gib.effects |= EF_FLAME;
1386
1387         if(_explode)
1388         {
1389                 _gib.think = vehicles_gib_explode;
1390                 _gib.nextthink = time + random() * _explode;
1391                 _gib.touch = vehicles_gib_explode;
1392         }
1393         else
1394         {
1395                 _gib.cnt = time + _maxtime;
1396                 _gib.think = vehicles_gib_think;
1397                 _gib.nextthink = time + _maxtime - 1;
1398                 _gib.alpha = 1;
1399         }
1400         return _gib;
1401 }
1402
1403 /*
1404 vector predict_target(entity _targ, vector _from, float _shot_speed)
1405 {
1406     float i;                // loop
1407     float _distance;        // How far to target
1408     float _impact_time;     // How long untill projectile impacts
1409     vector _predict_pos;    // Predicted enemy location
1410     vector _original_origin;// Where target is before predicted
1411
1412      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1413
1414     _predict_pos = _original_origin;
1415     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1416     {
1417         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1418         _impact_time = _distance / _shot_speed; // Calculate impact time
1419         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1420     }
1421
1422     return _predict_pos;
1423 }
1424 */