qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick (entity to)
  15 {
  16         spamsound (self, CH_SHOTS_SINGLE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         newmine.realowner = self.realowner;
  29         setsize(newmine, '-4 -4 -4', '4 4 4');
  30         setorigin(newmine, self.origin);
  31         setmodel(newmine, "models/mine.md3");
  32         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  33
  34         newmine.oldvelocity = self.velocity;
  35
  36         newmine.takedamage = self.takedamage;
  37         newmine.damageforcescale = self.damageforcescale;
  38         newmine.health = self.health;
  39         newmine.event_damage = self.event_damage;
  40         newmine.spawnshieldtime = self.spawnshieldtime;
  41
  42         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  43         newmine.projectiledeathtype = self.projectiledeathtype;
  44
  45         newmine.mine_time = self.mine_time;
  46
  47         newmine.touch = SUB_Null;
  48         newmine.think = W_Mine_Think;
  49         newmine.nextthink = time;
  50         newmine.cnt = self.cnt;
  51         newmine.flags = self.flags;
  52
  53         remove(self);
  54         self = newmine;
  55
  56         if(to)
  57                 SetMovetypeFollow(self, to);
  58 }
  59
  60 void W_Mine_Explode ()
  61 {
  62         if(other.takedamage == DAMAGE_AIM)
  63                 if(other.classname == "player")
  64                         if(IsDifferentTeam(self.realowner, other))
  65                                 if(other.deadflag == DEAD_NO)
  66                                         if(IsFlying(other))
  67                                                 AnnounceTo(self.realowner, "airshot");
  68
  69         self.event_damage = SUB_Null;
  70         self.takedamage = DAMAGE_NO;
  71
  72         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  73
  74         if (self.realowner.weapon == WEP_MINE_LAYER)
  75         {
  76                 entity oldself;
  77                 oldself = self;
  78                 self = self.realowner;
  79                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  80                 {
  81                         self.cnt = WEP_MINE_LAYER;
  82                         ATTACK_FINISHED(self) = time;
  83                         self.switchweapon = w_getbestweapon(self);
  84                 }
  85                 self = oldself;
  86         }
  87         self.realowner.minelayer_mines -= 1;
  88         remove (self);
  89 }
  90
  91 void W_Mine_DoRemoteExplode ()
  92 {
  93         self.event_damage = SUB_Null;
  94         self.takedamage = DAMAGE_NO;
  95
  96         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
  97                 self.velocity = self.oldvelocity;
  98
  99         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 100
 101         if (self.realowner.weapon == WEP_MINE_LAYER)
 102         {
 103                 entity oldself;
 104                 oldself = self;
 105                 self = self.realowner;
 106                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
 107                 {
 108                         self.cnt = WEP_MINE_LAYER;
 109                         ATTACK_FINISHED(self) = time;
 110                         self.switchweapon = w_getbestweapon(self);
 111                 }
 112                 self = oldself;
 113         }
 114         self.realowner.minelayer_mines -= 1;
 115         remove (self);
 116 }
 117
 118 void W_Mine_RemoteExplode ()
 119 {
 120         if(self.realowner.deadflag == DEAD_NO)
 121                 if((self.spawnshieldtime >= 0)
 122                         ? (time >= self.spawnshieldtime) // timer
 123                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 124                 )
 125                 {
 126                         W_Mine_DoRemoteExplode();
 127                 }
 128 }
 129
 130 void W_Mine_ProximityExplode ()
 131 {
 132         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 133         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 134         {
 135                 entity head;
 136                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 137                 while(head)
 138                 {
 139                         if(head == self.realowner || !IsDifferentTeam(head, self.realowner))
 140                                 return;
 141                         head = head.chain;
 142                 }
 143         }
 144
 145         self.mine_time = 0;
 146         W_Mine_Explode();
 147 }
 148
 149 float W_Mine_Count(entity e)
 150 {
 151         float minecount;
 152         entity mine;
 153         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 154                 minecount += 1;
 155
 156         return minecount;
 157 }
 158
 159 void W_Mine_Think (void)
 160 {
 161         entity head;
 162
 163         self.nextthink = time;
 164
 165         if(self.movetype == MOVETYPE_FOLLOW)
 166         {
 167                 if(LostMovetypeFollow(self))
 168                 {
 169                         UnsetMovetypeFollow(self);
 170                         self.movetype = MOVETYPE_NONE;
 171                 }
 172         }
 173
 174         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 175         // TODO: replace this mine_trigger.wav sound with a real countdown
 176         if ((time > self.cnt) && (!self.mine_time))
 177         {
 178                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 179                         spamsound (self, CH_SHOTS_SINGLE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 180                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 181                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 182         }
 183
 184         // a player's mines shall explode if he disconnects or dies
 185         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 186         if(self.realowner.classname != "player" || self.realowner.deadflag != DEAD_NO)
 187         {
 188                 other = world;
 189                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 190                 W_Mine_Explode();
 191                 return;
 192         }
 193
 194         // set the mine for detonation when a foe gets close enough
 195         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 196         while(head)
 197         {
 198                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 199                 if(head != self.realowner && IsDifferentTeam(head, self.realowner)) // don't trigger for team mates
 200                 if(!self.mine_time)
 201                 {
 202                         spamsound (self, CH_SHOTS_SINGLE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 203                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 204                 }
 205                 head = head.chain;
 206         }
 207
 208         // explode if it's time to
 209         if(self.mine_time && time >= self.mine_time)
 210         {
 211                 W_Mine_ProximityExplode();
 212                 return;
 213         }
 214
 215         // remote detonation
 216         if (self.realowner.weapon == WEP_MINE_LAYER)
 217         if (self.realowner.deadflag == DEAD_NO)
 218         if (self.minelayer_detonate)
 219                 W_Mine_RemoteExplode();
 220 }
 221
 222 void W_Mine_Touch (void)
 223 {
 224         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 225                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 226
 227         PROJECTILE_TOUCH;
 228
 229         if(other && other.classname == "player" && other.deadflag == DEAD_NO)
 230         {
 231                 // hit a player
 232                 // don't stick
 233         }
 234         else
 235         {
 236                 W_Mine_Stick(other);
 237         }
 238 }
 239
 240 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 241 {
 242         if (self.health <= 0)
 243                 return;
 244         self.health = self.health - damage;
 245         self.angles = vectoangles(self.velocity);
 246         if (self.health <= 0)
 247                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 248 }
 249
 250 void W_Mine_Attack (void)
 251 {
 252         entity mine;
 253         entity flash;
 254
 255         // scan how many mines we placed, and return if we reached our limit
 256         if(autocvar_g_balance_minelayer_limit)
 257         {
 258
 259                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 260                 {
 261                         // the refire delay keeps this message from being spammed
 262                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 263                         play2(self, "weapons/unavailable.wav");
 264                         return;
 265                 }
 266         }
 267
 268         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 269
 270         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 271         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 272
 273         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 274         mine.owner = mine.realowner = self;
 275         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 276                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 277         else
 278                 mine.spawnshieldtime = -1;
 279         mine.classname = "mine";
 280         mine.bot_dodge = TRUE;
 281         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 282
 283         mine.takedamage = DAMAGE_YES;
 284         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 285         mine.health = autocvar_g_balance_minelayer_health;
 286         mine.event_damage = W_Mine_Damage;
 287
 288         mine.movetype = MOVETYPE_TOSS;
 289         PROJECTILE_MAKETRIGGER(mine);
 290         mine.projectiledeathtype = WEP_MINE_LAYER;
 291         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 292
 293         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 294         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 295         mine.angles = vectoangles (mine.velocity);
 296
 297         mine.touch = W_Mine_Touch;
 298         mine.think = W_Mine_Think;
 299         mine.nextthink = time;
 300         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 301         mine.flags = FL_PROJECTILE;
 302
 303         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 304
 305         // muzzle flash for 1st person view
 306         flash = spawn ();
 307         setmodel (flash, "models/flash.md3"); // precision set below
 308         SUB_SetFade (flash, time, 0.1);
 309         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 310         W_AttachToShotorg(flash, '5 0 0');
 311
 312         // common properties
 313
 314         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 315
 316         self.minelayer_mines = W_Mine_Count(self);
 317 }
 318
 319 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 320
 321 float W_PlacedMines(float detonate)
 322 {
 323         entity mine;
 324         float minfound;
 325
 326         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 327         {
 328                 if(detonate)
 329                 {
 330                         if(!mine.minelayer_detonate)
 331                         {
 332                                 mine.minelayer_detonate = TRUE;
 333                                 minfound = 1;
 334                         }
 335                 }
 336                 else
 337                         minfound = 1;
 338         }
 339         return minfound;
 340 }
 341
 342 float w_minelayer(float req)
 343 {
 344         entity mine;
 345         float ammo_amount;
 346
 347         if (req == WR_AIM)
 348         {
 349                 // aim and decide to fire if appropriate
 350                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 351                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 352                 {
 353                         // decide whether to detonate mines
 354                         entity targetlist, targ;
 355                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 356                         float selfdamage, teamdamage, enemydamage;
 357                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 358                         coredamage = autocvar_g_balance_minelayer_damage;
 359                         edgeradius = autocvar_g_balance_minelayer_radius;
 360                         recipricoledgeradius = 1 / edgeradius;
 361                         selfdamage = 0;
 362                         teamdamage = 0;
 363                         enemydamage = 0;
 364                         targetlist = findchainfloat(bot_attack, TRUE);
 365                         mine = find(world, classname, "mine");
 366                         while (mine)
 367                         {
 368                                 if (mine.realowner != self)
 369                                 {
 370                                         mine = find(mine, classname, "mine");
 371                                         continue;
 372                                 }
 373                                 targ = targetlist;
 374                                 while (targ)
 375                                 {
 376                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 377                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 378                                         // count potential damage according to type of target
 379                                         if (targ == self)
 380                                                 selfdamage = selfdamage + d;
 381                                         else if (targ.team == self.team && teamplay)
 382                                                 teamdamage = teamdamage + d;
 383                                         else if (bot_shouldattack(targ))
 384                                                 enemydamage = enemydamage + d;
 385                                         targ = targ.chain;
 386                                 }
 387                                 mine = find(mine, classname, "mine");
 388                         }
 389                         float desirabledamage;
 390                         desirabledamage = enemydamage;
 391                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 392                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 393                         if (teamplay && self.team)
 394                                 desirabledamage = desirabledamage - teamdamage;
 395
 396                         mine = find(world, classname, "mine");
 397                         while (mine)
 398                         {
 399                                 if (mine.realowner != self)
 400                                 {
 401                                         mine = find(mine, classname, "mine");
 402                                         continue;
 403                                 }
 404                                 makevectors(mine.v_angle);
 405                                 targ = targetlist;
 406                                 if (skill > 9) // normal players only do this for the target they are tracking
 407                                 {
 408                                         targ = targetlist;
 409                                         while (targ)
 410                                         {
 411                                                 if (
 412                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 413                                                         && desirabledamage > 0.1*coredamage
 414                                                 )self.BUTTON_ATCK2 = TRUE;
 415                                                 targ = targ.chain;
 416                                         }
 417                                 }else{
 418                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 419                                         //As the distance gets larger, a correct detonation gets near imposible
 420                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 421                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 422                                                 if(self.enemy.classname == "player")
 423                                                         if(desirabledamage >= 0.1*coredamage)
 424                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 425                                                                         self.BUTTON_ATCK2 = TRUE;
 426                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 427                                 }
 428
 429                                 mine = find(mine, classname, "mine");
 430                         }
 431                         // if we would be doing at X percent of the core damage, detonate it
 432                         // but don't fire a new shot at the same time!
 433                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 434                                 self.BUTTON_ATCK2 = TRUE;
 435                         if ((skill > 6.5) && (selfdamage > self.health))
 436                                 self.BUTTON_ATCK2 = FALSE;
 437                         //if(self.BUTTON_ATCK2 == TRUE)
 438                         //      dprint(ftos(desirabledamage),"\n");
 439                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 440                 }
 441         }
 442         else if (req == WR_THINK)
 443         {
 444                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 445                 {
 446                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 447                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 448                                 weapon_action(self.weapon, WR_RELOAD);
 449                 }
 450                 else if (self.BUTTON_ATCK)
 451                 {
 452                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 453                         {
 454                                 W_Mine_Attack();
 455                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 456                         }
 457                 }
 458
 459                 if (self.BUTTON_ATCK2)
 460                 {
 461                         if(W_PlacedMines(TRUE))
 462                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 463                 }
 464         }
 465         else if (req == WR_PRECACHE)
 466         {
 467                 precache_model ("models/flash.md3");
 468                 precache_model ("models/mine.md3");
 469                 precache_model ("models/weapons/g_minelayer.md3");
 470                 precache_model ("models/weapons/v_minelayer.md3");
 471                 precache_model ("models/weapons/h_minelayer.iqm");
 472                 precache_sound ("weapons/mine_det.wav");
 473                 precache_sound ("weapons/mine_fire.wav");
 474                 precache_sound ("weapons/mine_stick.wav");
 475                 precache_sound ("weapons/mine_trigger.wav");
 476                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 477         }
 478         else if (req == WR_SETUP)
 479         {
 480                 weapon_setup(WEP_MINE_LAYER);
 481                 self.current_ammo = ammo_rockets;
 482         }
 483         else if (req == WR_CHECKAMMO1)
 484         {
 485                 // don't switch while placing a mine
 486                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 487                 {
 488                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 489                         ammo_amount += self.weapon_load[WEP_MINE_LAYER] >= autocvar_g_balance_minelayer_ammo;
 490                         return ammo_amount;
 491                 }
 492         }
 493         else if (req == WR_CHECKAMMO2)
 494         {
 495                 if (W_PlacedMines(FALSE))
 496                         return TRUE;
 497                 else
 498                         return FALSE;
 499         }
 500         else if (req == WR_RELOAD)
 501         {
 502                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 503         }
 504         return TRUE;
 505 };
 506 #endif
 507 #ifdef CSQC
 508 float w_minelayer(float req)
 509 {
 510         if(req == WR_IMPACTEFFECT)
 511         {
 512                 vector org2;
 513                 org2 = w_org + w_backoff * 12;
 514                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 515                 if(!w_issilent)
 516                         sound(self, CH_SHOTS_SINGLE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 517         }
 518         else if(req == WR_PRECACHE)
 519         {
 520                 precache_sound("weapons/mine_exp.wav");
 521         }
 522         else if (req == WR_SUICIDEMESSAGE)
 523                 w_deathtypestring = _("%s exploded");
 524         else if (req == WR_KILLMESSAGE)
 525         {
 526                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 527                         w_deathtypestring = _("%s got too close to %s's mine");
 528                 else if(w_deathtype & HITTYPE_SPLASH)
 529                         w_deathtypestring = _("%s almost dodged %s's mine");
 530                 else
 531                         w_deathtypestring = _("%s stepped on %s's mine");
 532         }
 533         return TRUE;
 534 }
 535 #endif
 536 #endif