qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5 float autocvar_g_vehicles_allow_flagcarry;
   6
   7 float autocvar_g_vehicles_nex_damagerate = 0.5;
   8 float autocvar_g_vehicles_uzi_damagerate = 0.5;
   9 float autocvar_g_vehicles_rifle_damagerate = 0.75;
  10 float autocvar_g_vehicles_minstanex_damagerate = 0.001;
  11 float autocvar_g_vehicles_tag_damagerate = 5;
  12
  13
  14 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  15 void vehicles_return();
  16 void vehicles_enter();
  17 void vehicles_touch();
  18 void vehicles_reset_colors();
  19 void vehicles_clearrturn();
  20 void vehicles_setreturn();
  21
  22
  23 /** AuxiliaryXhair*
  24     Send additional points of interest to be drawn, to vehicle owner
  25 **/
  26 float MAX_AXH = 4;
  27 .entity AuxiliaryXhair[MAX_AXH];
  28
  29 float SendAuxiliaryXhair(entity to, float sf)
  30 {
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  33
  34         WriteByte(MSG_ENTITY, self.cnt);
  35
  36         WriteCoord(MSG_ENTITY, self.origin_x);
  37         WriteCoord(MSG_ENTITY, self.origin_y);
  38         WriteCoord(MSG_ENTITY, self.origin_z);
  39
  40     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  41     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  42     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  43
  44     return TRUE;
  45 }
  46
  47 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  48 {
  49     if (clienttype(own) != CLIENTTYPE_REAL)
  50         return;
  51
  52     entity axh;
  53
  54     axh_id = bound(0, axh_id, MAX_AXH);
  55     axh = own.(AuxiliaryXhair[axh_id]);
  56
  57     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  58     {
  59         axh                     = spawn();
  60         axh.cnt                 = axh_id;
  61         axh.drawonlytoclient    = own;
  62         axh.owner               = own;
  63         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  64     }
  65
  66     setorigin(axh, loc);
  67     axh.colormod            = clr;
  68     axh.SendFlags           = 0x01;
  69     own.(AuxiliaryXhair[axh_id]) = axh;
  70 }
  71
  72 /*
  73 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  74 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  75 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  76 {
  77         msgexntity = own;
  78
  79         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  80         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  81
  82         WriteByte(MSG_ONE, axh_id);
  83
  84         WriteCoord(MSG_ONE, loc_x);
  85         WriteCoord(MSG_ONE, loc_y);
  86         WriteCoord(MSG_ONE, loc_z);
  87
  88     WriteByte(MSG_ONE, rint(clr_x * 255));
  89     WriteByte(MSG_ONE, rint(clr_y * 255));
  90     WriteByte(MSG_ONE, rint(clr_z * 255));
  91
  92 }
  93 */
  94 // End AuxiliaryXhair
  95
  96 /**
  97     Notifies the client that he enterd a vehicle, and sends
  98     realavent data.
  99
 100     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 101 **/
 102 void CSQCVehicleSetup(entity own, float vehicle_id)
 103 {
 104     if (clienttype(own) != CLIENTTYPE_REAL)
 105         return;
 106
 107         msg_entity = own;
 108
 109         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 110         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 111         if(vehicle_id != 0)
 112             WriteByte(MSG_ONE, vehicle_id);
 113         else
 114         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 115 }
 116
 117 /** vehicles_locktarget
 118
 119     Generic target locking.
 120
 121     Figure out if what target is "locked" (if any), for missile tracking as such.
 122
 123     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 124     you have a locked in target.
 125
 126     Exspects a crosshair_trace() or equivalent to be
 127     dont before calling.
 128
 129 **/
 130 .entity lock_target;
 131 .float  lock_strength;
 132 .float  lock_time;
 133 .float  lock_soundtime;
 134 float   DAMAGE_TARGETDRONE = 10;
 135
 136 vector targetdrone_getnewspot()
 137 {
 138
 139         vector spot;
 140         float i;
 141         for(i = 0; i < 100; ++i)
 142         {
 143                 spot = self.origin + randomvec() * 1024;
 144                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 145                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 146                         return spot;
 147         }
 148         return self.origin;
 149 }
 150
 151 #if 0
 152 void targetdrone_think();
 153 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
 154 void targetdrone_renwe()
 155 {
 156         self.think = targetdrone_think;
 157         self.nextthink = time + 0.1;
 158         setorigin(self, targetdrone_getnewspot());
 159         self.health = 200;
 160         self.takedamage = DAMAGE_TARGETDRONE;
 161         self.event_damage = targetdrone_damage;
 162         self.solid = SOLID_BBOX;
 163         setmodel(self, "models/runematch/rune.mdl");
 164         self.effects = EF_LOWPRECISION;
 165         self.scale = 10;
 166         self.movetype = MOVETYPE_BOUNCEMISSILE;
 167         setsize(self, '-100 -100 -100', '100 100 100');
 168
 169 }
 170 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 171 {
 172         self.health -= damage;
 173         if(self.health <= 0)
 174         {
 175                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 176
 177                 if(!self.cnt)
 178                         remove(self);
 179                 else
 180                 {
 181                         self.think = targetdrone_renwe;
 182                         self.nextthink = time + 1 + random() * 2;
 183                         self.solid = SOLID_NOT;
 184                         setmodel(self, "");
 185                 }
 186         }
 187 }
 188 entity targetdrone_getfear()
 189 {
 190         entity fear;
 191         float i;
 192
 193         for(i = 64; i <= 1024; i += 64)
 194         {
 195                 fear = findradius(self.origin, i);
 196                 while(fear)
 197                 {
 198                         if(fear.bot_dodge)
 199                                 return fear;
 200
 201                         fear = fear.chain;
 202                 }
 203         }
 204
 205         return world;
 206 }
 207 void targetdrone_think()
 208 {
 209         self.nextthink = time + 0.1;
 210
 211         if(self.wp00)
 212         if(self.wp00.deadflag != DEAD_NO)
 213                 self.wp00 = targetdrone_getfear();
 214
 215         if(!self.wp00)
 216                 self.wp00 = targetdrone_getfear();
 217
 218         vector newdir;
 219
 220         if(self.wp00)
 221                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 222         else
 223                 newdir = randomvec() * 0.75;
 224
 225         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 226
 227         if(self.wp00)
 228                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 229         else
 230                 self.velocity = normalize(newdir) * 750;
 231
 232         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 233         if(trace_fraction != 1.0)
 234                 self.velocity = self.velocity * -1;
 235
 236         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 237 }
 238
 239 void targetdrone_spawn(vector _where, float _autorenew)
 240 {
 241         entity drone = spawn();
 242         setorigin(drone, _where);
 243         drone.think = targetdrone_renwe;
 244         drone.nextthink = time + 0.1;
 245         drone.cnt = _autorenew;
 246 }
 247 #endif
 248
 249 void vehicles_locktarget(float incr, float decr, float _lock_time)
 250 {
 251     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 252     {
 253         self.lock_target    = world;
 254         self.lock_strength  = 0;
 255         self.lock_time      = 0;
 256     }
 257
 258     if(self.lock_time > time)
 259     {
 260         if(self.lock_target)
 261         if(self.lock_soundtime < time)
 262         {
 263             self.lock_soundtime = time + 0.5;
 264             play2(self.owner, "vehicles/locked.wav");
 265         }
 266
 267         return;
 268     }
 269
 270     if(trace_ent != world)
 271     {
 272         if(teamplay && trace_ent.team == self.team)
 273             trace_ent = world;
 274
 275         if(trace_ent.deadflag != DEAD_NO)
 276             trace_ent = world;
 277
 278         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE ||
 279                                 trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET ||
 280                                 trace_ent.takedamage == DAMAGE_TARGETDRONE)
 281             trace_ent = world;
 282     }
 283
 284     if(self.lock_target == world && trace_ent != world)
 285         self.lock_target = trace_ent;
 286
 287     if(self.lock_target && trace_ent == self.lock_target)
 288     {
 289         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 290         {
 291             play2(self.owner, "vehicles/lock.wav");
 292             self.lock_soundtime = time + 0.8;
 293         }
 294         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 295         {
 296             play2(self.owner, "vehicles/locking.wav");
 297             self.lock_soundtime = time + 0.3;
 298         }
 299
 300     }
 301
 302     // Have a locking target
 303     // Trace hit current target
 304     if(trace_ent == self.lock_target && trace_ent != world)
 305     {
 306         self.lock_strength = min(self.lock_strength + incr, 1);
 307         if(self.lock_strength == 1)
 308             self.lock_time = time + _lock_time;
 309     }
 310     else
 311     {
 312         if(trace_ent)
 313             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 314         else
 315             self.lock_strength = max(self.lock_strength - decr, 0);
 316
 317         if(self.lock_strength == 0)
 318             self.lock_target = world;
 319     }
 320 }
 321
 322 #define VEHICLE_UPDATE_PLAYER(ply,fld,vhname) \
 323 ply.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 324
 325 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 326 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 327 if(trace_fraction != 1) \
 328     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 329
 330 // Hover movement support
 331 float  force_fromtag_power;
 332 float  force_fromtag_normpower;
 333 vector force_fromtag_origin;
 334 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 335 {
 336     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 337     v_forward  = normalize(v_forward) * -1;
 338     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 339
 340     force_fromtag_power = (1 - trace_fraction) * max_power;
 341     force_fromtag_normpower = force_fromtag_power / max_power;
 342
 343     return v_forward  * force_fromtag_power;
 344 }
 345
 346 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 347 // Can possibly be use to move abt any surface (inclusing walls/celings)
 348 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 349 {
 350
 351     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 352     v_forward  = normalize(v_forward) * -1;
 353     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 354
 355     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 356     if(trace_fraction == 1.0)
 357     {
 358         force_fromtag_normpower = -0.25;
 359         return '0 0 -200';
 360     }
 361
 362     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 363     force_fromtag_normpower = force_fromtag_power / max_power;
 364
 365     return v_forward  * force_fromtag_power;
 366 }
 367
 368 // Generic vehile projectile system
 369 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 370 {
 371     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 372     if(inflictor.owner == self.owner)
 373         return;
 374
 375     self.health -= damage;
 376     self.velocity += force;
 377     if(self.health < 1)
 378     {
 379         self.takedamage = DAMAGE_NO;
 380         self.event_damage = SUB_Null;
 381         self.think = self.use;
 382         self.nextthink = time;
 383     }
 384 }
 385
 386 void vehicles_projectile_explode()
 387 {
 388     if(self.owner && other != world)
 389     {
 390         if(other == self.owner.vehicle)
 391             return;
 392
 393         if(other == self.owner.vehicle.tur_head)
 394             return;
 395     }
 396
 397         PROJECTILE_TOUCH;
 398
 399         self.event_damage = SUB_Null;
 400     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, world, self.shot_force, self.totalfrags, other);
 401
 402     remove (self);
 403 }
 404
 405 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 406                            vector _org, vector _vel,
 407                            float _dmg, float _radi, float _force,  float _size,
 408                            float _deahtype, float _projtype, float _health,
 409                            float _cull, float _clianim, entity _owner)
 410 {
 411     entity proj;
 412
 413     proj = spawn();
 414
 415     PROJECTILE_MAKETRIGGER(proj);
 416     setorigin(proj, _org);
 417
 418     proj.shot_dmg         = _dmg;
 419     proj.shot_radius      = _radi;
 420     proj.shot_force       = _force;
 421     proj.totalfrags       = _deahtype;
 422     proj.solid            = SOLID_BBOX;
 423     proj.movetype         = MOVETYPE_FLYMISSILE;
 424     proj.flags            = FL_PROJECTILE;
 425     proj.bot_dodge        = TRUE;
 426     proj.bot_dodgerating  = _dmg;
 427     proj.velocity         = _vel;
 428     proj.touch            = vehicles_projectile_explode;
 429     proj.use              = vehicles_projectile_explode;
 430     proj.owner            = self;
 431     proj.realowner        = _owner;
 432     proj.think            = SUB_Remove;
 433     proj.nextthink        = time + 30;
 434
 435     if(_health)
 436     {
 437         proj.takedamage       = DAMAGE_AIM;
 438         proj.event_damage     = vehicles_projectile_damage;
 439         proj.health           = _health;
 440     }
 441     else
 442         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 443
 444     if(_mzlsound)
 445         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 446
 447     if(_mzlfx)
 448         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 449
 450
 451     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 452
 453     CSQCProjectile(proj, _clianim, _projtype, _cull);
 454
 455     return proj;
 456 }
 457 // End generic vehile projectile system
 458
 459 /** vehicles_spawn
 460     Exetuted for all vehicles on (re)spawn.
 461     Sets defaults for newly spawned units.
 462 **/
 463 void vehicles_spawn()
 464 {
 465     dprint("Spawning vehicle: ", self.netname, "\n");
 466
 467     // De-own & reset
 468     self.vehicle_hudmodel.viewmodelforclient = self;
 469
 470     self.owner              = world;
 471     self.touch              = vehicles_touch;
 472     self.event_damage       = vehicles_damage;
 473     self.iscreature         = TRUE;
 474     self.damagedbycontents      = TRUE;
 475     self.movetype           = MOVETYPE_WALK;
 476     self.solid              = SOLID_SLIDEBOX;
 477     self.takedamage         = DAMAGE_AIM;
 478         self.deadflag           = DEAD_NO;
 479     self.bot_attack         = TRUE;
 480     self.flags              = FL_NOTARGET;
 481     self.avelocity          = '0 0 0';
 482     self.velocity           = '0 0 0';
 483
 484     // Reset locking
 485     self.lock_strength      = 0;
 486     self.lock_target        = world;
 487     self.misc_bulletcounter = 0;
 488
 489     // Return to spawn
 490     self.angles             = self.pos2;
 491     setorigin(self, self.pos1 + '0 0 0');
 492     // Show it
 493     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 494
 495     if(self.vehicle_controller)
 496         self.team = self.vehicle_controller.team;
 497
 498     vehicles_reset_colors();
 499     self.vehicle_spawn(VHSF_NORMAL);
 500 }
 501
 502 // Better way of determening whats crushable needed! (fl_crushable?)
 503 float vehicles_crushable(entity e)
 504 {
 505     if(e.classname == "player")
 506         return TRUE;
 507
 508     if(e.classname == "monster_zombie")
 509         return TRUE;
 510
 511     return FALSE;
 512 }
 513
 514 void vehilces_impact(float _minspeed, float _speedfac, float _maxpain)
 515 {
 516     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 517         return;
 518
 519     if(self.play_time < time)
 520     {
 521         float wc = vlen(self.velocity - self.oldvelocity);
 522         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 523         //dprint("vel: ", vtos(self.velocity), "\n");
 524         if(_minspeed < wc)
 525         {
 526             float take = min(_speedfac * wc, _maxpain);
 527             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 528             self.play_time = time + 0.25;
 529
 530             //dprint("wc: ", ftos(wc), "\n");
 531             //dprint("take: ", ftos(take), "\n");
 532         }
 533     }
 534 }
 535
 536 .void() vehicle_impact;
 537 void vehicles_touch()
 538 {
 539     // Vehicle currently in use
 540     if(self.owner)
 541     {
 542         if(other != world)
 543         if(vehicles_crushable(other))
 544         {
 545             if(vlen(self.velocity) != 0)
 546                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 547
 548             return; // Dont do selfdamage when hitting "soft targets".
 549         }
 550
 551         if(self.play_time < time)
 552         if(self.vehicle_impact)
 553             self.vehicle_impact();
 554
 555         return;
 556     }
 557
 558     if(other.classname != "player")
 559         return;
 560
 561     if(other.deadflag != DEAD_NO)
 562         return;
 563
 564     if(other.vehicle != world)
 565         return;
 566
 567     vehicles_enter();
 568 }
 569 var float autocvar_g_vehicles_allow_bots = 0;
 570 void vehicles_enter()
 571 {
 572    // Remove this when bots know how to use vehicles
 573
 574     if (clienttype(other) == CLIENTTYPE_BOT)
 575         if (autocvar_g_vehicles_allow_bots)
 576             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 577         else
 578             return;
 579
 580     if(self.phase > time)
 581         return;
 582
 583     if(teamplay)
 584     if(self.team)
 585     if(self.team != other.team)
 586         return;
 587
 588     RemoveGrapplingHook(other);
 589
 590     self.vehicle_ammo1   = 0;
 591     self.vehicle_ammo2   = 0;
 592     self.vehicle_reload1 = 0;
 593     self.vehicle_reload2 = 0;
 594     self.vehicle_energy  = 0;
 595
 596     self.owner          = other;
 597     self.switchweapon   = other.switchweapon;
 598
 599     // .viewmodelforclient works better.
 600     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 601
 602     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 603
 604     self.event_damage         = vehicles_damage;
 605     self.nextthink            = 0;
 606     self.owner.angles         = self.angles;
 607     self.owner.takedamage     = DAMAGE_NO;
 608     self.owner.solid          = SOLID_NOT;
 609     self.owner.movetype       = MOVETYPE_NOCLIP;
 610     self.owner.alpha          = -1;
 611     self.owner.vehicle        = self;
 612     self.owner.event_damage   = SUB_Null;
 613     self.owner.view_ofs       = '0 0 0';
 614     self.colormap             = self.owner.colormap;
 615     if(self.tur_head)
 616         self.tur_head.colormap    = self.owner.colormap;
 617
 618     self.owner.hud            = self.hud;
 619     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 620
 621     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 622     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 623     self.owner.vehicle_reload1  = self.vehicle_reload1;
 624     self.owner.vehicle_reload2  = self.vehicle_reload2;
 625
 626     // Cant do this, hides attached objects too.
 627     //self.exteriormodeltoclient = self.owner;
 628     //self.tur_head.exteriormodeltoclient = self.owner;
 629
 630     other.flags &~= FL_ONGROUND;
 631     self.flags  &~= FL_ONGROUND;
 632
 633     self.team                 = self.owner.team;
 634     self.flags               -= FL_NOTARGET;
 635
 636     if (clienttype(other) == CLIENTTYPE_REAL)
 637     {
 638         msg_entity = other;
 639         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 640         WriteEntity(MSG_ONE, self.vehicle_viewport);
 641
 642         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 643         if(self.tur_head)
 644         {
 645             WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 646             WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 647             WriteAngle(MSG_ONE, 0);                                      // roll
 648         }
 649         else
 650         {
 651             WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 652             WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 653             WriteAngle(MSG_ONE,  0);                  // roll
 654         }
 655     }
 656
 657     vehicles_clearrturn();
 658
 659     CSQCVehicleSetup(self.owner, self.hud);
 660
 661     if(other.flagcarried)
 662     {
 663         if(!autocvar_g_vehicles_allow_flagcarry)
 664             DropFlag(other.flagcarried, world, world);
 665         else
 666         {
 667             other.flagcarried.scale = 1;
 668             setattachment(other.flagcarried, self, "");
 669             setorigin(other, '0 0 96');
 670         }
 671     }
 672
 673     self.vehicle_enter();
 674     antilag_clear(other);
 675 }
 676
 677 /** vehicles_findgoodexit
 678     Locates a valid location for the player to exit the vehicle.
 679     Will first try prefer_spot, then up 100 random spots arround the vehicle
 680     wich are in direct line of sight and empty enougth to hold a players bbox
 681 **/
 682 vector vehicles_findgoodexit(vector prefer_spot)
 683 {
 684     //vector exitspot;
 685     float mysize;
 686
 687     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 688     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 689         return prefer_spot;
 690
 691     mysize = vlen(self.maxs - self.mins);
 692     float i;
 693     vector v, v2;
 694     v2 = 0.5 * (self.absmin + self.absmax);
 695     for(i = 0; i < 100; ++i)
 696     {
 697         v = randomvec();
 698         v_z = 0;
 699         v = v2 + normalize(v) * mysize;
 700         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 701         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 702             return v;
 703     }
 704
 705     /*
 706     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 707     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 708     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 709         return exitspot;
 710
 711     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 712     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 713     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 714         return exitspot;
 715
 716     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 717     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 718     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 719         return exitspot;
 720
 721     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 722     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 723     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 724         return exitspot;
 725     */
 726
 727     return self.origin;
 728 }
 729
 730 /** vehicles_exit
 731     Standarrd vehicle release fucntion.
 732     custom code goes in self.vehicle_exit
 733 **/
 734 float vehicles_exit_running;
 735 void vehicles_exit(float eject)
 736 {
 737     entity _vehicle;
 738     entity _player;
 739     entity _oldself = self;
 740
 741     if(vehicles_exit_running)
 742     {
 743         dprint("^1vehicles_exit allready running! this is not good..\n");
 744         return;
 745     }
 746
 747     if(self.flags & FL_CLIENT)
 748     {
 749         _vehicle = self.vehicle;
 750
 751         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 752         {
 753             _vehicle.vehicle_exit(eject);
 754             self = _oldself;
 755             return;
 756         }
 757     }
 758     else
 759         _vehicle = self;
 760
 761     _player = _vehicle.owner;
 762
 763     self = _vehicle;
 764
 765     if (_player)
 766     {
 767         dprint("^3Player exits\n");
 768
 769         if (clienttype(_player) == CLIENTTYPE_REAL)
 770         {
 771             msg_entity = _player;
 772             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 773             WriteEntity( MSG_ONE, _player);
 774
 775             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 776             WriteAngle(MSG_ONE, 0);
 777             WriteAngle(MSG_ONE, _vehicle.angles_y);
 778             WriteAngle(MSG_ONE, 0);
 779         }
 780
 781         setsize(_player, PL_MIN,PL_MAX);
 782
 783         _player.takedamage     = DAMAGE_AIM;
 784         _player.solid          = SOLID_SLIDEBOX;
 785         _player.movetype       = MOVETYPE_WALK;
 786         _player.effects        &~= EF_NODRAW;
 787         _player.alpha          = 1;
 788         _player.PlayerPhysplug = SUB_Null;
 789         _player.vehicle        = world;
 790         _player.view_ofs       = PL_VIEW_OFS;
 791         _player.event_damage   = PlayerDamage;
 792         _player.hud            = HUD_NORMAL;
 793         _player.switchweapon   = _vehicle.switchweapon;
 794
 795         if(_player.flagcarried)
 796         {
 797             _player.flagcarried.scale = 0.6;
 798             setattachment(_player.flagcarried, _player, "");
 799             setorigin(_player.flagcarried, FLAG_CARRY_POS);
 800         }
 801
 802         CSQCVehicleSetup(_player, HUD_NORMAL);
 803     }
 804
 805
 806     dprint("^1Pilot exits\n");
 807     _vehicle.flags |= FL_NOTARGET;
 808
 809     if(_vehicle.deadflag == DEAD_NO)
 810         _vehicle.avelocity          = '0 0 0';
 811
 812     _vehicle.tur_head.nodrawtoclient             = world;
 813
 814     if(!teamplay)
 815         _vehicle.team = 0;
 816     else
 817         _vehicle.team = _vehicle.tur_head.team;
 818
 819
 820     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 821     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 822     _vehicle.phase = time + 1;
 823
 824     _vehicle.vehicle_exit(eject);
 825
 826     vehicles_setreturn();
 827     vehicles_reset_colors();
 828     _vehicle.owner = world;
 829     self = _oldself;
 830 }
 831
 832
 833 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 834 {
 835     if(self.regen_field < field_max)
 836     if(self.timer + rpause < time)
 837     {
 838         if(_healthscale)
 839             regen = regen * (self.vehicle_health / self.tur_health);
 840
 841         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 842
 843         if(self.owner)
 844             self.owner.regen_field = (self.regen_field / field_max) * 100;
 845     }
 846 }
 847
 848 void shieldhit_think()
 849 {
 850     self.alpha -= 0.1;
 851     if (self.alpha <= 0)
 852     {
 853         //setmodel(self, "");
 854         self.alpha = -1;
 855     }
 856     else
 857     {
 858         self.nextthink = time + 0.1;
 859     }
 860 }
 861
 862 void vehicles_painframe()
 863 {
 864     if(self.owner.vehicle_health <= 50)
 865     if(self.pain_frame < time)
 866     {
 867         float _ftmp;
 868         _ftmp = self.owner.vehicle_health / 50;
 869         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 870         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 871
 872         if(self.vehicle_flags & VHF_DMGSHAKE)
 873             self.velocity += randomvec() * 30;
 874
 875         if(self.vehicle_flags & VHF_DMGROLL)
 876             if(self.vehicle_flags & VHF_DMGHEADROLL)
 877                 self.tur_head.angles += randomvec();
 878             else
 879                 self.angles += randomvec();
 880
 881     }
 882 }
 883
 884 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 885 {
 886     self.dmg_time = time;
 887
 888     if(DEATH_ISWEAPON(deathtype, WEP_NEX))
 889         damage *= autocvar_g_vehicles_nex_damagerate;
 890
 891     if(DEATH_ISWEAPON(deathtype, WEP_UZI))
 892         damage *= autocvar_g_vehicles_uzi_damagerate;
 893
 894     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 895         damage *= autocvar_g_vehicles_rifle_damagerate;
 896
 897     if(DEATH_ISWEAPON(deathtype, WEP_MINSTANEX))
 898         damage *= autocvar_g_vehicles_minstanex_damagerate;
 899
 900     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 901         damage *= autocvar_g_vehicles_tag_damagerate;
 902
 903     self.enemy = attacker;
 904
 905     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 906     {
 907         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 908         {
 909             self.vehicle_shieldent = spawn();
 910             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 911
 912             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 913             setattachment(self.vehicle_shieldent, self, "");
 914             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 915             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 916             self.vehicle_shieldent.think       = shieldhit_think;
 917         }
 918
 919         self.vehicle_shieldent.colormod    = '1 1 1';
 920         self.vehicle_shieldent.alpha       = 0.45;
 921         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 922         self.vehicle_shieldent.nextthink   = time;
 923
 924         self.vehicle_shield -= damage;
 925
 926         if(self.vehicle_shield < 0)
 927         {
 928             self.vehicle_health            -= fabs(self.vehicle_shield);
 929             self.vehicle_shieldent.colormod = '2 0 0';
 930             self.vehicle_shield             = 0;
 931             self.vehicle_shieldent.alpha    = 0.75;
 932
 933                 if(sound_allowed(MSG_BROADCAST, attacker))
 934                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 935         }
 936         else
 937                 if(sound_allowed(MSG_BROADCAST, attacker))
 938                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 939
 940     }
 941     else
 942     {
 943         self.vehicle_health -= damage;
 944
 945         if(sound_allowed(MSG_BROADCAST, attacker))
 946             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 947     }
 948
 949     self.velocity += force; // * (vlen(force) / self.mass);
 950
 951     if(self.vehicle_health <= 0)
 952     {
 953         if(self.owner)
 954             if(self.vehicle_flags & VHF_DEATHEJECT)
 955                 vehicles_exit(VHEF_EJECT);
 956             else
 957                 vehicles_exit(VHEF_RELESE);
 958
 959         self.vehicle_die();
 960         vehicles_setreturn();
 961     }
 962 }
 963
 964 void vehicles_clearrturn()
 965 {
 966     entity ret;
 967     // Remove "return helper", if any.
 968     ret = findchain(classname, "vehicle_return");
 969     while(ret)
 970     {
 971         if(ret.wp00 == self)
 972         {
 973             ret.classname   = "";
 974             ret.think       = SUB_Remove;
 975             ret.nextthink   = time + 0.1;
 976
 977             if(ret.waypointsprite_attached)
 978                 WaypointSprite_Kill(ret.waypointsprite_attached);
 979
 980             return;
 981         }
 982         ret = ret.chain;
 983     }
 984 }
 985
 986 void vehicles_return()
 987 {
 988     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
 989
 990     self.wp00.think     = vehicles_spawn;
 991     self.wp00.nextthink = time;
 992
 993     if(self.waypointsprite_attached)
 994         WaypointSprite_Kill(self.waypointsprite_attached);
 995
 996     remove(self);
 997 }
 998
 999 void vehicles_showwp_goaway()
