Merge remote branch 'origin/fruitiex/loadblackbg'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_nex.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
3 #else
4 #ifdef SVQC
5 void SendCSQCNexBeamParticle() {
6         vector v;
7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
10         
11         WriteCoord(MSG_BROADCAST, w_shotorg_x);
12         WriteCoord(MSG_BROADCAST, w_shotorg_y);
13         WriteCoord(MSG_BROADCAST, w_shotorg_z);
14         WriteCoord(MSG_BROADCAST, v_x);
15         WriteCoord(MSG_BROADCAST, v_y);
16         WriteCoord(MSG_BROADCAST, v_z);
17 }
18
19 void W_Nex_Attack (float issecondary)
20 {
21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, f;
22         if(issecondary)
23         {
24                 mydmg = cvar("g_balance_nex_secondary_damage");
25                 myforce = cvar("g_balance_nex_secondary_force");
26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
30                 myammo = cvar("g_balance_nex_secondary_ammo");
31         }
32         else
33         {
34                 mydmg = cvar("g_balance_nex_primary_damage");
35                 myforce = cvar("g_balance_nex_primary_force");
36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
40                 myammo = cvar("g_balance_nex_primary_ammo");
41         }
42
43         float flying;
44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
45
46         f = ExponentialFalloff(cvar("g_balance_nex_velocitydependent_minspeed"), cvar("g_balance_nex_velocitydependent_maxspeed"), cvar("g_balance_nex_velocitydependent_halflife"), self.nexspeed);
47
48         // TODO: make it more obvious (through effects, indicator on weapon) that damage increases when speed increases
49         mydmg *= f;
50         myforce *= f;
51         //print("^1Damage: ^7", ftos(mydmg), "\n");
52
53         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
54
55         yoda = 0;
56         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
57
58         if(yoda && flying)
59                 AnnounceTo(self, "yoda");
60
61         //beam and muzzle flash done on client
62         SendCSQCNexBeamParticle();
63         
64         // flash and burn the wall
65         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
66                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
67
68         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
69                 self.ammo_cells = self.ammo_cells - myammo;
70 }
71
72 void spawnfunc_weapon_nex (void); // defined in t_items.qc
73
74 float w_nex(float req)
75 {
76         if (req == WR_AIM)
77         {
78                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
79                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
80         }
81         else if (req == WR_THINK)
82         {
83                 if (self.BUTTON_ATCK)
84                 {
85                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
86                         {
87                                 W_Nex_Attack(0);
88                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
89                         }
90                 }
91                 if (self.BUTTON_ATCK2)
92                 {
93                         if(cvar("g_balance_nex_secondary_charge"))
94                         {
95                                 if(self.ammo_cells)
96                                 {
97                                         self.nexspeed = min(cvar("g_balance_nex_velocitydependent_maxspeed"), self.nexspeed + cvar("g_balance_nex_secondary_charge_rate") * frametime / W_TICSPERFRAME);
98                                         self.ammo_cells = max(0, self.ammo_cells - cvar("g_balance_nex_secondary_charge_ammo") * frametime / W_TICSPERFRAME);
99                                 }
100                         }
101                         else if(cvar("g_balance_nex_secondary"))
102                         {
103                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
104                                 {
105                                         W_Nex_Attack(1);
106                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
107                                 }
108                         }
109                 }
110         }
111         else if (req == WR_PRECACHE)
112         {
113                 precache_model ("models/nexflash.md3");
114                 precache_model ("models/weapons/g_nex.md3");
115                 precache_model ("models/weapons/v_nex.md3");
116                 precache_model ("models/weapons/h_nex.iqm");
117                 precache_sound ("weapons/nexfire.wav");
118                 precache_sound ("weapons/nexwhoosh1.wav");
119                 precache_sound ("weapons/nexwhoosh2.wav");
120                 precache_sound ("weapons/nexwhoosh3.wav");
121         }
122         else if (req == WR_SETUP)
123                 weapon_setup(WEP_NEX);
124         else if (req == WR_CHECKAMMO1)
125                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
126         else if (req == WR_CHECKAMMO2)
127                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
128         return TRUE;
129 };
130 #endif
131 #ifdef CSQC
132 float w_nex(float req)
133 {
134         if(req == WR_IMPACTEFFECT)
135         {
136                 vector org2;
137                 org2 = w_org + w_backoff * 6;
138                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
139                 if(!w_issilent)
140                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
141         }
142         else if(req == WR_PRECACHE)
143         {
144                 precache_sound("weapons/neximpact.wav");
145         }
146         else if (req == WR_SUICIDEMESSAGE)
147                 w_deathtypestring = "%s did the impossible";
148         else if (req == WR_KILLMESSAGE)
149                 w_deathtypestring = "%s has been vaporized by %s";
150         return TRUE;
151 }
152 #endif
153 #endif