qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
   3 #else
   4 #ifdef SVQC
   5 void SendCSQCNexBeamParticle(float charge) {
   6         vector v;
   7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  10         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  11         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  13         WriteCoord(MSG_BROADCAST, v_x);
  14         WriteCoord(MSG_BROADCAST, v_y);
  15         WriteCoord(MSG_BROADCAST, v_z);
  16         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  17 }
  18
  19 void W_Nex_Attack (float issecondary)
  20 {
  21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  22         if(issecondary)
  23         {
  24                 mydmg = cvar("g_balance_nex_secondary_damage");
  25                 myforce = cvar("g_balance_nex_secondary_force");
  26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
  27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
  28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
  29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
  30                 myammo = cvar("g_balance_nex_secondary_ammo");
  31         }
  32         else
  33         {
  34                 mydmg = cvar("g_balance_nex_primary_damage");
  35                 myforce = cvar("g_balance_nex_primary_force");
  36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
  37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
  38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
  39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
  40                 myammo = cvar("g_balance_nex_primary_ammo");
  41         }
  42
  43         float flying;
  44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  45
  46         if(cvar("g_balance_nex_charge"))
  47         {
  48                 charge = cvar("g_balance_nex_charge_mindmg") / mydmg + (1 - cvar("g_balance_nex_charge_mindmg") / mydmg) * self.nex_charge;
  49                 self.nex_charge *= cvar("g_balance_nex_charge_shot_multiplier"); // do this AFTER setting mydmg/myforce
  50                                                                                  // O RLY? -- divVerent
  51         }
  52         else
  53                 charge = 1;
  54         mydmg *= charge;
  55         myforce *= charge;
  56
  57         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
  58
  59         yoda = 0;
  60         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  61
  62         if(yoda && flying)
  63                 AnnounceTo(self, "yoda");
  64
  65         //beam and muzzle flash done on client
  66         SendCSQCNexBeamParticle(charge);
  67
  68         // flash and burn the wall
  69         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  70                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  71
  72         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  73                 self.ammo_cells = self.ammo_cells - myammo;
  74 }
  75
  76 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  77
  78 .float nex_charge_pool_pauseregen_finished;
  79 float w_nex(float req)
  80 {
  81         float dt;
  82         if (req == WR_AIM)
  83         {
  84                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  85                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
  86         }
  87         else if (req == WR_THINK)
  88         {
  89                 if(cvar("g_balance_nex_charge") && self.nex_charge < cvar("g_balance_nex_charge_limit"))
  90                         self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_rate") * frametime / W_TICSPERFRAME);
  91
  92                 if(cvar("g_balance_nex_secondary_charge_pool"))
  93                 if(self.nex_charge_pool_ammo < 1)
  94                 {
  95                         if(self.nex_charge_pool_pauseregen_finished < time)
  96                                 self.nex_charge_pool_ammo = min(1, self.nex_charge_pool_ammo + cvar("g_balance_nex_secondary_charge_pool_regen") * frametime / W_TICSPERFRAME);
  97                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_nex_secondary_charge_pool_pause_health_regen"));
  98                 }
  99
 100                 if (self.BUTTON_ATCK)
 101                 {
 102                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
 103                         {
 104                                 W_Nex_Attack(0);
 105                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
 106                         }
 107                 }
 108                 if (self.BUTTON_ATCK2)
 109                 {
 110                         if(cvar("g_balance_nex_secondary_charge"))
 111                         {
 112                                 self.nex_charge_rottime = time + cvar("g_balance_nex_charge_rot_pause");
 113                                 dt = frametime / W_TICSPERFRAME;
 114
 115                                 if(cvar("g_balance_nex_secondary_charge_pool"))
 116                                 {
 117                                         if(cvar("g_balance_nex_secondary_ammo"))
 118                                         {
 119                                                 // always deplete if secondary is held
 120                                                 self.nex_charge_pool_ammo = max(0, self.nex_charge_pool_ammo - cvar("g_balance_nex_secondary_ammo") * dt);
 121
 122                                                 dt = min(dt, (1 - self.nex_charge) / cvar("g_balance_nex_secondary_charge_rate"));
 123                                                 self.nex_charge_pool_pauseregen_finished = time + cvar("g_balance_nex_secondary_charge_pool_pause_regen");
 124                                                 dt = min(dt, self.nex_charge_pool_ammo);
 125                                                 dt = max(0, dt);
 126
 127                                                 self.nex_charge += dt * cvar("g_balance_nex_secondary_charge_rate");
 128                                         }
 129                                 }
 130
 131                                 else if(cvar("g_balance_nex_secondary_ammo"))
 132                                 {
 133                                         if(self.nex_charge < 1)
 134                                         {
 135                                                 dt = min(dt, (1 - self.nex_charge) / cvar("g_balance_nex_secondary_charge_rate"));
 136                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 137                                                 {
 138                                                         dt = min(dt, (self.ammo_cells - cvar("g_balance_nex_primary_ammo")) / cvar("g_balance_nex_secondary_ammo"));
 139                                                         dt = max(0, dt);
 140                                                         if(dt > 0)
 141                                                         {
 142                                                                 self.ammo_cells = max(cvar("g_balance_nex_secondary_ammo"), self.ammo_cells - cvar("g_balance_nex_secondary_ammo") * dt);
 143                                                         }
 144                                                 }
 145                                                 self.nex_charge += dt * cvar("g_balance_nex_secondary_charge_rate");
 146                                         }
 147                                 }
 148                         }
 149                         else if(cvar("g_balance_nex_secondary"))
 150                         {
 151                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
 152                                 {
 153                                         W_Nex_Attack(1);
 154                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
 155                                 }
 156                         }
 157                 }
 158         }
 159         else if (req == WR_PRECACHE)
 160         {
 161                 precache_model ("models/nexflash.md3");
 162                 precache_model ("models/weapons/g_nex.md3");
 163                 precache_model ("models/weapons/v_nex.md3");
 164                 precache_model ("models/weapons/h_nex.iqm");
 165                 precache_sound ("weapons/nexfire.wav");
 166                 precache_sound ("weapons/nexwhoosh1.wav");
 167                 precache_sound ("weapons/nexwhoosh2.wav");
 168                 precache_sound ("weapons/nexwhoosh3.wav");
 169         }
 170         else if (req == WR_SETUP)
 171                 weapon_setup(WEP_NEX);
 172         else if (req == WR_CHECKAMMO1)
 173                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
 174         else if (req == WR_CHECKAMMO2)
 175                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo"); // don't allow charging if we don't have enough ammo
 176         return TRUE;
 177 };
 178 #endif
 179 #ifdef CSQC
 180 float w_nex(float req)
 181 {
 182         if(req == WR_IMPACTEFFECT)
 183         {
 184                 vector org2;
 185                 org2 = w_org + w_backoff * 6;
 186                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 187                 if(!w_issilent)
 188                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 189         }
 190         else if(req == WR_PRECACHE)
 191         {
 192                 precache_sound("weapons/neximpact.wav");
 193         }
 194         else if (req == WR_SUICIDEMESSAGE)
 195                 w_deathtypestring = "%s did the impossible";
 196         else if (req == WR_KILLMESSAGE)
 197                 w_deathtypestring = "%s has been vaporized by %s";
 198         return TRUE;
 199 }
 200 #endif
 201 #endif