qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(other.deadflag == DEAD_NO)
  60                                         if(IsFlying(other))
  61                                                 AnnounceTo(self.owner, "airshot");
  62
  63         self.event_damage = SUB_Null;
  64         self.takedamage = DAMAGE_NO;
  65
  66         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  67
  68         if (self.owner.weapon == WEP_MINE_LAYER)
  69         {
  70                 entity oldself;
  71                 oldself = self;
  72                 self = self.owner;
  73                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  74                 {
  75                         self.cnt = WEP_MINE_LAYER;
  76                         ATTACK_FINISHED(self) = time;
  77                         self.switchweapon = w_getbestweapon(self);
  78                 }
  79                 self = oldself;
  80         }
  81         self.owner.minelayer_mines -= 1;
  82         remove (self);
  83 }
  84
  85 void W_Mine_DoRemoteExplode ()
  86 {
  87         self.event_damage = SUB_Null;
  88         self.takedamage = DAMAGE_NO;
  89
  90         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  91
  92         if (self.owner.weapon == WEP_MINE_LAYER)
  93         {
  94                 entity oldself;
  95                 oldself = self;
  96                 self = self.owner;
  97                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  98                 {
  99                         self.cnt = WEP_MINE_LAYER;
 100                         ATTACK_FINISHED(self) = time;
 101                         self.switchweapon = w_getbestweapon(self);
 102                 }
 103                 self = oldself;
 104         }
 105         self.owner.minelayer_mines -= 1;
 106         remove (self);
 107 }
 108
 109 void W_Mine_RemoteExplode ()
 110 {
 111         if(self.owner.deadflag == DEAD_NO)
 112                 if((self.spawnshieldtime >= 0)
 113                         ? (time >= self.spawnshieldtime) // timer
 114                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 115                 )
 116                 {
 117                         W_Mine_DoRemoteExplode();
 118                 }
 119 }
 120
 121 void W_Mine_ProximityExplode ()
 122 {
 123         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 124         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 125         {
 126                 entity head;
 127                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 128                 while(head)
 129                 {
 130                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 131                                 return;
 132                         head = head.chain;
 133                 }
 134         }
 135
 136         self.mine_time = 0;
 137         W_Mine_Explode();
 138 }
 139
 140 float W_Mine_Count(entity e)
 141 {
 142         float minecount;
 143         entity mine;
 144         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == e)
 145                 minecount += 1;
 146
 147         return minecount;
 148 }
 149
 150 void W_Mine_Think (void)
 151 {
 152         entity head;
 153
 154         self.nextthink = time;
 155
 156         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 157         // TODO: replace this mine_trigger.wav sound with a real countdown
 158         if ((time > self.cnt) && (!self.mine_time))
 159         {
 160                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 161                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 162                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 163                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 164         }
 165
 166         // a player's mines shall explode if he disconnects or dies
 167         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 168         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 169         {
 170                 other = world;
 171                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 172                 W_Mine_Explode();
 173                 return;
 174         }
 175
 176         // set the mine for detonation when a foe gets close enough
 177         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 178         while(head)
 179         {
 180                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 181                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 182                 if(!self.mine_time)
 183                 {
 184                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 185                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 186                 }
 187                 head = head.chain;
 188         }
 189
 190         // explode if it's time to
 191         if(self.mine_time && time >= self.mine_time)
 192         {
 193                 W_Mine_ProximityExplode();
 194                 return;
 195         }
 196
 197         // remote detonation
 198         if (self.owner.weapon == WEP_MINE_LAYER)
 199         if (self.owner.deadflag == DEAD_NO)
 200         if (self.minelayer_detonate)
 201                 W_Mine_RemoteExplode();
 202 }
 203
 204 void W_Mine_Touch (void)
 205 {
 206         PROJECTILE_TOUCH;
 207         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 208                 W_Mine_Stick();
 209         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 210                 self.velocity = '0 0 0';
 211 }
 212
 213 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 214 {
 215         if (self.health <= 0)
 216                 return;
 217         self.health = self.health - damage;
 218         self.angles = vectoangles(self.velocity);
 219         if (self.health <= 0)
 220                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 221 }
 222
 223 void W_Mine_Attack (void)
 224 {
 225         entity mine;
 226         entity flash;
 227
 228         // scan how many mines we placed, and return if we reached our limit
 229         if(autocvar_g_balance_minelayer_limit)
 230         {
 231
 232                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 233                 {
 234                         // the refire delay keeps this message from being spammed
 235                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 236                         play2(self, "weapons/unavailable.wav");
 237                         return;
 238                 }
 239         }
 240
 241         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 242
 243         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 244         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 245
 246         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 247         mine.owner = self;
 248         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 249                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 250         else
 251                 mine.spawnshieldtime = -1;
 252         mine.classname = "mine";
 253         mine.bot_dodge = TRUE;
 254         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 255
 256         mine.takedamage = DAMAGE_YES;
 257         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 258         mine.health = autocvar_g_balance_minelayer_health;
 259         mine.event_damage = W_Mine_Damage;
 260
 261         mine.movetype = MOVETYPE_TOSS;
 262         PROJECTILE_MAKETRIGGER(mine);
 263         mine.projectiledeathtype = WEP_MINE_LAYER;
 264         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 265
 266         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 267         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 268         mine.angles = vectoangles (mine.velocity);
 269
 270         mine.touch = W_Mine_Touch;
 271         mine.think = W_Mine_Think;
 272         mine.nextthink = time;
 273         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 274         mine.flags = FL_PROJECTILE;
 275
 276         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 277
 278         // muzzle flash for 1st person view
 279         flash = spawn ();
 280         setmodel (flash, "models/flash.md3"); // precision set below
 281         SUB_SetFade (flash, time, 0.1);
 282         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 283         W_AttachToShotorg(flash, '5 0 0');
 284
 285         // common properties
 286
 287         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 288
 289         self.minelayer_mines = W_Mine_Count(self);
 290 }
 291
 292 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 293
 294 float W_PlacedMines(float detonate)
 295 {
 296         entity mine;
 297         float minfound;
 298
 299         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 300         {
 301                 if(detonate)
 302                 {
 303                         if(!mine.minelayer_detonate)
 304                         {
 305                                 mine.minelayer_detonate = TRUE;
 306                                 minfound = 1;
 307                         }
 308                 }
 309                 else
 310                         minfound = 1;
 311         }
 312         return minfound;
 313 }
 314
 315 float w_minelayer(float req)
 316 {
 317         entity mine;
 318         float ammo_amount;
 319
 320         if (req == WR_AIM)
 321         {
 322                 // aim and decide to fire if appropriate
 323                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 324                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 325                 {
 326                         // decide whether to detonate mines
 327                         entity targetlist, targ;
 328                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 329                         float selfdamage, teamdamage, enemydamage;
 330                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 331                         coredamage = autocvar_g_balance_minelayer_damage;
 332                         edgeradius = autocvar_g_balance_minelayer_radius;
 333                         recipricoledgeradius = 1 / edgeradius;
 334                         selfdamage = 0;
 335                         teamdamage = 0;
 336                         enemydamage = 0;
 337                         targetlist = findchainfloat(bot_attack, TRUE);
 338                         mine = find(world, classname, "mine");
 339                         while (mine)
 340                         {
 341                                 if (mine.owner != self)
 342                                 {
 343                                         mine = find(mine, classname, "mine");
 344                                         continue;
 345                                 }
 346                                 targ = targetlist;
 347                                 while (targ)
 348                                 {
 349                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 350                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 351                                         // count potential damage according to type of target
 352                                         if (targ == self)
 353                                                 selfdamage = selfdamage + d;
 354                                         else if (targ.team == self.team && teams_matter)
 355                                                 teamdamage = teamdamage + d;
 356                                         else if (bot_shouldattack(targ))
 357                                                 enemydamage = enemydamage + d;
 358                                         targ = targ.chain;
 359                                 }
 360                                 mine = find(mine, classname, "mine");
 361                         }
 362                         float desirabledamage;
 363                         desirabledamage = enemydamage;
 364                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 365                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 366                         if (teams_matter && self.team)
 367                                 desirabledamage = desirabledamage - teamdamage;
 368
 369                         mine = find(world, classname, "mine");
 370                         while (mine)
 371                         {
 372                                 if (mine.owner != self)
 373                                 {
 374                                         mine = find(mine, classname, "mine");
 375                                         continue;
 376                                 }
 377                                 makevectors(mine.v_angle);
 378                                 targ = targetlist;
 379                                 if (skill > 9) // normal players only do this for the target they are tracking
 380                                 {
 381                                         targ = targetlist;
 382                                         while (targ)
 383                                         {
 384                                                 if (
 385                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 386                                                         && desirabledamage > 0.1*coredamage
 387                                                 )self.BUTTON_ATCK2 = TRUE;
 388                                                 targ = targ.chain;
 389                                         }
 390                                 }else{
 391                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 392                                         //As the distance gets larger, a correct detonation gets near imposible
 393                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 394                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 395                                                 if(self.enemy.classname == "player")
 396                                                         if(desirabledamage >= 0.1*coredamage)
 397                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 398                                                                         self.BUTTON_ATCK2 = TRUE;
 399                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 400                                 }
 401
 402                                 mine = find(mine, classname, "mine");
 403                         }
 404                         // if we would be doing at X percent of the core damage, detonate it
 405                         // but don't fire a new shot at the same time!
 406                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 407                                 self.BUTTON_ATCK2 = TRUE;
 408                         if ((skill > 6.5) && (selfdamage > self.health))
 409                                 self.BUTTON_ATCK2 = FALSE;
 410                         //if(self.BUTTON_ATCK2 == TRUE)
 411                         //      dprint(ftos(desirabledamage),"\n");
 412                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 413                 }
 414         }
 415         else if (req == WR_THINK)
 416         {
 417                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 418                 {
 419                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 420                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 421                                 weapon_action(self.weapon, WR_RELOAD);
 422                 }
 423                 else if (self.BUTTON_ATCK)
 424                 {
 425                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 426                         {
 427                                 W_Mine_Attack();
 428                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 429                         }
 430                 }
 431
 432                 if (self.BUTTON_ATCK2)
 433                 {
 434                         if(W_PlacedMines(TRUE))
 435                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 436                 }
 437         }
 438         else if (req == WR_PRECACHE)
 439         {
 440                 precache_model ("models/flash.md3");
 441                 precache_model ("models/mine.md3");
 442                 precache_model ("models/weapons/g_minelayer.md3");
 443                 precache_model ("models/weapons/v_minelayer.md3");
 444                 precache_model ("models/weapons/h_minelayer.iqm");
 445                 precache_sound ("weapons/mine_det.wav");
 446                 precache_sound ("weapons/mine_fire.wav");
 447                 precache_sound ("weapons/mine_stick.wav");
 448                 precache_sound ("weapons/mine_trigger.wav");
 449                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 450         }
 451         else if (req == WR_SETUP)
 452         {
 453                 weapon_setup(WEP_MINE_LAYER);
 454                 self.current_ammo = ammo_rockets;
 455         }
 456         else if (req == WR_CHECKAMMO1)
 457         {
 458                 // don't switch while placing a mine
 459                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 460                 {
 461                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 462                         ammo_amount += self.weapon_load[WEP_MINE_LAYER] >= autocvar_g_balance_minelayer_ammo;
 463                         return ammo_amount;
 464                 }
 465         }
 466         else if (req == WR_CHECKAMMO2)
 467         {
 468                 if (W_PlacedMines(FALSE))
 469                         return TRUE;
 470                 else
 471                         return FALSE;
 472         }
 473         else if (req == WR_RELOAD)
 474         {
 475                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 476         }
 477         return TRUE;
 478 };
 479 #endif
 480 #ifdef CSQC
 481 float w_minelayer(float req)
 482 {
 483         if(req == WR_IMPACTEFFECT)
 484         {
 485                 vector org2;
 486                 org2 = w_org + w_backoff * 12;
 487                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 488                 if(!w_issilent)
 489                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 490         }
 491         else if(req == WR_PRECACHE)
 492         {
 493                 precache_sound("weapons/mine_exp.wav");
 494         }
 495         else if (req == WR_SUICIDEMESSAGE)
 496                 w_deathtypestring = _("%s exploded");
 497         else if (req == WR_KILLMESSAGE)
 498         {
 499                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 500                         w_deathtypestring = _("%s got too close to %s's mine");
 501                 else if(w_deathtype & HITTYPE_SPLASH)
 502                         w_deathtypestring = _("%s almost dodged %s's mine");
 503                 else
 504                         w_deathtypestring = _("%s stepped on %s's mine");
 505         }
 506         return TRUE;
 507 }
 508 #endif
 509 #endif