qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '0 0 -3', '0 0 -3');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 .entity lgbeam, exteriorlgbeam;
 188 void lgbeam_think()
 189 {
 190         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.lgbeam || self.owner.BUTTON_ATCK == 0)
 191         {
 192                 remove(self);
 193                 return;
 194         }
 195
 196         self.nextthink = time;
 197
 198         makevectors(self.owner.v_angle);
 199         vector angle;
 200         angle = v_forward;
 201
 202         vector force;
 203         force = angle * cvar("g_balance_electro_primary_force");
 204
 205         traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 206
 207         self.scale = vlen(self.owner.origin - trace_endpos) / 256 * (0.75 + 0.75 * random());
 208 }
 209
 210 void exteriorlgbeam_think()
 211 {
 212         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.exteriorlgbeam || self.owner.BUTTON_ATCK == 0)
 213         {
 214                 sound (self, CHAN_PROJECTILE, "sound/misc/null.wav", VOL_BASE, ATTN_NORM);
 215                 remove(self);
 216                 return;
 217         }
 218
 219         if (time - self.shot_spread + random() * 0.2 > 0)
 220         {
 221                 self.shot_spread = time + 2;
 222                 sound (self, CHAN_PROJECTILE, "turrets/phaser.wav", VOL_BASE, ATTN_NORM);
 223         }
 224
 225         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 226                 self.ammo_cells = max(0, self.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
 227
 228         self.nextthink = time;
 229
 230         makevectors(self.owner.v_angle);
 231         vector angle;
 232         angle = v_forward;
 233
 234         traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 235
 236         // apply the damage
 237         if(trace_fraction < 1)
 238         {
 239                 vector force;
 240                 force = angle * cvar("g_balance_electro_primary_force") + trace_ent.velocity * cvar("g_balance_electro_primary_velocityfactor") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
 241                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
 242         }
 243
 244         self.angles = '0 0 0';
 245         self.scale = vlen(gettaginfo(self, 0) - trace_endpos) / 256 * (0.75 + 0.75 * random());
 246
 247         // v_forward, v_right, v_up now are the ACTUAL directions
 248         // express self.angles in terms of them to aim at target!
 249         self.angles = vectoangles('1 0 0' * (angle * v_forward) + '0 -1 0' * (angle * v_right) + '0 0 1' * (angle * v_up));
 250 }
 251
 252 // experimental lightning gun
 253 void W_Electro_Attack3 (void)
 254 {
 255         entity beam, oldself;
 256
 257         self.lgbeam = beam = spawn();
 258         setmodel(beam,"models/turrets/phaser_beam.md3");
 259         beam.effects = EF_LOWPRECISION;
 260         beam.solid = SOLID_NOT;
 261         beam.think = lgbeam_think;
 262         beam.owner = self;
 263         beam.movetype = MOVETYPE_NONE;
 264         if(gettagindex(self.weaponentity, "shot"))
 265                 setattachment(beam, self.weaponentity, "shot");
 266         else
 267                 setattachment(beam, self.weaponentity, "tag_shot");
 268
 269         oldself = self;
 270         self = beam;
 271         self.think();
 272         self = oldself;
 273
 274         self.exteriorlgbeam = beam = spawn();
 275         setmodel(beam,"models/turrets/phaser_beam.md3");
 276         beam.effects = EF_LOWPRECISION;
 277         beam.solid = SOLID_NOT;
 278         beam.think = exteriorlgbeam_think;
 279         beam.owner = self;
 280         beam.movetype = MOVETYPE_NONE;
 281         //beam.viewmodelforclient = self;
 282         if(self.weaponentity.oldorigin_x > 0)
 283         {
 284                 setattachment(beam, self.exteriorweaponentity, "");
 285                 setorigin(beam, self.weaponentity.oldorigin);
 286         }
 287         else
 288         {
 289                 if(gettagindex(self.exteriorweaponentity, "shot"))
 290                         setattachment(beam, self.exteriorweaponentity, "shot");
 291                 else
 292                         setattachment(beam, self.exteriorweaponentity, "tag_shot");
 293         }
 294
 295         beam.shot_spread = 0;
 296         beam.bot_dodge = TRUE;
 297         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 298
 299         oldself = self;
 300         self = beam;
 301         self.think();
 302         self = oldself;
 303 }
 304
 305 void spawnfunc_weapon_electro (void)
 306 {
 307         weapon_defaultspawnfunc(WEP_ELECTRO);
 308 }
 309
 310 void w_electro_checkattack()
 311 {
 312         if(self.electro_count > 1)
 313         if(self.BUTTON_ATCK2)
 314         if(weapon_prepareattack(1, -1))
 315         {
 316                 W_Electro_Attack2();
 317                 self.electro_count -= 1;
 318                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 319                 return;
 320         }
 321
 322         w_ready();
 323 }
 324
 325 .float bot_secondary_electromooth;
 326 .float BUTTON_ATCK_prev;
 327 float w_electro(float req)
 328 {
 329         if (req == WR_AIM)
 330         {
 331                 self.BUTTON_ATCK=FALSE;
 332                 self.BUTTON_ATCK2=FALSE;
 333                 if(vlen(self.origin-self.enemy.origin) > 1000)
 334                         self.bot_secondary_electromooth = 0;
 335                 if(self.bot_secondary_electromooth == 0)
 336                 {
 337                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 338                         {
 339                                 self.BUTTON_ATCK = TRUE;
 340                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 341                         }
 342                 }
 343                 else
 344                 {
 345                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 346                         {
 347                                 self.BUTTON_ATCK2 = TRUE;
 348                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 349                         }
 350                 }
 351         }
 352         else if (req == WR_THINK)
 353         {
 354                 if (self.BUTTON_ATCK)
 355                 {
 356                         if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 357                         {
 358                                 if(cvar("g_balance_electro_lightning"))
 359                                 {
 360                                         if (self.BUTTON_ATCK_prev == 0)
 361                                         {
 362                                                 W_Electro_Attack3();
 363                                         }
 364                                         self.BUTTON_ATCK_prev = 1;
 365                                 }
 366                                 else
 367                                 {
 368                                         W_Electro_Attack();
 369                                 }
 370                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 371                         }
 372                 } else {
 373                         self.BUTTON_ATCK_prev = 0;
 374                 }
 375
 376                 if (self.BUTTON_ATCK2)
 377                 if (time >= self.electro_secondarytime)
 378                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 379                 {
 380                         W_Electro_Attack2();
 381                         self.electro_count = cvar("g_balance_electro_secondary_count");
 382                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 383                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 384                 }
 385         }
 386         else if (req == WR_PRECACHE)
 387         {
 388                 precache_model ("models/weapons/g_electro.md3");
 389                 precache_model ("models/weapons/v_electro.md3");
 390                 precache_model ("models/weapons/h_electro.iqm");
 391                 precache_sound ("weapons/electro_bounce.wav");
 392                 precache_sound ("weapons/electro_fire.wav");
 393                 precache_sound ("weapons/electro_fire2.wav");
 394                 precache_sound ("weapons/electro_impact.wav");
 395                 precache_sound ("weapons/electro_impact_combo.wav");
 396                 if(cvar("g_balance_electro_lightning"))
 397                         precache_sound ("weapons/crylink_fire2.wav");
 398         }
 399         else if (req == WR_SETUP)
 400                 weapon_setup(WEP_ELECTRO);
 401         else if (req == WR_CHECKAMMO1)
 402                 return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 403         else if (req == WR_CHECKAMMO2)
 404                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 405         else if (req == WR_RESETPLAYER)
 406         {
 407                 self.electro_secondarytime = time;
 408         }
 409         return TRUE;
 410 };
 411 #endif
 412 #ifdef CSQC
 413 float w_electro(float req)
 414 {
 415         if(req == WR_IMPACTEFFECT)
 416         {
 417                 vector org2;
 418                 org2 = w_org + w_backoff * 6;
 419                 if(w_deathtype & HITTYPE_SECONDARY)
 420                 {
 421                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 422                         if(!w_issilent)
 423                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 424                 }
 425                 else
 426                 {
 427                         if(w_deathtype & HITTYPE_BOUNCE)
 428                         {
 429                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 430                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 431                                 if(!w_issilent)
 432                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 433                         }
 434                         else
 435                         {
 436                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 437                                 if(!w_issilent)
 438                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 439                         }
 440                 }
 441         }
 442         else if(req == WR_PRECACHE)
 443         {
 444                 precache_sound("weapons/electro_impact.wav");
 445                 precache_sound("weapons/electro_impact_combo.wav");
 446         }
 447         else if (req == WR_SUICIDEMESSAGE)
 448         {
 449                 if(w_deathtype & HITTYPE_SECONDARY)
 450                         w_deathtypestring = "could not remember where they put plasma";
 451                 else
 452                         w_deathtypestring = "played with plasma";
 453         }
 454         else if (req == WR_KILLMESSAGE)
 455         {
 456                 if(w_deathtype & HITTYPE_SECONDARY)
 457                 {
 458                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 459                                 w_deathtypestring = "just noticed #'s blue ball";
 460                         else // unchecked: BOUNCE
 461                                 w_deathtypestring = "got in touch with #'s blue ball";
 462                 }
 463                 else
 464                 {
 465                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 466                                 w_deathtypestring = "felt the electrifying air of #'s combo";
 467                         else if(w_deathtype & HITTYPE_SPLASH)
 468                                 w_deathtypestring = "got too close to #'s blue beam";
 469                         else
 470                                 w_deathtypestring = "was blasted by #'s blue beam";
 471                 }
 472         }
 473         return TRUE;
 474 }
 475 #endif
 476 #endif