qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '0 0 -4', '0 0 -4');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 .vector hook_start, hook_end;
 188 float lgbeam_send(entity to, float sf)
 189 {
 190         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
 191         sf = sf & 0x7F;
 192         if(sound_allowed(MSG_BROADCAST, self.owner))
 193                 sf |= 0x80;
 194         WriteByte(MSG_ENTITY, sf);
 195         if(sf & 1)
 196         {
 197                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 198                 WriteCoord(MSG_ENTITY, cvar("g_balance_electro_primary_range"));
 199         }
 200         if(sf & 2)
 201         {
 202                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 203                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 204                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 205         }
 206         if(sf & 4)
 207         {
 208                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 209                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 210                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 211         }
 212         return TRUE;
 213 }
 214 .entity lgbeam;
 215 .float prevlgfire;
 216 void lgbeam_think()
 217 {
 218         self.owner.prevlgfire = time;
 219         if (self != self.owner.lgbeam)
 220         {
 221                 remove(self);
 222                 return;
 223         }
 224         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK)
 225         {
 226                 if(self == self.owner.lgbeam)
 227                         self.owner.lgbeam = world;
 228                 remove(self);
 229                 return;
 230         }
 231
 232         self.nextthink = time;
 233
 234         makevectors(self.owner.v_angle);
 235
 236         float dt, f;
 237         dt = frametime;
 238         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 239         {
 240                 if(cvar("g_balance_electro_primary_ammo"))
 241                         dt = min(frametime, self.owner.ammo_cells / cvar("g_balance_electro_primary_ammo"));
 242                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
 243         }
 244
 245         W_SetupShot_Range(self.owner, TRUE, 0, "", cvar("g_balance_electro_primary_damage") * dt, cvar("g_balance_electro_primary_range"));
 246         WarpZone_traceline_antilag(self.owner, w_shotorg, w_shotend, MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
 247
 248         // apply the damage
 249         if(trace_ent)
 250         {
 251                 vector force;
 252                 force = w_shotdir * cvar("g_balance_electro_primary_force") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
 253
 254                 f = ExponentialFalloff(cvar("g_balance_electro_primary_falloff_mindist"), cvar("g_balance_electro_primary_falloff_maxdist"), cvar("g_balance_electro_primary_falloff_halflifedist"), vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 255
 256                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 257                 Damage_RecordDamage(self.owner, WEP_ELECTRO, cvar("g_balance_electro_primary_damage") * dt * f);
 258         }
 259         W_Plasma_TriggerCombo(trace_endpos, cvar("g_balance_electro_primary_comboradius"), self.owner);
 260
 261         // draw effect
 262         if(w_shotorg != self.hook_start)
 263         {
 264                 self.SendFlags |= 2;
 265                 self.hook_start = w_shotorg;
 266         }
 267         if(w_shotend != self.hook_end)
 268         {
 269                 self.SendFlags |= 4;
 270                 self.hook_end = w_shotend;
 271         }
 272 }
 273
 274 // experimental lightning gun
 275 void W_Electro_Attack3 (void)
 276 {
 277         // only play fire sound if 0.5 sec has passed since player let go the fire button
 278         if(time - self.prevlgfire > 0.5)
 279         {
 280                 sound (self, CHAN_WEAPON, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 281         }
 282
 283         entity beam, oldself;
 284
 285         self.lgbeam = beam = spawn();
 286         beam.solid = SOLID_NOT;
 287         beam.think = lgbeam_think;
 288         beam.owner = self;
 289         beam.movetype = MOVETYPE_NONE;
 290         beam.shot_spread = 0;
 291         beam.bot_dodge = TRUE;
 292         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 293         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 294
 295         oldself = self;
 296         self = beam;
 297         self.think();
 298         self = oldself;
 299 }
 300
 301 void ElectroInit()
 302 {
 303         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 304         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 305         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 306         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 307         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 308 }
 309
 310 void spawnfunc_weapon_electro (void)
 311 {
 312         weapon_defaultspawnfunc(WEP_ELECTRO);
 313 }
 314
 315 void w_electro_checkattack()
 316 {
 317         if(self.electro_count > 1)
 318         if(self.BUTTON_ATCK2)
 319         if(weapon_prepareattack(1, -1))
 320         {
 321                 W_Electro_Attack2();
 322                 self.electro_count -= 1;
 323                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 324                 return;
 325         }
 326
 327         w_ready();
 328 }
 329
 330 .float bot_secondary_electromooth;
 331 .float BUTTON_ATCK_prev;
 332 float w_electro(float req)
 333 {
 334         if (req == WR_AIM)
 335         {
 336                 self.BUTTON_ATCK=FALSE;
 337                 self.BUTTON_ATCK2=FALSE;
 338                 if(vlen(self.origin-self.enemy.origin) > 1000)
 339                         self.bot_secondary_electromooth = 0;
 340                 if(self.bot_secondary_electromooth == 0)
 341                 {
 342                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 343                         {
 344                                 self.BUTTON_ATCK = TRUE;
 345                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 346                         }
 347                 }
 348                 else
 349                 {
 350                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 351                         {
 352                                 self.BUTTON_ATCK2 = TRUE;
 353                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 354                         }
 355                 }
 356         }
 357         else if (req == WR_THINK)
 358         {
 359                 if (self.BUTTON_ATCK)
 360                 {
 361                         if (weapon_prepareattack(0, (cvar("g_balance_electro_lightning") ? 0 : cvar("g_balance_electro_primary_refire"))))
 362                         {
 363                                 if(cvar("g_balance_electro_lightning"))
 364                                 {
 365                                         if ((!self.lgbeam) || wasfreed(self.lgbeam))
 366                                         {
 367                                                 W_Electro_Attack3();
 368                                         }
 369                                         self.BUTTON_ATCK_prev = 1;
 370                                 }
 371                                 else
 372                                 {
 373                                         W_Electro_Attack();
 374                                 }
 375                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 376                         }
 377                 } else {
 378                         if(cvar("g_balance_electro_lightning"))
 379                         {
 380                                 if (self.BUTTON_ATCK_prev != 0)
 381                                 {
 382                                         ATTACK_FINISHED(self) = time + cvar("g_balance_electro_primary_refire") * W_WeaponRateFactor();
 383                                 }
 384                                 self.BUTTON_ATCK_prev = 0;
 385                         }
 386                 }
 387
 388                 if (self.BUTTON_ATCK2)
 389                 if (time >= self.electro_secondarytime)
 390                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 391                 {
 392                         W_Electro_Attack2();
 393                         self.electro_count = cvar("g_balance_electro_secondary_count");
 394                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 395                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 396                 }
 397         }
 398         else if (req == WR_PRECACHE)
 399         {
 400                 precache_model ("models/weapons/g_electro.md3");
 401                 precache_model ("models/weapons/v_electro.md3");
 402                 precache_model ("models/weapons/h_electro.iqm");
 403                 precache_sound ("weapons/electro_bounce.wav");
 404                 precache_sound ("weapons/electro_fire.wav");
 405                 precache_sound ("weapons/electro_fire2.wav");
 406                 precache_sound ("weapons/electro_impact.wav");
 407                 precache_sound ("weapons/electro_impact_combo.wav");
 408                 if(cvar("g_balance_electro_lightning"))
 409                 {
 410                         precache_sound ("weapons/lgbeam_fire.wav");
 411                 }
 412         }
 413         else if (req == WR_SETUP)
 414                 weapon_setup(WEP_ELECTRO);
 415         else if (req == WR_CHECKAMMO1)
 416         {
 417                 if(cvar("g_balance_electro_lightning"))
 418                         return !cvar("g_balance_electro_primary_ammo") || (self.ammo_cells > 0);
 419                 else
 420                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 421         }
 422         else if (req == WR_CHECKAMMO2)
 423                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 424         else if (req == WR_RESETPLAYER)
 425         {
 426                 self.electro_secondarytime = time;
 427         }
 428         return TRUE;
 429 };
 430 #endif
 431 #ifdef CSQC
 432 float w_electro(float req)
 433 {
 434         if(req == WR_IMPACTEFFECT)
 435         {
 436                 vector org2;
 437                 org2 = w_org + w_backoff * 6;
 438                 if(w_deathtype & HITTYPE_SECONDARY)
 439                 {
 440                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 441                         if(!w_issilent)
 442                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 443                 }
 444                 else
 445                 {
 446                         if(w_deathtype & HITTYPE_BOUNCE)
 447                         {
 448                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 449                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 450                                 if(!w_issilent)
 451                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 452                         }
 453                         else
 454                         {
 455                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 456                                 if(!w_issilent)
 457                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 458                         }
 459                 }
 460         }
 461         else if(req == WR_PRECACHE)
 462         {
 463                 precache_sound("weapons/electro_impact.wav");
 464                 precache_sound("weapons/electro_impact_combo.wav");
 465         }
 466         else if (req == WR_SUICIDEMESSAGE)
 467         {
 468                 if(w_deathtype & HITTYPE_SECONDARY)
 469                         w_deathtypestring = "%s could not remember where they put plasma";
 470                 else
 471                         w_deathtypestring = "%s played with plasma";
 472         }
 473         else if (req == WR_KILLMESSAGE)
 474         {
 475                 if(w_deathtype & HITTYPE_SECONDARY)
 476                 {
 477                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 478                                 w_deathtypestring = "%s just noticed %s's blue ball";
 479                         else // unchecked: BOUNCE
 480                                 w_deathtypestring = "%s got in touch with %s's blue ball";
 481                 }
 482                 else
 483                 {
 484                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 485                                 w_deathtypestring = "%s felt the electrifying air of %s's combo";
 486                         else if(w_deathtype & HITTYPE_SPLASH)
 487                                 w_deathtypestring = "%s got too close to %s's blue beam";
 488                         else
 489                                 w_deathtypestring = "%s was blasted by %s's blue beam";
 490                 }
 491         }
 492         return TRUE;
 493 }
 494 #endif
 495 #endif