qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '0 0 -4', '0 0 -4');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 .entity lgbeam;
 188 .float prevlgfire;
 189 void lgbeam_think()
 190 {
 191         self.owner.prevlgfire = time;
 192         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.lgbeam || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK)
 193         {
 194                 remove(self);
 195                 return;
 196         }
 197
 198         self.nextthink = time;
 199
 200         makevectors(self.owner.v_angle);
 201         vector angle;
 202         angle = v_forward;
 203
 204         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 205
 206         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 207                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
 208
 209         // apply the damage
 210         if(trace_fraction < 1)
 211         {
 212                 vector force;
 213                 force = angle * cvar("g_balance_electro_primary_force") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
 214                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
 215                 W_Plasma_TriggerCombo(trace_endpos, cvar("g_balance_electro_primary_comboradius"), self.owner);
 216         }
 217
 218         // draw effect
 219         vector vecs, org;
 220         if(self.owner.weaponentity.movedir_x > 0)
 221         {
 222                 vecs = self.owner.weaponentity.movedir;
 223                 vecs_y = -vecs_y;
 224         }
 225         else
 226                 vecs = '0 0 0';
 227         org = self.owner.origin + self.owner.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
 228
 229         // TODO turn into a csqc entity
 230         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
 231         WriteByte(MSG_BROADCAST, TE_CSQC_BEAM);
 232         WriteByte(MSG_BROADCAST, num_for_edict(self.owner));
 233         WriteByte(MSG_BROADCAST, sound_allowed(MSG_BROADCAST, self.owner) ? 1 : 2);
 234         WriteCoord(MSG_BROADCAST, trace_endpos_x);
 235         WriteCoord(MSG_BROADCAST, trace_endpos_y);
 236         WriteCoord(MSG_BROADCAST, trace_endpos_z);
 237         WriteCoord(MSG_BROADCAST, org_x);
 238         WriteCoord(MSG_BROADCAST, org_y);
 239         WriteCoord(MSG_BROADCAST, org_z);
 240 }
 241
 242 // experimental lightning gun
 243 void W_Electro_Attack3 (void)
 244 {
 245         // only play fire sound if 0.5 sec has passed since player let go the fire button
 246         if(time - self.prevlgfire > 0.5)
 247         {
 248                 sound (self, CHAN_WEAPON, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 249         }
 250
 251         entity beam, oldself;
 252
 253         self.lgbeam = beam = spawn();
 254         beam.solid = SOLID_NOT;
 255         beam.think = lgbeam_think;
 256         beam.owner = self;
 257         beam.movetype = MOVETYPE_NONE;
 258         beam.shot_spread = 0;
 259         beam.bot_dodge = TRUE;
 260         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 261
 262         oldself = self;
 263         self = beam;
 264         self.think();
 265         self = oldself;
 266 }
 267
 268 void ElectroInit()
 269 {
 270         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 271         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 272         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 273         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 274         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 275 }
 276
 277 void spawnfunc_weapon_electro (void)
 278 {
 279         weapon_defaultspawnfunc(WEP_ELECTRO);
 280 }
 281
 282 void w_electro_checkattack()
 283 {
 284         if(self.electro_count > 1)
 285         if(self.BUTTON_ATCK2)
 286         if(weapon_prepareattack(1, -1))
 287         {
 288                 W_Electro_Attack2();
 289                 self.electro_count -= 1;
 290                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 291                 return;
 292         }
 293
 294         w_ready();
 295 }
 296
 297 .float bot_secondary_electromooth;
 298 .float BUTTON_ATCK_prev;
 299 float w_electro(float req)
 300 {
 301         if (req == WR_AIM)
 302         {
 303                 self.BUTTON_ATCK=FALSE;
 304                 self.BUTTON_ATCK2=FALSE;
 305                 if(vlen(self.origin-self.enemy.origin) > 1000)
 306                         self.bot_secondary_electromooth = 0;
 307                 if(self.bot_secondary_electromooth == 0)
 308                 {
 309                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 310                         {
 311                                 self.BUTTON_ATCK = TRUE;
 312                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 313                         }
 314                 }
 315                 else
 316                 {
 317                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 318                         {
 319                                 self.BUTTON_ATCK2 = TRUE;
 320                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 321                         }
 322                 }
 323         }
 324         else if (req == WR_THINK)
 325         {
 326                 if (self.BUTTON_ATCK)
 327                 {
 328                         if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 329                         {
 330                                 if(cvar("g_balance_electro_lightning"))
 331                                 {
 332                                         if (self.BUTTON_ATCK_prev == 0)
 333                                         {
 334                                                 W_Electro_Attack3();
 335                                         }
 336                                         self.BUTTON_ATCK_prev = 1;
 337                                 }
 338                                 else
 339                                 {
 340                                         W_Electro_Attack();
 341                                 }
 342                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 343                         }
 344                 } else {
 345                         self.BUTTON_ATCK_prev = 0;
 346                 }
 347
 348                 if (self.BUTTON_ATCK2)
 349                 if (time >= self.electro_secondarytime)
 350                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 351                 {
 352                         W_Electro_Attack2();
 353                         self.electro_count = cvar("g_balance_electro_secondary_count");
 354                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 355                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 356                 }
 357         }
 358         else if (req == WR_PRECACHE)
 359         {
 360                 precache_model ("models/weapons/g_electro.md3");
 361                 precache_model ("models/weapons/v_electro.md3");
 362                 precache_model ("models/weapons/h_electro.iqm");
 363                 precache_sound ("weapons/electro_bounce.wav");
 364                 precache_sound ("weapons/electro_fire.wav");
 365                 precache_sound ("weapons/electro_fire2.wav");
 366                 precache_sound ("weapons/electro_impact.wav");
 367                 precache_sound ("weapons/electro_impact_combo.wav");
 368                 if(cvar("g_balance_electro_lightning"))
 369                 {
 370                         precache_sound ("weapons/lgbeam_fire.wav");
 371                 }
 372         }
 373         else if (req == WR_SETUP)
 374                 weapon_setup(WEP_ELECTRO);
 375         else if (req == WR_CHECKAMMO1)
 376         {
 377                 if(cvar("g_balance_electro_lightning"))
 378                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo") * cvar("g_balance_electro_primary_refire");
 379                 else
 380                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 381         }
 382         else if (req == WR_CHECKAMMO2)
 383                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 384         else if (req == WR_RESETPLAYER)
 385         {
 386                 self.electro_secondarytime = time;
 387         }
 388         return TRUE;
 389 };
 390 #endif
 391 #ifdef CSQC
 392 float w_electro(float req)
 393 {
 394         if(req == WR_IMPACTEFFECT)
 395         {
 396                 vector org2;
 397                 org2 = w_org + w_backoff * 6;
 398                 if(w_deathtype & HITTYPE_SECONDARY)
 399                 {
 400                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 401                         if(!w_issilent)
 402                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 403                 }
 404                 else
 405                 {
 406                         if(w_deathtype & HITTYPE_BOUNCE)
 407                         {
 408                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 409                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 410                                 if(!w_issilent)
 411                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 412                         }
 413                         else
 414                         {
 415                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 416                                 if(!w_issilent)
 417                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 418                         }
 419                 }
 420         }
 421         else if(req == WR_PRECACHE)
 422         {
 423                 precache_sound("weapons/electro_impact.wav");
 424                 precache_sound("weapons/electro_impact_combo.wav");
 425         }
 426         else if (req == WR_SUICIDEMESSAGE)
 427         {
 428                 if(w_deathtype & HITTYPE_SECONDARY)
 429                         w_deathtypestring = "could not remember where they put plasma";
 430                 else
 431                         w_deathtypestring = "played with plasma";
 432         }
 433         else if (req == WR_KILLMESSAGE)
 434         {
 435                 if(w_deathtype & HITTYPE_SECONDARY)
 436                 {
 437                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 438                                 w_deathtypestring = "just noticed #'s blue ball";
 439                         else // unchecked: BOUNCE
 440                                 w_deathtypestring = "got in touch with #'s blue ball";
 441                 }
 442                 else
 443                 {
 444                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 445                                 w_deathtypestring = "felt the electrifying air of #'s combo";
 446                         else if(w_deathtype & HITTYPE_SPLASH)
 447                                 w_deathtypestring = "got too close to #'s blue beam";
 448                         else
 449                                 w_deathtypestring = "was blasted by #'s blue beam";
 450                 }
 451         }
 452         return TRUE;
 453 }
 454 #endif
 455 #endif