change the glow on the nex depending on how charged it is (warning: looks pretty...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_nex.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
3 #else
4 #ifdef SVQC
5 void SendCSQCNexBeamParticle(float charge) {
6         vector v;
7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
10         WriteCoord(MSG_BROADCAST, w_shotorg_x);
11         WriteCoord(MSG_BROADCAST, w_shotorg_y);
12         WriteCoord(MSG_BROADCAST, w_shotorg_z);
13         WriteCoord(MSG_BROADCAST, v_x);
14         WriteCoord(MSG_BROADCAST, v_y);
15         WriteCoord(MSG_BROADCAST, v_z);
16         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
17 }
18
19 void W_Nex_Attack (float issecondary)
20 {
21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
22         if(issecondary)
23         {
24                 mydmg = cvar("g_balance_nex_secondary_damage");
25                 myforce = cvar("g_balance_nex_secondary_force");
26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
30                 myammo = cvar("g_balance_nex_secondary_ammo");
31         }
32         else
33         {
34                 mydmg = cvar("g_balance_nex_primary_damage");
35                 myforce = cvar("g_balance_nex_primary_force");
36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
40                 myammo = cvar("g_balance_nex_primary_ammo");
41         }
42
43         float flying;
44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
45
46         if(cvar("g_balance_nex_charge"))
47         {
48                 charge = cvar("g_balance_nex_charge_mindmg") / mydmg + (1 - cvar("g_balance_nex_charge_mindmg") / mydmg) * self.nex_charge;
49                 self.nex_charge *= cvar("g_balance_nex_charge_shot_multiplier"); // do this AFTER setting mydmg/myforce
50                                                                                  // O RLY? -- divVerent
51                                                                          // YA RLY -- FruitieX
52         }
53         else
54                 charge = 1;
55         mydmg *= charge;
56         myforce *= charge;
57
58         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CHAN_WEAPON, mydmg);
59     if(charge > cvar("g_balance_nex_charge_limit") && cvar("g_balance_nex_charge_limit")) // if the Nex is overcharged, we play an extra sound
60     {
61         sound (self, CHAN_WEAPON2, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * cvar("g_balance_nex_charge_limit")) / (1 - 0.5 * cvar("g_balance_nex_charge_limit")), ATTN_NORM);
62     }
63
64         yoda = 0;
65         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
66
67         if(yoda && flying)
68                 AnnounceTo(self, "yoda");
69
70         //beam and muzzle flash done on client
71         SendCSQCNexBeamParticle(charge);
72         
73         // flash and burn the wall
74         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
75                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
76
77         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
78                 self.ammo_cells = self.ammo_cells - myammo;
79 }
80
81 void spawnfunc_weapon_nex (void); // defined in t_items.qc
82
83 .float nex_charge_pool_pauseregen_finished;
84 float w_nex(float req)
85 {
86         float dt;
87         if (req == WR_AIM)
88         {
89                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
90                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
91         }
92         else if (req == WR_THINK)
93         {
94                 if(cvar("g_balance_nex_charge") && self.nex_charge < cvar("g_balance_nex_charge_limit"))
95                         self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_rate") * frametime / W_TICSPERFRAME);
96
97         if(cvar("g_balance_nex_charge"))
98         {
99             self.weaponentity.weaponentity.glowmod = '1 1 1' * self.nex_charge;
100             self.exteriorweaponentity.glowmod = '1 1 1' * self.nex_charge;
101             if(self.nex_charge > cvar("g_balance_nex_charge_limit"))
102             {
103                 self.weaponentity.weaponentity.glowmod_y -= 0.5 * (self.nex_charge - cvar("g_balance_nex_charge_limit")) / (1 - cvar("g_balance_nex_charge_limit"));
104                 self.weaponentity.weaponentity.glowmod_z -= 0.5 * (self.nex_charge - cvar("g_balance_nex_charge_limit")) / (1 - cvar("g_balance_nex_charge_limit"));
105             }
106         }
107
108                 if(cvar("g_balance_nex_secondary_charge_pool"))
109                 if(self.nex_charge_pool_ammo < 1)
110                 {
111                         if(self.nex_charge_pool_pauseregen_finished < time)
112                                 self.nex_charge_pool_ammo = min(1, self.nex_charge_pool_ammo + cvar("g_balance_nex_secondary_charge_pool_regen") * frametime / W_TICSPERFRAME);
113                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_nex_secondary_charge_pool_pause_health_regen"));
114                 }
115
116                 if (self.BUTTON_ATCK)
117                 {
118                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
119                         {
120                                 W_Nex_Attack(0);
121                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
122                         }
123                 }
124                 if (self.BUTTON_ATCK2)
125                 {
126                         if(cvar("g_balance_nex_secondary_charge"))
127                         {
128                                 self.nex_charge_rottime = time + cvar("g_balance_nex_charge_rot_pause");
129                                 dt = frametime / W_TICSPERFRAME;
130
131                                 if(cvar("g_balance_nex_secondary_charge_pool"))
132                                 {
133                                         if(cvar("g_balance_nex_secondary_ammo"))
134                                         {
135                                                 // always deplete if secondary is held
136                                                 self.nex_charge_pool_ammo = max(0, self.nex_charge_pool_ammo - cvar("g_balance_nex_secondary_ammo") * dt);
137
138                                                 dt = min(dt, (1 - self.nex_charge) / cvar("g_balance_nex_secondary_charge_rate"));
139                                                 self.nex_charge_pool_pauseregen_finished = time + cvar("g_balance_nex_secondary_charge_pool_pause_regen");
140                                                 dt = min(dt, self.nex_charge_pool_ammo);
141                                                 dt = max(0, dt);
142
143                                                 self.nex_charge += dt * cvar("g_balance_nex_secondary_charge_rate");
144                                         }
145                                 }
146
147                                 else if(cvar("g_balance_nex_secondary_ammo"))
148                                 {
149                                         if(self.nex_charge < 1)
150                                         {
151                                                 dt = min(dt, (1 - self.nex_charge) / cvar("g_balance_nex_secondary_charge_rate"));
152                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
153                                                 {
154                                                         dt = min(dt, (self.ammo_cells - cvar("g_balance_nex_primary_ammo")) / cvar("g_balance_nex_secondary_ammo"));
155                                                         dt = max(0, dt);
156                                                         if(dt > 0)
157                                                         {
158                                                                 self.ammo_cells = max(cvar("g_balance_nex_secondary_ammo"), self.ammo_cells - cvar("g_balance_nex_secondary_ammo") * dt);
159                                                         }
160                                                 }
161                                                 self.nex_charge += dt * cvar("g_balance_nex_secondary_charge_rate");
162                                         }
163                                 }
164                         }
165                         else if(cvar("g_balance_nex_secondary"))
166                         {
167                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
168                                 {
169                                         W_Nex_Attack(1);
170                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
171                                 }
172                         }
173                 }
174         }
175         else if (req == WR_PRECACHE)
176         {
177                 precache_model ("models/nexflash.md3");
178                 precache_model ("models/weapons/g_nex.md3");
179                 precache_model ("models/weapons/v_nex.md3");
180                 precache_model ("models/weapons/h_nex.iqm");
181                 precache_sound ("weapons/nexfire.wav");
182                 precache_sound ("weapons/nexwhoosh1.wav");
183                 precache_sound ("weapons/nexwhoosh2.wav");
184                 precache_sound ("weapons/nexwhoosh3.wav");
185         }
186         else if (req == WR_SETUP)
187                 weapon_setup(WEP_NEX);
188         else if (req == WR_CHECKAMMO1)
189                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
190         else if (req == WR_CHECKAMMO2)
191                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo"); // don't allow charging if we don't have enough ammo
192         return TRUE;
193 };
194 #endif
195 #ifdef CSQC
196 float w_nex(float req)
197 {
198         if(req == WR_IMPACTEFFECT)
199         {
200                 vector org2;
201                 org2 = w_org + w_backoff * 6;
202                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
203                 if(!w_issilent)
204                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
205         }
206         else if(req == WR_PRECACHE)
207         {
208                 precache_sound("weapons/neximpact.wav");
209         }
210         else if (req == WR_SUICIDEMESSAGE)
211                 w_deathtypestring = "%s did the impossible";
212         else if (req == WR_KILLMESSAGE)
213                 w_deathtypestring = "%s has been vaporized by %s";
214         return TRUE;
215 }
216 #endif
217 #endif