qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", "Mortar");
   3 #else
   4 #ifdef SVQC
   5 void W_Grenade_Explode (void)
   6 {
   7         if(other.takedamage == DAMAGE_AIM)
   8                 if(other.classname == "player")
   9                         if(IsDifferentTeam(self.owner, other))
  10                                 if(other.deadflag == DEAD_NO)
  11                                         if(IsFlying(other))
  12                                                 AnnounceTo(self.owner, "airshot");
  13
  14         self.event_damage = SUB_Null;
  15         self.takedamage = DAMAGE_NO;
  16         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  17
  18         remove (self);
  19 }
  20
  21 void W_Grenade_Explode2 (void)
  22 {
  23         if(other.takedamage == DAMAGE_AIM)
  24                 if(other.classname == "player")
  25                         if(IsDifferentTeam(self.owner, other))
  26                                 if(IsFlying(other))
  27                                         AnnounceTo(self.owner, "airshot");
  28
  29         self.event_damage = SUB_Null;
  30         self.takedamage = DAMAGE_NO;
  31         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  32
  33         remove (self);
  34 }
  35
  36 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  37 {
  38         if (self.health <= 0)
  39                 return;
  40         self.health = self.health - damage;
  41         if (self.health <= 0)
  42         {
  43                 W_PrepareExplosionByDamage(attacker, self.think);
  44         }
  45 }
  46
  47 void W_Grenade_Touch1 (void)
  48 {
  49         PROJECTILE_TOUCH;
  50         if(cvar("g_balance_grenadelauncher_primary_sticky") && other.takedamage != DAMAGE_AIM)
  51         {
  52                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
  53
  54                 // let it stick whereever it is
  55                 self.velocity = '0 0 0';
  56                 self.movetype = MOVETYPE_NONE; // also disables gravity
  57                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
  58                 UpdateCSQCProjectile(self);
  59
  60                 // do not respond to any more touches
  61                 self.solid = SOLID_NOT;
  62
  63                 self.nextthink = min(self.nextthink, time + cvar("g_balance_grenadelauncher_primary_lifetime2"));
  64         }
  65         else
  66                 W_Grenade_Explode ();
  67 }
  68
  69 void W_Grenade_Touch2 (void)
  70 {
  71         PROJECTILE_TOUCH;
  72         if (other.takedamage == DAMAGE_AIM)
  73         {
  74                 self.use ();
  75         }
  76         else
  77         {
  78                 float r;
  79                 r = random() * 6;
  80                 if(r < 1)
  81                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  82                 else if(r < 2)
  83                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  84                 else if(r < 3)
  85                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  86                 else if(r < 4)
  87                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  88                 else if(r < 5)
  89                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  90                 else
  91                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  92                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  93         }
  94 }
  95
  96 void W_Grenade_Attack (void)
  97 {
  98         local entity gren;
  99
 100         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 101                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
 102         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav", cvar("g_balance_grenadelauncher_primary_damage"));
 103         w_shotdir = v_forward; // no TrueAim for grenades please
 104
 105         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 106
 107         gren = spawn ();
 108         gren.owner = self;
 109         gren.classname = "grenade";
 110         gren.bot_dodge = TRUE;
 111         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
 112         gren.movetype = MOVETYPE_BOUNCE;
 113         PROJECTILE_MAKETRIGGER(gren);
 114         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 115         setorigin(gren, w_shotorg);
 116         setsize(gren, '0 0 -3', '0 0 -3');
 117
 118         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
 119         gren.think = adaptor_think2use_hittype_splash;
 120         gren.use = W_Grenade_Explode;
 121         gren.touch = W_Grenade_Touch1;
 122
 123         gren.takedamage = DAMAGE_YES;
 124         gren.health = cvar("g_balance_grenadelauncher_primary_health");
 125         gren.event_damage = W_Grenade_Damage;
 126         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 127
 128         gren.angles = vectoangles (gren.velocity);
 129         gren.flags = FL_PROJECTILE;
 130
 131         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 132 }
 133
 134 void W_Grenade_Attack2 (void)
 135 {
 136         local entity gren;
 137
 138         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 139                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 140         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav", cvar("g_balance_grenadelauncher_secondary_damage"));
 141         w_shotdir = v_forward; // no TrueAim for grenades please
 142
 143         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 144
 145         gren = spawn ();
 146         gren.owner = self;
 147         gren.classname = "grenade";
 148         gren.bot_dodge = TRUE;
 149         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 150         gren.movetype = MOVETYPE_BOUNCE;
 151         gren.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
 152         gren.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
 153         PROJECTILE_MAKETRIGGER(gren);
 154         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 155         setorigin(gren, w_shotorg);
 156         setsize(gren, '0 0 -3', '0 0 -3');
 157
 158         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 159         gren.think = adaptor_think2use_hittype_splash;
 160         gren.use = W_Grenade_Explode2;
 161         gren.touch = W_Grenade_Touch2;
 162
 163         gren.takedamage = DAMAGE_YES;
 164         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 165         gren.damageforcescale = cvar("g_balance_grenadelauncher_secondary_damageforcescale");
 166         gren.event_damage = W_Grenade_Damage;
 167         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 168
 169         gren.angles = vectoangles (gren.velocity);
 170         gren.flags = FL_PROJECTILE;
 171
 172         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 173 }
 174
 175 void spawnfunc_weapon_grenadelauncher (void)
 176 {
 177         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 178 }
 179
 180 .float bot_secondary_grenademooth;
 181 float w_glauncher(float req)
 182 {
 183         if (req == WR_AIM)
 184         {
 185                 self.BUTTON_ATCK = FALSE;
 186                 self.BUTTON_ATCK2 = FALSE;
 187                 if (self.bot_secondary_grenademooth == 0)
 188                 {
 189                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 190                         {
 191                                 self.BUTTON_ATCK = TRUE;
 192                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 193                         }
 194                 }
 195                 else
 196                 {
 197                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 198                         {
 199                                 self.BUTTON_ATCK2 = TRUE;
 200                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 201                         }
 202                 }
 203         }
 204         else if (req == WR_THINK)
 205         {
 206                 if (self.BUTTON_ATCK)
 207                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 208                 {
 209                         if(cvar("g_balance_grenadelauncher_primary2secondary"))
 210                                 W_Grenade_Attack2();
 211                         else
 212                                 W_Grenade_Attack();
 213                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 214                 }
 215                 if (self.BUTTON_ATCK2 && !cvar("g_balance_grenadelauncher_primary2secondary"))
 216                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 217                 {
 218                         W_Grenade_Attack2();
 219                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 220                 }
 221         }
 222         else if (req == WR_PRECACHE)
 223         {
 224                 precache_model ("models/weapons/g_gl.md3");
 225                 precache_model ("models/weapons/v_gl.md3");
 226                 precache_model ("models/weapons/h_gl.iqm");
 227                 precache_sound ("weapons/grenade_bounce1.wav");
 228                 precache_sound ("weapons/grenade_bounce2.wav");
 229                 precache_sound ("weapons/grenade_bounce3.wav");
 230                 precache_sound ("weapons/grenade_bounce4.wav");
 231                 precache_sound ("weapons/grenade_bounce5.wav");
 232                 precache_sound ("weapons/grenade_bounce6.wav");
 233                 precache_sound ("weapons/grenade_stick.wav");
 234                 precache_sound ("weapons/grenade_fire.wav");
 235         }
 236         else if (req == WR_SETUP)
 237                 weapon_setup(WEP_GRENADE_LAUNCHER);
 238         else if (req == WR_CHECKAMMO1)
 239                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 240         else if (req == WR_CHECKAMMO2)
 241                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 242         return TRUE;
 243 };
 244 #endif
 245 #ifdef CSQC
 246 float w_glauncher(float req)
 247 {
 248         if(req == WR_IMPACTEFFECT)
 249         {
 250                 vector org2;
 251                 org2 = w_org + w_backoff * 12;
 252                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 253                 if(!w_issilent)
 254                         sound(self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 255         }
 256         else if(req == WR_PRECACHE)
 257         {
 258                 precache_sound("weapons/grenade_impact.wav");
 259         }
 260         else if (req == WR_SUICIDEMESSAGE)
 261         {
 262                 if(w_deathtype & HITTYPE_SECONDARY)
 263                         w_deathtypestring = "tried out his own grenade";
 264                 else
 265                         w_deathtypestring = "detonated";
 266         }
 267         else if (req == WR_KILLMESSAGE)
 268         {
 269                 if(w_deathtype & HITTYPE_SPLASH)
 270                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 271                                 w_deathtypestring = "didn't see #'s grenade";
 272                         else // unchecked: SECONDARY
 273                                 w_deathtypestring = "almost dodged #'s grenade";
 274                 else // unchecked: SECONDARY, BOUNCE
 275                         w_deathtypestring = "ate #'s grenade";
 276         }
 277         return TRUE;
 278 }
 279 #endif
 280 #endif