qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", "Rocket Launcher");
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void W_Rocket_Unregister()
   9 {
  10         if(self.owner && self.owner.lastrocket == self)
  11         {
  12                 self.owner.lastrocket = world;
  13                 // self.owner.rl_release = 1;
  14         }
  15 }
  16
  17 void W_Rocket_Explode ()
  18 {
  19         W_Rocket_Unregister();
  20
  21         if(other.takedamage == DAMAGE_AIM)
  22                 if(other.classname == "player")
  23                         if(IsDifferentTeam(self.owner, other))
  24                                 if(IsFlying(other))
  25                                         AnnounceTo(self.owner, "airshot");
  26
  27         self.event_damage = SUB_Null;
  28         self.takedamage = DAMAGE_NO;
  29
  30         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  31
  32         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  33         {
  34                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  35                 {
  36                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  37                         ATTACK_FINISHED(self.owner) = time;
  38                         self.owner.switchweapon = w_getbestweapon(self.owner);
  39                 }
  40                 if(g_laserguided_missile)
  41                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  42         }
  43         remove (self);
  44 }
  45
  46 void W_Rocket_DoRemoteExplode ()
  47 {
  48         W_Rocket_Unregister();
  49
  50         self.event_damage = SUB_Null;
  51         self.takedamage = DAMAGE_NO;
  52
  53         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_remote_damage"), cvar("g_balance_rocketlauncher_remote_edgedamage"), cvar("g_balance_rocketlauncher_remote_radius"), world, cvar("g_balance_rocketlauncher_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  54
  55         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  56         {
  57                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  58                 {
  59                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  60                         ATTACK_FINISHED(self.owner) = time;
  61                         self.owner.switchweapon = w_getbestweapon(self.owner);
  62                 }
  63                 if(g_laserguided_missile)
  64                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  65         }
  66         remove (self);
  67 }
  68
  69 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  70 {
  71         entity head, selected;
  72         vector dir;
  73         float dist, maxdist,// bestdist,
  74                 dot,// bestdot,
  75                 points, bestpoints;
  76         //bestdist = 9999;
  77         //bestdot = -2;
  78         bestpoints = 0;
  79         maxdist = 800;
  80         selected = world;
  81
  82         makevectors(e.angles);
  83
  84         head = find(world, classname, "laser_target");
  85         while(head)
  86         {
  87                 points = 0;
  88                 dir = normalize(head.origin - self.origin);
  89                 dot = dir * v_forward;
  90                 dist = vlen(head.origin - self.origin);
  91                 if(dist > maxdist)
  92                         dist = maxdist;
  93
  94                 // gain points for being in front
  95                 points = points + ((dot+1)*0.5) * 500
  96                         * (1 + crandom()*dot_variance);
  97                 // gain points for being close away
  98                 points = points + (1 - dist/maxdist) * 1000
  99                         * (1 + crandom()*dot_variance);
 100
 101                 traceline(e.origin, head.origin, TRUE, self);
 102                 if(trace_fraction < 1)
 103                 {
 104                         points = 0;
 105                 }
 106
 107                 if(points > bestpoints)//random() > 0.5)//
 108                 {
 109                         bestpoints = points;
 110                         selected = head;
 111                 }
 112
 113                 head = find(head, classname, "laser_target");
 114         }
 115
 116         //bprint(selected.owner.netname);
 117         //bprint("\n");
 118         return selected;
 119 }
 120
 121 void W_Rocket_RemoteExplode()
 122 {
 123         if(self.owner.deadflag == DEAD_NO)
 124         if(self.owner.lastrocket)
 125         {
 126                 if((self.spawnshieldtime >= 0)
 127                         ? (time >= self.spawnshieldtime) // timer
 128                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
 129                 )
 130                 {
 131                         W_Rocket_DoRemoteExplode();
 132                 }
 133         }
 134 }
 135
 136 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 137 {
 138         if(thisdir * goaldir > maxturn_cos)
 139                 return goaldir;
 140         float f, m2;
 141         vector v;
 142         // solve:
 143         //   g = normalize(thisdir + goaldir * X)
 144         //   thisdir * g = maxturn
 145         //
 146         //   gg = thisdir + goaldir * X
 147         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 148         //
 149         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 150         f = thisdir * goaldir;
 151         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 152         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 153         m2 = maxturn_cos * maxturn_cos;
 154         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 155         return normalize(thisdir + goaldir * v_y); // the larger solution!
 156 }
 157
 158 void W_Rocket_Think (void)
 159 {
 160         entity e;
 161         vector desireddir, olddir, newdir, desiredorigin, goal;
 162 #if 0
 163         float cosminang, cosmaxang, cosang;
 164 #endif
 165         float turnrate, velspeed, f;
 166         self.nextthink = time;
 167         if (time > self.cnt)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Rocket_Explode ();
 172                 return;
 173         }
 174
 175         if(g_laserguided_missile)
 176         {
 177                 // accelerate
 178                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 179                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 180                 if (velspeed > 0)
 181                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 182         }
 183         else
 184         {
 185                 // accelerate
 186                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 187                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 188                 if (velspeed > 0)
 189                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 190         }
 191
 192         // laser guided, or remote detonation
 193         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 194         {
 195                 if(g_laserguided_missile)
 196                 {
 197                         if(self.rl_detonate_later)
 198                                 W_Rocket_RemoteExplode();
 199
 200                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 201                         {
 202                                 if(self.owner.laser_on)
 203                                 {
 204                                         if(self.attack_finished_single < time)
 205                                         {
 206                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 207                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 208                                         }
 209
 210                                         if(!self.enemy)
 211                                                 self.enemy = self.owner.weaponentity.lasertarget;
 212                                 }
 213                                 else self.enemy = world;
 214                         }
 215                         else // don't allow stealing: always target my owner's laser (if it exists)
 216                                 self.enemy = self.owner.weaponentity.lasertarget;
 217
 218                         if(self.enemy != world)
 219                         {
 220                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 221                                 velspeed = vlen(self.velocity);
 222                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 223                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 224                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 225                                 olddir = normalize(self.velocity);                                      // get my current direction
 226                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 227                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 228                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 229
 230                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 231                         }
 232                 }
 233                 else
 234                 {
 235                         if(self == self.owner.lastrocket)
 236                         if not(self.owner.rl_release)
 237                         if not(self.BUTTON_ATCK2)
 238                         if(cvar("g_balance_rocketlauncher_guiderate"))
 239                         if(time > self.pushltime)
 240                         if(self.owner.deadflag == DEAD_NO)
 241                         {
 242                                 f = cvar("g_balance_rocketlauncher_guideratedelay");
 243                                 if(f)
 244                                         f = bound(0, (time - self.pushltime) / f, 1);
 245                                 else
 246                                         f = 1;
 247
 248                                 velspeed = vlen(self.velocity);
 249
 250                                 makevectors(self.owner.v_angle);
 251                                 desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 252                                 desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 253                                 olddir = normalize(self.velocity);
 254
 255 #if 0
 256                                 // disabled this code because it doesn't do what I want it to do :P
 257                                 cosminang = cos(cvar("g_balance_rocketlauncher_guidefadeangle") * DEG2RAD);
 258                                 cosmaxang = cos(cvar("g_balance_rocketlauncher_guidemaxangle") * DEG2RAD);
 259                                 cosang = desireddir * normalize(self.origin - desiredorigin);
 260                                 if(cosminang == cosmaxang)
 261                                         f *= (cosang >= cosminang);
 262                                 else
 263                                         f *= bound(0, (cosang - cosmaxang) / (cosminang - cosmaxang), 1);
 264 #endif
 265
 266                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 267                                 // but we are limiting the rate at which we can turn!
 268                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 269                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * DEG2RAD));
 270
 271                                 self.velocity = newdir * velspeed;
 272                                 self.angles = vectoangles(self.velocity);
 273
 274                                 if(!self.count)
 275                                 {
 276                                         pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 277                                         // TODO add a better sound here
 278                                         sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 279                                         self.count = 1;
 280                                 }
 281                         }
 282
 283                         if(self.rl_detonate_later)
 284                                 W_Rocket_RemoteExplode();
 285                 }
 286         }
 287
 288         if(self.csqcprojectile_clientanimate == 0)
 289                 UpdateCSQCProjectile(self);
 290 }
 291
 292 void W_Rocket_Touch (void)
 293 {
 294         if(WarpZone_Projectile_Touch())
 295         {
 296                 if(wasfreed(self))
 297                         W_Rocket_Unregister();
 298                 return;
 299         }
 300         W_Rocket_Unregister();
 301         W_Rocket_Explode ();
 302 }
 303
 304 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 305 {
 306         if (self.health <= 0)
 307                 return;
 308         self.health = self.health - damage;
 309         self.angles = vectoangles(self.velocity);
 310         if (self.health <= 0)
 311                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 312 }
 313
 314 void W_Rocket_Attack (void)
 315 {
 316         local entity missile;
 317         local entity flash;
 318
 319         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 320                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 321
 322         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 323         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 324
 325         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 326         missile.owner = self;
 327         self.lastrocket = missile;
 328         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 329                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 330         else
 331                 missile.spawnshieldtime = -1;
 332         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 333         missile.classname = "rocket";
 334         missile.bot_dodge = TRUE;
 335         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 336
 337         missile.takedamage = DAMAGE_YES;
 338         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 339         missile.health = cvar("g_balance_rocketlauncher_health");
 340         missile.event_damage = W_Rocket_Damage;
 341
 342         missile.movetype = MOVETYPE_FLY;
 343         PROJECTILE_MAKETRIGGER(missile);
 344         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 345         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 346
 347         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 348         if(g_laserguided_missile && self.laser_on)
 349                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_laserguided_speedstart"), 0);
 350         else
 351                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_speedstart"), 0);
 352         missile.angles = vectoangles (missile.velocity);
 353
 354         missile.touch = W_Rocket_Touch;
 355         missile.think = W_Rocket_Think;
 356         missile.nextthink = time;
 357         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 358         missile.flags = FL_PROJECTILE;
 359
 360         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 361
 362         // muzzle flash for 1st person view
 363         flash = spawn ();
 364         setmodel (flash, "models/flash.md3"); // precision set below
 365         SUB_SetFade (flash, time, 0.1);
 366         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 367         W_AttachToShotorg(flash, '5 0 0');
 368
 369         // common properties
 370 }
 371
 372 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 373
 374 float w_rlauncher(float req)
 375 {
 376         entity rock;
 377         float rockfound;
 378         if (req == WR_AIM)
 379         {
 380                 // aim and decide to fire if appropriate
 381                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 382                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 383                 {
 384                         // decide whether to detonate rockets
 385                         local entity missile, targetlist, targ;
 386                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 387                         local float selfdamage, teamdamage, enemydamage;
 388                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 389                         coredamage = cvar("g_balance_rocketlauncher_damage");
 390                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 391                         recipricoledgeradius = 1 / edgeradius;
 392                         selfdamage = 0;
 393                         teamdamage = 0;
 394                         enemydamage = 0;
 395                         targetlist = findchainfloat(bot_attack, TRUE);
 396                         missile = find(world, classname, "rocket");
 397                         while (missile)
 398                         {
 399                                 if (missile.owner != self)
 400                                 {
 401                                         missile = find(missile, classname, "rocket");
 402                                         continue;
 403                                 }
 404                                 targ = targetlist;
 405                                 while (targ)
 406                                 {
 407                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 408                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 409                                         // count potential damage according to type of target
 410                                         if (targ == self)
 411                                                 selfdamage = selfdamage + d;
 412                                         else if (targ.team == self.team && teams_matter)
 413                                                 teamdamage = teamdamage + d;
 414                                         else if (bot_shouldattack(targ))
 415                                                 enemydamage = enemydamage + d;
 416                                         targ = targ.chain;
 417                                 }
 418                                 missile = find(missile, classname, "rocket");
 419                         }
 420                         local float desirabledamage;
 421                         desirabledamage = enemydamage;
 422                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 423                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 424                         if (self.team && teamplay != 1)
 425                                 desirabledamage = desirabledamage - teamdamage;
 426
 427                         missile = find(world, classname, "rocket");
 428                         while (missile)
 429                         {
 430                                 if (missile.owner != self)
 431                                 {
 432                                         missile = find(missile, classname, "rocket");
 433                                         continue;
 434                                 }
 435                                 makevectors(missile.v_angle);
 436                                 targ = targetlist;
 437                                 if (skill > 9) // normal players only do this for the target they are tracking
 438                                 {
 439                                         targ = targetlist;
 440                                         while (targ)
 441                                         {
 442                                                 if (
 443                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 444                                                         && desirabledamage > 0.1*coredamage
 445                                                 )self.BUTTON_ATCK2 = TRUE;
 446                                                 targ = targ.chain;
 447                                         }
 448                                 }else{
 449                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 450                                         //As the distance gets larger, a correct detonation gets near imposible
 451                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 452                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 453                                                 if(self.enemy.classname == "player")
 454                                                         if(desirabledamage >= 0.1*coredamage)
 455                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 456                                                                         self.BUTTON_ATCK2 = TRUE;
 457                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 458                                 }
 459
 460                                 missile = find(missile, classname, "rocket");
 461                         }
 462                         // if we would be doing at X percent of the core damage, detonate it
 463                         // but don't fire a new shot at the same time!
 464                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 465                                 self.BUTTON_ATCK2 = TRUE;
 466                         if ((skill > 6.5) && (selfdamage > self.health))
 467                                 self.BUTTON_ATCK2 = FALSE;
 468                         //if(self.BUTTON_ATCK2 == TRUE)
 469                         //      dprint(ftos(desirabledamage),"\n");
 470                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 471                 }
 472         }
 473         else if (req == WR_THINK)
 474         {
 475                 if(g_laserguided_missile)
 476                 {
 477                         if (self.BUTTON_ATCK && self.rl_release)
 478                         {
 479                                 rockfound = 0;
 480                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 481                                 {
 482                                         if(!rock.rl_detonate_later)
 483                                         {
 484                                                 rock.rl_detonate_later = TRUE;
 485                                                 rockfound = 1;
 486                                         }
 487                                 }
 488                                 if(rockfound)
 489                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 490                                 else
 491                                 {
 492                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 493                                         {
 494                                                 W_Rocket_Attack();
 495                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 496                                         }
 497                                 }
 498                                 self.rl_release = 0;
 499                         }
 500                         if (!self.BUTTON_ATCK)
 501                                 self.rl_release = 1;
 502                         if (self.BUTTON_ATCK2)
 503                         if(self.exteriorweaponentity.attack_finished_single < time)
 504                         {
 505                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 506                                 self.laser_on = !self.laser_on;
 507                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 508                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 509                         }
 510                 }
 511                 else
 512                 {
 513                         if (self.BUTTON_ATCK)
 514                         {
 515                                 if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 516                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 517                                 {
 518                                         W_Rocket_Attack();
 519                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 520                                         self.rl_release = 0;
 521                                 }
 522                         }
 523                         else
 524                                 self.rl_release = 1;
 525
 526                         if (self.BUTTON_ATCK2)
 527                         {
 528                                 rockfound = 0;
 529                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 530                                 {
 531                                         if(!rock.rl_detonate_later)
 532                                         {
 533                                                 rock.rl_detonate_later = TRUE;
 534                                                 rockfound = 1;
 535                                         }
 536                                 }
 537                                 if(rockfound)
 538                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 539                         }
 540                 }
 541         }
 542         else if (req == WR_PRECACHE)
 543         {
 544                 precache_model ("models/flash.md3");
 545                 precache_model ("models/weapons/g_rl.md3");
 546                 precache_model ("models/weapons/v_rl.md3");
 547                 precache_model ("models/weapons/h_rl.iqm");
 548                 precache_sound ("weapons/rocket_det.wav");
 549                 precache_sound ("weapons/rocket_fire.wav");
 550                 precache_sound ("weapons/rocket_mode.wav");
 551                 if (g_laserguided_missile)
 552                 {
 553                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 554                 }
 555         }
 556         else if (req == WR_SETUP)
 557         {
 558                 weapon_setup(WEP_ROCKET_LAUNCHER);
 559                 self.rl_release = 1;
 560         }
 561         else if (req == WR_CHECKAMMO1)
 562         {
 563                 // don't switch while guiding a missile
 564                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 565                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 566                         return FALSE;
 567         }
 568         else if (req == WR_CHECKAMMO2)
 569                 return FALSE;
 570         else if (req == WR_RESETPLAYER)
 571         {
 572                 self.rl_release = 0;
 573         }
 574         return TRUE;
 575 };
 576 #endif
 577 #ifdef CSQC
 578 float w_rlauncher(float req)
 579 {
 580         if(req == WR_IMPACTEFFECT)
 581         {
 582                 vector org2;
 583                 org2 = w_org + w_backoff * 12;
 584                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 585                 if(!w_issilent)
 586                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 587         }
 588         else if(req == WR_PRECACHE)
 589         {
 590                 precache_sound("weapons/rocket_impact.wav");
 591         }
 592         else if (req == WR_SUICIDEMESSAGE)
 593                 w_deathtypestring = "%s exploded";
 594         else if (req == WR_KILLMESSAGE)
 595         {
 596                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 597                         w_deathtypestring = "%s got too close to %s's rocket";
 598                 else if(w_deathtype & HITTYPE_SPLASH)
 599                         w_deathtypestring = "%s almost dodged %s's rocket";
 600                 else
 601                         w_deathtypestring = "%s ate %s's rocket";
 602         }
 603         return TRUE;
 604 }
 605 #endif
 606 #endif