1000 {
1001     if(self.waypointsprite_attached)
1002         WaypointSprite_Kill(self.waypointsprite_attached);
1003
1004     remove(self);
1005
1006 }
1007
1008 void vehicles_showwp()
1009 {
1010     entity oldself;
1011     vector rgb;
1012
1013     if(self.cnt)
1014     {
1015         self.think      = vehicles_return;
1016         self.nextthink  = self.cnt;
1017     }
1018     else
1019     {
1020         self.think      = vehicles_return;
1021         self.nextthink  = time +1;
1022
1023         oldself = self;
1024         self = spawn();
1025         setmodel(self, "null");
1026         self.team = oldself.wp00.team;
1027         self.wp00 = oldself.wp00;
1028         setorigin(self, oldself.wp00.pos1);
1029
1030         self.nextthink = time + 5;
1031         self.think = vehicles_showwp_goaway;
1032     }
1033
1034     if(teamplay && self.team)
1035             rgb = TeamColor(self.team);
1036     else
1037             rgb = '1 1 1';
1038     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
1039     if(self.waypointsprite_attached)
1040     {
1041         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1042         if(oldself == world)
1043             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1044         WaypointSprite_Ping(self.waypointsprite_attached);
1045     }
1046
1047     if(oldself != world)
1048         self = oldself;
1049 }
1050
1051 void vehicles_setreturn()
1052 {
1053     entity ret;
1054
1055     vehicles_clearrturn();
1056
1057     ret = spawn();
1058     ret.classname   = "vehicle_return";
1059     ret.wp00       = self;
1060     ret.team        = self.team;
1061     ret.think       = vehicles_showwp;
1062
1063     if(self.deadflag != DEAD_NO)
1064     {
1065         ret.cnt         = time + self.vehicle_respawntime;
1066         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
1067     }
1068     else
1069     {
1070         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
1071     }
1072
1073     setmodel(ret, "null");
1074     setorigin(ret, self.pos1 + '0 0 96');
1075
1076 }
1077
1078 void vehicles_reset_colors()
1079 {
1080     entity e;
1081     float _effects, _colormap;
1082     vector _glowmod, _colormod;
1083
1084     if(autocvar_g_nodepthtestplayers)
1085         _effects = EF_NODEPTHTEST;
1086
1087     if(autocvar_g_fullbrightplayers)
1088         _effects |= EF_FULLBRIGHT;
1089
1090     if(self.team)
1091         _colormap = 1024 + (self.team - 1) * 17;
1092     else
1093         _colormap = 1024;
1094
1095     _glowmod  = '0 0 0';
1096     _colormod = '0 0 0';
1097
1098     // Find all ents attacked to main model and setup effects, colormod etc.
1099     e = findchainentity(tag_entity, self);
1100     while(e)
1101     {
1102         if(e != self.vehicle_shieldent)
1103         {
1104             e.effects   = _effects; //  | EF_LOWPRECISION;
1105             e.colormod  = _colormod;
1106             e.colormap  = _colormap;
1107             e.alpha     = 1;
1108         }
1109         e = e.chain;
1110     }
1111
1112     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1113     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1114     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1115     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1116
1117     self.alpha     = 1;
1118     self.avelocity = '0 0 0';
1119     self.velocity  = '0 0 0';
1120     self.effects   = _effects;
1121 }
1122
1123 void vehicle_use()
1124 {
1125     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1126
1127     self.tur_head.team = activator.team;
1128
1129     if(self.tur_head.team == 0)
1130         self.active = ACTIVE_NOT;
1131     else
1132         self.active = ACTIVE_ACTIVE;
1133
1134     if(self.active == ACTIVE_ACTIVE && self.deadflag != DEAD_NO)
1135     {
1136         vehicles_setreturn();
1137         vehicles_reset_colors();
1138     }
1139     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1140     {
1141
1142     }
1143 }
1144
1145 float vehicle_addplayerslot(    entity _owner,
1146                                 entity _slot,
1147                                 float _hud,
1148                                 string _hud_model,
1149                                 float() _framefunc,
1150                                 void(float) _exitfunc)
1151 {
1152     if not (_owner.vehicle_flags & VHF_MULTISLOT)
1153         _owner.vehicle_flags |= VHF_MULTISLOT;
1154
1155     _slot.PlayerPhysplug = _framefunc;
1156     _slot.vehicle_exit = _exitfunc;
1157     _slot.hud = _hud;
1158     _slot.vehicle_flags = VHF_PLAYERSLOT;
1159     _slot.vehicle_viewport = spawn();
1160     _slot.vehicle_hudmodel = spawn();
1161     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1162     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1163
1164     setmodel(_slot.vehicle_hudmodel, _hud_model);
1165     setmodel(_slot.vehicle_viewport, "null");
1166
1167     setattachment(_slot.vehicle_hudmodel, _slot, "");
1168     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1169
1170     return TRUE;
1171 }
1172
1173 float vehicle_initialize(string  net_name,
1174                          string  bodymodel,
1175                          string  topmodel,
1176                          string  hudmodel,
1177                          string  toptag,
1178                          string  hudtag,
1179                          string  viewtag,
1180                          float   vhud,
1181                          vector  min_s,
1182                          vector  max_s,
1183                          float   nodrop,
1184                          void(float _spawnflag)  spawnproc,
1185                          float   _respawntime,
1186                          float() physproc,
1187                          void()  enterproc,
1188                          void(float extflag) exitfunc,
1189                          void() dieproc,
1190                          void() thinkproc,
1191                          float  use_csqc,
1192                          float _max_health)
1193 {
1194     if(self.targetname)
1195     {
1196         self.vehicle_controller = find(world, target, self.targetname);
1197         if(!self.vehicle_controller)
1198         {
1199             bprint("^1WARNING: ^3Vehicle with invalid .targetname\n");
1200         }
1201         else
1202         {
1203             self.team = self.vehicle_controller.team;
1204             self.use = vehicle_use;
1205         }
1206     }
1207
1208     addstat(STAT_HUD, AS_INT,  hud);
1209         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1210         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1211         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1212
1213         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
1214         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1215
1216         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
1217         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1218
1219     if(bodymodel == "")
1220         error("vehicles: missing bodymodel!");
1221
1222     if(hudmodel == "")
1223         error("vehicles: missing hudmodel!");
1224
1225     if(net_name == "")
1226         self.netname = self.classname;
1227     else
1228         self.netname = net_name;
1229
1230     if(self.team && !teamplay)
1231         self.team = 0;
1232
1233     self.vehicle_flags |= VHF_ISVEHICLE;
1234
1235     setmodel(self, bodymodel);
1236
1237     self.vehicle_viewport   = spawn();
1238     self.vehicle_hudmodel   = spawn();
1239     self.tur_head           = spawn();
1240     self.tur_head.owner     = self;
1241     self.takedamage         = DAMAGE_AIM;
1242     self.bot_attack         = TRUE;
1243     self.iscreature         = TRUE;
1244     self.damagedbycontents      = TRUE;
1245     self.hud                = vhud;
1246     self.tur_health          = _max_health;
1247     self.vehicle_die         = dieproc;
1248     self.vehicle_exit        = exitfunc;
1249     self.vehicle_enter       = enterproc;
1250     self.PlayerPhysplug      = physproc;
1251     self.event_damage        = vehicles_damage;
1252     self.touch               = vehicles_touch;
1253     self.think               = vehicles_spawn;
1254     self.nextthink           = time;
1255     self.vehicle_respawntime = _respawntime;
1256     self.vehicle_spawn       = spawnproc;
1257
1258     if(autocvar_g_nodepthtestplayers)
1259         self.effects = self.effects | EF_NODEPTHTEST;
1260
1261     if(autocvar_g_fullbrightplayers)
1262         self.effects = self.effects | EF_FULLBRIGHT;
1263
1264     setmodel(self.vehicle_hudmodel, hudmodel);
1265     setmodel(self.vehicle_viewport, "null");
1266
1267     if(topmodel != "")
1268     {
1269         setmodel(self.tur_head, topmodel);
1270         setattachment(self.tur_head, self, toptag);
1271         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1272         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1273     }
1274     else
1275     {
1276         setattachment(self.tur_head, self, "");
1277         setattachment(self.vehicle_hudmodel, self, hudtag);
1278         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1279     }
1280
1281     setsize(self, min_s, max_s);
1282     if not (nodrop)
1283     {
1284         setorigin(self, self.origin);
1285         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1286         setorigin(self, trace_endpos);
1287     }
1288
1289     self.pos1 = self.origin;
1290     self.pos2 = self.angles;
1291     self.tur_head.team = self.team;
1292
1293     return TRUE;
1294 }
1295
1296 void vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1297                          float _pichlimit_min, float _pichlimit_max,
1298                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1299 {
1300     vector vtmp;
1301     float ftmp;
1302
1303     vtmp = vectoangles(normalize(_target - gettaginfo(_turrret, gettagindex(_turrret, _tagname))));
1304     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1305     vtmp = AnglesTransform_Normalize(vtmp, TRUE);
1306
1307     ftmp = _aimspeed * sys_frametime;
1308     vtmp_y = bound(-ftmp, vtmp_y, ftmp);
1309     vtmp_x = bound(-ftmp, vtmp_x, ftmp);
1310     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
1311     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
1312 }