qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick (entity to)
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.oldvelocity = self.velocity;
  34
  35         newmine.takedamage = self.takedamage;
  36         newmine.damageforcescale = self.damageforcescale;
  37         newmine.health = self.health;
  38         newmine.event_damage = self.event_damage;
  39         newmine.spawnshieldtime = self.spawnshieldtime;
  40
  41         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  42         newmine.projectiledeathtype = self.projectiledeathtype;
  43
  44         newmine.mine_time = self.mine_time;
  45
  46         newmine.touch = SUB_Null;
  47         newmine.think = W_Mine_Think;
  48         newmine.nextthink = time;
  49         newmine.cnt = self.cnt;
  50         newmine.flags = self.flags;
  51
  52         remove(self);
  53         self = newmine;
  54
  55         if(to)
  56                 SetMovetypeFollow(self, to);
  57 }
  58
  59 void W_Mine_Explode ()
  60 {
  61         if(other.takedamage == DAMAGE_AIM)
  62                 if(other.classname == "player")
  63                         if(IsDifferentTeam(self.owner, other))
  64                                 if(other.deadflag == DEAD_NO)
  65                                         if(IsFlying(other))
  66                                                 AnnounceTo(self.owner, "airshot");
  67
  68         self.event_damage = SUB_Null;
  69         self.takedamage = DAMAGE_NO;
  70
  71         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  72
  73         if (self.owner.weapon == WEP_MINE_LAYER)
  74         {
  75                 entity oldself;
  76                 oldself = self;
  77                 self = self.owner;
  78                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  79                 {
  80                         self.cnt = WEP_MINE_LAYER;
  81                         ATTACK_FINISHED(self) = time;
  82                         self.switchweapon = w_getbestweapon(self);
  83                 }
  84                 self = oldself;
  85         }
  86         self.owner.minelayer_mines -= 1;
  87         remove (self);
  88 }
  89
  90 void W_Mine_DoRemoteExplode ()
  91 {
  92         self.event_damage = SUB_Null;
  93         self.takedamage = DAMAGE_NO;
  94
  95         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
  96                 self.velocity = self.oldvelocity;
  97
  98         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  99
 100         if (self.owner.weapon == WEP_MINE_LAYER)
 101         {
 102                 entity oldself;
 103                 oldself = self;
 104                 self = self.owner;
 105                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
 106                 {
 107                         self.cnt = WEP_MINE_LAYER;
 108                         ATTACK_FINISHED(self) = time;
 109                         self.switchweapon = w_getbestweapon(self);
 110                 }
 111                 self = oldself;
 112         }
 113         self.owner.minelayer_mines -= 1;
 114         remove (self);
 115 }
 116
 117 void W_Mine_RemoteExplode ()
 118 {
 119         if(self.owner.deadflag == DEAD_NO)
 120                 if((self.spawnshieldtime >= 0)
 121                         ? (time >= self.spawnshieldtime) // timer
 122                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 123                 )
 124                 {
 125                         W_Mine_DoRemoteExplode();
 126                 }
 127 }
 128
 129 void W_Mine_ProximityExplode ()
 130 {
 131         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 132         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 133         {
 134                 entity head;
 135                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 136                 while(head)
 137                 {
 138                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 139                                 return;
 140                         head = head.chain;
 141                 }
 142         }
 143
 144         self.mine_time = 0;
 145         W_Mine_Explode();
 146 }
 147
 148 float W_Mine_Count(entity e)
 149 {
 150         float minecount;
 151         entity mine;
 152         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == e)
 153                 minecount += 1;
 154
 155         return minecount;
 156 }
 157
 158 void W_Mine_Think (void)
 159 {
 160         entity head;
 161
 162         self.nextthink = time;
 163
 164         if(self.movetype == MOVETYPE_FOLLOW)
 165         {
 166                 if(LostMovetypeFollow(self))
 167                 {
 168                         UnsetMovetypeFollow(self);
 169                         self.movetype = MOVETYPE_NONE;
 170                 }
 171         }
 172
 173         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 174         // TODO: replace this mine_trigger.wav sound with a real countdown
 175         if ((time > self.cnt) && (!self.mine_time))
 176         {
 177                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 178                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 179                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 180                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 181         }
 182
 183         // a player's mines shall explode if he disconnects or dies
 184         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 185         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 186         {
 187                 other = world;
 188                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 189                 W_Mine_Explode();
 190                 return;
 191         }
 192
 193         // set the mine for detonation when a foe gets close enough
 194         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 195         while(head)
 196         {
 197                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 198                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 199                 if(!self.mine_time)
 200                 {
 201                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 202                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 203                 }
 204                 head = head.chain;
 205         }
 206
 207         // explode if it's time to
 208         if(self.mine_time && time >= self.mine_time)
 209         {
 210                 W_Mine_ProximityExplode();
 211                 return;
 212         }
 213
 214         // remote detonation
 215         if (self.owner.weapon == WEP_MINE_LAYER)
 216         if (self.owner.deadflag == DEAD_NO)
 217         if (self.minelayer_detonate)
 218                 W_Mine_RemoteExplode();
 219 }
 220
 221 void W_Mine_Touch (void)
 222 {
 223         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 224                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 225
 226         PROJECTILE_TOUCH;
 227
 228         if(other && other.classname == "player" && other.deadflag == DEAD_NO)
 229         {
 230                 // hit a player
 231                 // don't stick
 232         }
 233         else
 234         {
 235                 W_Mine_Stick(other);
 236         }
 237 }
 238
 239 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 240 {
 241         if (self.health <= 0)
 242                 return;
 243         self.health = self.health - damage;
 244         self.angles = vectoangles(self.velocity);
 245         if (self.health <= 0)
 246                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 247 }
 248
 249 void W_Mine_Attack (void)
 250 {
 251         entity mine;
 252         entity flash;
 253
 254         // scan how many mines we placed, and return if we reached our limit
 255         if(autocvar_g_balance_minelayer_limit)
 256         {
 257
 258                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 259                 {
 260                         // the refire delay keeps this message from being spammed
 261                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 262                         play2(self, "weapons/unavailable.wav");
 263                         return;
 264                 }
 265         }
 266
 267         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 268
 269         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 270         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 271
 272         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 273         mine.owner = self;
 274         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 275                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 276         else
 277                 mine.spawnshieldtime = -1;
 278         mine.classname = "mine";
 279         mine.bot_dodge = TRUE;
 280         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 281
 282         mine.takedamage = DAMAGE_YES;
 283         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 284         mine.health = autocvar_g_balance_minelayer_health;
 285         mine.event_damage = W_Mine_Damage;
 286
 287         mine.movetype = MOVETYPE_TOSS;
 288         PROJECTILE_MAKETRIGGER(mine);
 289         mine.projectiledeathtype = WEP_MINE_LAYER;
 290         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 291
 292         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 293         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 294         mine.angles = vectoangles (mine.velocity);
 295
 296         mine.touch = W_Mine_Touch;
 297         mine.think = W_Mine_Think;
 298         mine.nextthink = time;
 299         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 300         mine.flags = FL_PROJECTILE;
 301
 302         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 303
 304         // muzzle flash for 1st person view
 305         flash = spawn ();
 306         setmodel (flash, "models/flash.md3"); // precision set below
 307         SUB_SetFade (flash, time, 0.1);
 308         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 309         W_AttachToShotorg(flash, '5 0 0');
 310
 311         // common properties
 312
 313         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 314
 315         self.minelayer_mines = W_Mine_Count(self);
 316 }
 317
 318 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 319
 320 float W_PlacedMines(float detonate)
 321 {
 322         entity mine;
 323         float minfound;
 324
 325         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 326         {
 327                 if(detonate)
 328                 {
 329                         if(!mine.minelayer_detonate)
 330                         {
 331                                 mine.minelayer_detonate = TRUE;
 332                                 minfound = 1;
 333                         }
 334                 }
 335                 else
 336                         minfound = 1;
 337         }
 338         return minfound;
 339 }
 340
 341 float w_minelayer(float req)
 342 {
 343         entity mine;
 344         float ammo_amount;
 345
 346         if (req == WR_AIM)
 347         {
 348                 // aim and decide to fire if appropriate
 349                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 350                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 351                 {
 352                         // decide whether to detonate mines
 353                         entity targetlist, targ;
 354                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 355                         float selfdamage, teamdamage, enemydamage;
 356                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 357                         coredamage = autocvar_g_balance_minelayer_damage;
 358                         edgeradius = autocvar_g_balance_minelayer_radius;
 359                         recipricoledgeradius = 1 / edgeradius;
 360                         selfdamage = 0;
 361                         teamdamage = 0;
 362                         enemydamage = 0;
 363                         targetlist = findchainfloat(bot_attack, TRUE);
 364                         mine = find(world, classname, "mine");
 365                         while (mine)
 366                         {
 367                                 if (mine.owner != self)
 368                                 {
 369                                         mine = find(mine, classname, "mine");
 370                                         continue;
 371                                 }
 372                                 targ = targetlist;
 373                                 while (targ)
 374                                 {
 375                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 376                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 377                                         // count potential damage according to type of target
 378                                         if (targ == self)
 379                                                 selfdamage = selfdamage + d;
 380                                         else if (targ.team == self.team && teamplay)
 381                                                 teamdamage = teamdamage + d;
 382                                         else if (bot_shouldattack(targ))
 383                                                 enemydamage = enemydamage + d;
 384                                         targ = targ.chain;
 385                                 }
 386                                 mine = find(mine, classname, "mine");
 387                         }
 388                         float desirabledamage;
 389                         desirabledamage = enemydamage;
 390                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 391                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 392                         if (teamplay && self.team)
 393                                 desirabledamage = desirabledamage - teamdamage;
 394
 395                         mine = find(world, classname, "mine");
 396                         while (mine)
 397                         {
 398                                 if (mine.owner != self)
 399                                 {
 400                                         mine = find(mine, classname, "mine");
 401                                         continue;
 402                                 }
 403                                 makevectors(mine.v_angle);
 404                                 targ = targetlist;
 405                                 if (skill > 9) // normal players only do this for the target they are tracking
 406                                 {
 407                                         targ = targetlist;
 408                                         while (targ)
 409                                         {
 410                                                 if (
 411                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 412                                                         && desirabledamage > 0.1*coredamage
 413                                                 )self.BUTTON_ATCK2 = TRUE;
 414                                                 targ = targ.chain;
 415                                         }
 416                                 }else{
 417                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 418                                         //As the distance gets larger, a correct detonation gets near imposible
 419                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 420                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 421                                                 if(self.enemy.classname == "player")
 422                                                         if(desirabledamage >= 0.1*coredamage)
 423                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 424                                                                         self.BUTTON_ATCK2 = TRUE;
 425                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 426                                 }
 427
 428                                 mine = find(mine, classname, "mine");
 429                         }
 430                         // if we would be doing at X percent of the core damage, detonate it
 431                         // but don't fire a new shot at the same time!
 432                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 433                                 self.BUTTON_ATCK2 = TRUE;
 434                         if ((skill > 6.5) && (selfdamage > self.health))
 435                                 self.BUTTON_ATCK2 = FALSE;
 436                         //if(self.BUTTON_ATCK2 == TRUE)
 437                         //      dprint(ftos(desirabledamage),"\n");
 438                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 439                 }
 440         }
 441         else if (req == WR_THINK)
 442         {
 443                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 444                 {
 445                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 446                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 447                                 weapon_action(self.weapon, WR_RELOAD);
 448                 }
 449                 else if (self.BUTTON_ATCK)
 450                 {
 451                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 452                         {
 453                                 W_Mine_Attack();
 454                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 455                         }
 456                 }
 457
 458                 if (self.BUTTON_ATCK2)
 459                 {
 460                         if(W_PlacedMines(TRUE))
 461                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 462                 }
 463         }
 464         else if (req == WR_PRECACHE)
 465         {
 466                 precache_model ("models/flash.md3");
 467                 precache_model ("models/mine.md3");
 468                 precache_model ("models/weapons/g_minelayer.md3");
 469                 precache_model ("models/weapons/v_minelayer.md3");
 470                 precache_model ("models/weapons/h_minelayer.iqm");
 471                 precache_sound ("weapons/mine_det.wav");
 472                 precache_sound ("weapons/mine_fire.wav");
 473                 precache_sound ("weapons/mine_stick.wav");
 474                 precache_sound ("weapons/mine_trigger.wav");
 475                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 476         }
 477         else if (req == WR_SETUP)
 478         {
 479                 weapon_setup(WEP_MINE_LAYER);
 480                 self.current_ammo = ammo_rockets;
 481         }
 482         else if (req == WR_CHECKAMMO1)
 483         {
 484                 // don't switch while placing a mine
 485                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 486                 {
 487                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 488                         ammo_amount += self.weapon_load[WEP_MINE_LAYER] >= autocvar_g_balance_minelayer_ammo;
 489                         return ammo_amount;
 490                 }
 491         }
 492         else if (req == WR_CHECKAMMO2)
 493         {
 494                 if (W_PlacedMines(FALSE))
 495                         return TRUE;
 496                 else
 497                         return FALSE;
 498         }
 499         else if (req == WR_RELOAD)
 500         {
 501                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 502         }
 503         return TRUE;
 504 };
 505 #endif
 506 #ifdef CSQC
 507 float w_minelayer(float req)
 508 {
 509         if(req == WR_IMPACTEFFECT)
 510         {
 511                 vector org2;
 512                 org2 = w_org + w_backoff * 12;
 513                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 514                 if(!w_issilent)
 515                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 516         }
 517         else if(req == WR_PRECACHE)
 518         {
 519                 precache_sound("weapons/mine_exp.wav");
 520         }
 521         else if (req == WR_SUICIDEMESSAGE)
 522                 w_deathtypestring = _("%s exploded");
 523         else if (req == WR_KILLMESSAGE)
 524         {
 525                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 526                         w_deathtypestring = _("%s got too close to %s's mine");
 527                 else if(w_deathtype & HITTYPE_SPLASH)
 528                         w_deathtypestring = _("%s almost dodged %s's mine");
 529                 else
 530                         w_deathtypestring = _("%s stepped on %s's mine");
 531         }
 532         return TRUE;
 533 }
 534 #endif
 535 #endif