qcsrc/server/w_minstanex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MINSTANEX,
   4 /* function  */ w_minstanex,
   5 /* ammotype  */ IT_CELLS,
   6 /* impulse   */ 7,
   7 /* flags     */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* model     */ "minstanex",
  10 /* shortname */ "minstanex",
  11 /* fullname  */ _("MinstaNex")
  12 );
  13 #else
  14 #ifdef SVQC
  15 .float minstanex_lasthit;
  16 .float jump_interval;
  17
  18 void W_MinstaNex_Attack (void)
  19 {
  20         float flying;
  21         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  22
  23         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  24
  25         yoda = 0;
  26         damage_goodhits = 0;
  27         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_MINSTANEX);
  28
  29         if(yoda && flying)
  30                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  31         if(damage_goodhits && self.minstanex_lasthit)
  32         {
  33                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  34                 damage_goodhits = 0; // only every second time
  35         }
  36
  37         self.minstanex_lasthit = damage_goodhits;
  38
  39         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  40
  41         // teamcolor / hit beam effect
  42         vector v;
  43         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  44         switch(self.team)
  45         {
  46                 case NUM_TEAM_1:   // Red
  47                         if(damage_goodhits)
  48                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  49                         else
  50                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  51                         break;
  52                 case NUM_TEAM_2:   // Blue
  53                         if(damage_goodhits)
  54                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  55                         else
  56                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  57                         break;
  58                 case NUM_TEAM_3:   // Yellow
  59                         if(damage_goodhits)
  60                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  61                         else
  62                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  63                         break;
  64                 case NUM_TEAM_4:   // Pink
  65                         if(damage_goodhits)
  66                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
  67                         else
  68                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
  69                         break;
  70                 default:
  71                         if(damage_goodhits)
  72                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
  73                         else
  74                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
  75                         break;
  76         }
  77
  78         W_DecreaseAmmo(ammo_cells, ((g_minstagib) ? 1 : autocvar_g_balance_minstanex_ammo), autocvar_g_balance_minstanex_reload_ammo);
  79 }
  80
  81 void spawnfunc_weapon_minstanex (void); // defined in t_items.qc
  82
  83 float w_minstanex(float req)
  84 {
  85         float ammo_amount;
  86         float minstanex_ammo;
  87
  88         // now multiple WR_s use this
  89         minstanex_ammo = ((g_minstagib) ? 1 : autocvar_g_balance_minstanex_ammo);
  90
  91         if (req == WR_AIM)
  92         {
  93                 if(self.ammo_cells > 0)
  94                         self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  95                 else
  96                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_laser_primary_speed, 0, autocvar_g_balance_laser_primary_lifetime, FALSE);
  97         }
  98         else if (req == WR_THINK)
  99         {
 100                 // if the laser uses load, we also consider its ammo for reloading
 101                 if(autocvar_g_balance_minstanex_reload_ammo && autocvar_g_balance_minstanex_laser_ammo && self.clip_load < min(minstanex_ammo, autocvar_g_balance_minstanex_laser_ammo)) // forced reload
 102                         weapon_action(self.weapon, WR_RELOAD);
 103                 else if(autocvar_g_balance_minstanex_reload_ammo && self.clip_load < minstanex_ammo) // forced reload
 104                         weapon_action(self.weapon, WR_RELOAD);
 105                 else if (self.BUTTON_ATCK)
 106                 {
 107                         if (weapon_prepareattack(0, autocvar_g_balance_minstanex_refire))
 108                         {
 109                                 W_MinstaNex_Attack();
 110                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minstanex_animtime, w_ready);
 111                         }
 112                 }
 113                 else if (self.BUTTON_ATCK2)
 114                 {
 115                         if (self.jump_interval <= time)
 116                         if (weapon_prepareattack(1, -1))
 117                         {
 118                                 // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 119                                 self.jump_interval = time + autocvar_g_balance_minstanex_laser_refire * W_WeaponRateFactor();
 120
 121                                 // decrease ammo for the laser?
 122                                 if(autocvar_g_balance_minstanex_laser_ammo)
 123                                         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_minstanex_laser_ammo, autocvar_g_balance_minstanex_reload_ammo);
 124
 125                                 // ugly minstagib hack to reuse the fire mode of the laser
 126                                 float w;
 127                                 w = self.weapon;
 128                                 self.weapon = WEP_LASER;
 129                                 W_Laser_Attack(2);
 130                                 self.weapon = w;
 131
 132                                 // now do normal refire
 133                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_minstanex_laser_animtime, w_ready);
 134                         }
 135                 }
 136         }
 137         else if (req == WR_PRECACHE)
 138         {
 139                 precache_model ("models/nexflash.md3");
 140                 precache_model ("models/weapons/g_minstanex.md3");
 141                 precache_model ("models/weapons/v_minstanex.md3");
 142                 precache_model ("models/weapons/h_minstanex.iqm");
 143                 precache_sound ("weapons/minstanexfire.wav");
 144                 precache_sound ("weapons/nexwhoosh1.wav");
 145                 precache_sound ("weapons/nexwhoosh2.wav");
 146                 precache_sound ("weapons/nexwhoosh3.wav");
 147                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 148                 w_laser(WR_PRECACHE);
 149         }
 150         else if (req == WR_SETUP)
 151         {
 152                 weapon_setup(WEP_MINSTANEX);
 153                 self.current_ammo = ammo_cells;
 154                 self.minstanex_lasthit = 0;
 155         }
 156         else if (req == WR_CHECKAMMO1)
 157         {
 158                 ammo_amount = self.ammo_cells >= minstanex_ammo;
 159                 ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= minstanex_ammo;
 160                 return ammo_amount;
 161         }
 162         else if (req == WR_CHECKAMMO2)
 163         {
 164                 if(!autocvar_g_balance_minstanex_laser_ammo)
 165                         return TRUE;
 166                 ammo_amount = self.ammo_cells >= autocvar_g_balance_minstanex_laser_ammo;
 167                 ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= autocvar_g_balance_minstanex_laser_ammo;
 168                 return ammo_amount;
 169         }
 170         else if (req == WR_RESETPLAYER)
 171         {
 172                 self.minstanex_lasthit = 0;
 173         }
 174         else if (req == WR_RELOAD)
 175         {
 176                 float used_ammo;
 177                 if(autocvar_g_balance_minstanex_laser_ammo)
 178                         used_ammo = min(minstanex_ammo, autocvar_g_balance_minstanex_laser_ammo);
 179                 else
 180                         used_ammo = minstanex_ammo;
 181
 182                 W_Reload(used_ammo, autocvar_g_balance_minstanex_reload_ammo, autocvar_g_balance_minstanex_reload_time, "weapons/reload.wav");
 183         }
 184         else if (req == WR_SUICIDEMESSAGE)
 185         {
 186                 return WEAPON_THINKING_WITH_PORTALS;
 187         }
 188         else if (req == WR_KILLMESSAGE)
 189         {
 190                 return WEAPON_MINSTANEX_MURDER;
 191         }
 192         return TRUE;
 193 }
 194 #endif
 195 #ifdef CSQC
 196 float w_minstanex(float req)
 197 {
 198         if(req == WR_IMPACTEFFECT)
 199         {
 200                 vector org2;
 201                 org2 = w_org + w_backoff * 6;
 202                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 203                 if(!w_issilent)
 204                         sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTEN_NORM);
 205         }
 206         else if(req == WR_PRECACHE)
 207         {
 208                 precache_sound("weapons/neximpact.wav");
 209         }
 210         return TRUE;
 211 }
 212 #endif
 213 #endif