qcsrc/server/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(PORTO, w_porto, 0, 0, WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON, 0, "porto" , "porto", _("Port-O-Launch"))
   3 #else
   4 #ifdef SVQC
   5 .entity porto_current;
   6 .vector porto_v_angle; // holds "held" view angles
   7 .float porto_v_angle_held;
   8 .vector right_vector;
   9
  10 void W_Porto_Success (void)
  11 {
  12         if(self.realowner == world)
  13         {
  14                 objerror("Cannot succeed successfully: no owner\n");
  15                 return;
  16         }
  17
  18         self.realowner.porto_current = world;
  19         remove(self);
  20 }
  21
  22 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  23 void W_Porto_Fail (float failhard)
  24 {
  25         if(self.realowner == world)
  26         {
  27                 objerror("Cannot fail successfully: no owner\n");
  28                 return;
  29         }
  30
  31         // no portals here!
  32         if(self.cnt < 0)
  33         {
  34                 Portal_ClearWithID(self.realowner, self.portal_id);
  35         }
  36
  37         self.realowner.porto_current = world;
  38
  39         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !WEPSET_CONTAINS_EW(self.realowner, WEP_PORTO))
  40         {
  41                 setsize (self, '-16 -16 0', '16 16 32');
  42                 setorigin(self, self.origin + trace_plane_normal);
  43                 if(move_out_of_solid(self))
  44                 {
  45                         self.flags = FL_ITEM;
  46                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  47                         tracetoss(self, self);
  48                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  49                         {
  50                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  51                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  52                         }
  53                 }
  54         }
  55         remove(self);
  56 }
  57
  58 void W_Porto_Remove (entity p)
  59 {
  60         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  61         {
  62                 entity oldself;
  63                 oldself = self;
  64                 self = p.porto_current;
  65                 W_Porto_Fail(1);
  66                 self = oldself;
  67         }
  68 }
  69
  70 void W_Porto_Think (void)
  71 {
  72         trace_plane_normal = '0 0 0';
  73         if(self.realowner.playerid != self.playerid)
  74                 remove(self);
  75         else
  76                 W_Porto_Fail(0);
  77 }
  78
  79 void W_Porto_Touch (void)
  80 {
  81         vector norm;
  82
  83         // do not use PROJECTILE_TOUCH here
  84         // FIXME but DO handle warpzones!
  85
  86         if(other.classname == "portal")
  87                 return; // handled by the portal
  88
  89         norm = trace_plane_normal;
  90         if(trace_ent.iscreature)
  91         {
  92                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
  93                 if(trace_fraction >= 1)
  94                         return;
  95                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  96                         return;
  97                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  98                         return;
  99         }
 100
 101         if(self.realowner.playerid != self.playerid)
 102         {
 103                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 104                 remove(self);
 105         }
 106         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 107         {
 108                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTN_NORM);
 109                 // just reflect
 110                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 111                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 112         }
 113         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 114         {
 115                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 116                 W_Porto_Fail(0);
 117                 if(self.cnt < 0)
 118                         Portal_ClearAll_PortalsOnly(self.realowner);
 119         }
 120         else if(self.cnt == 0)
 121         {
 122                 // in-portal only
 123                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 124                 {
 125                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 126                         trace_plane_normal = norm;
 127                         centerprint(self.realowner, "^1In^7-portal created.");
 128                         W_Porto_Success();
 129                 }
 130                 else
 131                 {
 132                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 133                         trace_plane_normal = norm;
 134                         W_Porto_Fail(0);
 135                 }
 136         }
 137         else if(self.cnt == 1)
 138         {
 139                 // out-portal only
 140                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 141                 {
 142                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 143                         trace_plane_normal = norm;
 144                         centerprint(self.realowner, "^1Out^7-portal created.");
 145                         W_Porto_Success();
 146                 }
 147                 else
 148                 {
 149                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 150                         trace_plane_normal = norm;
 151                         W_Porto_Fail(0);
 152                 }
 153         }
 154         else if(self.effects & EF_RED)
 155         {
 156                 self.effects += EF_BLUE - EF_RED;
 157                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 158                 {
 159                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 160                         trace_plane_normal = norm;
 161                         centerprint(self.realowner, "^1In^7-portal created.");
 162                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 163                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 164                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 165                 }
 166                 else
 167                 {
 168                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 169                         trace_plane_normal = norm;
 170                         Portal_ClearAll_PortalsOnly(self.realowner);
 171                         W_Porto_Fail(0);
 172                 }
 173         }
 174         else
 175         {
 176                 if(self.realowner.portal_in.portal_id == self.portal_id)
 177                 {
 178                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 179                         {
 180                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 181                                 trace_plane_normal = norm;
 182                                 centerprint(self.realowner, "^4Out^7-portal created.");
 183                                 W_Porto_Success();
 184                         }
 185                         else
 186                         {
 187                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 188                                 Portal_ClearAll_PortalsOnly(self.realowner);
 189                                 W_Porto_Fail(0);
 190                         }
 191                 }
 192                 else
 193                 {
 194                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 195                         Portal_ClearAll_PortalsOnly(self.realowner);
 196                         W_Porto_Fail(0);
 197                 }
 198         }
 199 }
 200
 201 void W_Porto_Attack (float type)
 202 {
 203         entity gren;
 204
 205         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 206         // always shoot from the eye
 207         w_shotdir = v_forward;
 208         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 209
 210         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 211
 212         gren = spawn ();
 213         gren.cnt = type;
 214         gren.owner = gren.realowner = self;
 215         gren.playerid = self.playerid;
 216         gren.classname = "porto";
 217         gren.bot_dodge = TRUE;
 218         gren.bot_dodgerating = 200;
 219         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 220         PROJECTILE_MAKETRIGGER(gren);
 221         gren.effects = EF_RED;
 222         gren.scale = 4;
 223         setorigin(gren, w_shotorg);
 224         setsize(gren, '0 0 0', '0 0 0');
 225
 226         if(type > 0)
 227                 gren.nextthink = time + autocvar_g_balance_porto_secondary_lifetime;
 228         else
 229                 gren.nextthink = time + autocvar_g_balance_porto_primary_lifetime;
 230         gren.think = W_Porto_Think;
 231         gren.touch = W_Porto_Touch;
 232
 233         if(type > 0)
 234         {
 235                 if(self.items & IT_STRENGTH)
 236                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_secondary_speed * autocvar_g_balance_powerup_strength_force, 0);
 237                 else
 238                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_secondary_speed, 0);
 239         }
 240         else
 241         {
 242                 if(self.items & IT_STRENGTH)
 243                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_primary_speed * autocvar_g_balance_powerup_strength_force, 0);
 244                 else
 245                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_primary_speed, 0);
 246         }
 247
 248         gren.angles = vectoangles (gren.velocity);
 249         gren.flags = FL_PROJECTILE;
 250
 251         gren.portal_id = time;
 252         self.porto_current = gren;
 253         gren.playerid = self.playerid;
 254         fixedmakevectors(fixedvectoangles(gren.velocity));
 255         gren.right_vector = v_right;
 256
 257         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 258
 259         if(type > 0)
 260                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 261         else
 262                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 263
 264         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 265 }
 266
 267 void spawnfunc_weapon_porto (void)
 268 {
 269         weapon_defaultspawnfunc(WEP_PORTO);
 270 }
 271
 272 float w_nexball_weapon(float req);
 273 float w_porto(float req)
 274 {
 275         //vector v_angle_save;
 276
 277         if (g_nexball) { return w_nexball_weapon(req); }
 278         if (req == WR_AIM)
 279         {
 280                 self.BUTTON_ATCK = FALSE;
 281                 self.BUTTON_ATCK2 = FALSE;
 282                 if(!autocvar_g_balance_porto_secondary)
 283                         if(bot_aim(autocvar_g_balance_porto_primary_speed, 0, autocvar_g_balance_grenadelauncher_primary_lifetime, FALSE))
 284                                 self.BUTTON_ATCK = TRUE;
 285         }
 286         else if (req == WR_THINK)
 287         {
 288                 if(autocvar_g_balance_porto_secondary)
 289                 {
 290                         if (self.BUTTON_ATCK)
 291                         if (!self.porto_current)
 292                         if (!self.porto_forbidden)
 293                         if (weapon_prepareattack(0, autocvar_g_balance_porto_primary_refire))
 294                         {
 295                                 W_Porto_Attack(0);
 296                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_porto_primary_animtime, w_ready);
 297                         }
 298
 299                         if (self.BUTTON_ATCK2)
 300                         if (!self.porto_current)
 301                         if (!self.porto_forbidden)
 302                         if (weapon_prepareattack(1, autocvar_g_balance_porto_secondary_refire))
 303                         {
 304                                 W_Porto_Attack(1);
 305                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_porto_secondary_animtime, w_ready);
 306                         }
 307                 }
 308                 else
 309                 {
 310                         if(self.porto_v_angle_held)
 311                         {
 312                                 if(!self.BUTTON_ATCK2)
 313                                 {
 314                                         self.porto_v_angle_held = 0;
 315
 316                                         ClientData_Touch(self);
 317                                 }
 318                         }
 319                         else
 320                         {
 321                                 if(self.BUTTON_ATCK2)
 322                                 {
 323                                         self.porto_v_angle = self.v_angle;
 324                                         self.porto_v_angle_held = 1;
 325
 326                                         ClientData_Touch(self);
 327                                 }
 328                         }
 329                         if(self.porto_v_angle_held)
 330                                 makevectors(self.porto_v_angle); // override the previously set angles
 331
 332                         if (self.BUTTON_ATCK)
 333                         if (!self.porto_current)
 334                         if (!self.porto_forbidden)
 335                         if (weapon_prepareattack(0, autocvar_g_balance_porto_primary_refire))
 336                         {
 337                                 W_Porto_Attack(-1);
 338                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_porto_primary_animtime, w_ready);
 339                         }
 340                 }
 341         }
 342         else if (req == WR_PRECACHE)
 343         {
 344                 precache_model ("models/weapons/g_porto.md3");
 345                 precache_model ("models/weapons/v_porto.md3");
 346                 precache_model ("models/weapons/h_porto.iqm");
 347                 precache_model ("models/portal.md3");
 348                 precache_sound ("porto/bounce.wav");
 349                 precache_sound ("porto/create.wav");
 350                 precache_sound ("porto/expire.wav");
 351                 precache_sound ("porto/explode.wav");
 352                 precache_sound ("porto/fire.wav");
 353                 precache_sound ("porto/unsupported.wav");
 354         }
 355         else if (req == WR_SETUP)
 356         {
 357                 weapon_setup(WEP_PORTO);
 358                 self.current_ammo = ammo_none;
 359         }
 360         else if (req == WR_RESETPLAYER)
 361         {
 362                 self.porto_current = world;
 363         }
 364         return TRUE;
 365 }
 366 #endif
 367 #ifdef CSQC
 368 float w_porto(float req)
 369 {
 370         if(req == WR_IMPACTEFFECT)
 371         {
 372                 print("Since when does Porto send DamageInfo?\n");
 373         }
 374         else if(req == WR_PRECACHE)
 375         {
 376                 // nothing to do
 377         }
 378         return TRUE;
 379 }
 380 #endif
 381 #endif