qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", "Rocket Launcher");
   3 #else
   4 .float rl_release;
   5 .float rl_detonate_later;
   6
   7 void W_Rocket_Unregister()
   8 {
   9         if(self.owner && self.owner.lastrocket == self)
  10         {
  11                 self.owner.lastrocket = world;
  12                 // self.owner.rl_release = 1;
  13         }
  14 }
  15
  16 void W_Rocket_Explode (void)
  17 {
  18         W_Rocket_Unregister();
  19
  20         if(other.takedamage == DAMAGE_AIM)
  21                 if(other.classname == "player")
  22                         if(IsDifferentTeam(self.owner, other))
  23                                 if(IsFlying(other))
  24                                         AnnounceTo(self.owner, "airshot");
  25
  26         self.event_damage = SUB_Null;
  27         self.takedamage = DAMAGE_NO;
  28         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  29
  30         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  31         {
  32                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  33                 {
  34                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  35                         ATTACK_FINISHED(self.owner) = time;
  36                         self.owner.switchweapon = w_getbestweapon(self.owner);
  37                 }
  38                 if(g_laserguided_missile)
  39                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  40         }
  41         remove (self);
  42 }
  43
  44 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  45 {
  46         entity head, selected;
  47         vector dir;
  48         float dist, maxdist,// bestdist,
  49                 dot,// bestdot,
  50                 points, bestpoints;
  51         //bestdist = 9999;
  52         //bestdot = -2;
  53         bestpoints = 0;
  54         maxdist = 800;
  55         selected = world;
  56
  57         makevectors(e.angles);
  58
  59         head = find(world, classname, "laser_target");
  60         while(head)
  61         {
  62                 points = 0;
  63                 dir = normalize(head.origin - self.origin);
  64                 dot = dir * v_forward;
  65                 dist = vlen(head.origin - self.origin);
  66                 if(dist > maxdist)
  67                         dist = maxdist;
  68
  69                 // gain points for being in front
  70                 points = points + ((dot+1)*0.5) * 500
  71                         * (1 + crandom()*dot_variance);
  72                 // gain points for being close away
  73                 points = points + (1 - dist/maxdist) * 1000
  74                         * (1 + crandom()*dot_variance);
  75
  76                 traceline(e.origin, head.origin, TRUE, self);
  77                 if(trace_fraction < 1)
  78                 {
  79                         points = 0;
  80                 }
  81
  82                 if(points > bestpoints)//random() > 0.5)//
  83                 {
  84                         bestpoints = points;
  85                         selected = head;
  86                 }
  87
  88                 head = find(head, classname, "laser_target");
  89         }
  90
  91         //bprint(selected.owner.netname);
  92         //bprint("\n");
  93         return selected;
  94 }
  95
  96 void W_Rocket_RemoteExplode()
  97 {
  98         if(self.owner.deadflag == DEAD_NO)
  99         if(self.owner.lastrocket)
 100         {
 101                 if((self.spawnshieldtime >= 0)
 102                         ? (time >= self.spawnshieldtime) // timer
 103                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
 104                 )
 105                 {
 106                         other = world;
 107                         self.projectiledeathtype |= HITTYPE_BOUNCE;
 108                         W_Rocket_Explode ();
 109                 }
 110                 else
 111                 {
 112                 }
 113         }
 114 }
 115
 116 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 117 {
 118         if(thisdir * goaldir > maxturn_cos)
 119                 return goaldir;
 120         float f, m2;
 121         vector v;
 122         // solve:
 123         //   g = normalize(thisdir + goaldir * X)
 124         //   thisdir * g = maxturn
 125         //
 126         //   gg = thisdir + goaldir * X
 127         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 128         //
 129         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 130         f = thisdir * goaldir;
 131         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 132         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 133         m2 = maxturn_cos * maxturn_cos;
 134         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 135         return normalize(thisdir + goaldir * v_y); // the larger solution!
 136 }
 137
 138 void W_Rocket_Think (void)
 139 {
 140         entity e;
 141         vector desireddir, olddir, newdir, desiredorigin, goal;
 142 #if 0
 143         float cosminang, cosmaxang, cosang;
 144 #endif
 145         float turnrate, velspeed, f;
 146         self.nextthink = time;
 147         if (time > self.cnt)
 148         {
 149                 other = world;
 150                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 151                 W_Rocket_Explode ();
 152                 return;
 153         }
 154
 155         if(g_laserguided_missile)
 156         {
 157                 // accelerate
 158                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 159                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 160                 if (velspeed > 0)
 161                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 162         }
 163         else
 164         {
 165                 // accelerate
 166                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 167                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 168                 if (velspeed > 0)
 169                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 170         }
 171
 172         // laser guided, or remote detonation
 173         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 174         {
 175                 if(g_laserguided_missile)
 176                 {
 177                         if(self.rl_detonate_later)
 178                                 W_Rocket_RemoteExplode();
 179
 180                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 181                         {
 182                                 if(self.owner.laser_on)
 183                                 {
 184                                         if(self.attack_finished_single < time)
 185                                         {
 186                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 187                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 188                                         }
 189
 190                                         if(!self.enemy)
 191                                                 self.enemy = self.owner.weaponentity.lasertarget;
 192                                 }
 193                                 else self.enemy = world;
 194                         }
 195                         else // don't allow stealing: always target my owner's laser (if it exists)
 196                                 self.enemy = self.owner.weaponentity.lasertarget;
 197
 198                         if(self.enemy != world)
 199                         {
 200                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 201                                 velspeed = vlen(self.velocity);
 202                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 203                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 204                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 205                                 olddir = normalize(self.velocity);                                      // get my current direction
 206                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 207                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 208                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 209
 210                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 211                         }
 212                 }
 213                 else
 214                 {
 215                         if(self == self.owner.lastrocket)
 216                         if not(self.owner.rl_release)
 217                         if not(self.BUTTON_ATCK2)
 218                         if(cvar("g_balance_rocketlauncher_guiderate"))
 219                         if(time > self.pushltime)
 220                         if(self.owner.deadflag == DEAD_NO)
 221                         {
 222                                 f = cvar("g_balance_rocketlauncher_guideratedelay");
 223                                 if(f)
 224                                         f = bound(0, (time - self.pushltime) / f, 1);
 225                                 else
 226                                         f = 1;
 227
 228                                 velspeed = vlen(self.velocity);
 229
 230                                 makevectors(self.owner.v_angle);
 231                                 desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 232                                 desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 233                                 olddir = normalize(self.velocity);
 234
 235 #if 0
 236                                 // disabled this code because it doesn't do what I want it to do :P
 237                                 cosminang = cos(cvar("g_balance_rocketlauncher_guidefadeangle") * DEG2RAD);
 238                                 cosmaxang = cos(cvar("g_balance_rocketlauncher_guidemaxangle") * DEG2RAD);
 239                                 cosang = desireddir * normalize(self.origin - desiredorigin);
 240                                 if(cosminang == cosmaxang)
 241                                         f *= (cosang >= cosminang);
 242                                 else
 243                                         f *= bound(0, (cosang - cosmaxang) / (cosminang - cosmaxang), 1);
 244 #endif
 245
 246                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 247                                 // but we are limiting the rate at which we can turn!
 248                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 249                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * DEG2RAD));
 250
 251                                 self.velocity = newdir * velspeed;
 252                                 self.angles = vectoangles(self.velocity);
 253
 254                                 if(!self.count)
 255                                 {
 256                                         pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 257                                         // TODO add a better sound here
 258                                         sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 259                                         self.count = 1;
 260                                 }
 261                         }
 262
 263                         if(self.rl_detonate_later)
 264                                 W_Rocket_RemoteExplode();
 265                 }
 266         }
 267
 268         if(self.csqcprojectile_clientanimate == 0)
 269                 UpdateCSQCProjectile(self);
 270 }
 271
 272 void W_Rocket_Touch (void)
 273 {
 274         W_Rocket_Unregister();
 275
 276         PROJECTILE_TOUCH;
 277         W_Rocket_Explode ();
 278 }
 279
 280 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 281 {
 282         if (self.health <= 0)
 283                 return;
 284         self.health = self.health - damage;
 285         self.angles = vectoangles(self.velocity);
 286         if (self.health <= 0)
 287                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 288 }
 289
 290 void W_Rocket_Attack (void)
 291 {
 292         local entity missile;
 293         local entity flash;
 294
 295         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 296                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 297
 298         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 299         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 300
 301         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 302         missile.owner = self;
 303         self.lastrocket = missile;
 304         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 305                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 306         else
 307                 missile.spawnshieldtime = -1;
 308         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 309         missile.classname = "rocket";
 310         missile.bot_dodge = TRUE;
 311         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 312
 313         missile.takedamage = DAMAGE_YES;
 314         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 315         missile.health = cvar("g_balance_rocketlauncher_health");
 316         missile.event_damage = W_Rocket_Damage;
 317
 318         missile.movetype = MOVETYPE_FLY;
 319         PROJECTILE_MAKETRIGGER(missile);
 320         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 321         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 322
 323         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 324         if(g_laserguided_missile && self.laser_on)
 325                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_laserguided_speedstart"), 0);
 326         else
 327                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_speedstart"), 0);
 328         missile.angles = vectoangles (missile.velocity);
 329
 330         missile.touch = W_Rocket_Touch;
 331         missile.think = W_Rocket_Think;
 332         missile.nextthink = time;
 333         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 334         missile.flags = FL_PROJECTILE;
 335
 336         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 337
 338         // muzzle flash for 1st person view
 339         flash = spawn ();
 340         setmodel (flash, "models/flash.md3"); // precision set below
 341         SUB_SetFade (flash, time, 0.1);
 342         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 343         W_AttachToShotorg(flash, '5 0 0');
 344
 345         // common properties
 346 }
 347
 348 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 349
 350 float w_rlauncher(float req)
 351 {
 352         entity rock;
 353         float rockfound;
 354         if (req == WR_AIM)
 355         {
 356                 // aim and decide to fire if appropriate
 357                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 358                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 359                 {
 360                         // decide whether to detonate rockets
 361                         local entity missile, targetlist, targ;
 362                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 363                         local float selfdamage, teamdamage, enemydamage;
 364                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 365                         coredamage = cvar("g_balance_rocketlauncher_damage");
 366                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 367                         recipricoledgeradius = 1 / edgeradius;
 368                         selfdamage = 0;
 369                         teamdamage = 0;
 370                         enemydamage = 0;
 371                         targetlist = findchainfloat(bot_attack, TRUE);
 372                         missile = find(world, classname, "rocket");
 373                         while (missile)
 374                         {
 375                                 if (missile.owner != self)
 376                                 {
 377                                         missile = find(missile, classname, "rocket");
 378                                         continue;
 379                                 }
 380                                 targ = targetlist;
 381                                 while (targ)
 382                                 {
 383                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 384                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 385                                         // count potential damage according to type of target
 386                                         if (targ == self)
 387                                                 selfdamage = selfdamage + d;
 388                                         else if (targ.team == self.team && teams_matter)
 389                                                 teamdamage = teamdamage + d;
 390                                         else if (bot_shouldattack(targ))
 391                                                 enemydamage = enemydamage + d;
 392                                         targ = targ.chain;
 393                                 }
 394                                 missile = find(missile, classname, "rocket");
 395                         }
 396                         local float desirabledamage;
 397                         desirabledamage = enemydamage;
 398                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 399                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 400                         if (self.team && teamplay != 1)
 401                                 desirabledamage = desirabledamage - teamdamage;
 402
 403                         missile = find(world, classname, "rocket");
 404                         while (missile)
 405                         {
 406                                 if (missile.owner != self)
 407                                 {
 408                                         missile = find(missile, classname, "rocket");
 409                                         continue;
 410                                 }
 411                                 makevectors(missile.v_angle);
 412                                 targ = targetlist;
 413                                 if (skill > 9) // normal players only do this for the target they are tracking
 414                                 {
 415                                         targ = targetlist;
 416                                         while (targ)
 417                                         {
 418                                                 if (
 419                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 420                                                         && desirabledamage > 0.1*coredamage
 421                                                 )self.BUTTON_ATCK2 = TRUE;
 422                                                 targ = targ.chain;
 423                                         }
 424                                 }else{
 425                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 426                                         //As the distance gets larger, a correct detonation gets near imposible
 427                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 428                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 429                                                 if(self.enemy.classname == "player")
 430                                                         if(desirabledamage >= 0.1*coredamage)
 431                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 432                                                                         self.BUTTON_ATCK2 = TRUE;
 433                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 434                                 }
 435
 436                                 missile = find(missile, classname, "rocket");
 437                         }
 438                         // if we would be doing at X percent of the core damage, detonate it
 439                         // but don't fire a new shot at the same time!
 440                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 441                                 self.BUTTON_ATCK2 = TRUE;
 442                         if ((skill > 6.5) && (selfdamage > self.health))
 443                                 self.BUTTON_ATCK2 = FALSE;
 444                         //if(self.BUTTON_ATCK2 == TRUE)
 445                         //      dprint(ftos(desirabledamage),"\n");
 446                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 447                 }
 448         }
 449         else if (req == WR_THINK)
 450         {
 451                 if(g_laserguided_missile)
 452                 {
 453                         if (self.BUTTON_ATCK && self.rl_release)
 454                         {
 455                                 rockfound = 0;
 456                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 457                                 {
 458                                         if(!rock.rl_detonate_later)
 459                                         {
 460                                                 rock.rl_detonate_later = TRUE;
 461                                                 rockfound = 1;
 462                                         }
 463                                 }
 464                                 if(rockfound)
 465                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 466                                 else
 467                                 {
 468                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 469                                         {
 470                                                 W_Rocket_Attack();
 471                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 472                                         }
 473                                 }
 474                                 self.rl_release = 0;
 475                         }
 476                         if (!self.BUTTON_ATCK)
 477                                 self.rl_release = 1;
 478                         if (self.BUTTON_ATCK2)
 479                         if(self.exteriorweaponentity.attack_finished_single < time)
 480                         {
 481                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 482                                 self.laser_on = !self.laser_on;
 483                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 484                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 485                         }
 486                 }
 487                 else
 488                 {
 489                         if (self.BUTTON_ATCK)
 490                         {
 491                                 if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 492                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 493                                 {
 494                                         W_Rocket_Attack();
 495                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 496                                         self.rl_release = 0;
 497                                 }
 498                         }
 499                         else
 500                                 self.rl_release = 1;
 501
 502                         if (self.BUTTON_ATCK2)
 503                         {
 504                                 rockfound = 0;
 505                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 506                                 {
 507                                         if(!rock.rl_detonate_later)
 508                                         {
 509                                                 rock.rl_detonate_later = TRUE;
 510                                                 rockfound = 1;
 511                                         }
 512                                 }
 513                                 if(rockfound)
 514                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 515                         }
 516                 }
 517         }
 518         else if (req == WR_PRECACHE)
 519         {
 520                 precache_model ("models/flash.md3");
 521                 precache_model ("models/weapons/g_rl.md3");
 522                 precache_model ("models/weapons/v_rl.md3");
 523                 precache_model ("models/weapons/h_rl.iqm");
 524                 precache_sound ("weapons/rocket_det.wav");
 525                 precache_sound ("weapons/rocket_fire.wav");
 526                 precache_sound ("weapons/rocket_mode.wav");
 527                 if (g_laserguided_missile)
 528                 {
 529                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 530                 }
 531         }
 532         else if (req == WR_SETUP)
 533         {
 534                 weapon_setup(WEP_ROCKET_LAUNCHER);
 535                 self.rl_release = 1;
 536         }
 537         else if (req == WR_CHECKAMMO1)
 538         {
 539                 // don't switch while guiding a missile
 540                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 541                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 542                         return FALSE;
 543         }
 544         else if (req == WR_CHECKAMMO2)
 545                 return FALSE;
 546         else if (req == WR_SUICIDEMESSAGE)
 547                 w_deathtypestring = "exploded";
 548         else if (req == WR_KILLMESSAGE)
 549         {
 550                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 551                         w_deathtypestring = "got too close to #'s rocket";
 552                 else if(w_deathtype & HITTYPE_SPLASH)
 553                         w_deathtypestring = "almost dodged #'s rocket";
 554                 else
 555                         w_deathtypestring = "ate #'s rocket";
 556         }
 557         else if (req == WR_RESETPLAYER)
 558         {
 559                 self.rl_release = 0;
 560         }
 561         return TRUE;
 562 };
 563 #endif