qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", "Mine Layer");
   3 #else
   4 #ifdef SVQC
   5 .float minelayer_detonate;
   6 .float mine_number, mine_time;
   7
   8 void spawnfunc_weapon_minelayer (void)
   9 {
  10         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  11 }
  12
  13 void W_Mine_Unregister()
  14 {
  15         if(self.owner && self.owner.lastmine == self)
  16                 self.owner.lastmine = world;
  17 }
  18
  19 void W_Mine_Explode ()
  20 {
  21         W_Mine_Unregister();
  22
  23         if(other.takedamage == DAMAGE_AIM)
  24                 if(other.classname == "player")
  25                         if(IsDifferentTeam(self.owner, other))
  26                                 if(IsFlying(other))
  27                                         AnnounceTo(self.owner, "airshot");
  28
  29         self.event_damage = SUB_Null;
  30         self.takedamage = DAMAGE_NO;
  31
  32         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_damage"), cvar("g_balance_minelayer_edgedamage"), cvar("g_balance_minelayer_radius"), world, cvar("g_balance_minelayer_force"), self.projectiledeathtype, other);
  33
  34         if (self.owner.weapon == WEP_MINE_LAYER)
  35         {
  36                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  37                 {
  38                         self.owner.cnt = WEP_MINE_LAYER;
  39                         ATTACK_FINISHED(self.owner) = time;
  40                         self.owner.switchweapon = w_getbestweapon(self.owner);
  41                 }
  42         }
  43         remove (self);
  44 }
  45
  46 void W_Mine_DoRemoteExplode ()
  47 {
  48         W_Mine_Unregister();
  49
  50         self.event_damage = SUB_Null;
  51         self.takedamage = DAMAGE_NO;
  52
  53         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_remote_damage"), cvar("g_balance_minelayer_remote_edgedamage"), cvar("g_balance_minelayer_remote_radius"), world, cvar("g_balance_minelayer_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  54
  55         if (self.owner.weapon == WEP_MINE_LAYER)
  56         {
  57                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  58                 {
  59                         self.owner.cnt = WEP_MINE_LAYER;
  60                         ATTACK_FINISHED(self.owner) = time;
  61                         self.owner.switchweapon = w_getbestweapon(self.owner);
  62                 }
  63         }
  64         remove (self);
  65 }
  66
  67 void W_Mine_RemoteExplode()
  68 {
  69         if(self.owner.deadflag == DEAD_NO)
  70         if(self.owner.lastmine)
  71         {
  72                 if((self.spawnshieldtime >= 0)
  73                         ? (time >= self.spawnshieldtime) // timer
  74                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_minelayer_radius")) // safety device
  75                 )
  76                 {
  77                         W_Mine_DoRemoteExplode();
  78                 }
  79         }
  80 }
  81
  82 void W_Mine_Think (void)
  83 {
  84         self.nextthink = time;
  85         if (time > self.cnt)
  86         {
  87                 other = world;
  88                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  89                 W_Mine_Explode ();
  90                 return;
  91         }
  92
  93         // detect players who are close the mine and explode if the player should detonate it
  94         entity head;
  95         head = findradius(self.origin, cvar("g_balance_minelayer_detectionradius"));
  96
  97         while(head)
  98         {
  99                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 100                 if(head != self.owner)
 101                 if(IsDifferentTeam(head, self.owner)) // don't detonate for team mates
 102                 if(!self.mine_time)
 103                 {
 104                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 105                         self.mine_time = time + cvar("g_balance_minelayer_time");
 106                 }
 107                 head = head.chain;
 108         }
 109
 110         // explode if it's time
 111         if(self.mine_time && time >= self.mine_time)
 112         {
 113                 self.mine_time = 0;
 114                 W_Mine_Explode();
 115         }
 116
 117         // remote detonation
 118         if (self.owner.weapon == WEP_MINE_LAYER)
 119         if (self.owner.deadflag == DEAD_NO)
 120         if (self.minelayer_detonate)
 121                 W_Mine_RemoteExplode();
 122
 123         if(self.csqcprojectile_clientanimate == 0)
 124                 UpdateCSQCProjectile(self);
 125 }
 126
 127 void W_Mine_Touch (void)
 128 {
 129         PROJECTILE_TOUCH;
 130         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
 131         self.movetype = MOVETYPE_NONE; // lock the mine in place
 132         // TODO: make sure this doesn't cause the mine to get stuck in the air if it falls over a moving entity
 133 }
 134
 135 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 136 {
 137         if (self.health <= 0)
 138                 return;
 139         self.health = self.health - damage;
 140         self.angles = vectoangles(self.velocity);
 141         if (self.health <= 0)
 142                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 143 }
 144
 145 void W_Mine_Attack (void)
 146 {
 147         local entity mine;
 148         local entity flash;
 149
 150         // scan how many mines we placed, and return if we reached our limit
 151         if(cvar("g_balance_minelayer_limit"))
 152         {
 153                 entity mine;
 154                 self.mine_number = 0;
 155                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 156                         self.mine_number += 1;
 157
 158                 if(self.mine_number >= cvar("g_balance_minelayer_limit"))
 159                 {
 160                         // the refire delay keeps this message from being spammed
 161                         sprint(self, strcat("You cannot place more than ^2", cvar_string("g_balance_minelayer_limit"), " ^7mines at a time\n") );
 162                         play2(self, "weapons/unavailable.wav");
 163                         return;
 164                 }
 165         }
 166
 167         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 168                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_minelayer_ammo");
 169
 170         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", cvar("g_balance_minelayer_damage"));
 171         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 172
 173         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 174         mine.owner = self;
 175         self.lastmine = mine;
 176         if(cvar("g_balance_minelayer_detonatedelay") >= 0)
 177                 mine.spawnshieldtime = time + cvar("g_balance_minelayer_detonatedelay");
 178         else
 179                 mine.spawnshieldtime = -1;
 180         mine.classname = "mine";
 181         mine.bot_dodge = TRUE;
 182         mine.bot_dodgerating = cvar("g_balance_minelayer_damage") * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 183
 184         mine.takedamage = DAMAGE_YES;
 185         mine.damageforcescale = cvar("g_balance_minelayer_damageforcescale");
 186         mine.health = cvar("g_balance_minelayer_health");
 187         mine.event_damage = W_Mine_Damage;
 188
 189         mine.movetype = MOVETYPE_TOSS;
 190         PROJECTILE_MAKETRIGGER(mine);
 191         mine.projectiledeathtype = WEP_MINE_LAYER;
 192         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 193
 194         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 195         W_SetupProjectileVelocity(mine, cvar("g_balance_minelayer_speedstart"), 0);
 196         mine.angles = vectoangles (mine.velocity);
 197
 198         mine.touch = W_Mine_Touch;
 199         mine.think = W_Mine_Think;
 200         mine.nextthink = time;
 201         mine.cnt = time + cvar("g_balance_minelayer_lifetime");
 202         mine.flags = FL_PROJECTILE;
 203
 204         CSQCProjectile(mine, FALSE, PROJECTILE_MINE, TRUE);
 205
 206         // muzzle flash for 1st person view
 207         flash = spawn ();
 208         setmodel (flash, "models/flash.md3"); // precision set below
 209         SUB_SetFade (flash, time, 0.1);
 210         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 211         W_AttachToShotorg(flash, '5 0 0');
 212
 213         // common properties
 214 }
 215
 216 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 217
 218 float w_minelayer(float req)
 219 {
 220         entity mine;
 221         float minfound;
 222         if (req == WR_AIM)
 223         {
 224                 // aim and decide to fire if appropriate
 225                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_minelayer_speed"), 0, cvar("g_balance_minelayer_lifetime"), FALSE);
 226                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 227                 {
 228                         // decide whether to detonate mines
 229                         local entity mine, targetlist, targ;
 230                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 231                         local float selfdamage, teamdamage, enemydamage;
 232                         edgedamage = cvar("g_balance_minelayer_edgedamage");
 233                         coredamage = cvar("g_balance_minelayer_damage");
 234                         edgeradius = cvar("g_balance_minelayer_radius");
 235                         recipricoledgeradius = 1 / edgeradius;
 236                         selfdamage = 0;
 237                         teamdamage = 0;
 238                         enemydamage = 0;
 239                         targetlist = findchainfloat(bot_attack, TRUE);
 240                         mine = find(world, classname, "mine");
 241                         while (mine)
 242                         {
 243                                 if (mine.owner != self)
 244                                 {
 245                                         mine = find(mine, classname, "mine");
 246                                         continue;
 247                                 }
 248                                 targ = targetlist;
 249                                 while (targ)
 250                                 {
 251                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 252                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 253                                         // count potential damage according to type of target
 254                                         if (targ == self)
 255                                                 selfdamage = selfdamage + d;
 256                                         else if (targ.team == self.team && teams_matter)
 257                                                 teamdamage = teamdamage + d;
 258                                         else if (bot_shouldattack(targ))
 259                                                 enemydamage = enemydamage + d;
 260                                         targ = targ.chain;
 261                                 }
 262                                 mine = find(mine, classname, "mine");
 263                         }
 264                         local float desirabledamage;
 265                         desirabledamage = enemydamage;
 266                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 267                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 268                         if (self.team && teamplay != 1)
 269                                 desirabledamage = desirabledamage - teamdamage;
 270
 271                         mine = find(world, classname, "mine");
 272                         while (mine)
 273                         {
 274                                 if (mine.owner != self)
 275                                 {
 276                                         mine = find(mine, classname, "mine");
 277                                         continue;
 278                                 }
 279                                 makevectors(mine.v_angle);
 280                                 targ = targetlist;
 281                                 if (skill > 9) // normal players only do this for the target they are tracking
 282                                 {
 283                                         targ = targetlist;
 284                                         while (targ)
 285                                         {
 286                                                 if (
 287                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 288                                                         && desirabledamage > 0.1*coredamage
 289                                                 )self.BUTTON_ATCK2 = TRUE;
 290                                                 targ = targ.chain;
 291                                         }
 292                                 }else{
 293                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 294                                         //As the distance gets larger, a correct detonation gets near imposible
 295                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 296                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 297                                                 if(self.enemy.classname == "player")
 298                                                         if(desirabledamage >= 0.1*coredamage)
 299                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 300                                                                         self.BUTTON_ATCK2 = TRUE;
 301                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 302                                 }
 303
 304                                 mine = find(mine, classname, "mine");
 305                         }
 306                         // if we would be doing at X percent of the core damage, detonate it
 307                         // but don't fire a new shot at the same time!
 308                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 309                                 self.BUTTON_ATCK2 = TRUE;
 310                         if ((skill > 6.5) && (selfdamage > self.health))
 311                                 self.BUTTON_ATCK2 = FALSE;
 312                         //if(self.BUTTON_ATCK2 == TRUE)
 313                         //      dprint(ftos(desirabledamage),"\n");
 314                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 315                 }
 316         }
 317         else if (req == WR_THINK)
 318         {
 319                 if (self.BUTTON_ATCK)
 320                 {
 321                         if(weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 322                         {
 323                                 W_Mine_Attack();
 324                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 325                         }
 326                 }
 327
 328                 if (self.BUTTON_ATCK2)
 329                 {
 330                         minfound = 0;
 331                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 332                         {
 333                                 if(!mine.minelayer_detonate)
 334                                 {
 335                                         mine.minelayer_detonate = TRUE;
 336                                         minfound = 1;
 337                                 }
 338                         }
 339                         if(minfound)
 340                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 341                 }
 342         }
 343         else if (req == WR_PRECACHE)
 344         {
 345                 precache_model ("models/flash.md3");
 346                 precache_model ("models/weapons/g_minelayer.md3");
 347                 precache_model ("models/weapons/v_minelayer.md3");
 348                 precache_model ("models/weapons/h_minelayer.iqm");
 349                 precache_sound ("weapons/mine_det.wav");
 350                 precache_sound ("weapons/mine_fire.wav");
 351                 precache_sound ("weapons/mine_stick.wav");
 352                 precache_sound ("weapons/mine_trigger.wav");
 353         }
 354         else if (req == WR_SETUP)
 355         {
 356                 weapon_setup(WEP_MINE_LAYER);
 357         }
 358         else if (req == WR_CHECKAMMO1)
 359         {
 360                 // don't switch while placing a mine
 361                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 362                         && self.ammo_rockets < cvar("g_balance_minelayer_ammo"))
 363                         return FALSE;
 364         }
 365         else if (req == WR_CHECKAMMO2)
 366                 return FALSE;
 367         return TRUE;
 368 };
 369 #endif
 370 #ifdef CSQC
 371 float w_minelayer(float req)
 372 {
 373         if(req == WR_IMPACTEFFECT)
 374         {
 375                 vector org2;
 376                 org2 = w_org + w_backoff * 12;
 377                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 378                 if(!w_issilent)
 379                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 380         }
 381         else if(req == WR_PRECACHE)
 382         {
 383                 precache_sound("weapons/mine_exp.wav");
 384         }
 385         else if (req == WR_SUICIDEMESSAGE)
 386                 w_deathtypestring = "%s exploded";
 387         else if (req == WR_KILLMESSAGE)
 388         {
 389                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 390                         w_deathtypestring = "%s got too close to %s's mine";
 391                 else if(w_deathtype & HITTYPE_SPLASH)
 392                         w_deathtypestring = "%s almost dodged %s's mine";
 393                 else
 394                         w_deathtypestring = "%s stepped on %s's mine";
 395         }
 396         return TRUE;
 397 }
 398 #endif
 399 #endif