Merge remote branch 'origin/fruitiex/fruitbalance' into divVerent/fruitbalance
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_electro.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
3 #else
4 #ifdef SVQC
5 .float electro_count;
6 .float electro_secondarytime;
7
8 void W_Plasma_Explode_Combo (void);
9
10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
11 {
12         local entity e;
13         e = WarpZone_FindRadius(org, rad, TRUE);
14         while (e)
15         {
16                 if (e.classname == "plasma")
17                 {
18                         // change owner to whoever caused the combo explosion
19                         e.owner = own;
20                         e.takedamage = DAMAGE_NO;
21                         e.classname = "plasma_chain";
22                         e.think = W_Plasma_Explode_Combo;
23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
24                 }
25                 e = e.chain;
26         }
27 }
28
29 void W_Plasma_Explode (void)
30 {
31         if(other.takedamage == DAMAGE_AIM)
32                 if(other.classname == "player")
33                         if(IsDifferentTeam(self.owner, other))
34                                 if(other.deadflag == DEAD_NO)
35                                         if(IsFlying(other))
36                                                 AnnounceTo(self.owner, "electrobitch");
37
38         self.event_damage = SUB_Null;
39         self.takedamage = DAMAGE_NO;
40         if (self.movetype == MOVETYPE_BOUNCE)
41         {
42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
43         }
44         else
45         {
46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
48         }
49
50         remove (self);
51 }
52
53 void W_Plasma_Explode_Combo (void)
54 {
55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
56
57         self.event_damage = SUB_Null;
58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
59         remove (self);
60 }
61
62 void W_Plasma_Touch (void)
63 {
64         PROJECTILE_TOUCH;
65         if (other.takedamage == DAMAGE_AIM) {
66                 W_Plasma_Explode ();
67         } else {
68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
70         }
71 }
72
73 void W_Plasma_TouchExplode (void)
74 {
75         PROJECTILE_TOUCH;
76         W_Plasma_Explode ();
77 }
78
79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
80 {
81         if(self.health <= 0)
82                 return;
83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
84         self.health = self.health - damage;
85         if (self.health <= 0)
86         {
87                 self.takedamage = DAMAGE_NO;
88                 self.nextthink = time;
89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
90                 {
91                         // change owner to whoever caused the combo explosion
92                         self.owner = inflictor.owner;
93                         self.classname = "plasma_chain";
94                         self.think = W_Plasma_Explode_Combo;
95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
97                 }
98                 else
99                 {
100                         self.use = W_Plasma_Explode;
101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
102                 }
103         }
104 }
105
106 void W_Electro_Attack()
107 {
108         local entity proj;
109
110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
111
112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
113
114         proj = spawn ();
115         proj.classname = "plasma_prim";
116         proj.owner = self;
117         proj.bot_dodge = TRUE;
118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
119         proj.use = W_Plasma_Explode;
120         proj.think = adaptor_think2use_hittype_splash;
121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
122         PROJECTILE_MAKETRIGGER(proj);
123         proj.projectiledeathtype = WEP_ELECTRO;
124         setorigin(proj, w_shotorg);
125
126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
128         proj.movetype = MOVETYPE_FLY;
129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
130         proj.angles = vectoangles(proj.velocity);
131         proj.touch = W_Plasma_TouchExplode;
132         setsize(proj, '0 0 -3', '0 0 -3');
133         proj.flags = FL_PROJECTILE;
134
135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
136         //sounds bad
137
138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
139 }
140
141 void W_Electro_Attack2()
142 {
143         local entity proj;
144
145         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
146         w_shotdir = v_forward; // no TrueAim for grenades please
147
148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
149
150         proj = spawn ();
151         proj.classname = "plasma";
152         proj.owner = self;
153         proj.use = W_Plasma_Explode;
154         proj.think = adaptor_think2use_hittype_splash;
155         proj.bot_dodge = TRUE;
156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
158         PROJECTILE_MAKETRIGGER(proj);
159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
160         setorigin(proj, w_shotorg);
161
162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
164         //proj.glow_size = 50;
165         //proj.glow_color = 45;
166         proj.movetype = MOVETYPE_BOUNCE;
167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
168         proj.touch = W_Plasma_Touch;
169         setsize(proj, '0 0 -4', '0 0 -4');
170         proj.takedamage = DAMAGE_YES;
171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
172         proj.health = cvar("g_balance_electro_secondary_health");
173         proj.event_damage = W_Plasma_Damage;
174         proj.flags = FL_PROJECTILE;
175
176 #if 0
177         entity p2;
178         p2 = spawn();
179         copyentity(proj, p2);
180         setmodel(p2, "models/ebomb.mdl");
181         setsize(p2, proj.mins, proj.maxs);
182 #endif
183
184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
185 }
186
187 .vector hook_start, hook_end;
188 float lgbeam_send(entity to, float sf)
189 {
190         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
191         sf = sf & 0x7F;
192         if(sound_allowed(MSG_BROADCAST, self.owner))
193                 sf |= 0x80;
194         WriteByte(MSG_ENTITY, sf);
195         if(sf & 1)
196         {
197                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
198         }
199         if(sf & 2)
200         {
201                 WriteCoord(MSG_ENTITY, self.hook_start_x);
202                 WriteCoord(MSG_ENTITY, self.hook_start_y);
203                 WriteCoord(MSG_ENTITY, self.hook_start_z);
204         }
205         if(sf & 4)
206         {
207                 WriteCoord(MSG_ENTITY, self.hook_end_x);
208                 WriteCoord(MSG_ENTITY, self.hook_end_y);
209                 WriteCoord(MSG_ENTITY, self.hook_end_z);
210         }
211         return TRUE;
212 }
213 .entity lgbeam;
214 .float prevlgfire;
215 void lgbeam_think()
216 {
217         vector endpos;
218         float oldsolid;
219
220         self.owner.prevlgfire = time;
221         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.lgbeam || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK)
222         {
223                 remove(self);
224                 return;
225         }
226
227         self.nextthink = time;
228
229         makevectors(self.owner.v_angle);
230         vector angle;
231         angle = v_forward;
232         // get effect origin
233         vector vecs, org;
234         if(self.owner.weaponentity.movedir_x > 0)
235                 vecs = self.owner.weaponentity.movedir;
236         else
237                 vecs = '0 0 0';
238         if(debug_shotorg != '0 0 0')
239                 vecs = debug_shotorg;
240         org = self.owner.origin + self.owner.view_ofs + v_forward * vecs_x + v_right * -vecs_y + v_up * vecs_z;
241
242         oldsolid = self.owner.dphitcontentsmask;
243         self.owner.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
244
245         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
246         endpos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
247         WarpZone_traceline_antilag(self.owner, org, endpos + 4 * normalize(endpos - org), MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
248
249         self.owner.dphitcontentsmask = oldsolid;
250
251         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
252                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
253
254         // apply the damage
255         if(trace_fraction < 1)
256         {
257                 vector force;
258                 force = angle * cvar("g_balance_electro_primary_force") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
259                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
260                 W_Plasma_TriggerCombo(trace_endpos, cvar("g_balance_electro_primary_comboradius"), self.owner);
261         }
262
263         // draw effect
264         if(org != self.hook_start)
265         {
266                 self.SendFlags |= 2;
267                 self.hook_start = org;
268         }
269         if(endpos != self.hook_end)
270         {
271                 self.SendFlags |= 4;
272                 self.hook_end = endpos;
273         }
274 }
275
276 // experimental lightning gun
277 void W_Electro_Attack3 (void)
278 {
279         // only play fire sound if 0.5 sec has passed since player let go the fire button
280         if(time - self.prevlgfire > 0.5)
281         {
282                 sound (self, CHAN_WEAPON, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
283         }
284
285         entity beam, oldself;
286
287         self.lgbeam = beam = spawn();
288         beam.solid = SOLID_NOT;
289         beam.think = lgbeam_think;
290         beam.owner = self;
291         beam.movetype = MOVETYPE_NONE;
292         beam.shot_spread = 0;
293         beam.bot_dodge = TRUE;
294         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
295         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
296
297         oldself = self;
298         self = beam;
299         self.think();
300         self = oldself;
301 }
302
303 void ElectroInit()
304 {
305         weapon_action(WEP_ELECTRO, WR_PRECACHE);
306         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
307         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
308         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
309         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
310 }
311
312 void spawnfunc_weapon_electro (void)
313 {
314         weapon_defaultspawnfunc(WEP_ELECTRO);
315 }
316
317 void w_electro_checkattack()
318 {
319         if(self.electro_count > 1)
320         if(self.BUTTON_ATCK2)
321         if(weapon_prepareattack(1, -1))
322         {
323                 W_Electro_Attack2();
324                 self.electro_count -= 1;
325                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
326                 return;
327         }
328
329         w_ready();
330 }
331
332 .float bot_secondary_electromooth;
333 .float BUTTON_ATCK_prev;
334 float w_electro(float req)
335 {
336         if (req == WR_AIM)
337         {
338                 self.BUTTON_ATCK=FALSE;
339                 self.BUTTON_ATCK2=FALSE;
340                 if(vlen(self.origin-self.enemy.origin) > 1000)
341                         self.bot_secondary_electromooth = 0;
342                 if(self.bot_secondary_electromooth == 0)
343                 {
344                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
345                         {
346                                 self.BUTTON_ATCK = TRUE;
347                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
348                         }
349                 }
350                 else
351                 {
352                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
353                         {
354                                 self.BUTTON_ATCK2 = TRUE;
355                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
356                         }
357                 }
358         }
359         else if (req == WR_THINK)
360         {
361                 if (self.BUTTON_ATCK)
362                 {
363                         if (weapon_prepareattack(0, (cvar("g_balance_electro_lightning") ? 0 : cvar("g_balance_electro_primary_refire"))))
364                         {
365                                 if(cvar("g_balance_electro_lightning"))
366                                 {
367                                         if (self.BUTTON_ATCK_prev == 0)
368                                         {
369                                                 W_Electro_Attack3();
370                                         }
371                                         self.BUTTON_ATCK_prev = 1;
372                                 }
373                                 else
374                                 {
375                                         W_Electro_Attack();
376                                 }
377                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
378                         }
379                 } else {
380                         self.BUTTON_ATCK_prev = 0;
381                 }
382
383                 if (self.BUTTON_ATCK2)
384                 if (time >= self.electro_secondarytime)
385                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
386                 {
387                         W_Electro_Attack2();
388                         self.electro_count = cvar("g_balance_electro_secondary_count");
389                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
390                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
391                 }
392         }
393         else if (req == WR_PRECACHE)
394         {
395                 precache_model ("models/weapons/g_electro.md3");
396                 precache_model ("models/weapons/v_electro.md3");
397                 precache_model ("models/weapons/h_electro.iqm");
398                 precache_sound ("weapons/electro_bounce.wav");
399                 precache_sound ("weapons/electro_fire.wav");
400                 precache_sound ("weapons/electro_fire2.wav");
401                 precache_sound ("weapons/electro_impact.wav");
402                 precache_sound ("weapons/electro_impact_combo.wav");
403                 if(cvar("g_balance_electro_lightning"))
404                 {
405                         precache_sound ("weapons/lgbeam_fire.wav");
406                 }
407         }
408         else if (req == WR_SETUP)
409                 weapon_setup(WEP_ELECTRO);
410         else if (req == WR_CHECKAMMO1)
411         {
412                 if(cvar("g_balance_electro_lightning"))
413                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo") * cvar("g_balance_electro_primary_refire");
414                 else
415                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
416         }
417         else if (req == WR_CHECKAMMO2)
418                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
419         else if (req == WR_RESETPLAYER)
420         {
421                 self.electro_secondarytime = time;
422         }
423         return TRUE;
424 };
425 #endif
426 #ifdef CSQC
427 float w_electro(float req)
428 {
429         if(req == WR_IMPACTEFFECT)
430         {
431                 vector org2;
432                 org2 = w_org + w_backoff * 6;
433                 if(w_deathtype & HITTYPE_SECONDARY)
434                 {
435                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
436                         if(!w_issilent)
437                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
438                 }
439                 else
440                 {
441                         if(w_deathtype & HITTYPE_BOUNCE)
442                         {
443                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
444                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
445                                 if(!w_issilent)
446                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
447                         }
448                         else
449                         {
450                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
451                                 if(!w_issilent)
452                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
453                         }
454                 }
455         }
456         else if(req == WR_PRECACHE)
457         {
458                 precache_sound("weapons/electro_impact.wav");
459                 precache_sound("weapons/electro_impact_combo.wav");
460         }
461         else if (req == WR_SUICIDEMESSAGE)
462         {
463                 if(w_deathtype & HITTYPE_SECONDARY)
464                         w_deathtypestring = "could not remember where they put plasma";
465                 else
466                         w_deathtypestring = "played with plasma";
467         }
468         else if (req == WR_KILLMESSAGE)
469         {
470                 if(w_deathtype & HITTYPE_SECONDARY)
471                 {
472                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
473                                 w_deathtypestring = "just noticed #'s blue ball";
474                         else // unchecked: BOUNCE
475                                 w_deathtypestring = "got in touch with #'s blue ball";
476                 }
477                 else
478                 {
479                         if(w_deathtype & HITTYPE_BOUNCE) // combo
480                                 w_deathtypestring = "felt the electrifying air of #'s combo";
481                         else if(w_deathtype & HITTYPE_SPLASH)
482                                 w_deathtypestring = "got too close to #'s blue beam";
483                         else
484                                 w_deathtypestring = "was blasted by #'s blue beam";
485                 }
486         }
487         return TRUE;
488 }
489 #endif
490 #endif