only add a "base charge" up to 50%
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_nex.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
3 #else
4 #ifdef SVQC
5 void SendCSQCNexBeamParticle() {
6         vector v;
7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
10         
11         WriteCoord(MSG_BROADCAST, w_shotorg_x);
12         WriteCoord(MSG_BROADCAST, w_shotorg_y);
13         WriteCoord(MSG_BROADCAST, w_shotorg_z);
14         WriteCoord(MSG_BROADCAST, v_x);
15         WriteCoord(MSG_BROADCAST, v_y);
16         WriteCoord(MSG_BROADCAST, v_z);
17 }
18
19 void W_Nex_Attack (float issecondary)
20 {
21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo;
22         if(issecondary)
23         {
24                 mydmg = cvar("g_balance_nex_secondary_damage");
25                 myforce = cvar("g_balance_nex_secondary_force");
26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
30                 myammo = cvar("g_balance_nex_secondary_ammo");
31         }
32         else
33         {
34                 mydmg = cvar("g_balance_nex_primary_damage");
35                 myforce = cvar("g_balance_nex_primary_force");
36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
40                 myammo = cvar("g_balance_nex_primary_ammo");
41         }
42
43         float flying;
44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
45
46         if(cvar("g_balance_nex_charge"))
47         {
48                 mydmg *= self.nex_charge;
49                 myforce *= self.nex_charge;
50                 //print("^1Damage: ^7", ftos(mydmg), "\n");
51                 self.nex_charge *= cvar("g_balance_nex_charge_shot_multiplier"); // do this AFTER setting mydmg/myforce
52         }
53
54         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
55
56         yoda = 0;
57         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
58
59         if(yoda && flying)
60                 AnnounceTo(self, "yoda");
61
62         //beam and muzzle flash done on client
63         SendCSQCNexBeamParticle();
64         
65         // flash and burn the wall
66         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
67                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
68
69         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
70                 self.ammo_cells = self.ammo_cells - myammo;
71 }
72
73 void spawnfunc_weapon_nex (void); // defined in t_items.qc
74
75 float w_nex(float req)
76 {
77         if (req == WR_AIM)
78         {
79                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
80                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
81         }
82         else if (req == WR_THINK)
83         {
84                 if(cvar("g_balance_nex_charge") && self.nex_charge < cvar("g_balance_nex_charge_limit"))
85                         self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_rate") * frametime / W_TICSPERFRAME);
86                 if (self.BUTTON_ATCK)
87                 {
88                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
89                         {
90                                 W_Nex_Attack(0);
91                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
92                         }
93                 }
94                 if (self.BUTTON_ATCK2)
95                 {
96                         if(cvar("g_balance_nex_secondary_charge"))
97                         {
98                                 if(self.ammo_cells)
99                                 {
100                                         self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_secondary_charge_rate") * frametime / W_TICSPERFRAME);
101                                         self.ammo_cells = max(0, self.ammo_cells - cvar("g_balance_nex_secondary_ammo") * frametime / W_TICSPERFRAME);
102                                 }
103                         }
104                         else if(cvar("g_balance_nex_secondary"))
105                         {
106                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
107                                 {
108                                         W_Nex_Attack(1);
109                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
110                                 }
111                         }
112                 }
113         }
114         else if (req == WR_PRECACHE)
115         {
116                 precache_model ("models/nexflash.md3");
117                 precache_model ("models/weapons/g_nex.md3");
118                 precache_model ("models/weapons/v_nex.md3");
119                 precache_model ("models/weapons/h_nex.iqm");
120                 precache_sound ("weapons/nexfire.wav");
121                 precache_sound ("weapons/nexwhoosh1.wav");
122                 precache_sound ("weapons/nexwhoosh2.wav");
123                 precache_sound ("weapons/nexwhoosh3.wav");
124         }
125         else if (req == WR_SETUP)
126                 weapon_setup(WEP_NEX);
127         else if (req == WR_CHECKAMMO1)
128                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
129         else if (req == WR_CHECKAMMO2)
130                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
131         return TRUE;
132 };
133 #endif
134 #ifdef CSQC
135 float w_nex(float req)
136 {
137         if(req == WR_IMPACTEFFECT)
138         {
139                 vector org2;
140                 org2 = w_org + w_backoff * 6;
141                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
142                 if(!w_issilent)
143                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
144         }
145         else if(req == WR_PRECACHE)
146         {
147                 precache_sound("weapons/neximpact.wav");
148         }
149         else if (req == WR_SUICIDEMESSAGE)
150                 w_deathtypestring = "%s did the impossible";
151         else if (req == WR_KILLMESSAGE)
152                 w_deathtypestring = "%s has been vaporized by %s";
153         return TRUE;
154 }
155 #endif
156 #endif