qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '0 0 -4', '0 0 -4');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 .vector hook_start, hook_end;
 188 float lgbeam_send(entity to, float sf)
 189 {
 190         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
 191         sf = sf & 0x7F;
 192         if(sound_allowed(MSG_BROADCAST, self.owner))
 193                 sf |= 0x80;
 194         WriteByte(MSG_ENTITY, sf);
 195         if(sf & 1)
 196         {
 197                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 198         }
 199         if(sf & 2)
 200         {
 201                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 202                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 203                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 204         }
 205         if(sf & 4)
 206         {
 207                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 208                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 209                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 210         }
 211         return TRUE;
 212 }
 213 .entity lgbeam;
 214 .float prevlgfire;
 215 void lgbeam_think()
 216 {
 217         vector endpos;
 218         self.owner.prevlgfire = time;
 219         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.lgbeam || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK)
 220         {
 221                 remove(self);
 222                 return;
 223         }
 224
 225         self.nextthink = time;
 226
 227         makevectors(self.owner.v_angle);
 228         vector angle;
 229         angle = v_forward;
 230         // get effect origin
 231         vector vecs, org;
 232         if(self.owner.weaponentity.movedir_x > 0)
 233                 vecs = self.owner.weaponentity.movedir;
 234         else
 235                 vecs = '0 0 0';
 236         if(debug_shotorg != '0 0 0')
 237                 vecs = debug_shotorg;
 238         org = self.owner.origin + self.owner.view_ofs + v_forward * vecs_x + v_right * -vecs_y + v_up * vecs_z;
 239
 240         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 241         endpos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 242         WarpZone_traceline_antilag(self.owner, org, endpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 243
 244         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 245                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
 246
 247         // apply the damage
 248         if(trace_fraction < 1)
 249         {
 250                 vector force;
 251                 force = angle * cvar("g_balance_electro_primary_force") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
 252                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
 253                 W_Plasma_TriggerCombo(trace_endpos, cvar("g_balance_electro_primary_comboradius"), self.owner);
 254         }
 255
 256         // draw effect
 257         if(org != self.hook_start)
 258         {
 259                 self.SendFlags |= 2;
 260                 self.hook_start = org;
 261         }
 262         if(endpos != self.hook_end)
 263         {
 264                 self.SendFlags |= 4;
 265                 self.hook_end = endpos;
 266         }
 267 }
 268
 269 // experimental lightning gun
 270 void W_Electro_Attack3 (void)
 271 {
 272         // only play fire sound if 0.5 sec has passed since player let go the fire button
 273         if(time - self.prevlgfire > 0.5)
 274         {
 275                 sound (self, CHAN_WEAPON, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 276         }
 277
 278         entity beam, oldself;
 279
 280         self.lgbeam = beam = spawn();
 281         beam.solid = SOLID_NOT;
 282         beam.think = lgbeam_think;
 283         beam.owner = self;
 284         beam.movetype = MOVETYPE_NONE;
 285         beam.shot_spread = 0;
 286         beam.bot_dodge = TRUE;
 287         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 288         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 289
 290         oldself = self;
 291         self = beam;
 292         self.think();
 293         self = oldself;
 294 }
 295
 296 void ElectroInit()
 297 {
 298         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 299         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 300         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 301         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 302         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 303 }
 304
 305 void spawnfunc_weapon_electro (void)
 306 {
 307         weapon_defaultspawnfunc(WEP_ELECTRO);
 308 }
 309
 310 void w_electro_checkattack()
 311 {
 312         if(self.electro_count > 1)
 313         if(self.BUTTON_ATCK2)
 314         if(weapon_prepareattack(1, -1))
 315         {
 316                 W_Electro_Attack2();
 317                 self.electro_count -= 1;
 318                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 319                 return;
 320         }
 321
 322         w_ready();
 323 }
 324
 325 .float bot_secondary_electromooth;
 326 .float BUTTON_ATCK_prev;
 327 float w_electro(float req)
 328 {
 329         if (req == WR_AIM)
 330         {
 331                 self.BUTTON_ATCK=FALSE;
 332                 self.BUTTON_ATCK2=FALSE;
 333                 if(vlen(self.origin-self.enemy.origin) > 1000)
 334                         self.bot_secondary_electromooth = 0;
 335                 if(self.bot_secondary_electromooth == 0)
 336                 {
 337                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 338                         {
 339                                 self.BUTTON_ATCK = TRUE;
 340                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 341                         }
 342                 }
 343                 else
 344                 {
 345                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 346                         {
 347                                 self.BUTTON_ATCK2 = TRUE;
 348                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 349                         }
 350                 }
 351         }
 352         else if (req == WR_THINK)
 353         {
 354                 if (self.BUTTON_ATCK)
 355                 {
 356                         if (weapon_prepareattack(0, (cvar("g_balance_electro_lightning") ? 0 : cvar("g_balance_electro_primary_refire"))))
 357                         {
 358                                 if(cvar("g_balance_electro_lightning"))
 359                                 {
 360                                         if (self.BUTTON_ATCK_prev == 0)
 361                                         {
 362                                                 W_Electro_Attack3();
 363                                         }
 364                                         self.BUTTON_ATCK_prev = 1;
 365                                 }
 366                                 else
 367                                 {
 368                                         W_Electro_Attack();
 369                                 }
 370                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 371                         }
 372                 } else {
 373                         self.BUTTON_ATCK_prev = 0;
 374                 }
 375
 376                 if (self.BUTTON_ATCK2)
 377                 if (time >= self.electro_secondarytime)
 378                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 379                 {
 380                         W_Electro_Attack2();
 381                         self.electro_count = cvar("g_balance_electro_secondary_count");
 382                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 383                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 384                 }
 385         }
 386         else if (req == WR_PRECACHE)
 387         {
 388                 precache_model ("models/weapons/g_electro.md3");
 389                 precache_model ("models/weapons/v_electro.md3");
 390                 precache_model ("models/weapons/h_electro.iqm");
 391                 precache_sound ("weapons/electro_bounce.wav");
 392                 precache_sound ("weapons/electro_fire.wav");
 393                 precache_sound ("weapons/electro_fire2.wav");
 394                 precache_sound ("weapons/electro_impact.wav");
 395                 precache_sound ("weapons/electro_impact_combo.wav");
 396                 if(cvar("g_balance_electro_lightning"))
 397                 {
 398                         precache_sound ("weapons/lgbeam_fire.wav");
 399                 }
 400         }
 401         else if (req == WR_SETUP)
 402                 weapon_setup(WEP_ELECTRO);
 403         else if (req == WR_CHECKAMMO1)
 404         {
 405                 if(cvar("g_balance_electro_lightning"))
 406                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo") * cvar("g_balance_electro_primary_refire");
 407                 else
 408                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 409         }
 410         else if (req == WR_CHECKAMMO2)
 411                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 412         else if (req == WR_RESETPLAYER)
 413         {
 414                 self.electro_secondarytime = time;
 415         }
 416         return TRUE;
 417 };
 418 #endif
 419 #ifdef CSQC
 420 float w_electro(float req)
 421 {
 422         if(req == WR_IMPACTEFFECT)
 423         {
 424                 vector org2;
 425                 org2 = w_org + w_backoff * 6;
 426                 if(w_deathtype & HITTYPE_SECONDARY)
 427                 {
 428                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 429                         if(!w_issilent)
 430                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 431                 }
 432                 else
 433                 {
 434                         if(w_deathtype & HITTYPE_BOUNCE)
 435                         {
 436                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 437                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 438                                 if(!w_issilent)
 439                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 440                         }
 441                         else
 442                         {
 443                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 444                                 if(!w_issilent)
 445                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 446                         }
 447                 }
 448         }
 449         else if(req == WR_PRECACHE)
 450         {
 451                 precache_sound("weapons/electro_impact.wav");
 452                 precache_sound("weapons/electro_impact_combo.wav");
 453         }
 454         else if (req == WR_SUICIDEMESSAGE)
 455         {
 456                 if(w_deathtype & HITTYPE_SECONDARY)
 457                         w_deathtypestring = "could not remember where they put plasma";
 458                 else
 459                         w_deathtypestring = "played with plasma";
 460         }
 461         else if (req == WR_KILLMESSAGE)
 462         {
 463                 if(w_deathtype & HITTYPE_SECONDARY)
 464                 {
 465                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 466                                 w_deathtypestring = "just noticed #'s blue ball";
 467                         else // unchecked: BOUNCE
 468                                 w_deathtypestring = "got in touch with #'s blue ball";
 469                 }
 470                 else
 471                 {
 472                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 473                                 w_deathtypestring = "felt the electrifying air of #'s combo";
 474                         else if(w_deathtype & HITTYPE_SPLASH)
 475                                 w_deathtypestring = "got too close to #'s blue beam";
 476                         else
 477                                 w_deathtypestring = "was blasted by #'s blue beam";
 478                 }
 479         }
 480         return TRUE;
 481 }
 482 #endif
 483 #endif