qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", "Rocket Launcher");
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void W_Rocket_Unregister()
   9 {
  10         if(self.owner && self.owner.lastrocket == self)
  11         {
  12                 self.owner.lastrocket = world;
  13                 // self.owner.rl_release = 1;
  14         }
  15 }
  16
  17 void W_Rocket_Explode ()
  18 {
  19         W_Rocket_Unregister();
  20
  21         if(other.takedamage == DAMAGE_AIM)
  22                 if(other.classname == "player")
  23                         if(IsDifferentTeam(self.owner, other))
  24                                 if(IsFlying(other))
  25                                         AnnounceTo(self.owner, "airshot");
  26
  27         self.event_damage = SUB_Null;
  28         self.takedamage = DAMAGE_NO;
  29
  30         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  31
  32         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  33         {
  34                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  35                 {
  36                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  37                         ATTACK_FINISHED(self.owner) = time;
  38                         self.owner.switchweapon = w_getbestweapon(self.owner);
  39                 }
  40                 if(g_laserguided_missile)
  41                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  42         }
  43         remove (self);
  44 }
  45
  46 void W_Rocket_DoRemoteExplode ()
  47 {
  48         W_Rocket_Unregister();
  49
  50         self.event_damage = SUB_Null;
  51         self.takedamage = DAMAGE_NO;
  52
  53         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_remote_damage"), cvar("g_balance_rocketlauncher_remote_edgedamage"), cvar("g_balance_rocketlauncher_remote_radius"), world, cvar("g_balance_rocketlauncher_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  54
  55         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  56         {
  57                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  58                 {
  59                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  60                         ATTACK_FINISHED(self.owner) = time;
  61                         self.owner.switchweapon = w_getbestweapon(self.owner);
  62                 }
  63                 if(g_laserguided_missile)
  64                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  65         }
  66         remove (self);
  67 }
  68
  69 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  70 {
  71         entity head, selected;
  72         vector dir;
  73         float dist, maxdist,// bestdist,
  74                 dot,// bestdot,
  75                 points, bestpoints;
  76         //bestdist = 9999;
  77         //bestdot = -2;
  78         bestpoints = 0;
  79         maxdist = 800;
  80         selected = world;
  81
  82         makevectors(e.angles);
  83
  84         head = find(world, classname, "laser_target");
  85         while(head)
  86         {
  87                 points = 0;
  88                 dir = normalize(head.origin - self.origin);
  89                 dot = dir * v_forward;
  90                 dist = vlen(head.origin - self.origin);
  91                 if(dist > maxdist)
  92                         dist = maxdist;
  93
  94                 // gain points for being in front
  95                 points = points + ((dot+1)*0.5) * 500
  96                         * (1 + crandom()*dot_variance);
  97                 // gain points for being close away
  98                 points = points + (1 - dist/maxdist) * 1000
  99                         * (1 + crandom()*dot_variance);
 100
 101                 traceline(e.origin, head.origin, TRUE, self);
 102                 if(trace_fraction < 1)
 103                 {
 104                         points = 0;
 105                 }
 106
 107                 if(points > bestpoints)//random() > 0.5)//
 108                 {
 109                         bestpoints = points;
 110                         selected = head;
 111                 }
 112
 113                 head = find(head, classname, "laser_target");
 114         }
 115
 116         //bprint(selected.owner.netname);
 117         //bprint("\n");
 118         return selected;
 119 }
 120
 121 void W_Rocket_RemoteExplode()
 122 {
 123         if(self.owner.deadflag == DEAD_NO)
 124         if(self.owner.lastrocket)
 125         {
 126                 if((self.spawnshieldtime >= 0)
 127                         ? (time >= self.spawnshieldtime) // timer
 128                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
 129                 )
 130                 {
 131                         W_Rocket_DoRemoteExplode();
 132                 }
 133         }
 134 }
 135
 136 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 137 {
 138         if(thisdir * goaldir > maxturn_cos)
 139                 return goaldir;
 140         float f, m2;
 141         vector v;
 142         // solve:
 143         //   g = normalize(thisdir + goaldir * X)
 144         //   thisdir * g = maxturn
 145         //
 146         //   gg = thisdir + goaldir * X
 147         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 148         //
 149         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 150         f = thisdir * goaldir;
 151         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 152         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 153         m2 = maxturn_cos * maxturn_cos;
 154         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 155         return normalize(thisdir + goaldir * v_y); // the larger solution!
 156 }
 157
 158 void W_Rocket_Think (void)
 159 {
 160         entity e;
 161         vector desireddir, olddir, newdir, desiredorigin, goal;
 162 #if 0
 163         float cosminang, cosmaxang, cosang;
 164 #endif
 165         float turnrate, velspeed, f;
 166         self.nextthink = time;
 167         if (time > self.cnt)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Rocket_Explode ();
 172                 return;
 173         }
 174
 175         if(g_laserguided_missile)
 176         {
 177                 // accelerate
 178                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 179                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 180                 if (velspeed > 0)
 181                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 182         }
 183         else
 184         {
 185                 // accelerate
 186                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 187                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 188                 if (velspeed > 0)
 189                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 190         }
 191
 192         // laser guided, or remote detonation
 193         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 194         {
 195                 if(g_laserguided_missile)
 196                 {
 197                         if(self.rl_detonate_later)
 198                                 W_Rocket_RemoteExplode();
 199
 200                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 201                         {
 202                                 if(self.owner.laser_on)
 203                                 {
 204                                         if(self.attack_finished_single < time)
 205                                         {
 206                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 207                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 208                                         }
 209
 210                                         if(!self.enemy)
 211                                                 self.enemy = self.owner.weaponentity.lasertarget;
 212                                 }
 213                                 else self.enemy = world;
 214                         }
 215                         else // don't allow stealing: always target my owner's laser (if it exists)
 216                                 self.enemy = self.owner.weaponentity.lasertarget;
 217
 218                         if(self.enemy != world)
 219                         {
 220                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 221                                 velspeed = vlen(self.velocity);
 222                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 223                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 224                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 225                                 olddir = normalize(self.velocity);                                      // get my current direction
 226                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 227                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 228                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 229
 230                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 231                         }
 232                 }
 233                 else
 234                 {
 235                         if(self == self.owner.lastrocket)
 236                         if not(self.owner.rl_release)
 237                         if not(self.BUTTON_ATCK2)
 238                         if(cvar("g_balance_rocketlauncher_guiderate"))
 239                         if(time > self.pushltime)
 240                         if(self.owner.deadflag == DEAD_NO)
 241                         {
 242                                 f = cvar("g_balance_rocketlauncher_guideratedelay");
 243                                 if(f)
 244                                         f = bound(0, (time - self.pushltime) / f, 1);
 245                                 else
 246                                         f = 1;
 247
 248                                 velspeed = vlen(self.velocity);
 249
 250                                 makevectors(self.owner.v_angle);
 251                                 desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 252                                 desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 253                                 olddir = normalize(self.velocity);
 254
 255 #if 0
 256                                 // disabled this code because it doesn't do what I want it to do :P
 257                                 cosminang = cos(cvar("g_balance_rocketlauncher_guidefadeangle") * DEG2RAD);
 258                                 cosmaxang = cos(cvar("g_balance_rocketlauncher_guidemaxangle") * DEG2RAD);
 259                                 cosang = desireddir * normalize(self.origin - desiredorigin);
 260                                 if(cosminang == cosmaxang)
 261                                         f *= (cosang >= cosminang);
 262                                 else
 263                                         f *= bound(0, (cosang - cosmaxang) / (cosminang - cosmaxang), 1);
 264 #endif
 265
 266                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 267                                 // but we are limiting the rate at which we can turn!
 268                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 269                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * DEG2RAD));
 270
 271                                 self.velocity = newdir * velspeed;
 272                                 self.angles = vectoangles(self.velocity);
 273
 274                                 if(!self.count)
 275                                 {
 276                                         pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 277                                         // TODO add a better sound here
 278                                         sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 279                                         self.count = 1;
 280                                 }
 281                         }
 282
 283                         if(self.rl_detonate_later)
 284                                 W_Rocket_RemoteExplode();
 285                 }
 286         }
 287
 288         if(self.csqcprojectile_clientanimate == 0)
 289                 UpdateCSQCProjectile(self);
 290 }
 291
 292 void W_Rocket_Touch (void)
 293 {
 294         W_Rocket_Unregister();
 295
 296         PROJECTILE_TOUCH;
 297         W_Rocket_Explode ();
 298 }
 299
 300 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 301 {
 302         if (self.health <= 0)
 303                 return;
 304         self.health = self.health - damage;
 305         self.angles = vectoangles(self.velocity);
 306         if (self.health <= 0)
 307                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 308 }
 309
 310 void W_Rocket_Attack (void)
 311 {
 312         local entity missile;
 313         local entity flash;
 314
 315         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 316                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 317
 318         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 319         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 320
 321         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 322         missile.owner = self;
 323         self.lastrocket = missile;
 324         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 325                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 326         else
 327                 missile.spawnshieldtime = -1;
 328         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 329         missile.classname = "rocket";
 330         missile.bot_dodge = TRUE;
 331         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 332
 333         missile.takedamage = DAMAGE_YES;
 334         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 335         missile.health = cvar("g_balance_rocketlauncher_health");
 336         missile.event_damage = W_Rocket_Damage;
 337
 338         missile.movetype = MOVETYPE_FLY;
 339         PROJECTILE_MAKETRIGGER(missile);
 340         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 341         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 342
 343         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 344         if(g_laserguided_missile && self.laser_on)
 345                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_laserguided_speedstart"), 0);
 346         else
 347                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_speedstart"), 0);
 348         missile.angles = vectoangles (missile.velocity);
 349
 350         missile.touch = W_Rocket_Touch;
 351         missile.think = W_Rocket_Think;
 352         missile.nextthink = time;
 353         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 354         missile.flags = FL_PROJECTILE;
 355
 356         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 357
 358         // muzzle flash for 1st person view
 359         flash = spawn ();
 360         setmodel (flash, "models/flash.md3"); // precision set below
 361         SUB_SetFade (flash, time, 0.1);
 362         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 363         W_AttachToShotorg(flash, '5 0 0');
 364
 365         // common properties
 366 }
 367
 368 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 369
 370 float w_rlauncher(float req)
 371 {
 372         entity rock;
 373         float rockfound;
 374         if (req == WR_AIM)
 375         {
 376                 // aim and decide to fire if appropriate
 377                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 378                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 379                 {
 380                         // decide whether to detonate rockets
 381                         local entity missile, targetlist, targ;
 382                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 383                         local float selfdamage, teamdamage, enemydamage;
 384                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 385                         coredamage = cvar("g_balance_rocketlauncher_damage");
 386                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 387                         recipricoledgeradius = 1 / edgeradius;
 388                         selfdamage = 0;
 389                         teamdamage = 0;
 390                         enemydamage = 0;
 391                         targetlist = findchainfloat(bot_attack, TRUE);
 392                         missile = find(world, classname, "rocket");
 393                         while (missile)
 394                         {
 395                                 if (missile.owner != self)
 396                                 {
 397                                         missile = find(missile, classname, "rocket");
 398                                         continue;
 399                                 }
 400                                 targ = targetlist;
 401                                 while (targ)
 402                                 {
 403                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 404                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 405                                         // count potential damage according to type of target
 406                                         if (targ == self)
 407                                                 selfdamage = selfdamage + d;
 408                                         else if (targ.team == self.team && teams_matter)
 409                                                 teamdamage = teamdamage + d;
 410                                         else if (bot_shouldattack(targ))
 411                                                 enemydamage = enemydamage + d;
 412                                         targ = targ.chain;
 413                                 }
 414                                 missile = find(missile, classname, "rocket");
 415                         }
 416                         local float desirabledamage;
 417                         desirabledamage = enemydamage;
 418                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 419                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 420                         if (self.team && teamplay != 1)
 421                                 desirabledamage = desirabledamage - teamdamage;
 422
 423                         missile = find(world, classname, "rocket");
 424                         while (missile)
 425                         {
 426                                 if (missile.owner != self)
 427                                 {
 428                                         missile = find(missile, classname, "rocket");
 429                                         continue;
 430                                 }
 431                                 makevectors(missile.v_angle);
 432                                 targ = targetlist;
 433                                 if (skill > 9) // normal players only do this for the target they are tracking
 434                                 {
 435                                         targ = targetlist;
 436                                         while (targ)
 437                                         {
 438                                                 if (
 439                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 440                                                         && desirabledamage > 0.1*coredamage
 441                                                 )self.BUTTON_ATCK2 = TRUE;
 442                                                 targ = targ.chain;
 443                                         }
 444                                 }else{
 445                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 446                                         //As the distance gets larger, a correct detonation gets near imposible
 447                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 448                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 449                                                 if(self.enemy.classname == "player")
 450                                                         if(desirabledamage >= 0.1*coredamage)
 451                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 452                                                                         self.BUTTON_ATCK2 = TRUE;
 453                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 454                                 }
 455
 456                                 missile = find(missile, classname, "rocket");
 457                         }
 458                         // if we would be doing at X percent of the core damage, detonate it
 459                         // but don't fire a new shot at the same time!
 460                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 461                                 self.BUTTON_ATCK2 = TRUE;
 462                         if ((skill > 6.5) && (selfdamage > self.health))
 463                                 self.BUTTON_ATCK2 = FALSE;
 464                         //if(self.BUTTON_ATCK2 == TRUE)
 465                         //      dprint(ftos(desirabledamage),"\n");
 466                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 467                 }
 468         }
 469         else if (req == WR_THINK)
 470         {
 471                 if(g_laserguided_missile)
 472                 {
 473                         if (self.BUTTON_ATCK && self.rl_release)
 474                         {
 475                                 rockfound = 0;
 476                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 477                                 {
 478                                         if(!rock.rl_detonate_later)
 479                                         {
 480                                                 rock.rl_detonate_later = TRUE;
 481                                                 rockfound = 1;
 482                                         }
 483                                 }
 484                                 if(rockfound)
 485                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 486                                 else
 487                                 {
 488                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 489                                         {
 490                                                 W_Rocket_Attack();
 491                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 492                                         }
 493                                 }
 494                                 self.rl_release = 0;
 495                         }
 496                         if (!self.BUTTON_ATCK)
 497                                 self.rl_release = 1;
 498                         if (self.BUTTON_ATCK2)
 499                         if(self.exteriorweaponentity.attack_finished_single < time)
 500                         {
 501                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 502                                 self.laser_on = !self.laser_on;
 503                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 504                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 505                         }
 506                 }
 507                 else
 508                 {
 509                         if (self.BUTTON_ATCK)
 510                         {
 511                                 if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 512                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 513                                 {
 514                                         W_Rocket_Attack();
 515                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 516                                         self.rl_release = 0;
 517                                 }
 518                         }
 519                         else
 520                                 self.rl_release = 1;
 521
 522                         if (self.BUTTON_ATCK2)
 523                         {
 524                                 rockfound = 0;
 525                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 526                                 {
 527                                         if(!rock.rl_detonate_later)
 528                                         {
 529                                                 rock.rl_detonate_later = TRUE;
 530                                                 rockfound = 1;
 531                                         }
 532                                 }
 533                                 if(rockfound)
 534                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 535                         }
 536                 }
 537         }
 538         else if (req == WR_PRECACHE)
 539         {
 540                 precache_model ("models/flash.md3");
 541                 precache_model ("models/weapons/g_rl.md3");
 542                 precache_model ("models/weapons/v_rl.md3");
 543                 precache_model ("models/weapons/h_rl.iqm");
 544                 precache_sound ("weapons/rocket_det.wav");
 545                 precache_sound ("weapons/rocket_fire.wav");
 546                 precache_sound ("weapons/rocket_mode.wav");
 547                 if (g_laserguided_missile)
 548                 {
 549                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 550                 }
 551         }
 552         else if (req == WR_SETUP)
 553         {
 554                 weapon_setup(WEP_ROCKET_LAUNCHER);
 555                 self.rl_release = 1;
 556         }
 557         else if (req == WR_CHECKAMMO1)
 558         {
 559                 // don't switch while guiding a missile
 560                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 561                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 562                         return FALSE;
 563         }
 564         else if (req == WR_CHECKAMMO2)
 565                 return FALSE;
 566         else if (req == WR_RESETPLAYER)
 567         {
 568                 self.rl_release = 0;
 569         }
 570         return TRUE;
 571 };
 572 #endif
 573 #ifdef CSQC
 574 float w_rlauncher(float req)
 575 {
 576         if(req == WR_IMPACTEFFECT)
 577         {
 578                 vector org2;
 579                 org2 = w_org + w_backoff * 12;
 580                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 581                 if(!w_issilent)
 582                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 583         }
 584         else if(req == WR_PRECACHE)
 585         {
 586                 precache_sound("weapons/rocket_impact.wav");
 587         }
 588         else if (req == WR_SUICIDEMESSAGE)
 589                 w_deathtypestring = "exploded";
 590         else if (req == WR_KILLMESSAGE)
 591         {
 592                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 593                         w_deathtypestring = "got too close to #'s rocket";
 594                 else if(w_deathtype & HITTYPE_SPLASH)
 595                         w_deathtypestring = "almost dodged #'s rocket";
 596                 else
 597                         w_deathtypestring = "ate #'s rocket";
 598         }
 599         return TRUE;
 600 }
 601 #endif
 602 #endif