properly draw the hook through warpzones again too; fix interpolation issues
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_laser.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(LASER, w_laser, 0, 1, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, 0, "laser", "laser", "Laser");
3 #else
4 #ifdef SVQC
5 void(float imp) W_SwitchWeapon;
6
7 void W_Laser_Touch (void)
8 {
9         PROJECTILE_TOUCH;
10
11         self.event_damage = SUB_Null;
12         if (self.dmg)
13                 RadiusDamage (self, self.owner, cvar("g_balance_laser_secondary_damage"), cvar("g_balance_laser_secondary_edgedamage"), cvar("g_balance_laser_secondary_radius"), world, cvar("g_balance_laser_secondary_force"), self.projectiledeathtype, other);
14         else
15                 RadiusDamage (self, self.owner, cvar("g_balance_laser_primary_damage"), cvar("g_balance_laser_primary_edgedamage"), cvar("g_balance_laser_primary_radius"), world, cvar("g_balance_laser_primary_force"), self.projectiledeathtype, other);
16
17         remove (self);
18 }
19
20 void W_Laser_Think()
21 {
22         self.movetype = MOVETYPE_FLY;
23         self.think = SUB_Remove;
24         if (self.dmg)
25                 self.nextthink = time + cvar("g_balance_laser_secondary_lifetime");
26         else
27                 self.nextthink = time + cvar("g_balance_laser_primary_lifetime");
28         CSQCProjectile(self, TRUE, PROJECTILE_LASER, TRUE);
29 }
30
31 void W_Laser_Attack (float issecondary)
32 {
33         local entity missile;
34         vector s_forward;
35         float a;
36         float nodamage;
37
38         if(issecondary == 2) // minstanex shot
39                 nodamage = g_minstagib;
40         else
41                 nodamage = FALSE;
42
43         if (issecondary == 1)
44                 a = cvar("g_balance_laser_secondary_shotangle");
45         else
46                 a = cvar("g_balance_laser_primary_shotangle");
47         s_forward = v_forward * cos(a * DEG2RAD) + v_up * sin(a * DEG2RAD);
48
49         if(nodamage)
50                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", 0);
51         else if(issecondary == 1)
52                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", cvar("g_balance_laser_secondary_damage"));
53         else
54                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", cvar("g_balance_laser_primary_damage"));
55         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
56
57         missile = spawn ();
58         missile.owner = self;
59         missile.classname = "laserbolt";
60         missile.dmg = (issecondary == 1);
61         if(!nodamage)
62         {
63                 missile.bot_dodge = TRUE;
64                 if (issecondary == 1)
65                         missile.bot_dodgerating = cvar("g_balance_laser_secondary_damage");
66                 else
67                         missile.bot_dodgerating = cvar("g_balance_laser_primary_damage");
68         }
69
70         PROJECTILE_MAKETRIGGER(missile);
71         missile.projectiledeathtype = WEP_LASER;
72         if(issecondary == 1)
73                 missile.projectiledeathtype |= HITTYPE_SECONDARY;
74
75         setorigin (missile, w_shotorg);
76         setsize(missile, '0 0 0', '0 0 0');
77
78         if (issecondary == 1)
79                 W_SETUPPROJECTILEVELOCITY(missile, g_balance_laser_secondary);
80         else
81                 W_SETUPPROJECTILEVELOCITY(missile, g_balance_laser_primary);
82         missile.angles = vectoangles (missile.velocity);
83         //missile.glow_color = 250; // 244, 250
84         //missile.glow_size = 120;
85         missile.touch = W_Laser_Touch;
86
87         missile.flags = FL_PROJECTILE;
88
89         missile.think = W_Laser_Think;
90         if (issecondary == 1)
91                 missile.nextthink = time + cvar("g_balance_laser_secondary_delay");
92         else
93                 missile.nextthink = time + cvar("g_balance_laser_primary_delay");
94         if(time >= missile.nextthink)
95         {
96                 entity oldself;
97                 oldself = self;
98                 self = missile;
99                 self.think();
100                 self = oldself;
101         }
102 }
103
104 .vector hook_start, hook_end;
105 float gauntletbeam_send(entity to, float sf)
106 {
107         WriteByte(MSG_ENTITY, ENT_CLIENT_GAUNTLET);
108         sf = sf & 0x7F;
109         if(sound_allowed(MSG_BROADCAST, self.owner))
110                 sf |= 0x80;
111         WriteByte(MSG_ENTITY, sf);
112         if(sf & 1)
113         {
114                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
115         }
116         if(sf & 2)
117         {
118                 WriteCoord(MSG_ENTITY, self.hook_start_x);
119                 WriteCoord(MSG_ENTITY, self.hook_start_y);
120                 WriteCoord(MSG_ENTITY, self.hook_start_z);
121         }
122         if(sf & 4)
123         {
124                 WriteCoord(MSG_ENTITY, self.hook_end_x);
125                 WriteCoord(MSG_ENTITY, self.hook_end_y);
126                 WriteCoord(MSG_ENTITY, self.hook_end_z);
127         }
128         return TRUE;
129 }
130 .entity gauntletbeam;
131 .float prevgauntletfire;
132 void gauntletbeam_think()
133 {
134         vector endpos;
135         float damage, myforce, myradius;
136         if(self.cnt)
137         {
138                 damage = cvar("g_balance_laser_secondary_damage");
139                 myforce = cvar("g_balance_laser_secondary_force");
140                 myradius = cvar("g_balance_laser_secondary_radius");
141         }
142         else
143         {
144                 damage = cvar("g_balance_laser_primary_damage");
145                 myforce = cvar("g_balance_laser_primary_force");
146                 myradius = cvar("g_balance_laser_primary_radius");
147         }
148
149         self.owner.prevgauntletfire = time;
150         if (self.owner.weaponentity.state != WS_INUSE || self != self.owner.gauntletbeam || self.owner.deadflag != DEAD_NO || (!self.owner.BUTTON_ATCK2 && self.cnt) || (!self.owner.BUTTON_ATCK && !self.cnt))
151         {
152                 remove(self);
153                 return;
154         }
155
156         self.nextthink = time;
157
158         makevectors(self.owner.v_angle);
159         vector angle;
160         angle = v_forward;
161         // get effect origin
162         vector vecs, org;
163         if(self.owner.weaponentity.movedir_x > 0)
164                 vecs = self.owner.weaponentity.movedir;
165         else
166                 vecs = '0 0 0';
167         if(debug_shotorg != '0 0 0')
168                 vecs = debug_shotorg;
169         org = self.owner.origin + self.owner.view_ofs + v_forward * vecs_x + v_right * -vecs_y + v_up * vecs_z;
170         
171         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * myradius, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
172         endpos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
173         WarpZone_traceline_antilag(self.owner, org, endpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
174
175         // apply the damage
176         if(trace_fraction < 1)
177         {
178                 vector force;
179                 force = angle * myforce;
180                 Damage (trace_ent, self.owner, self.owner, damage * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
181         }
182
183         // draw effect
184         if(org != self.hook_start)
185         {
186                 self.SendFlags |= 2;
187                 self.hook_start = org;
188         }
189         if(endpos != self.hook_end)
190         {
191                 self.SendFlags |= 4;
192                 self.hook_end = endpos;
193         }
194 }
195
196 // experimental gauntlet
197 void W_Laser_Attack2 (float issecondary)
198 {
199         // only play fire sound if 0.5 sec has passed since player let go the fire button
200         if(time - self.prevgauntletfire > 0.5)
201         {
202                 sound (self, CHAN_WEAPON, "weapons/gauntlet_fire.wav", VOL_BASE, ATTN_NORM);
203         }
204
205         entity beam, oldself;
206
207         self.gauntletbeam = beam = spawn();
208         beam.solid = SOLID_NOT;
209         beam.think = gauntletbeam_think;
210         beam.owner = self;
211         beam.movetype = MOVETYPE_NONE;
212         beam.shot_spread = 0;
213         beam.bot_dodge = TRUE;
214         beam.bot_dodgerating = cvar("g_balance_laser_primary_damage");
215         beam.cnt = issecondary;
216         Net_LinkEntity(beam, FALSE, 0, gauntletbeam_send);
217
218         oldself = self;
219         self = beam;
220         self.think();
221         self = oldself;
222 }
223
224 void LaserInit()
225 {
226         weapon_action(WEP_LASER, WR_PRECACHE);
227         gauntlet_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 1);
228         gauntlet_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 2);
229         gauntlet_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 3);
230         gauntlet_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 4);
231 }
232
233 void spawnfunc_weapon_laser (void)
234 {
235         weapon_defaultspawnfunc(WEP_LASER);
236 }
237
238 float w_laser(float req)
239 {
240         local float r1;
241         local float r2;
242         if (req == WR_AIM)
243         {
244                 if(cvar("g_balance_laser_secondary"))
245                 {
246                         r1 = cvar("g_balance_laser_primary_damage");
247                         r2 = cvar("g_balance_laser_secondary_damage");
248                         if (random() * (r2 + r1) > r1)
249                                 self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_laser_secondary_speed"), 0, cvar("g_balance_laser_secondary_lifetime"), FALSE);
250                         else
251                                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
252                 }
253                 else
254                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
255         }
256         else if (req == WR_THINK)
257         {
258                 if (self.BUTTON_ATCK)
259                 if (weapon_prepareattack(0, cvar("g_balance_laser_primary_refire")))
260                 {
261                         if(cvar("g_balance_laser_primary_gauntlet"))
262                                 W_Laser_Attack2(0);
263                         else
264                                 W_Laser_Attack(0);
265                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_laser_primary_animtime"), w_ready);
266                 }
267                 if (self.BUTTON_ATCK2)
268                 {
269                         if(cvar("g_balance_laser_secondary"))
270                         {
271                                 if (weapon_prepareattack(0, cvar("g_balance_laser_secondary_refire")))
272                                 {
273                                         if(cvar("g_balance_laser_secondary_gauntlet"))
274                                                 W_Laser_Attack2(1);
275                                         else
276                                                 W_Laser_Attack(1);
277                                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_laser_secondary_animtime"), w_ready);
278                                 }
279                         }
280                         else
281                         {
282                                 if(self.switchweapon == WEP_LASER) // don't do this if already switching
283                                         W_SwitchWeapon (self.cnt);
284                         }
285                 }
286         }
287         else if (req == WR_PRECACHE)
288         {
289                 precache_model ("models/weapons/g_laser.md3");
290                 precache_model ("models/weapons/v_laser.md3");
291                 precache_model ("models/weapons/h_laser.iqm");
292                 precache_sound ("weapons/lasergun_fire.wav");
293                 precache_sound ("weapons/gauntlet_fire.wav");
294         }
295         else if (req == WR_SETUP)
296                 weapon_setup(WEP_LASER);
297         else if (req == WR_CHECKAMMO1)
298                 return TRUE;
299         else if (req == WR_CHECKAMMO2)
300                 return TRUE;
301         return TRUE;
302 };
303 #endif
304 #ifdef CSQC
305 float w_laser(float req)
306 {
307         if(req == WR_IMPACTEFFECT)
308         {
309                 vector org2;
310                 org2 = w_org + w_backoff * 6;
311                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
312                 if(!w_issilent)
313                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
314         }
315         else if(req == WR_PRECACHE)
316         {
317                 precache_sound("weapons/laserimpact.wav");
318         }
319         else if (req == WR_SUICIDEMESSAGE)
320                 w_deathtypestring = "lasered themself to hell";
321         else if (req == WR_KILLMESSAGE)
322         {
323                 w_deathtypestring = "was lasered to death by"; // unchecked: SPLASH
324         }
325         return TRUE;
326 }
327 #endif
328 #endif