qcsrc/server/w_hlac.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ HLAC,
   4 /* function  */ w_hlac,
   5 /* ammotype  */ IT_CELLS,
   6 /* impulse   */ 6,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* model     */ "hlac",
  10 /* shortname */ "hlac",
  11 /* fullname  */ _("Heavy Laser Assault Cannon")
  12 );
  13 #else
  14 #ifdef SVQC
  15
  16 void W_HLAC_Touch (void)
  17 {
  18         PROJECTILE_TOUCH;
  19
  20         self.event_damage = func_null;
  21
  22         if(self.projectiledeathtype & HITTYPE_SECONDARY)
  23                 RadiusDamage (self, self.realowner, autocvar_g_balance_hlac_secondary_damage, autocvar_g_balance_hlac_secondary_edgedamage, autocvar_g_balance_hlac_secondary_radius, world, autocvar_g_balance_hlac_secondary_force, self.projectiledeathtype, other);
  24         else
  25                 RadiusDamage (self, self.realowner, autocvar_g_balance_hlac_primary_damage, autocvar_g_balance_hlac_primary_edgedamage, autocvar_g_balance_hlac_primary_radius, world, autocvar_g_balance_hlac_primary_force, self.projectiledeathtype, other);
  26
  27         remove (self);
  28 }
  29
  30 void W_HLAC_Attack (void)
  31 {
  32         entity missile;
  33     float spread;
  34
  35         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_reload_ammo);
  36
  37     spread = autocvar_g_balance_hlac_primary_spread_min + (autocvar_g_balance_hlac_primary_spread_add * self.misc_bulletcounter);
  38     spread = min(spread,autocvar_g_balance_hlac_primary_spread_max);
  39     if(self.crouch)
  40         spread = spread * autocvar_g_balance_hlac_primary_spread_crouchmod;
  41
  42         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_A, autocvar_g_balance_hlac_primary_damage);
  43         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  44         if (!autocvar_g_norecoil)
  45         {
  46                 self.punchangle_x = random () - 0.5;
  47                 self.punchangle_y = random () - 0.5;
  48         }
  49
  50         missile = spawn ();
  51         missile.owner = missile.realowner = self;
  52         missile.classname = "hlacbolt";
  53         missile.bot_dodge = TRUE;
  54
  55     missile.bot_dodgerating = autocvar_g_balance_hlac_primary_damage;
  56
  57         missile.movetype = MOVETYPE_FLY;
  58         PROJECTILE_MAKETRIGGER(missile);
  59
  60         setorigin (missile, w_shotorg);
  61         setsize(missile, '0 0 0', '0 0 0');
  62
  63         W_SetupProjectileVelocity(missile, autocvar_g_balance_hlac_primary_speed, spread);
  64         //missile.angles = vectoangles (missile.velocity); // csqc
  65
  66         missile.touch = W_HLAC_Touch;
  67         missile.think = SUB_Remove;
  68
  69     missile.nextthink = time + autocvar_g_balance_hlac_primary_lifetime;
  70
  71         missile.flags = FL_PROJECTILE;
  72         missile.projectiledeathtype = WEP_HLAC;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_HLAC_Attack2f (void)
  80 {
  81         entity missile;
  82     float spread;
  83
  84     spread = autocvar_g_balance_hlac_secondary_spread;
  85
  86
  87     if(self.crouch)
  88         spread = spread * autocvar_g_balance_hlac_secondary_spread_crouchmod;
  89
  90         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_A, autocvar_g_balance_hlac_secondary_damage);
  91         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  92
  93         missile = spawn ();
  94         missile.owner = missile.realowner = self;
  95         missile.classname = "hlacbolt";
  96         missile.bot_dodge = TRUE;
  97
  98     missile.bot_dodgerating = autocvar_g_balance_hlac_secondary_damage;
  99
 100         missile.movetype = MOVETYPE_FLY;
 101         PROJECTILE_MAKETRIGGER(missile);
 102
 103         setorigin (missile, w_shotorg);
 104         setsize(missile, '0 0 0', '0 0 0');
 105
 106         W_SetupProjectileVelocity(missile, autocvar_g_balance_hlac_secondary_speed, spread);
 107         //missile.angles = vectoangles (missile.velocity); // csqc
 108
 109         missile.touch = W_HLAC_Touch;
 110         missile.think = SUB_Remove;
 111
 112     missile.nextthink = time + autocvar_g_balance_hlac_secondary_lifetime;
 113
 114         missile.flags = FL_PROJECTILE;
 115         missile.missile_flags = MIF_SPLASH;
 116         missile.projectiledeathtype = WEP_HLAC | HITTYPE_SECONDARY;
 117
 118         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
 119
 120         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 121 }
 122
 123 void W_HLAC_Attack2 (void)
 124 {
 125     float i;
 126
 127         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_hlac_secondary_ammo, autocvar_g_balance_hlac_reload_ammo);
 128
 129     for(i=autocvar_g_balance_hlac_secondary_shots;i>0;--i)
 130         W_HLAC_Attack2f();
 131
 132         if (!autocvar_g_norecoil)
 133         {
 134                 self.punchangle_x = random () - 0.5;
 135                 self.punchangle_y = random () - 0.5;
 136         }
 137 }
 138
 139 // weapon frames
 140 void HLAC_fire1_02()
 141 {
 142         if(self.weapon != self.switchweapon) // abort immediately if switching
 143         {
 144                 w_ready();
 145                 return;
 146         }
 147
 148         if (self.BUTTON_ATCK)
 149         {
 150                 if (!weapon_action(self.weapon, WR_CHECKAMMO1))
 151                 if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 152                 {
 153                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 154                         w_ready();
 155                         return;
 156                 }
 157
 158                 ATTACK_FINISHED(self) = time + autocvar_g_balance_hlac_primary_refire * W_WeaponRateFactor();
 159                 W_HLAC_Attack();
 160                 self.misc_bulletcounter = self.misc_bulletcounter + 1;
 161         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_refire, HLAC_fire1_02);
 162         }
 163         else
 164         {
 165                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_animtime, w_ready);
 166         }
 167 }
 168
 169 void spawnfunc_weapon_hlac (void)
 170 {
 171         weapon_defaultspawnfunc(WEP_HLAC);
 172 }
 173
 174 float w_hlac(float req)
 175 {
 176         float ammo_amount;
 177         if (req == WR_AIM)
 178         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hlac_primary_speed, 0, autocvar_g_balance_hlac_primary_lifetime, FALSE);
 179         else if (req == WR_THINK)
 180         {
 181                 if(autocvar_g_balance_hlac_reload_ammo && self.clip_load < min(autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_secondary_ammo)) // forced reload
 182                         weapon_action(self.weapon, WR_RELOAD);
 183                 else if (self.BUTTON_ATCK)
 184                 {
 185                         if (weapon_prepareattack(0, autocvar_g_balance_hlac_primary_refire))
 186                         {
 187                                 self.misc_bulletcounter = 0;
 188                                 W_HLAC_Attack();
 189                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_refire, HLAC_fire1_02);
 190                         }
 191                 }
 192
 193                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hlac_secondary)
 194                 {
 195                         if (weapon_prepareattack(1, autocvar_g_balance_hlac_secondary_refire))
 196                         {
 197                                 W_HLAC_Attack2();
 198                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hlac_secondary_animtime, w_ready);
 199                         }
 200                 }
 201         }
 202         else if (req == WR_PRECACHE)
 203         {
 204         precache_model ("models/weapons/g_hlac.md3");
 205                 precache_model ("models/weapons/v_hlac.md3");
 206                 precache_model ("models/weapons/h_hlac.iqm");
 207                 precache_sound ("weapons/lasergun_fire.wav");
 208                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 209
 210         }
 211         else if (req == WR_SETUP)
 212         {
 213                 weapon_setup(WEP_HLAC);
 214                 self.current_ammo = ammo_cells;
 215         }
 216         else if (req == WR_CHECKAMMO1)
 217         {
 218                 ammo_amount = self.ammo_cells >= autocvar_g_balance_hlac_primary_ammo;
 219                 ammo_amount += self.(weapon_load[WEP_HLAC]) >= autocvar_g_balance_hlac_primary_ammo;
 220                 return ammo_amount;
 221         }
 222         else if (req == WR_CHECKAMMO2)
 223         {
 224                 ammo_amount = self.ammo_cells >= autocvar_g_balance_hlac_secondary_ammo;
 225                 ammo_amount += self.(weapon_load[WEP_HLAC]) >= autocvar_g_balance_hlac_secondary_ammo;
 226                 return ammo_amount;
 227         }
 228         else if (req == WR_RELOAD)
 229         {
 230                 W_Reload(min(autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_secondary_ammo), autocvar_g_balance_hlac_reload_ammo, autocvar_g_balance_hlac_reload_time, "weapons/reload.wav");
 231         }
 232         else if (req == WR_SUICIDEMESSAGE)
 233         {
 234                 return WEAPON_HLAC_SUICIDE;
 235         }
 236         else if (req == WR_KILLMESSAGE)
 237         {
 238                 return WEAPON_HLAC_MURDER;
 239         }
 240         return TRUE;
 241 }
 242 #endif
 243 #ifdef CSQC
 244 float w_hlac(float req)
 245 {
 246         if(req == WR_IMPACTEFFECT)
 247         {
 248                 vector org2;
 249                 org2 = w_org + w_backoff * 6;
 250                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 251                 if(!w_issilent)
 252                         sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTEN_NORM);
 253         }
 254         else if(req == WR_PRECACHE)
 255         {
 256                 precache_sound("weapons/laserimpact.wav");
 257         }
 258         return TRUE;
 259 }
 260 #endif
 261 #endif