qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  18         bullets = autocvar_g_balance_shotgun_primary_bullets;
  19         d = autocvar_g_balance_shotgun_primary_damage;
  20         f = autocvar_g_balance_shotgun_primary_force;
  21         spread = autocvar_g_balance_shotgun_primary_spread;
  22         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  23         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  24
  25         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  26         for (sc = 0;sc < bullets;sc = sc + 1)
  27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  28         endFireBallisticBullet();
  29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  30                 self.ammo_shells = self.ammo_shells - ammoamount;
  31
  32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  33
  34         // casing code
  35         if (autocvar_g_casings >= 1)
  36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  38
  39         // muzzle flash for 1st person view
  40         flash = spawn();
  41         setmodel(flash, "models/uziflash.md3"); // precision set below
  42         flash.think = SUB_Remove;
  43         flash.nextthink = time + 0.06;
  44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  45         W_AttachToShotorg(flash, '5 0 0');
  46
  47 }
  48
  49 void shotgun_meleethink (void)
  50 {
  51         // store time when we started swinging down inside self.cnt
  52         if(!self.cnt)
  53                 self.cnt = time;
  54
  55         makevectors(self.owner.v_angle);
  56         vector angle;
  57         angle = v_forward;
  58
  59         float meleetime;
  60         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  61
  62         // perform trace
  63         float f;
  64         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  65         vector targpos;
  66         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  67
  68         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  69
  70         // apply the damage, also remove self
  71         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  72         {
  73                 vector force;
  74                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  75                 if(accuracy_isgooddamage(self.owner, trace_ent))
  76                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  77                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  78                 remove(self);
  79         }
  80         else if(time >= self.cnt + meleetime) // missed, remove ent
  81                 remove(self);
  82         else // continue swinging the weapon in hope of hitting someone :)
  83                 self.nextthink = time;
  84 }
  85
  86 void W_Shotgun_Attack2 (void)
  87 {
  88         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  89         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
  90
  91         entity meleetemp;
  92         meleetemp = spawn();
  93         meleetemp.owner = self;
  94         meleetemp.think = shotgun_meleethink;
  95         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
  96         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
  97 }
  98
  99 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 100
 101 .float shotgun_primarytime;
 102
 103 float w_shotgun(float req)
 104 {
 105         if (req == WR_AIM)
 106                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 107                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 108                 else
 109                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 110         else if (req == WR_THINK)
 111         {
 112                 if (self.BUTTON_ATCK)
 113                 {
 114                         if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 115                         {
 116                                 if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 117                                 {
 118                                         W_Shotgun_Attack();
 119                                         self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 120                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 121                                 }
 122                         }
 123                 }
 124                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 125                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 126                 {
 127                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 128                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 129                 }
 130         }
 131         else if (req == WR_PRECACHE)
 132         {
 133                 precache_model ("models/uziflash.md3");
 134                 precache_model ("models/weapons/g_shotgun.md3");
 135                 precache_model ("models/weapons/v_shotgun.md3");
 136                 precache_model ("models/weapons/h_shotgun.iqm");
 137                 precache_sound ("misc/itempickup.wav");
 138                 precache_sound ("weapons/shotgun_fire.wav");
 139                 precache_sound ("weapons/shotgun_melee.wav");
 140         }
 141         else if (req == WR_SETUP)
 142                 weapon_setup(WEP_SHOTGUN);
 143         else if (req == WR_CHECKAMMO1)
 144                 return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 145         else if (req == WR_CHECKAMMO2)
 146         {
 147                 return TRUE;
 148         }
 149         return TRUE;
 150 };
 151 #endif
 152 #ifdef CSQC
 153 .float prevric;
 154 float w_shotgun(float req)
 155 {
 156         if(req == WR_IMPACTEFFECT)
 157         {
 158                 vector org2;
 159                 org2 = w_org + w_backoff * 2;
 160                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 161                 if(!w_issilent && time - self.prevric > 0.25)
 162                 {
 163                         if(w_random < 0.0165)
 164                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 165                         else if(w_random < 0.033)
 166                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 167                         else if(w_random < 0.05)
 168                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 169                         self.prevric = time;
 170                 }
 171         }
 172         else if(req == WR_PRECACHE)
 173         {
 174                 precache_sound("weapons/ric1.wav");
 175                 precache_sound("weapons/ric2.wav");
 176                 precache_sound("weapons/ric3.wav");
 177         }
 178         else if (req == WR_SUICIDEMESSAGE)
 179                 w_deathtypestring = "%s did the impossible";
 180         else if (req == WR_KILLMESSAGE)
 181         {
 182                 if(w_deathtype & HITTYPE_SECONDARY)
 183                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 184                 else
 185                         w_deathtypestring = "%s was gunned by %s";
 186         }
 187         return TRUE;
 188 }
 189 #endif
 190 #endif