qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SHOTGUN,
   4 /* function  */ w_shotgun,
   5 /* ammotype  */ IT_SHELLS,
   6 /* impulse   */ 2,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_LOW,
   9 /* model     */ "shotgun",
  10 /* shortname */ "shotgun",
  11 /* fullname  */ _("Shotgun")
  12 );
  13 #else
  14 #ifdef SVQC
  15
  16 void W_Shotgun_Attack (void)
  17 {
  18         float   sc;
  19         float   ammoamount;
  20         float   bullets;
  21         float   d;
  22         float   f;
  23         float   spread;
  24         float   bulletspeed;
  25         float   bulletconstant;
  26         entity flash;
  27
  28         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  29         bullets = autocvar_g_balance_shotgun_primary_bullets;
  30         d = autocvar_g_balance_shotgun_primary_damage;
  31         f = autocvar_g_balance_shotgun_primary_force;
  32         spread = autocvar_g_balance_shotgun_primary_spread;
  33         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  34         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  35
  36         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  37
  38         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  39         for (sc = 0;sc < bullets;sc = sc + 1)
  40                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  41         endFireBallisticBullet();
  42
  43         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  44
  45         // casing code
  46         if (autocvar_g_casings >= 1)
  47                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  48                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  49
  50         // muzzle flash for 1st person view
  51         flash = spawn();
  52         setmodel(flash, "models/uziflash.md3"); // precision set below
  53         flash.think = SUB_Remove;
  54         flash.nextthink = time + 0.06;
  55         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  56         W_AttachToShotorg(flash, '5 0 0');
  57 }
  58
  59 .float swing_prev;
  60 .entity swing_alreadyhit;
  61 void shotgun_meleethink (void)
  62 {
  63         // declarations
  64         float i, f, swing, swing_factor, swing_damage, meleetime, is_player, is_monster;
  65         entity target_victim;
  66         vector targpos;
  67
  68         if(!self.cnt) // set start time of melee
  69         {
  70                 self.cnt = time;
  71                 W_PlayStrengthSound(self.realowner);
  72         }
  73
  74         makevectors(self.realowner.v_angle); // update values for v_* vectors
  75
  76         // calculate swing percentage based on time
  77         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  78         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
  79         f = ((1 - swing) * autocvar_g_balance_shotgun_secondary_melee_traces);
  80
  81         // check to see if we can still continue, otherwise give up now
  82         if((self.realowner.deadflag != DEAD_NO) && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)
  83         {
  84                 remove(self);
  85                 return;
  86         }
  87
  88         // if okay, perform the traces needed for this frame
  89         for(i=self.swing_prev; i < f; ++i)
  90         {
  91                 swing_factor = ((1 - (i / autocvar_g_balance_shotgun_secondary_melee_traces)) * 2 - 1);
  92
  93                 targpos = (self.realowner.origin + self.realowner.view_ofs
  94                         + (v_forward * autocvar_g_balance_shotgun_secondary_melee_range)
  95                         + (v_up * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_up)
  96                         + (v_right * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_side));
  97
  98                 WarpZone_traceline_antilag(self, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self, ANTILAG_LATENCY(self.realowner));
  99
 100                 // draw lightning beams for debugging
 101                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 102                 //te_customflash(targpos, 40,  2, '1 1 1');
 103
 104                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body");
 105                 is_monster = (trace_ent.flags & FL_MONSTER);
 106
 107                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 108                         && (trace_ent.takedamage == DAMAGE_AIM)
 109                         && (trace_ent != self.swing_alreadyhit)
 110                         && ((is_player || is_monster) || autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage))
 111                 {
 112                         target_victim = trace_ent; // so it persists through other calls
 113
 114                         if(is_player || is_monster) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 115                                 swing_damage = (autocvar_g_balance_shotgun_secondary_damage * min(1, swing_factor + 1));
 116                         else
 117                                 swing_damage = (autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage * min(1, swing_factor + 1));
 118
 119                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 120
 121                         Damage(target_victim, self.realowner, self.realowner,
 122                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 123                                 self.realowner.origin + self.realowner.view_ofs,
 124                                 v_forward * autocvar_g_balance_shotgun_secondary_force);
 125
 126                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage); }
 127
 128                         // draw large red flash for debugging
 129                         //te_customflash(targpos, 200, 2, '15 0 0');
 130
 131                         if(autocvar_g_balance_shotgun_secondary_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 132                         {
 133                                 self.swing_alreadyhit = target_victim;
 134                                 continue; // move along to next trace
 135                         }
 136                         else
 137                         {
 138                                 remove(self);
 139                                 return;
 140                         }
 141                 }
 142         }
 143
 144         if(time >= self.cnt + meleetime)
 145         {
 146                 // melee is finished
 147                 remove(self);
 148                 return;
 149         }
 150         else
 151         {
 152                 // set up next frame
 153                 self.swing_prev = i;
 154                 self.nextthink = time;
 155         }
 156 }
 157
 158 void W_Shotgun_Attack2 (void)
 159 {
 160         sound (self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTEN_NORM);
 161         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 162
 163         entity meleetemp;
 164         meleetemp = spawn();
 165         meleetemp.realowner = self;
 166         meleetemp.think = shotgun_meleethink;
 167         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay * W_WeaponRateFactor();
 168         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 169 }
 170
 171 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 172
 173 .float shotgun_primarytime;
 174
 175 float w_shotgun(float req)
 176 {
 177         float ammo_amount;
 178         if (req == WR_AIM)
 179                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 180                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 181                 else
 182                 {
 183                         if(autocvar_g_antilag_bullets)
 184                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 185                         else
 186                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_shotgun_primary_speed, 0, 0.001, FALSE);
 187                 }
 188
 189         else if (req == WR_THINK)
 190         {
 191                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 192                 {
 193                         // don't force reload an empty shotgun if its melee attack is active
 194                         if (!(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo))
 195                                 weapon_action(self.weapon, WR_RELOAD);
 196                 }
 197                 else
 198                 {
 199                         if (self.BUTTON_ATCK)
 200                         {
 201                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 202                                 {
 203                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 204                                         {
 205                                                 W_Shotgun_Attack();
 206                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire * W_WeaponRateFactor();
 207                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 208                                         }
 209                                 }
 210                         }
 211                 }
 212                 if (self.clip_load >= 0) // we are not currently reloading
 213                 if (!self.crouch) // no crouchmelee please
 214                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 215                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 216                 {
 217                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 218                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 219                 }
 220         }
 221         else if (req == WR_PRECACHE)
 222         {
 223                 precache_model ("models/uziflash.md3");
 224                 precache_model ("models/weapons/g_shotgun.md3");
 225                 precache_model ("models/weapons/v_shotgun.md3");
 226                 precache_model ("models/weapons/h_shotgun.iqm");
 227                 precache_sound ("misc/itempickup.wav");
 228                 precache_sound ("weapons/shotgun_fire.wav");
 229                 precache_sound ("weapons/shotgun_melee.wav");
 230                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 231         }
 232         else if (req == WR_SETUP)
 233         {
 234                 weapon_setup(WEP_SHOTGUN);
 235                 self.current_ammo = ammo_shells;
 236         }
 237         else if (req == WR_CHECKAMMO1)
 238         {
 239                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 240                 ammo_amount += self.(weapon_load[WEP_SHOTGUN]) >= autocvar_g_balance_shotgun_primary_ammo;
 241                 return ammo_amount;
 242         }
 243         else if (req == WR_CHECKAMMO2)
 244         {
 245                 // melee attack is always available
 246                 return TRUE;
 247         }
 248         else if (req == WR_RELOAD)
 249         {
 250                 W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 251         }
 252         else if (req == WR_SUICIDEMESSAGE)
 253         {
 254                 return WEAPON_THINKING_WITH_PORTALS;
 255         }
 256         else if (req == WR_KILLMESSAGE)
 257         {
 258                 if(w_deathtype & HITTYPE_SECONDARY)
 259                         return WEAPON_SHOTGUN_MURDER_SLAP;
 260                 else
 261                         return WEAPON_SHOTGUN_MURDER;
 262         }
 263         return TRUE;
 264 }
 265 #endif
 266 #ifdef CSQC
 267 .float prevric;
 268 float w_shotgun(float req)
 269 {
 270         if(req == WR_IMPACTEFFECT)
 271         {
 272                 vector org2;
 273                 org2 = w_org + w_backoff * 2;
 274                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 275                 if(!w_issilent && time - self.prevric > 0.25)
 276                 {
 277                         if(w_random < 0.0165)
 278                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTEN_NORM);
 279                         else if(w_random < 0.033)
 280                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTEN_NORM);
 281                         else if(w_random < 0.05)
 282                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTEN_NORM);
 283                         self.prevric = time;
 284                 }
 285         }
 286         else if(req == WR_PRECACHE)
 287         {
 288                 precache_sound("weapons/ric1.wav");
 289                 precache_sound("weapons/ric2.wav");
 290                 precache_sound("weapons/ric3.wav");
 291         }
 292         return TRUE;
 293 }
 294 #endif
 295 #endif