add a slow rot to 50% nex charge (even when not holding the gun), improve the current...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_nex.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
3 #else
4 #ifdef SVQC
5 void SendCSQCNexBeamParticle(float charge) {
6         vector v;
7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
10         WriteCoord(MSG_BROADCAST, w_shotorg_x);
11         WriteCoord(MSG_BROADCAST, w_shotorg_y);
12         WriteCoord(MSG_BROADCAST, w_shotorg_z);
13         WriteCoord(MSG_BROADCAST, v_x);
14         WriteCoord(MSG_BROADCAST, v_y);
15         WriteCoord(MSG_BROADCAST, v_z);
16         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
17 }
18
19 void W_Nex_Attack (float issecondary)
20 {
21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
22         if(issecondary)
23         {
24                 mydmg = cvar("g_balance_nex_secondary_damage");
25                 myforce = cvar("g_balance_nex_secondary_force");
26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
30                 myammo = cvar("g_balance_nex_secondary_ammo");
31         }
32         else
33         {
34                 mydmg = cvar("g_balance_nex_primary_damage");
35                 myforce = cvar("g_balance_nex_primary_force");
36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
40                 myammo = cvar("g_balance_nex_primary_ammo");
41         }
42
43         float flying;
44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
45
46         if(cvar("g_balance_nex_charge"))
47         {
48                 charge = cvar("g_balance_nex_charge_mindmg") / mydmg + (1 - cvar("g_balance_nex_charge_mindmg") / mydmg) * self.nex_charge;
49                 self.nex_charge = self.nex_charge * cvar("g_balance_nex_charge_shot_multiplier"); // do this AFTER setting mydmg/myforce
50         }
51         else
52                 charge = 1;
53         mydmg = mydmg * charge;
54         myforce = myforce * charge;
55
56         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
57
58         yoda = 0;
59         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
60
61         if(yoda && flying)
62                 AnnounceTo(self, "yoda");
63
64         //beam and muzzle flash done on client
65         SendCSQCNexBeamParticle(charge);
66         
67         // flash and burn the wall
68         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
69                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
70
71         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
72                 self.ammo_cells = self.ammo_cells - myammo;
73 }
74
75 void spawnfunc_weapon_nex (void); // defined in t_items.qc
76
77 float w_nex(float req)
78 {
79         float dt;
80         if (req == WR_AIM)
81         {
82                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
83                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
84         }
85         else if (req == WR_THINK)
86         {
87                 if(cvar("g_balance_nex_charge") && self.nex_charge < cvar("g_balance_nex_charge_limit"))
88                         self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_rate") * frametime / W_TICSPERFRAME);
89
90                 if (self.BUTTON_ATCK)
91                 {
92                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
93                         {
94                                 W_Nex_Attack(0);
95                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
96                         }
97                 }
98                 if (self.BUTTON_ATCK2)
99                 {
100                         if(cvar("g_balance_nex_secondary_charge"))
101                         {
102                                 dt = frametime / W_TICSPERFRAME;
103                                 if(self.nex_charge < 1)
104                                 {
105                                         dt = min(dt, (1 - self.nex_charge) / cvar("g_balance_nex_secondary_charge_rate"));
106                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
107                                         {
108                                                 if(cvar("g_balance_nex_secondary_ammo"))
109                                                 {
110                                                         dt = min(dt, (self.ammo_cells - cvar("g_balance_nex_primary_ammo")) / cvar("g_balance_nex_secondary_ammo"));
111                                                         dt = max(0, dt);
112                                                         if(dt > 0)
113                                                         {
114                                                                 self.ammo_cells = max(cvar("g_balance_nex_secondary_ammo"), self.ammo_cells - cvar("g_balance_nex_secondary_ammo") * dt);
115                                                         }
116                                                 }
117                                         }
118                                         self.nex_charge += dt * cvar("g_balance_nex_secondary_charge_rate");
119                                 }
120                         }
121                         else if(cvar("g_balance_nex_secondary"))
122                         {
123                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
124                                 {
125                                         W_Nex_Attack(1);
126                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
127                                 }
128                         }
129                 }
130         }
131         else if (req == WR_PRECACHE)
132         {
133                 precache_model ("models/nexflash.md3");
134                 precache_model ("models/weapons/g_nex.md3");
135                 precache_model ("models/weapons/v_nex.md3");
136                 precache_model ("models/weapons/h_nex.iqm");
137                 precache_sound ("weapons/nexfire.wav");
138                 precache_sound ("weapons/nexwhoosh1.wav");
139                 precache_sound ("weapons/nexwhoosh2.wav");
140                 precache_sound ("weapons/nexwhoosh3.wav");
141         }
142         else if (req == WR_SETUP)
143                 weapon_setup(WEP_NEX);
144         else if (req == WR_CHECKAMMO1)
145                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
146         else if (req == WR_CHECKAMMO2)
147         {
148                 if(cvar("g_balance_nex_secondary_charge"))
149                         return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
150                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
151         }
152         return TRUE;
153 };
154 #endif
155 #ifdef CSQC
156 float w_nex(float req)
157 {
158         if(req == WR_IMPACTEFFECT)
159         {
160                 vector org2;
161                 org2 = w_org + w_backoff * 6;
162                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
163                 if(!w_issilent)
164                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
165         }
166         else if(req == WR_PRECACHE)
167         {
168                 precache_sound("weapons/neximpact.wav");
169         }
170         else if (req == WR_SUICIDEMESSAGE)
171                 w_deathtypestring = "%s did the impossible";
172         else if (req == WR_KILLMESSAGE)
173                 w_deathtypestring = "%s has been vaporized by %s";
174         return TRUE;
175 }
176 #endif
177 #endif